lisp/textmodes/reftex-dcr.el

   1 ;;; reftex-dcr.el --- viewing cross references and citations with RefTeX
   2
   3 ;; Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Carsten Dominik <dominik@science.uva.nl>
   7 ;; Maintainer: auctex-devel@gnu.org
   8 ;; Version: 4.31
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30 (provide 'reftex-dcr)
  31 (provide 'reftex-vcr)
  32 (require 'reftex)
  33 ;;;
  34
  35 (defun reftex-view-crossref (&optional arg auto-how fail-quietly)
  36   "View cross reference of macro at point.  Point must be on the KEY
  37 argument.  When at at `\\ref' macro, show corresponding `\\label'
  38 definition, also in external documents (`xr').  When on a label, show
  39 a locations where KEY is referenced.  Subsequent calls find additional
  40 locations.  When on a `\\cite', show the associated `\\bibitem' macro or
  41 the BibTeX database entry.  When on a `\\bibitem', show a `\\cite' macro
  42 which uses this KEY. When on an `\\index', show other locations marked
  43 by the same index entry.
  44 To define additional cross referencing items, use the option
  45 `reftex-view-crossref-extra'.  See also `reftex-view-crossref-from-bibtex'.
  46 With one or two C-u prefixes, enforce rescanning of the document.
  47 With argument 2, select the window showing the cross reference.
  48 AUTO-HOW is only for the automatic crossref display and is handed through
  49 to the functions `reftex-view-cr-cite' and `reftex-view-cr-ref'."
  50
  51   (interactive "P")
  52   ;; See where we are.
  53   (let* ((macro (car (reftex-what-macro-safe 1)))
  54          (key (reftex-this-word "^{}%\n\r, \t"))
  55          dw)
  56
  57     (if (or (null macro) (reftex-in-comment))
  58         (or fail-quietly
  59             (error "Not on a crossref macro argument"))
  60
  61       (setq reftex-call-back-to-this-buffer (current-buffer))
  62
  63       (cond
  64        ((string-match "\\`\\\\cite\\|cite\\*?\\'\\|bibentry" macro)
  65         ;; A citation macro: search for bibitems or BibTeX entries
  66         (setq dw (reftex-view-cr-cite arg key auto-how)))
  67        ((string-match "\\`\\\\ref\\|ref\\(range\\)?\\*?\\'" macro)
  68         ;; A reference macro: search for labels
  69         (setq dw (reftex-view-cr-ref arg key auto-how)))
  70        (auto-how nil)  ;; No further action for automatic display (speed)
  71        ((or (equal macro "\\label")
  72             (member macro reftex-macros-with-labels))
  73         ;; A label macro: search for reference macros
  74         (reftex-access-scan-info arg)
  75         (setq dw (reftex-view-regexp-match
  76                   (format reftex-find-reference-format (regexp-quote key))
  77                   4 nil nil)))
  78        ((equal macro "\\bibitem")
  79         ;; A bibitem macro: search for citations
  80         (reftex-access-scan-info arg)
  81         (setq dw (reftex-view-regexp-match
  82                   (format reftex-find-citation-regexp-format (regexp-quote key))
  83                   4 nil nil)))
  84        ((member macro reftex-macros-with-index)
  85         (reftex-access-scan-info arg)
  86         (setq dw (reftex-view-regexp-match
  87                   (format reftex-find-index-entry-regexp-format
  88                           (regexp-quote key))
  89                   3 nil nil)))
  90        (t
  91         (reftex-access-scan-info arg)
  92         (catch 'exit
  93           (let ((list reftex-view-crossref-extra)
  94                 entry mre action group)
  95             (while (setq entry (pop list))
  96               (setq mre (car entry)
  97                     action (nth 1 entry)
  98                     group (nth 2 entry))
  99               (when (string-match mre macro)
 100                 (setq dw (reftex-view-regexp-match
 101                           (format action key) group nil nil))
 102                 (throw 'exit t))))
 103           (error "Not on a crossref macro argument"))))
 104       (if (and (eq arg 2) (windowp dw)) (select-window dw)))))
 105
 106 (defun reftex-view-cr-cite (arg key how)
 107   ;; View crossreference of a ref cite.  HOW can have the values
 108   ;; nil:         Show in another window.
 109   ;; echo:        Show one-line info in echo area.
 110   ;; tmp-window:  Show in small window and arrange for window to disappear.
 111
 112   ;; Ensure access to scanning info
 113   (reftex-access-scan-info (or arg current-prefix-arg))
 114
 115   (if (eq how 'tmp-window)
 116       ;; Remember the window configuration
 117       (put 'reftex-auto-view-crossref 'last-window-conf
 118            (current-window-configuration)))
 119
 120   (let (files size item (pos (point)) (win (selected-window)) pop-win
 121               (bibtype (reftex-bib-or-thebib)))
 122     ;; Find the citation mode and the file list
 123     (cond
 124 ;     ((assq 'bib (symbol-value reftex-docstruct-symbol))
 125      ((eq bibtype 'bib)
 126       (setq item nil
 127             files (reftex-get-bibfile-list)))
 128 ;     ((assq 'thebib (symbol-value reftex-docstruct-symbol))
 129      ((eq bibtype 'thebib)
 130       (setq item t
 131             files (reftex-uniquify
 132                    (mapcar 'cdr
 133                            (reftex-all-assq
 134                             'thebib (symbol-value reftex-docstruct-symbol))))))
 135      (reftex-default-bibliography
 136       (setq item nil
 137             files (reftex-default-bibliography)))
 138      (how)  ;; don't throw for special display
 139      (t (error "Cannot display crossref")))
 140
 141     (if (eq how 'echo)
 142         ;; Display in Echo area
 143         (reftex-echo-cite key files item)
 144       ;; Display in a window
 145       (if (not (eq how 'tmp-window))
 146           ;; Normal display
 147           (reftex-pop-to-bibtex-entry key files nil t item)
 148         ;; A temporary window
 149         (condition-case nil
 150             (reftex-pop-to-bibtex-entry key files nil t item)
 151           (error (goto-char pos)
 152                  (message "cite: no such citation key %s" key)
 153                  (error "")))
 154         ;; Resize the window
 155         (setq size (max 1 (count-lines (point)
 156                                        (reftex-end-of-bib-entry item))))
 157         (let ((window-min-height 2))
 158           (shrink-window (1- (- (window-height) size)))
 159           (recenter 0))
 160         ;; Arrange restoration
 161         (add-hook 'pre-command-hook 'reftex-restore-window-conf))
 162
 163         ;; Normal display in other window
 164       (add-hook 'pre-command-hook 'reftex-highlight-shall-die)
 165       (setq pop-win (selected-window))
 166       (select-window win)
 167       (goto-char pos)
 168       (when (equal arg 2)
 169         (select-window pop-win)))))
 170
 171 (defun reftex-view-cr-ref (arg label how)
 172   ;; View crossreference of a ref macro.  HOW can have the values
 173   ;; nil:         Show in another window.
 174   ;; echo:        Show one-line info in echo area.
 175   ;; tmp-window:  Show in small window and arrange for window to disappear.
 176
 177   ;; Ensure access to scanning info
 178   (reftex-access-scan-info (or arg current-prefix-arg))
 179
 180   (if (eq how 'tmp-window)
 181       ;; Remember the window configuration
 182       (put 'reftex-auto-view-crossref 'last-window-conf
 183            (current-window-configuration)))
 184
 185   (let* ((xr-data (assoc 'xr (symbol-value reftex-docstruct-symbol)))
 186          (xr-re (nth 2 xr-data))
 187          (entry (assoc label (symbol-value reftex-docstruct-symbol)))
 188          (win (selected-window)) pop-win (pos (point)))
 189
 190     (if (and (not entry) (stringp label) xr-re (string-match xr-re label))
 191         ;; Label is defined in external document
 192         (save-excursion
 193           (save-match-data
 194             (set-buffer
 195              (or (reftex-get-file-buffer-force
 196                   (cdr (assoc (match-string 1 label) (nth 1
 197                                                           xr-data))))
 198                  (error "Problem with external label %s" label))))
 199           (setq label (substring label (match-end 1)))
 200           (reftex-access-scan-info)
 201           (setq entry
 202                 (assoc label (symbol-value reftex-docstruct-symbol)))))
 203     (if (eq how 'echo)
 204         ;; Display in echo area
 205         (reftex-echo-ref label entry (symbol-value reftex-docstruct-symbol))
 206       (let ((window-conf (current-window-configuration)))
 207         (condition-case nil
 208             (reftex-show-label-location entry t nil t t)
 209           (error (set-window-configuration window-conf)
 210                  (message "ref: Label %s not found" label)
 211                  (error "ref: Label %s not found" label)))) ;; 2nd is line OK
 212       (add-hook 'pre-command-hook 'reftex-highlight-shall-die)
 213
 214       (when (eq how 'tmp-window)
 215         ;; Resize window and arrange restauration
 216         (shrink-window (1- (- (window-height) 9)))
 217         (recenter '(4))
 218         (add-hook 'pre-command-hook 'reftex-restore-window-conf))
 219       (setq pop-win (selected-window))
 220       (select-window win)
 221       (goto-char pos)
 222       (when (equal arg 2)
 223         (select-window pop-win)))))
 224
 225 (defun reftex-mouse-view-crossref (ev)
 226   "View cross reference of \\ref or \\cite macro where you click.
 227 If the macro at point is a \\ref, show the corresponding label definition.
 228 If it is a \\cite, show the BibTeX database entry.
 229 If there is no such macro at point, search forward to find one.
 230 With argument, actually select the window showing the cross reference."
 231   (interactive "e")
 232   (mouse-set-point ev)
 233   (reftex-view-crossref current-prefix-arg))
 234
 235 (defun reftex-view-crossref-when-idle ()
 236   ;; Display info about crossref at point in echo area or a window.
 237   ;; This function was desigend to work with an idle timer.
 238   ;; We try to get out of here as quickly as possible if the call is useless.
 239   (and reftex-mode
 240        ;; Make sure message area is free if we need it.
 241        (or (eq reftex-auto-view-crossref 'window) (not (current-message)))
 242        ;; Make sure we are not already displaying this one
 243        (not (memq last-command '(reftex-view-crossref
 244                                  reftex-mouse-view-crossref)))
 245        ;; Quick precheck if this might be a relevant spot
 246        ;; `reftex-view-crossref' will do a more thorough check.
 247        (save-excursion
 248          (search-backward "\\" nil t)
 249          (looking-at "\\\\[a-zA-Z]*\\(cite\\|ref\\|bibentry\\)"))
 250
 251        (condition-case nil
 252            (let ((current-prefix-arg nil))
 253              (cond
 254               ((eq reftex-auto-view-crossref t)
 255                (reftex-view-crossref -1 'echo 'quiet))
 256               ((eq reftex-auto-view-crossref 'window)
 257                (reftex-view-crossref -1 'tmp-window 'quiet))
 258               (t nil)))
 259          (error nil))))
 260
 261 (defun reftex-restore-window-conf ()
 262   (set-window-configuration (get 'reftex-auto-view-crossref 'last-window-conf))
 263   (put 'reftex-auto-view-crossref 'last-window-conf nil)
 264   (remove-hook 'pre-command-hook 'reftex-restore-window-conf))
 265
 266 (defun reftex-echo-ref (label entry docstruct)
 267   ;; Display crossref info in echo area.
 268   (cond
 269    ((null docstruct)
 270     (message "%s"
 271              (substitute-command-keys (format reftex-no-info-message "ref"))))
 272    ((null entry)
 273     (message "ref: unknown label: %s" label))
 274    (t
 275     (when (stringp (nth 2 entry))
 276       (message "ref(%s): %s" (nth 1 entry) (nth 2 entry)))
 277     (let ((buf (get-buffer " *Echo Area*")))
 278       (when buf
 279         (save-excursion
 280           (set-buffer buf)
 281           (run-hooks 'reftex-display-copied-context-hook)))))))
 282
 283 (defun reftex-echo-cite (key files item)
 284   ;; Display citation info in echo area.
 285   (let* ((cache (assq 'bibview-cache (symbol-value reftex-docstruct-symbol)))
 286          (cache-entry (assoc key (cdr cache)))
 287          entry string buf (all-files files))
 288
 289     (if (and reftex-cache-cite-echo cache-entry)
 290         ;; We can just use the cache
 291         (setq string (cdr cache-entry))
 292
 293       ;; Need to look in the database
 294       (unless reftex-revisit-to-echo
 295         (setq files (reftex-visited-files files)))
 296
 297       (setq entry
 298             (condition-case nil
 299                 (save-excursion
 300                   (reftex-pop-to-bibtex-entry key files nil nil item t))
 301               (error
 302                (if (and files (= (length all-files) (length files)))
 303                    (message "cite: no such database entry: %s" key)
 304                  (message "%s" (substitute-command-keys
 305                                 (format reftex-no-info-message "cite"))))
 306                nil)))
 307       (when entry
 308         (if item
 309             (setq string (reftex-nicify-text entry))
 310           (setq string (reftex-make-cite-echo-string
 311                         (reftex-parse-bibtex-entry entry)
 312                         reftex-docstruct-symbol)))))
 313     (unless (or (null string) (equal string ""))
 314       (message "cite: %s" string))
 315     (when (setq buf (get-buffer " *Echo Area*"))
 316       (save-excursion
 317         (set-buffer buf)
 318         (run-hooks 'reftex-display-copied-context-hook)))))
 319
 320 (defvar reftex-use-itimer-in-xemacs nil
 321   "*Non-nil means use the idle timers in XEmacs for crossref display.
 322 Currently, idle timer restart is broken and we use the post-command-hook.")
 323
 324 (defun reftex-toggle-auto-view-crossref ()
 325   "Toggle the automatic display of crossref information in the echo area.
 326 When active, leaving point idle in the argument of a \\ref or \\cite macro
 327 will display info in the echo area."
 328   (interactive)
 329   (if reftex-auto-view-crossref-timer
 330       (progn
 331         (if (featurep 'xemacs)
 332             (if reftex-use-itimer-in-xemacs
 333                 (delete-itimer reftex-auto-view-crossref-timer)
 334               (remove-hook 'post-command-hook 'reftex-start-itimer-once))
 335           (cancel-timer reftex-auto-view-crossref-timer))
 336         (setq reftex-auto-view-crossref-timer nil)
 337         (message "Automatic display of crossref information was turned off"))
 338     (setq reftex-auto-view-crossref-timer
 339           (if (featurep 'xemacs)
 340               (if reftex-use-itimer-in-xemacs
 341                   (start-itimer "RefTeX Idle Timer"
 342                                 'reftex-view-crossref-when-idle
 343                                 reftex-idle-time reftex-idle-time t)
 344                 (add-hook 'post-command-hook 'reftex-start-itimer-once)
 345                 t)
 346             (run-with-idle-timer
 347              reftex-idle-time t 'reftex-view-crossref-when-idle)))
 348     (unless reftex-auto-view-crossref
 349       (setq reftex-auto-view-crossref t))
 350     (message "Automatic display of crossref information was turned on")))
 351
 352 (defun reftex-start-itimer-once ()
 353    (and (featurep 'xemacs) reftex-mode
 354         (not (itimer-live-p reftex-auto-view-crossref-timer))
 355         (setq reftex-auto-view-crossref-timer
 356               (start-itimer "RefTeX Idle Timer"
 357                             'reftex-view-crossref-when-idle
 358                             reftex-idle-time nil t))))
 359
 360 (declare-function bibtex-beginning-of-entry "bibtex" ())
 361
 362 (defun reftex-view-crossref-from-bibtex (&optional arg)
 363   "View location in a LaTeX document which cites the BibTeX entry at point.
 364 Since BibTeX files can be used by many LaTeX documents, this function
 365 prompts upon first use for a buffer in RefTeX mode.  To reset this
 366 link to a document, call the function with with a prefix arg.
 367 Calling this function several times find successive citation locations."
 368   (interactive "P")
 369   (when arg
 370     ;; Break connection to reference buffer
 371     (put 'reftex-bibtex-view-cite-locations :ref-buffer nil))
 372   (let ((ref-buffer (get 'reftex-bibtex-view-cite-locations :ref-buffer)))
 373     ;; Establish connection to reference buffer
 374     (unless ref-buffer
 375       (setq ref-buffer
 376             (save-excursion
 377               (completing-read
 378                "Reference buffer: "
 379                (delq nil
 380                      (mapcar
 381                       (lambda (b)
 382                         (set-buffer b)
 383                         (if reftex-mode (list (buffer-name b)) nil))
 384                       (buffer-list)))
 385                nil t)))
 386       (put 'reftex-bibtex-view-cite-locations :ref-buffer ref-buffer))
 387     ;; Search for citations
 388     (bibtex-beginning-of-entry)
 389     (if (looking-at
 390          "@[a-zA-Z]+[ \t\n\r]*[{(][ \t\n\r]*\\([^, \t\r\n}]+\\)")
 391         (progn
 392           (goto-char (match-beginning 1))
 393           (reftex-view-regexp-match
 394            (format reftex-find-citation-regexp-format
 395                    (regexp-quote (match-string 1)))
 396            4 arg ref-buffer))
 397       (error "Cannot find citation key in BibTeX entry"))))
 398
 399 (defun reftex-view-regexp-match (re &optional highlight-group new ref-buffer)
 400   ;; Search for RE in current document or in the document of REF-BUFFER.
 401   ;; Continue the search, if the same re was searched last.
 402   ;; Highlight the group HIGHLIGHT-GROUP of the match.
 403   ;; When NEW is non-nil, start a new search regardless.
 404   ;; Match point is displayed in another window.
 405   ;; Upon success, returns the window which displays the match.
 406
 407   ;;; Decide if new search or continued search
 408   (let* ((oldprop (get 'reftex-view-regexp-match :props))
 409          (newprop (list (current-buffer) re))
 410          (cont (and (not new) (equal oldprop newprop)))
 411          (cnt (if cont (get 'reftex-view-regexp-match :cnt) 0))
 412          (current-window (selected-window))
 413          (window-conf (current-window-configuration))
 414          match pop-window)
 415     (switch-to-buffer-other-window (or ref-buffer (current-buffer)))
 416     ;; Search
 417     (condition-case nil
 418         (if cont
 419             (setq match (reftex-global-search-continue))
 420           (reftex-access-scan-info)
 421           (setq match (reftex-global-search re (reftex-all-document-files))))
 422       (error nil))
 423     ;; Evaluate the match.
 424     (if match
 425         (progn
 426           (put 'reftex-view-regexp-match :props newprop)
 427           (put 'reftex-view-regexp-match :cnt (incf cnt))
 428           (reftex-highlight 0 (match-beginning highlight-group)
 429                             (match-end highlight-group))
 430           (add-hook 'pre-command-hook 'reftex-highlight-shall-die)
 431           (setq pop-window (selected-window)))
 432       (put 'reftex-view-regexp-match :props nil)
 433       (or cont (set-window-configuration window-conf)))
 434     (select-window current-window)
 435     (if match
 436         (progn
 437           (message "Match Nr. %s" cnt)
 438           pop-window)
 439       (if cont
 440           (error "No further matches (total number of matches: %d)" cnt)
 441         (error "No matches")))))
 442
 443 (defvar reftex-global-search-marker (make-marker))
 444 (defun reftex-global-search (regexp file-list)
 445   ;; Start a search for REGEXP in all files of FILE-LIST
 446   (put 'reftex-global-search :file-list file-list)
 447   (put 'reftex-global-search :regexp regexp)
 448   (move-marker reftex-global-search-marker nil)
 449   (reftex-global-search-continue))
 450
 451 (defun reftex-global-search-continue ()
 452   ;; Continue a global search started with `reftex-global-search'
 453   (unless (get 'reftex-global-search :file-list)
 454     (error "No global search to continue"))
 455   (let* ((file-list (get 'reftex-global-search :file-list))
 456          (regexp (get 'reftex-global-search :regexp))
 457          (buf (or (marker-buffer reftex-global-search-marker)
 458                   (reftex-get-file-buffer-force (car file-list))))
 459          (pos (or (marker-position reftex-global-search-marker) 1))
 460          file)
 461     ;; Take up starting position
 462     (unless buf (error "No such buffer %s" buf))
 463     (switch-to-buffer buf)
 464     (widen)
 465     (goto-char pos)
 466     ;; Search and switch file if necessary
 467     (if (catch 'exit
 468           (while t
 469             (when (re-search-forward regexp nil t)
 470               (move-marker reftex-global-search-marker (point))
 471               (throw 'exit t))
 472             ;; No match - goto next file
 473             (pop file-list)
 474             (or file-list (throw 'exit nil))
 475             (setq file (car file-list)
 476                   buf (reftex-get-file-buffer-force file))
 477             (unless buf (error "Cannot access file %s" file))
 478             (put 'reftex-global-search :file-list file-list)
 479             (switch-to-buffer buf)
 480             (widen)
 481             (goto-char 1)))
 482         t
 483       (move-marker reftex-global-search-marker nil)
 484       (error "All files processed"))))
 485
 486 ;; arch-tag: d2f52b56-744e-44ad-830d-1fc193b90eda
 487 ;;; reftex-dcr.el ends here