lisp/autorevert.el

   1 ;;; autorevert.el --- revert buffers when files on disk change
   2
   3 ;; Copyright (C) 1997, 1998, 1999, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Anders Lindgren <andersl@andersl.com>
   6 ;; Keywords: convenience
   7 ;; Created: 1997-06-01
   8 ;; Date: 1999-11-30
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Introduction:
  30 ;;
  31 ;; Whenever a file that Emacs is editing has been changed by another
  32 ;; program the user normally has to execute the command `revert-buffer'
  33 ;; to load the new content of the file into Emacs.
  34 ;;
  35 ;; This package contains two minor modes: Global Auto-Revert Mode and
  36 ;; Auto-Revert Mode.  Both modes automatically revert buffers
  37 ;; whenever the corresponding files have been changed on disk.
  38 ;;
  39 ;; Auto-Revert Mode can be activated for individual buffers.
  40 ;; Global Auto-Revert Mode applies to all file buffers.
  41 ;;
  42 ;; Both modes operate by checking the time stamp of all files at
  43 ;; intervals of `auto-revert-interval'.  The default is every five
  44 ;; seconds.  The check is aborted whenever the user actually uses
  45 ;; Emacs.  You should never even notice that this package is active
  46 ;; (except that your buffers will be reverted, of course).
  47
  48 ;; Usage:
  49 ;;
  50 ;; Go to the appropriate buffer and press:
  51 ;;   M-x auto-revert-mode RET
  52 ;;
  53 ;; To activate Global Auto-Revert Mode, press:
  54 ;;   M-x global-auto-revert-mode RET
  55 ;;
  56 ;; To activate Global Auto-Revert Mode every time Emacs is started
  57 ;; customise the option `global-auto-revert-mode' or the following
  58 ;; line could be added to your ~/.emacs:
  59 ;;   (global-auto-revert-mode 1)
  60 ;;
  61 ;; The function `turn-on-auto-revert-mode' could be added to any major
  62 ;; mode hook to activate Auto-Revert Mode for all buffers in that
  63 ;; mode.  For example, the following line will activate Auto-Revert
  64 ;; Mode in all C mode buffers:
  65 ;;
  66 ;; (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)
  67
  68 ;;; Code:
  69
  70 ;; Dependencies:
  71
  72 (require 'timer)
  73 (autoload 'dired-get-filename "dired")
  74 (autoload 'vc-workfile-version "vc-hooks")
  75 (autoload 'vc-mode-line        "vc-hooks")
  76
  77 (eval-when-compile
  78   (defvar dired-directory)
  79   (defvar vc-mode)
  80   (require 'cl))
  81
  82
  83 ;; Custom Group:
  84 ;;
  85 ;; The two modes will be placed next to Auto Save Mode under the
  86 ;; Files group under Emacs.
  87
  88 (defgroup auto-revert nil
  89   "Revert individual buffers when files on disk change.
  90
  91 Auto-Revert Mode can be activated for individual buffer.
  92 Global Auto-Revert Mode applies to all buffers."
  93   :group 'files
  94   :group 'convenience)
  95
  96
  97 ;; Variables:
  98
  99 ;; Autoload for the benefit of `make-mode-line-mouse-sensitive'.
 100 ;;;###autoload
 101 (defvar auto-revert-mode nil
 102   "*Non-nil when Auto-Revert Mode is active.
 103 Never set this variable directly, use the command `auto-revert-mode' instead.")
 104 (put 'auto-revert-mode 'permanent-local t)
 105
 106 (defvar auto-revert-timer nil
 107   "Timer used by Auto-Revert Mode.")
 108
 109 (defcustom auto-revert-interval 5
 110   "Time, in seconds, between Auto-Revert Mode file checks.
 111 The value may be an integer or floating point number.
 112
 113 If a timer is already active, there are two ways to make sure
 114 that the new value will take effect immediately.  You can set
 115 this variable through Custom or you can call the command
 116 `auto-revert-set-timer' after setting the variable.  Otherwise,
 117 the new value will take effect the first time Auto Revert Mode
 118 calls `auto-revert-set-timer' for internal reasons or in your
 119 next editing session."
 120   :group 'auto-revert
 121   :type 'number
 122   :set (lambda (variable value)
 123          (set-default variable value)
 124          (and (boundp 'auto-revert-timer)
 125               auto-revert-timer
 126               (auto-revert-set-timer))))
 127
 128 (defcustom auto-revert-stop-on-user-input t
 129   "When non-nil Auto-Revert Mode stops checking files on user input."
 130   :group 'auto-revert
 131   :type 'boolean)
 132
 133 (defcustom auto-revert-verbose t
 134   "When nil, Auto-Revert Mode will not generate any messages.
 135
 136 Currently, messages are generated when the mode is activated or
 137 deactivated, and whenever a file is reverted."
 138   :group 'auto-revert
 139   :type 'boolean)
 140
 141 (defcustom auto-revert-mode-text " ARev"
 142   "String to display in the mode line when Auto-Revert Mode is active.
 143
 144 \(When the string is not empty, make sure that it has a leading space.)"
 145   :tag "Auto Revert Mode Text"          ; To separate it from `global-...'
 146   :group 'auto-revert
 147   :type 'string)
 148
 149 (defcustom auto-revert-mode-hook nil
 150   "Functions to run when Auto-Revert Mode is activated."
 151   :tag "Auto Revert Mode Hook"          ; To separate it from `global-...'
 152   :group 'auto-revert
 153   :type 'hook)
 154
 155 (defcustom global-auto-revert-mode-text ""
 156   "String to display when Global Auto-Revert Mode is active.
 157
 158 The default is nothing since when this mode is active this text doesn't
 159 vary over time, or between buffers.  Hence mode line text
 160 would only waste precious space."
 161   :group 'auto-revert
 162   :type 'string)
 163
 164 (defcustom global-auto-revert-mode-hook nil
 165   "Hook called when Global Auto-Revert Mode is activated."
 166   :group 'auto-revert
 167   :type 'hook)
 168
 169 (defcustom global-auto-revert-non-file-buffers nil
 170   "When nil only file buffers are reverted by Global Auto-Revert Mode.
 171
 172 When non-nil, both file buffers and buffers with a custom
 173 `revert-buffer-function' are reverted by Global Auto-Revert Mode.
 174
 175 Use this option with care since it could lead to excessive reverts.
 176 Note also that for some non-file buffers the check whether the
 177 buffer needs updating may be imperfect, due to efficiency
 178 considerations, and may not take all information listed in the
 179 buffer into account.  Hence, a non-nil value for this option does
 180 not necessarily make manual updates useless for non-file buffers."
 181   :group 'auto-revert
 182   :type 'boolean)
 183
 184 (defcustom global-auto-revert-ignore-modes '()
 185   "List of major modes Global Auto-Revert Mode should not check."
 186   :group 'auto-revert
 187   :type '(repeat sexp))
 188
 189 (defcustom auto-revert-load-hook nil
 190   "Functions to run when Auto-Revert Mode is first loaded."
 191   :tag "Load Hook"
 192   :group 'auto-revert
 193   :type 'hook)
 194
 195 (defvar global-auto-revert-ignore-buffer nil
 196   "*When non-nil, Global Auto-Revert Mode will not revert this buffer.
 197
 198 This variable becomes buffer local when set in any fashion.")
 199 (make-variable-buffer-local 'global-auto-revert-ignore-buffer)
 200
 201 (defvar buffer-stale-function nil
 202   "Function to check whether a non-file buffer needs reverting.
 203 This should be a function with one optional argument NOCONFIRM.
 204 Auto Revert Mode sets NOCONFIRM to t.  The function should return
 205 non-nil if the buffer should be reverted.  The buffer is current
 206 when this function is called.
 207
 208 The idea behind the NOCONFIRM argument is that the same function
 209 can also be used to ask the user whether the buffer should be
 210 reverted.  In such a situation one has to be less careful about,
 211 say, reverting remote files, than if the function is called at
 212 regular intervals by Auto Revert Mode.")
 213
 214 ;; Internal variables:
 215
 216 (defvar auto-revert-buffer-list '()
 217   "List of buffers in Auto-Revert Mode.
 218
 219 Note that only Auto-Revert Mode, never Global Auto-Revert Mode, adds
 220 buffers to this list.
 221
 222 The timer function `auto-revert-buffers' is responsible for purging
 223 the list of old buffers.")
 224
 225 (defvar auto-revert-remaining-buffers '()
 226   "Buffers not checked when user input stopped execution.")
 227
 228
 229 ;; Functions:
 230
 231 ;;;###autoload
 232 (define-minor-mode auto-revert-mode
 233   "Toggle reverting buffer when file on disk changes.
 234
 235 With arg, turn Auto Revert mode on if and only if arg is positive.
 236 This is a minor mode that affects only the current buffer.
 237 Use `global-auto-revert-mode' to automatically revert all buffers."
 238   nil auto-revert-mode-text nil
 239   (if auto-revert-mode
 240       (if (not (memq (current-buffer) auto-revert-buffer-list))
 241           (push (current-buffer) auto-revert-buffer-list))
 242     (setq auto-revert-buffer-list
 243           (delq (current-buffer) auto-revert-buffer-list)))
 244   (auto-revert-set-timer)
 245   (when auto-revert-mode
 246     (auto-revert-buffers)))
 247
 248
 249 ;;;###autoload
 250 (defun turn-on-auto-revert-mode ()
 251   "Turn on Auto-Revert Mode.
 252
 253 This function is designed to be added to hooks, for example:
 254   (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)"
 255   (auto-revert-mode 1))
 256
 257
 258 ;;;###autoload
 259 (define-minor-mode global-auto-revert-mode
 260   "Revert any buffer when file on disk change.
 261
 262 With arg, turn Auto Revert mode on globally if and only if arg is positive.
 263 This is a minor mode that affects all buffers.
 264 Use `auto-revert-mode' to revert a particular buffer."
 265   :global t :group 'auto-revert :lighter global-auto-revert-mode-text
 266   (auto-revert-set-timer)
 267   (when global-auto-revert-mode
 268     (auto-revert-buffers)))
 269
 270
 271 (defun auto-revert-set-timer ()
 272   "Restart or cancel the timer."
 273   (interactive)
 274   (if (timerp auto-revert-timer)
 275       (cancel-timer auto-revert-timer))
 276   (setq auto-revert-timer
 277         (if (or global-auto-revert-mode auto-revert-buffer-list)
 278             (run-with-timer auto-revert-interval
 279                             auto-revert-interval
 280                             'auto-revert-buffers)
 281           nil)))
 282
 283 (defun auto-revert-active-p ()
 284   "Check if auto-revert is active (in current buffer or globally)."
 285   (or auto-revert-mode
 286       (and
 287        global-auto-revert-mode
 288        (not global-auto-revert-ignore-buffer)
 289        (not (memq major-mode
 290                   global-auto-revert-ignore-modes)))))
 291
 292 (defun auto-revert-vc-cvs-file-version (file)
 293   "Get version of FILE by reading control file on disk."
 294   (let* ((control "CVS/Entries")
 295          (name    (file-name-nondirectory file))
 296          (path    (format "%s/%s"
 297                           (file-name-directory file)
 298                           control)))
 299     (when (file-exists-p path)
 300       (with-temp-buffer
 301         (insert-file-contents-literally path)
 302         (goto-char (point-min))
 303         (when (re-search-forward
 304                ;; /file.txt/1.3/Mon Sep 15 18:43:20 2003//
 305                (format "%s/\\([.0-9]+\\)" (regexp-quote name))
 306                nil t)
 307           (match-string 1))))))
 308
 309 (defun auto-revert-vc-buffer-p ()
 310   "Check if buffer is version controlled."
 311   (and (boundp 'vc-mode)
 312        (string-match "[0-9]" (or vc-mode ""))))
 313
 314 (defun auto-revert-handler-vc ()
 315   "Check if version controlled buffer needs revert."
 316   ;; [Emacs 1]
 317   ;; 1. File is saved     (*)
 318   ;; 2. checkin is done 1.1 -> 1.2
 319   ;; 3. VC reverts, so that updated version number is shown in mode line
 320   ;;
 321   ;; Suppose the same file has been opened in another Emacs and
 322   ;; autorevert.el is on.
 323   ;;
 324   ;; [Emacs 2]
 325   ;; 1. Step (1) is detected and buffer is reverted.
 326   ;; 2. But check in does not always change the file in dis, but possibly only
 327   ;;    control files like CVS/Entries
 328   ;; 3. The buffer is not reverted to update VC version line.
 329   ;;    Incorrect version number 1.1 is shown in this Emacs
 330   ;;
 331   (when (featurep 'vc)
 332     (let* ((file           (buffer-file-name))
 333            (backend        (vc-backend (buffer-file-name)))
 334            (version-buffer (vc-workfile-version file)))
 335       (when (stringp version-buffer)
 336         (cond
 337          ((eq backend 'CVS)
 338           (let ((version-file
 339                  (auto-revert-vc-cvs-file-version (buffer-file-name))))
 340             (and (stringp version-file)
 341                  (not (string-match version-file version-buffer)))))
 342          ((eq backend 'RCS)
 343           ;; TODO:
 344           ))))))
 345
 346 (defun auto-revert-handler ()
 347   "Revert current buffer."
 348   (unless (buffer-modified-p)
 349     (let (revert)
 350       (cond
 351        ((auto-revert-vc-buffer-p)
 352         (when (auto-revert-handler-vc)
 353           (setq revert 'vc)))
 354        ((or (and (buffer-file-name)
 355                  (file-readable-p (buffer-file-name))
 356                  (not (verify-visited-file-modtime (current-buffer))))
 357             (and global-auto-revert-non-file-buffers
 358                  revert-buffer-function
 359                  (boundp 'buffer-stale-function)
 360                  (functionp buffer-stale-function)
 361                  (funcall buffer-stale-function t)))
 362         (setq revert t)))
 363       (when revert
 364         (revert-buffer 'ignore-auto 'dont-ask 'preserve-modes)
 365         (if (eq revert 'vc)
 366             (vc-mode-line buffer-file-name))
 367         (if auto-revert-verbose
 368             (message "Reverting buffer `%s'." (buffer-name)))))))
 369
 370 (defun auto-revert-buffers ()
 371   "Revert buffers as specified by Auto-Revert and Global Auto-Revert Mode.
 372
 373 Should `global-auto-revert-mode' be active all file buffers are checked.
 374
 375 Should `auto-revert-mode' be active in some buffers, those buffers
 376 are checked.
 377
 378 Non-file buffers that have a custom `revert-buffer-function' are
 379 reverted either when Auto-Revert Mode is active in that buffer, or
 380 when the variable `global-auto-revert-non-file-buffers' is non-nil
 381 and Global Auto-Revert Mode is active.
 382
 383 This function stops whenever there is user input.  The buffers not
 384 checked are stored in the variable `auto-revert-remaining-buffers'.
 385
 386 To avoid starvation, the buffers in `auto-revert-remaining-buffers'
 387 are checked first the next time this function is called.
 388
 389 This function is also responsible for removing buffers no longer in
 390 Auto-Revert mode from `auto-revert-buffer-list', and for canceling
 391 the timer when no buffers need to be checked."
 392   (let ((bufs (if global-auto-revert-mode
 393                   (buffer-list)
 394                 auto-revert-buffer-list))
 395         (remaining '())
 396         (new '()))
 397     ;; Partition `bufs' into two halves depending on whether or not
 398     ;; the buffers are in `auto-revert-remaining-buffers'.  The two
 399     ;; halves are then re-joined with the "remaining" buffers at the
 400     ;; head of the list.
 401     (dolist (buf auto-revert-remaining-buffers)
 402       (if (memq buf bufs)
 403           (push buf remaining)))
 404     (dolist (buf bufs)
 405       (if (not (memq buf remaining))
 406           (push buf new)))
 407     (setq bufs (nreverse (nconc new remaining)))
 408     (while (and bufs
 409                 (not (and auto-revert-stop-on-user-input
 410                           (input-pending-p))))
 411       (let ((buf (car bufs)))
 412         (if (buffer-name buf)           ; Buffer still alive?
 413             (with-current-buffer buf
 414               ;; Test if someone has turned off Auto-Revert Mode in a
 415               ;; non-standard way, for example by changing major mode.
 416               (if (and (not auto-revert-mode)
 417                        (memq buf auto-revert-buffer-list))
 418                   (setq auto-revert-buffer-list
 419                         (delq buf auto-revert-buffer-list)))
 420               (when (auto-revert-active-p)
 421                 (auto-revert-handler)
 422                 ;; `preserve-modes' avoids changing the (minor) modes.  But we
 423                 ;; do want to reset the mode for VC, so we do it explicitly.
 424                 (vc-find-file-hook)))
 425           ;; Remove dead buffer from `auto-revert-buffer-list'.
 426           (setq auto-revert-buffer-list
 427                 (delq buf auto-revert-buffer-list))))
 428       (setq bufs (cdr bufs)))
 429     (setq auto-revert-remaining-buffers bufs)
 430     ;; Check if we should cancel the timer.
 431     (when (and (not global-auto-revert-mode)
 432                (null auto-revert-buffer-list))
 433       (cancel-timer auto-revert-timer)
 434       (setq auto-revert-timer nil))))
 435
 436
 437 ;; The end:
 438 (provide 'autorevert)
 439
 440 (run-hooks 'auto-revert-load-hook)
 441
 442 ;;; arch-tag: f6bcb07b-4841-477e-9e44-b18678e58876
 443 ;;; autorevert.el ends here