lisp/textmodes/nroff-mode.el

   1 ;;; nroff-mode.el --- GNU Emacs major mode for editing nroff source
   2
   3 ;; Copyright (C) 1985, 1986, 1994, 1995, 1997, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: wp
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This package is a major mode for editing nroff source code.  It knows
  27 ;; about various nroff constructs, ms, mm, and me macros, and will fill
  28 ;; and indent paragraphs properly in their presence.  It also includes
  29 ;; a command to count text lines (excluding nroff constructs), a command
  30 ;; to center a line, and movement commands that know how to skip macros.
  31
  32 ;; Paragraph filling and line-counting currently don't respect comments,
  33 ;; as they should.
  34
  35 ;;; Code:
  36
  37 (defgroup nroff nil
  38   "Nroff mode."
  39   :link '(custom-group-link :tag "Font Lock Faces group" font-lock-faces)
  40   :group 'wp
  41   :prefix "nroff-")
  42
  43
  44 (defcustom nroff-electric-mode nil
  45   "Non-nil means automatically closing requests when you insert an open."
  46   :group 'nroff
  47   :type 'boolean)
  48
  49 (defvar nroff-mode-map
  50   (let ((map (make-sparse-keymap))
  51         (menu-map (make-sparse-keymap)))
  52     (define-key map "\t"  'tab-to-tab-stop)
  53     (define-key map "\es" 'center-line)
  54     (define-key map "\e?" 'nroff-count-text-lines)
  55     (define-key map "\n"  'nroff-electric-newline)
  56     (define-key map "\en" 'nroff-forward-text-line)
  57     (define-key map "\ep" 'nroff-backward-text-line)
  58     (define-key map [menu-bar nroff-mode] (cons "Nroff" menu-map))
  59     (define-key menu-map [nn]
  60       '(menu-item "Newline" nroff-electric-newline
  61                   :help "Insert newline for nroff mode; special if nroff-electric mode"))
  62     (define-key menu-map [nc]
  63       '(menu-item "Count text lines" nroff-count-text-lines
  64                   :help "Count lines in region, except for nroff request lines."))
  65     (define-key menu-map [nf]
  66       '(menu-item "Forward text line" nroff-forward-text-line
  67                   :help "Go forward one nroff text line, skipping lines of nroff requests"))
  68     (define-key menu-map [nb]
  69       '(menu-item "Backward text line" nroff-backward-text-line
  70                   :help "Go backward one nroff text line, skipping lines of nroff requests"))
  71     (define-key menu-map [ne]
  72       '(menu-item "Electric newline mode"
  73                   nroff-electric-mode
  74                   :help "Auto insert closing requests if necessary"
  75                   :button (:toggle . nroff-electric-mode)))
  76     map)
  77   "Major mode keymap for `nroff-mode'.")
  78
  79 (defvar nroff-mode-syntax-table
  80   (let ((st (copy-syntax-table text-mode-syntax-table)))
  81     ;; " isn't given string quote syntax in text-mode but it
  82     ;; (arguably) should be for use round nroff arguments (with ` and
  83     ;; ' used otherwise).
  84     (modify-syntax-entry ?\" "\"  2" st)
  85     ;; Comments are delimited by \" and newline.
  86     ;; And in groff also \# to newline.
  87     (modify-syntax-entry ?# ".  2"  st)
  88     (modify-syntax-entry ?\\ "\\  1" st)
  89     (modify-syntax-entry ?\n ">" st)
  90     st)
  91   "Syntax table used while in `nroff-mode'.")
  92
  93 (defvar nroff-imenu-expression
  94   ;; man headers:
  95   '((nil "^\\.SH \"?\\([^\"\n]*\\)\"?$" 1)))
  96
  97 (defcustom nroff-font-lock-keywords
  98   (list
  99    ;; Directives are . or ' at start of line, followed by
 100    ;; optional whitespace, then command (which my be longer than
 101    ;; 2 characters in groff).  Perhaps the arguments should be
 102    ;; fontified as well.
 103    "^[.']\\s-*\\sw+"
 104    ;; There are numerous groff escapes; the following get things
 105    ;; like \-, \(em (standard troff) and \f[bar] (groff
 106    ;; variants).  This won't currently do groff's \A'foo' and
 107    ;; the like properly.  One might expect it to highlight an escape's
 108    ;; arguments in common cases, like \f.
 109    (concat "\\\\"                     ; backslash
 110          "\\("                        ; followed by various possibilities
 111          (mapconcat 'identity
 112                     '("[f*n]*\\[.+?]" ; some groff extensions
 113                       "(.."           ; two chars after (
 114                       "[^(\"#]"       ; single char escape
 115                       ) "\\|")
 116          "\\)")
 117    )
 118   "Font-lock highlighting control in `nroff-mode'."
 119   :group 'nroff
 120   :type '(repeat regexp))
 121
 122 (defcustom nroff-mode-hook nil
 123   "Hook run by function `nroff-mode'."
 124   :type 'hook
 125   :group 'nroff)
 126
 127 ;;;###autoload
 128 (define-derived-mode nroff-mode text-mode "Nroff"
 129   "Major mode for editing text intended for nroff to format.
 130 \\{nroff-mode-map}
 131 Turning on Nroff mode runs `text-mode-hook', then `nroff-mode-hook'.
 132 Also, try `nroff-electric-mode', for automatically inserting
 133 closing requests for requests that are used in matched pairs."
 134   (set (make-local-variable 'font-lock-defaults)
 135        ;; SYNTAX-BEGIN is set to backward-paragraph to avoid slow-down
 136        ;; near the end of large buffers due to searching to buffer's
 137        ;; beginning.
 138        '(nroff-font-lock-keywords nil t nil backward-paragraph))
 139   (set (make-local-variable 'outline-regexp) "\\.H[ ]+[1-7]+ ")
 140   (set (make-local-variable 'outline-level) 'nroff-outline-level)
 141   ;; now define a bunch of variables for use by commands in this mode
 142   (set (make-local-variable 'page-delimiter) "^\\.\\(bp\\|SK\\|OP\\)")
 143   (set (make-local-variable 'paragraph-start)
 144        (concat "[.']\\|" paragraph-start))
 145   (set (make-local-variable 'paragraph-separate)
 146        (concat "[.']\\|" paragraph-separate))
 147   ;; comment syntax added by mit-erl!gildea 18 Apr 86
 148   (set (make-local-variable 'comment-start) "\\\" ")
 149   (set (make-local-variable 'comment-start-skip) "\\\\[\"#][ \t]*")
 150   (set (make-local-variable 'comment-column) 24)
 151   (set (make-local-variable 'comment-indent-function) 'nroff-comment-indent)
 152   (set (make-local-variable 'comment-insert-comment-function)
 153        'nroff-insert-comment-function)
 154   (set (make-local-variable 'imenu-generic-expression) nroff-imenu-expression))
 155
 156 (defun nroff-outline-level ()
 157   (save-excursion
 158     (looking-at outline-regexp)
 159     (skip-chars-forward ".H ")
 160     (string-to-number (buffer-substring (point) (+ 1 (point))))))
 161
 162 ;; Compute how much to indent a comment in nroff/troff source.
 163 ;; By mit-erl!gildea April 86
 164 (defun nroff-comment-indent ()
 165   "Compute indent for an nroff/troff comment.
 166 Puts a full-stop before comments on a line by themselves."
 167   (let ((pt (point)))
 168     (unwind-protect
 169         (progn
 170           (skip-chars-backward " \t")
 171           (if (bolp)
 172               (progn
 173                 ;; FIXME delete-horizontal-space?
 174                 (setq pt (1+ pt))
 175                 (insert ?.)
 176                 1)
 177             (if (save-excursion
 178                   (backward-char 1)
 179                   (looking-at "^[.']"))
 180                 1
 181               (max comment-column
 182                    (* 8 (/ (+ (current-column)
 183                               9) 8)))))) ; add 9 to ensure at least two blanks
 184       (goto-char pt))))
 185
 186 ;; http://lists.gnu.org/archive/html/emacs-devel/2007-10/msg01869.html
 187 (defun nroff-insert-comment-function ()
 188   "Function for `comment-insert-comment-function' in `nroff-mode'."
 189   (indent-to (nroff-comment-indent))
 190   (insert comment-start))
 191
 192 (defun nroff-count-text-lines (start end &optional print)
 193   "Count lines in region, except for nroff request lines.
 194 All lines not starting with a period are counted up.
 195 Interactively, print result in echo area.
 196 Noninteractively, return number of non-request lines from START to END."
 197   (interactive "r\np")
 198   (if print
 199       (message "Region has %d text lines" (nroff-count-text-lines start end))
 200     (save-excursion
 201       (save-restriction
 202         (narrow-to-region start end)
 203         (goto-char (point-min))
 204         (- (buffer-size) (nroff-forward-text-line (buffer-size)))))))
 205
 206 (defun nroff-forward-text-line (&optional cnt)
 207   "Go forward one nroff text line, skipping lines of nroff requests.
 208 An argument is a repeat count; if negative, move backward."
 209   (interactive "p")
 210   (if (not cnt) (setq cnt 1))
 211   (while (and (> cnt 0) (not (eobp)))
 212     (forward-line 1)
 213     (while (and (not (eobp)) (looking-at "[.']."))
 214       (forward-line 1))
 215     (setq cnt (- cnt 1)))
 216   (while (and (< cnt 0) (not (bobp)))
 217     (forward-line -1)
 218     (while (and (not (bobp))
 219                 (looking-at "[.']."))
 220       (forward-line -1))
 221     (setq cnt (+ cnt 1)))
 222   cnt)
 223
 224 (defun nroff-backward-text-line (&optional cnt)
 225   "Go backward one nroff text line, skipping lines of nroff requests.
 226 An argument is a repeat count; negative means move forward."
 227   (interactive "p")
 228   (nroff-forward-text-line (- cnt)))
 229
 230 (defconst nroff-brace-table
 231   '((".(b" . ".)b")
 232     (".(l" . ".)l")
 233     (".(q" . ".)q")
 234     (".(c" . ".)c")
 235     (".(x" . ".)x")
 236     (".(z" . ".)z")
 237     (".(d" . ".)d")
 238     (".(f" . ".)f")
 239     (".LG" . ".NL")
 240     (".SM" . ".NL")
 241     (".LD" . ".DE")
 242     (".CD" . ".DE")
 243     (".BD" . ".DE")
 244     (".DS" . ".DE")
 245     (".DF" . ".DE")
 246     (".FS" . ".FE")
 247     (".KS" . ".KE")
 248     (".KF" . ".KE")
 249     (".LB" . ".LE")
 250     (".AL" . ".LE")
 251     (".BL" . ".LE")
 252     (".DL" . ".LE")
 253     (".ML" . ".LE")
 254     (".RL" . ".LE")
 255     (".VL" . ".LE")
 256     (".RS" . ".RE")
 257     (".TS" . ".TE")
 258     (".EQ" . ".EN")
 259     (".PS" . ".PE")
 260     (".BS" . ".BE")
 261     (".G1" . ".G2")                     ; grap
 262     (".na" . ".ad b")
 263     (".nf" . ".fi")
 264     (".de" . "..")))
 265
 266 (defun nroff-electric-newline (arg)
 267   "Insert newline for nroff mode; special if nroff-electric mode.
 268 In `nroff-electric-mode', if ending a line containing an nroff opening request,
 269 automatically inserts the matching closing request after point."
 270   (interactive "P")
 271   (let ((completion (save-excursion
 272                       (beginning-of-line)
 273                       (and (null arg)
 274                            nroff-electric-mode
 275                            (<= (point) (- (point-max) 3))
 276                            (cdr (assoc (buffer-substring (point)
 277                                                          (+ 3 (point)))
 278                                        nroff-brace-table)))))
 279         (needs-nl (not (looking-at "[ \t]*$"))))
 280     (if (null completion)
 281         (newline (prefix-numeric-value arg))
 282       (save-excursion
 283         (insert "\n\n" completion)
 284         (if needs-nl (insert "\n")))
 285       (forward-char 1))))
 286
 287 (define-minor-mode nroff-electric-mode
 288   "Toggle `nroff-electric-newline' minor mode.
 289 `nroff-electric-newline' forces Emacs to check for an nroff request at the
 290 beginning of the line, and insert the matching closing request if necessary.
 291 This command toggles that mode (off->on, on->off), with an argument,
 292 turns it on if arg is positive, otherwise off."
 293   :lighter " Electric"
 294   (or (derived-mode-p 'nroff-mode) (error "Must be in nroff mode")))
 295
 296 ;; Old names that were not namespace clean.
 297 (define-obsolete-function-alias 'count-text-lines 'nroff-count-text-lines "22.1")
 298 (define-obsolete-function-alias 'forward-text-line 'nroff-forward-text-line "22.1")
 299 (define-obsolete-function-alias 'backward-text-line 'nroff-backward-text-line "22.1")
 300 (define-obsolete-function-alias 'electric-nroff-newline 'nroff-electric-newline "22.1")
 301 (define-obsolete-function-alias 'electric-nroff-mode 'nroff-electric-mode "22.1")
 302
 303 (provide 'nroff-mode)
 304
 305 ;; arch-tag: 6e276340-6c65-4f65-b4e3-0ca431ddfb6c
 306 ;;; nroff-mode.el ends here