lisp/vc-dir.el

   1 ;;; vc-dir.el --- Directory status display under VC
   2
   3 ;; Copyright (C) 2007, 2008, 2009, 2010
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author:   Dan Nicolaescu <dann@ics.uci.edu>
   7 ;; Keywords: tools
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Credits:
  25
  26 ;; The original VC directory status implementation was based on dired.
  27 ;; This implementation was inspired by PCL-CVS.
  28 ;; Many people contributed comments, ideas and code to this
  29 ;; implementation.  These include:
  30 ;;
  31 ;;   Alexandre Julliard  <julliard@winehq.org>
  32 ;;   Stefan Monnier  <monnier@iro.umontreal.ca>
  33 ;;   Tom Tromey  <tromey@redhat.com>
  34
  35 ;;; Commentary:
  36 ;;
  37
  38 ;;; Todo:  see vc.el.
  39
  40 (require 'vc-hooks)
  41 (require 'vc)
  42 (require 'tool-bar)
  43 (require 'ewoc)
  44
  45 ;;; Code:
  46 (eval-when-compile
  47   (require 'cl))
  48
  49 (defcustom vc-dir-mode-hook nil
  50   "Normal hook run by `vc-dir-mode'.
  51 See `run-hooks'."
  52   :type 'hook
  53   :group 'vc)
  54
  55 ;; Used to store information for the files displayed in the directory buffer.
  56 ;; Each item displayed corresponds to one of these defstructs.
  57 (defstruct (vc-dir-fileinfo
  58             (:copier nil)
  59             (:type list)            ;So we can use `member' on lists of FIs.
  60             (:constructor
  61              ;; We could define it as an alias for `list'.
  62              vc-dir-create-fileinfo (name state &optional extra marked directory))
  63             (:conc-name vc-dir-fileinfo->))
  64   name                                  ;Keep it as first, for `member'.
  65   state
  66   ;; For storing backend specific information.
  67   extra
  68   marked
  69   ;; To keep track of not updated files during a global refresh
  70   needs-update
  71   ;; To distinguish files and directories.
  72   directory)
  73
  74 (defvar vc-ewoc nil)
  75
  76 (defvar vc-dir-process-buffer nil
  77   "The buffer used for the asynchronous call that computes status.")
  78
  79 (defvar vc-dir-backend nil
  80   "The backend used by the current *vc-dir* buffer.")
  81
  82 (defun vc-dir-move-to-goal-column ()
  83   ;; Used to keep the cursor on the file name column.
  84   (beginning-of-line)
  85   (unless (eolp)
  86     ;; Must be in sync with vc-default-dir-printer.
  87     (forward-char 25)))
  88
  89 (defun vc-dir-prepare-status-buffer (bname dir backend &optional create-new)
  90   "Find a buffer named BNAME showing DIR, or create a new one."
  91   (setq dir (file-name-as-directory (expand-file-name dir)))
  92   (let* ;; Look for another buffer name BNAME visiting the same directory.
  93       ((buf (save-excursion
  94               (unless create-new
  95                 (dolist (buffer vc-dir-buffers)
  96                   (when (buffer-live-p buffer)
  97                     (set-buffer buffer)
  98                     (when (and (derived-mode-p 'vc-dir-mode)
  99                                (eq vc-dir-backend backend)
 100                                (string= default-directory dir))
 101                       (return buffer))))))))
 102     (or buf
 103         ;; Create a new buffer named BNAME.
 104         ;; We pass a filename to create-file-buffer because it is what
 105         ;; the function expects, and also what uniquify needs (if active)
 106         (with-current-buffer (create-file-buffer (expand-file-name bname dir))
 107           (cd dir)
 108           (vc-setup-buffer (current-buffer))
 109           ;; Reset the vc-parent-buffer-name so that it does not appear
 110           ;; in the mode-line.
 111           (setq vc-parent-buffer-name nil)
 112           (current-buffer)))))
 113
 114 (defvar vc-dir-menu-map
 115   (let ((map (make-sparse-keymap "VC-dir")))
 116     (define-key map [quit]
 117       '(menu-item "Quit" quit-window
 118                   :help "Quit"))
 119     (define-key map [kill]
 120       '(menu-item "Kill Update Command" vc-dir-kill-dir-status-process
 121                   :enable (vc-dir-busy)
 122                   :help "Kill the command that updates the directory buffer"))
 123     (define-key map [refresh]
 124       '(menu-item "Refresh" revert-buffer
 125                   :enable (not (vc-dir-busy))
 126                   :help "Refresh the contents of the directory buffer"))
 127     (define-key map [remup]
 128       '(menu-item "Hide up-to-date" vc-dir-hide-up-to-date
 129                   :help "Hide up-to-date items from display"))
 130     ;; Movement.
 131     (define-key map [sepmv] '("--"))
 132     (define-key map [next-line]
 133       '(menu-item "Next line" vc-dir-next-line
 134                   :help "Go to the next line" :keys "n"))
 135     (define-key map [previous-line]
 136       '(menu-item "Previous line" vc-dir-previous-line
 137                   :help "Go to the previous line"))
 138     ;; Marking.
 139     (define-key map [sepmrk] '("--"))
 140     (define-key map [unmark-all]
 141       '(menu-item "Unmark All" vc-dir-unmark-all-files
 142                   :help "Unmark all files that are in the same state as the current file\
 143 \nWith prefix argument unmark all files"))
 144     (define-key map [unmark-previous]
 145       '(menu-item "Unmark previous " vc-dir-unmark-file-up
 146                   :help "Move to the previous line and unmark the file"))
 147
 148     (define-key map [mark-all]
 149       '(menu-item "Mark All" vc-dir-mark-all-files
 150                   :help "Mark all files that are in the same state as the current file\
 151 \nWith prefix argument mark all files"))
 152     (define-key map [unmark]
 153       '(menu-item "Unmark" vc-dir-unmark
 154                   :help "Unmark the current file or all files in the region"))
 155
 156     (define-key map [mark]
 157       '(menu-item "Mark" vc-dir-mark
 158                   :help "Mark the current file or all files in the region"))
 159
 160     (define-key map [sepopn] '("--"))
 161     (define-key map [qr]
 162       '(menu-item "Query Replace in Files..." vc-dir-query-replace-regexp
 163                   :help "Replace a string in the marked files"))
 164     (define-key map [se]
 165       '(menu-item "Search Files..." vc-dir-search
 166                   :help "Search a regexp in the marked files"))
 167     (define-key map [ires]
 168       '(menu-item "Isearch Regexp Files..." vc-dir-isearch-regexp
 169                   :help "Incremental search a regexp in the marked files"))
 170     (define-key map [ise]
 171       '(menu-item "Isearch Files..." vc-dir-isearch
 172                   :help "Incremental search a string in the marked files"))
 173     (define-key map [open-other]
 174       '(menu-item "Open in other window" vc-dir-find-file-other-window
 175                   :help "Find the file on the current line, in another window"))
 176     (define-key map [open]
 177       '(menu-item "Open file" vc-dir-find-file
 178                   :help "Find the file on the current line"))
 179     (define-key map [sepvcdet] '("--"))
 180     ;; FIXME: This needs a key binding.  And maybe a better name
 181     ;; ("Insert" like PCL-CVS uses does not sound that great either)...
 182     (define-key map [ins]
 183       '(menu-item "Show File" vc-dir-show-fileentry
 184                   :help "Show a file in the VC status listing even though it might be up to date"))
 185     (define-key map [annotate]
 186       '(menu-item "Annotate" vc-annotate
 187                   :help "Display the edit history of the current file using colors"))
 188     (define-key map [diff]
 189       '(menu-item "Compare with Base Version" vc-diff
 190                   :help "Compare file set with the base version"))
 191     (define-key map [log]
 192      '(menu-item "Show history" vc-print-log
 193      :help "List the change log of the current file set in a window"))
 194     ;; VC commands.
 195     (define-key map [sepvccmd] '("--"))
 196     (define-key map [update]
 197       '(menu-item "Update to latest version" vc-update
 198                   :help "Update the current fileset's files to their tip revisions"))
 199     (define-key map [revert]
 200       '(menu-item "Revert to base version" vc-revert
 201                   :help "Revert working copies of the selected fileset to their repository contents."))
 202     (define-key map [next-action]
 203       ;; FIXME: This really really really needs a better name!
 204       ;; And a key binding too.
 205       '(menu-item "Check In/Out" vc-next-action
 206                   :help "Do the next logical version control operation on the current fileset"))
 207     (define-key map [register]
 208       '(menu-item "Register" vc-register
 209                   :help "Register file set into the version control system"))
 210     map)
 211   "Menu for VC dir.")
 212
 213 ;; VC backends can use this to add mode-specific menu items to
 214 ;; vc-dir-menu-map.
 215 (defun vc-dir-menu-map-filter (orig-binding)
 216   (when (and (symbolp orig-binding) (fboundp orig-binding))
 217     (setq orig-binding (indirect-function orig-binding)))
 218   (let ((ext-binding
 219          (when (derived-mode-p 'vc-dir-mode)
 220            (vc-call-backend vc-dir-backend 'extra-status-menu))))
 221     (if (null ext-binding)
 222         orig-binding
 223       (append orig-binding
 224               '("----")
 225               ext-binding))))
 226
 227 (defvar vc-dir-mode-map
 228   (let ((map (make-sparse-keymap)))
 229     ;; VC commands
 230     (define-key map "v" 'vc-next-action)   ;; C-x v v
 231     (define-key map "=" 'vc-diff)          ;; C-x v =
 232     (define-key map "i" 'vc-register)      ;; C-x v i
 233     (define-key map "+" 'vc-update)        ;; C-x v +
 234     (define-key map "l" 'vc-print-log)     ;; C-x v l
 235     ;; More confusing than helpful, probably
 236     ;;(define-key map "R" 'vc-revert) ;; u is taken by vc-dir-unmark.
 237     ;;(define-key map "A" 'vc-annotate) ;; g is taken by revert-buffer
 238     ;;                                     bound by `special-mode'.
 239     ;; Marking.
 240     (define-key map "m" 'vc-dir-mark)
 241     (define-key map "M" 'vc-dir-mark-all-files)
 242     (define-key map "u" 'vc-dir-unmark)
 243     (define-key map "U" 'vc-dir-unmark-all-files)
 244     (define-key map "\C-?" 'vc-dir-unmark-file-up)
 245     (define-key map "\M-\C-?" 'vc-dir-unmark-all-files)
 246     ;; Movement.
 247     (define-key map "n" 'vc-dir-next-line)
 248     (define-key map " " 'vc-dir-next-line)
 249     (define-key map "\t" 'vc-dir-next-directory)
 250     (define-key map "p" 'vc-dir-previous-line)
 251     (define-key map [backtab] 'vc-dir-previous-directory)
 252     ;;; Rebind paragraph-movement commands.
 253     (define-key map "\M-}" 'vc-dir-next-directory)
 254     (define-key map "\M-{" 'vc-dir-previous-directory)
 255     (define-key map [C-down] 'vc-dir-next-directory)
 256     (define-key map [C-up] 'vc-dir-previous-directory)
 257     ;; The remainder.
 258     (define-key map "f" 'vc-dir-find-file)
 259     (define-key map "\C-m" 'vc-dir-find-file)
 260     (define-key map "o" 'vc-dir-find-file-other-window)
 261     (define-key map "\C-c\C-c" 'vc-dir-kill-dir-status-process)
 262     (define-key map [down-mouse-3] 'vc-dir-menu)
 263     (define-key map [mouse-2] 'vc-dir-toggle-mark)
 264     (define-key map [follow-link] 'mouse-face)
 265     (define-key map "x" 'vc-dir-hide-up-to-date)
 266     (define-key map [?\C-k] 'vc-dir-kill-line)
 267     (define-key map "S" 'vc-dir-search) ;; FIXME: Maybe use A like dired?
 268     (define-key map "Q" 'vc-dir-query-replace-regexp)
 269     (define-key map (kbd "M-s a C-s")   'vc-dir-isearch)
 270     (define-key map (kbd "M-s a M-C-s") 'vc-dir-isearch-regexp)
 271
 272     ;; Hook up the menu.
 273     (define-key map [menu-bar vc-dir-mode]
 274       `(menu-item
 275         ;; VC backends can use this to add mode-specific menu items to
 276         ;; vc-dir-menu-map.
 277         "VC-dir" ,vc-dir-menu-map :filter vc-dir-menu-map-filter))
 278     map)
 279   "Keymap for directory buffer.")
 280
 281 (defmacro vc-dir-at-event (event &rest body)
 282   "Evaluate BODY with point located at event-start of EVENT.
 283 If BODY uses EVENT, it should be a variable,
 284  otherwise it will be evaluated twice."
 285   (let ((posn (make-symbol "vc-dir-at-event-posn")))
 286     `(save-excursion
 287        (unless (equal ,event '(tool-bar))
 288          (let ((,posn (event-start ,event)))
 289            (set-buffer (window-buffer (posn-window ,posn)))
 290            (goto-char (posn-point ,posn))))
 291        ,@body)))
 292
 293 (defun vc-dir-menu (e)
 294   "Popup the VC dir menu."
 295   (interactive "e")
 296   (vc-dir-at-event e (popup-menu vc-dir-menu-map e)))
 297
 298 (defvar vc-dir-tool-bar-map
 299   (let ((map (make-sparse-keymap)))
 300     (tool-bar-local-item-from-menu 'vc-dir-find-file "open"
 301                                    map vc-dir-mode-map)
 302     (tool-bar-local-item "bookmark_add"
 303                          'vc-dir-toggle-mark 'vc-dir-toggle-mark map
 304                          :help "Toggle mark on current item"
 305                          :label "Toggle Mark")
 306     (tool-bar-local-item-from-menu 'vc-dir-previous-line "left-arrow"
 307                                    map vc-dir-mode-map
 308                                    :rtl "right-arrow")
 309     (tool-bar-local-item-from-menu 'vc-dir-next-line "right-arrow"
 310                                    map vc-dir-mode-map
 311                                    :rtl "left-arrow")
 312     (tool-bar-local-item-from-menu 'vc-print-log "info"
 313                                    map vc-dir-mode-map)
 314     (tool-bar-local-item-from-menu 'revert-buffer "refresh"
 315                                    map vc-dir-mode-map)
 316     (tool-bar-local-item-from-menu 'nonincremental-search-forward
 317                                    "search" map nil
 318                                    :label "Search")
 319     (tool-bar-local-item-from-menu 'vc-dir-query-replace-regexp
 320                                    "search-replace" map vc-dir-mode-map
 321                                    :label "Replace")
 322     (tool-bar-local-item-from-menu 'vc-dir-kill-dir-status-process "cancel"
 323                                    map vc-dir-mode-map
 324                                    :label "Cancel")
 325     (tool-bar-local-item-from-menu 'quit-window "exit"
 326                                    map vc-dir-mode-map)
 327     map))
 328
 329 (defun vc-dir-node-directory (node)
 330   ;; Compute the directory for NODE.
 331   ;; If it's a directory node, get it from the node.
 332   (let ((data (ewoc-data node)))
 333     (or (vc-dir-fileinfo->directory data)
 334         ;; Otherwise compute it from the file name.
 335         (file-name-directory
 336          (directory-file-name
 337           (expand-file-name
 338            (vc-dir-fileinfo->name data)))))))
 339
 340 (defun vc-dir-update (entries buffer &optional noinsert)
 341   "Update BUFFER's ewoc from the list of ENTRIES.
 342 If NOINSERT, ignore elements on ENTRIES which are not in the ewoc."
 343   ;; Add ENTRIES to the vc-dir buffer BUFFER.
 344   (with-current-buffer buffer
 345     ;; Insert the entries sorted by name into the ewoc.
 346     ;; We assume the ewoc is sorted too, which should be the
 347     ;; case if we always add entries with vc-dir-update.
 348     (setq entries
 349           ;; Sort: first files and then subdirectories.
 350           ;; XXX: this is VERY inefficient, it computes the directory
 351           ;; names too many times
 352           (sort entries
 353                 (lambda (entry1 entry2)
 354                   (let ((dir1 (file-name-directory
 355                                 (directory-file-name (expand-file-name (car entry1)))))
 356                         (dir2 (file-name-directory
 357                                (directory-file-name (expand-file-name (car entry2))))))
 358                     (cond
 359                      ((string< dir1 dir2) t)
 360                      ((not (string= dir1 dir2)) nil)
 361                      ((string< (car entry1) (car entry2))))))))
 362     ;; Insert directory entries in the right places.
 363     (let ((entry (car entries))
 364           (node (ewoc-nth vc-ewoc 0))
 365           (dotname (file-relative-name default-directory)))
 366       ;; Insert . if it is not present.
 367       (unless node
 368         (ewoc-enter-last
 369          vc-ewoc (vc-dir-create-fileinfo
 370                   dotname nil nil nil default-directory))
 371         (setq node (ewoc-nth vc-ewoc 0)))
 372
 373       (while (and entry node)
 374         (let* ((entryfile (car entry))
 375                (entrydir (file-name-directory (directory-file-name
 376                                                (expand-file-name entryfile))))
 377                (nodedir (vc-dir-node-directory node)))
 378           (cond
 379            ;; First try to find the directory.
 380            ((string-lessp nodedir entrydir)
 381             (setq node (ewoc-next vc-ewoc node)))
 382            ((string-equal nodedir entrydir)
 383             ;; Found the directory, find the place for the file name.
 384             (let ((nodefile (vc-dir-fileinfo->name (ewoc-data node))))
 385               (cond
 386                ((string= nodefile dotname)
 387                 (setq node (ewoc-next vc-ewoc node)))
 388                ((string-lessp nodefile entryfile)
 389                 (setq node (ewoc-next vc-ewoc node)))
 390                ((string-equal nodefile entryfile)
 391                 (setf (vc-dir-fileinfo->state (ewoc-data node)) (nth 1 entry))
 392                 (setf (vc-dir-fileinfo->extra (ewoc-data node)) (nth 2 entry))
 393                 (setf (vc-dir-fileinfo->needs-update (ewoc-data node)) nil)
 394                 (ewoc-invalidate vc-ewoc node)
 395                 (setq entries (cdr entries))
 396                 (setq entry (car entries))
 397                 (setq node (ewoc-next vc-ewoc node)))
 398                (t
 399                 (ewoc-enter-before vc-ewoc node
 400                                    (apply 'vc-dir-create-fileinfo entry))
 401                 (setq entries (cdr entries))
 402                 (setq entry (car entries))))))
 403            (t
 404             ;; We might need to insert a directory node if the
 405             ;; previous node was in a different directory.
 406             (let* ((rd (file-relative-name entrydir))
 407                    (prev-node (ewoc-prev vc-ewoc node))
 408                    (prev-dir (vc-dir-node-directory prev-node)))
 409               (unless (string-equal entrydir prev-dir)
 410                 (ewoc-enter-before
 411                  vc-ewoc node (vc-dir-create-fileinfo rd nil nil nil entrydir))))
 412             ;; Now insert the node itself.
 413             (ewoc-enter-before vc-ewoc node
 414                                (apply 'vc-dir-create-fileinfo entry))
 415             (setq entries (cdr entries) entry (car entries))))))
 416       ;; We're past the last node, all remaining entries go to the end.
 417       (unless (or node noinsert)
 418         (let ((lastdir (vc-dir-node-directory (ewoc-nth vc-ewoc -1))))
 419           (dolist (entry entries)
 420             (let ((entrydir (file-name-directory
 421                              (directory-file-name (expand-file-name (car entry))))))
 422               ;; Insert a directory node if needed.
 423               (unless (string-equal lastdir entrydir)
 424                 (setq lastdir entrydir)
 425                 (let ((rd (file-relative-name entrydir)))
 426                   (ewoc-enter-last
 427                    vc-ewoc (vc-dir-create-fileinfo rd nil nil nil entrydir))))
 428               ;; Now insert the node itself.
 429               (ewoc-enter-last vc-ewoc
 430                                (apply 'vc-dir-create-fileinfo entry)))))))))
 431
 432 (defun vc-dir-busy ()
 433   (and (buffer-live-p vc-dir-process-buffer)
 434        (get-buffer-process vc-dir-process-buffer)))
 435
 436 (defun vc-dir-kill-dir-status-process ()
 437   "Kill the temporary buffer and associated process."
 438   (interactive)
 439   (when (buffer-live-p vc-dir-process-buffer)
 440     (let ((proc (get-buffer-process vc-dir-process-buffer)))
 441       (when proc (delete-process proc))
 442       (setq vc-dir-process-buffer nil)
 443       (setq mode-line-process nil))))
 444
 445 (defun vc-dir-kill-query ()
 446   ;; Make sure that when the status buffer is killed the update
 447   ;; process running in background is also killed.
 448   (if (vc-dir-busy)
 449     (when (y-or-n-p "Status update process running, really kill status buffer? ")
 450       (vc-dir-kill-dir-status-process)
 451       t)
 452     t))
 453
 454 (defun vc-dir-next-line (arg)
 455   "Go to the next line.
 456 If a prefix argument is given, move by that many lines."
 457   (interactive "p")
 458   (with-no-warnings
 459     (ewoc-goto-next vc-ewoc arg)
 460     (vc-dir-move-to-goal-column)))
 461
 462 (defun vc-dir-previous-line (arg)
 463   "Go to the previous line.
 464 If a prefix argument is given, move by that many lines."
 465   (interactive "p")
 466   (ewoc-goto-prev vc-ewoc arg)
 467   (vc-dir-move-to-goal-column))
 468
 469 (defun vc-dir-next-directory ()
 470   "Go to the next directory."
 471   (interactive)
 472   (let ((orig (point)))
 473     (if
 474         (catch 'foundit
 475           (while t
 476             (let* ((next (ewoc-next vc-ewoc (ewoc-locate vc-ewoc))))
 477               (cond ((not next)
 478                      (throw 'foundit t))
 479                     (t
 480                      (progn
 481                        (ewoc-goto-node vc-ewoc next)
 482                        (vc-dir-move-to-goal-column)
 483                        (if (vc-dir-fileinfo->directory (ewoc-data next))
 484                            (throw 'foundit nil))))))))
 485         (goto-char orig))))
 486
 487 (defun vc-dir-previous-directory ()
 488   "Go to the previous directory."
 489   (interactive)
 490   (let ((orig (point)))
 491     (if
 492         (catch 'foundit
 493           (while t
 494             (let* ((prev (ewoc-prev vc-ewoc (ewoc-locate vc-ewoc))))
 495               (cond ((not prev)
 496                      (throw 'foundit t))
 497                     (t
 498                      (progn
 499                        (ewoc-goto-node vc-ewoc prev)
 500                        (vc-dir-move-to-goal-column)
 501                        (if (vc-dir-fileinfo->directory (ewoc-data prev))
 502                            (throw 'foundit nil))))))))
 503         (goto-char orig))))
 504
 505 (defun vc-dir-mark-unmark (mark-unmark-function)
 506   (if (use-region-p)
 507       (let ((firstl (line-number-at-pos (region-beginning)))
 508             (lastl (line-number-at-pos (region-end))))
 509         (save-excursion
 510           (goto-char (region-beginning))
 511           (while (<= (line-number-at-pos) lastl)
 512             (funcall mark-unmark-function))))
 513     (funcall mark-unmark-function)))
 514
 515 (defun vc-dir-parent-marked-p (arg)
 516   ;; Return nil if none of the parent directories of arg is marked.
 517   (let* ((argdir (vc-dir-node-directory arg))
 518          (arglen (length argdir))
 519          (crt arg)
 520          data dir)
 521     ;; Go through the predecessors, checking if any directory that is
 522     ;; a parent is marked.
 523     (while (setq crt (ewoc-prev vc-ewoc crt))
 524       (setq data (ewoc-data crt))
 525       (setq dir (vc-dir-node-directory crt))
 526       (when (and (vc-dir-fileinfo->directory data)
 527                  (vc-string-prefix-p dir argdir))
 528         (when (vc-dir-fileinfo->marked data)
 529           (error "Cannot mark `%s', parent directory `%s' marked"
 530                  (vc-dir-fileinfo->name (ewoc-data arg))
 531                  (vc-dir-fileinfo->name data)))))
 532     nil))
 533
 534 (defun vc-dir-children-marked-p (arg)
 535   ;; Return nil if none of the children of arg is marked.
 536   (let* ((argdir-re (concat "\\`" (regexp-quote (vc-dir-node-directory arg))))
 537          (is-child t)
 538          (crt arg)
 539          data dir)
 540     (while (and is-child (setq crt (ewoc-next vc-ewoc crt)))
 541       (setq data (ewoc-data crt))
 542       (setq dir (vc-dir-node-directory crt))
 543       (if (string-match argdir-re dir)
 544           (when (vc-dir-fileinfo->marked data)
 545             (error "Cannot mark `%s', child `%s' marked"
 546                    (vc-dir-fileinfo->name (ewoc-data arg))
 547                    (vc-dir-fileinfo->name data)))
 548         ;; We are done, we got to an entry that is not a child of `arg'.
 549         (setq is-child nil)))
 550     nil))
 551
 552 (defun vc-dir-mark-file (&optional arg)
 553   ;; Mark ARG or the current file and move to the next line.
 554   (let* ((crt (or arg (ewoc-locate vc-ewoc)))
 555          (file (ewoc-data crt))
 556          (isdir (vc-dir-fileinfo->directory file)))
 557     (when (or (and isdir (not (vc-dir-children-marked-p crt)))
 558               (and (not isdir) (not (vc-dir-parent-marked-p crt))))
 559       (setf (vc-dir-fileinfo->marked file) t)
 560       (ewoc-invalidate vc-ewoc crt)
 561       (unless (or arg (mouse-event-p last-command-event))
 562         (vc-dir-next-line 1)))))
 563
 564 (defun vc-dir-mark ()
 565   "Mark the current file or all files in the region.
 566 If the region is active, mark all the files in the region.
 567 Otherwise mark the file on the current line and move to the next
 568 line."
 569   (interactive)
 570   (vc-dir-mark-unmark 'vc-dir-mark-file))
 571
 572 (defun vc-dir-mark-all-files (arg)
 573   "Mark all files with the same state as the current one.
 574 With a prefix argument mark all files.
 575 If the current entry is a directory, mark all child files.
 576
 577 The commands operate on files that are on the same state.
 578 This command is intended to make it easy to select all files that
 579 share the same state."
 580   (interactive "P")
 581   (if arg
 582       ;; Mark all files.
 583       (progn
 584         ;; First check that no directory is marked, we can't mark
 585         ;; files in that case.
 586         (ewoc-map
 587          (lambda (filearg)
 588            (when (and (vc-dir-fileinfo->directory filearg)
 589                       (vc-dir-fileinfo->marked filearg))
 590              (error "Cannot mark all files, directory `%s' marked"
 591                     (vc-dir-fileinfo->name filearg))))
 592          vc-ewoc)
 593         (ewoc-map
 594          (lambda (filearg)
 595            (unless (vc-dir-fileinfo->marked filearg)
 596              (setf (vc-dir-fileinfo->marked filearg) t)
 597              t))
 598          vc-ewoc))
 599     (let ((data (ewoc-data (ewoc-locate vc-ewoc))))
 600       (if (vc-dir-fileinfo->directory data)
 601           ;; It's a directory, mark child files.
 602           (let ((crt (ewoc-locate vc-ewoc)))
 603             (unless (vc-dir-children-marked-p crt)
 604               (while (setq crt (ewoc-next vc-ewoc crt))
 605                 (let ((crt-data (ewoc-data crt)))
 606                   (unless (vc-dir-fileinfo->directory crt-data)
 607                     (setf (vc-dir-fileinfo->marked crt-data) t)
 608                     (ewoc-invalidate vc-ewoc crt))))))
 609         ;; It's a file
 610         (let ((state (vc-dir-fileinfo->state data))
 611               (crt (ewoc-nth vc-ewoc 0)))
 612           (while crt
 613             (let ((crt-data (ewoc-data crt)))
 614               (when (and (not (vc-dir-fileinfo->marked crt-data))
 615                          (eq (vc-dir-fileinfo->state crt-data) state)
 616                          (not (vc-dir-fileinfo->directory crt-data)))
 617                 (vc-dir-mark-file crt)))
 618             (setq crt (ewoc-next vc-ewoc crt))))))))
 619
 620 (defun vc-dir-unmark-file ()
 621   ;; Unmark the current file and move to the next line.
 622   (let* ((crt (ewoc-locate vc-ewoc))
 623          (file (ewoc-data crt)))
 624     (setf (vc-dir-fileinfo->marked file) nil)
 625     (ewoc-invalidate vc-ewoc crt)
 626     (unless (mouse-event-p last-command-event)
 627       (vc-dir-next-line 1))))
 628
 629 (defun vc-dir-unmark ()
 630   "Unmark the current file or all files in the region.
 631 If the region is active, unmark all the files in the region.
 632 Otherwise mark the file on the current line and move to the next
 633 line."
 634   (interactive)
 635   (vc-dir-mark-unmark 'vc-dir-unmark-file))
 636
 637 (defun vc-dir-unmark-file-up ()
 638   "Move to the previous line and unmark the file."
 639   (interactive)
 640   ;; If we're on the first line, we won't move up, but we will still
 641   ;; remove the mark.  This seems a bit odd but it is what buffer-menu
 642   ;; does.
 643   (let* ((prev (ewoc-goto-prev vc-ewoc 1))
 644          (file (ewoc-data prev)))
 645     (setf (vc-dir-fileinfo->marked file) nil)
 646     (ewoc-invalidate vc-ewoc prev)
 647     (vc-dir-move-to-goal-column)))
 648
 649 (defun vc-dir-unmark-all-files (arg)
 650   "Unmark all files with the same state as the current one.
 651 With a prefix argument unmark all files.
 652 If the current entry is a directory, unmark all the child files.
 653
 654 The commands operate on files that are on the same state.
 655 This command is intended to make it easy to deselect all files
 656 that share the same state."
 657   (interactive "P")
 658   (if arg
 659       (ewoc-map
 660        (lambda (filearg)
 661          (when (vc-dir-fileinfo->marked filearg)
 662            (setf (vc-dir-fileinfo->marked filearg) nil)
 663            t))
 664        vc-ewoc)
 665     (let* ((crt (ewoc-locate vc-ewoc))
 666            (data (ewoc-data crt)))
 667       (if (vc-dir-fileinfo->directory data)
 668           ;; It's a directory, unmark child files.
 669           (while (setq crt (ewoc-next vc-ewoc crt))
 670             (let ((crt-data (ewoc-data crt)))
 671               (unless (vc-dir-fileinfo->directory crt-data)
 672                 (setf (vc-dir-fileinfo->marked crt-data) nil)
 673                 (ewoc-invalidate vc-ewoc crt))))
 674         ;; It's a file
 675         (let ((crt-state (vc-dir-fileinfo->state (ewoc-data crt))))
 676           (ewoc-map
 677            (lambda (filearg)
 678              (when (and (vc-dir-fileinfo->marked filearg)
 679                         (eq (vc-dir-fileinfo->state filearg) crt-state))
 680                (setf (vc-dir-fileinfo->marked filearg) nil)
 681                t))
 682            vc-ewoc))))))
 683
 684 (defun vc-dir-toggle-mark-file ()
 685   (let* ((crt (ewoc-locate vc-ewoc))
 686          (file (ewoc-data crt)))
 687     (if (vc-dir-fileinfo->marked file)
 688         (vc-dir-unmark-file)
 689       (vc-dir-mark-file))))
 690
 691 (defun vc-dir-toggle-mark (e)
 692   (interactive "e")
 693   (vc-dir-at-event e (vc-dir-mark-unmark 'vc-dir-toggle-mark-file)))
 694
 695 (defun vc-dir-delete-file ()
 696   "Delete the marked files, or the current file if no marks."
 697   (interactive)
 698   (mapc 'vc-delete-file (or (vc-dir-marked-files)
 699                             (list (vc-dir-current-file)))))
 700
 701 (defun vc-dir-find-file ()
 702   "Find the file on the current line."
 703   (interactive)
 704   (find-file (vc-dir-current-file)))
 705
 706 (defun vc-dir-find-file-other-window (&optional event)
 707   "Find the file on the current line, in another window."
 708   (interactive (list last-nonmenu-event))
 709   (if event (posn-set-point (event-end event)))
 710   (find-file-other-window (vc-dir-current-file)))
 711
 712 (defun vc-dir-isearch ()
 713   "Search for a string through all marked buffers using Isearch."
 714   (interactive)
 715   (multi-isearch-files
 716    (mapcar 'car (vc-dir-marked-only-files-and-states))))
 717
 718 (defun vc-dir-isearch-regexp ()
 719   "Search for a regexp through all marked buffers using Isearch."
 720   (interactive)
 721   (multi-isearch-files-regexp
 722    (mapcar 'car (vc-dir-marked-only-files-and-states))))
 723
 724 (defun vc-dir-search (regexp)
 725   "Search through all marked files for a match for REGEXP.
 726 For marked directories, use the files displayed from those directories.
 727 Stops when a match is found.
 728 To continue searching for next match, use command \\[tags-loop-continue]."
 729   (interactive "sSearch marked files (regexp): ")
 730   (tags-search regexp '(mapcar 'car (vc-dir-marked-only-files-and-states))))
 731
 732 (defun vc-dir-query-replace-regexp (from to &optional delimited)
 733   "Do `query-replace-regexp' of FROM with TO, on all marked files.
 734 For marked directories, use the files displayed from those directories.
 735 If a directory is marked, then use the files displayed for that directory.
 736 Third arg DELIMITED (prefix arg) means replace only word-delimited matches.
 737 If you exit (\\[keyboard-quit], RET or q), you can resume the query replace
 738 with the command \\[tags-loop-continue]."
 739   ;; FIXME: this is almost a copy of `dired-do-replace-regexp'.  This
 740   ;; should probably be made generic and used in both places instead of
 741   ;; duplicating it here.
 742   (interactive
 743    (let ((common
 744           (query-replace-read-args
 745            "Query replace regexp in marked files" t t)))
 746      (list (nth 0 common) (nth 1 common) (nth 2 common))))
 747   (dolist (file (mapcar 'car (vc-dir-marked-only-files-and-states)))
 748     (let ((buffer (get-file-buffer file)))
 749       (if (and buffer (with-current-buffer buffer
 750                         buffer-read-only))
 751           (error "File `%s' is visited read-only" file))))
 752   (tags-query-replace from to delimited
 753                       '(mapcar 'car (vc-dir-marked-only-files-and-states))))
 754
 755 (defun vc-dir-current-file ()
 756   (let ((node (ewoc-locate vc-ewoc)))
 757     (unless node
 758       (error "No file available"))
 759     (expand-file-name (vc-dir-fileinfo->name (ewoc-data node)))))
 760
 761 (defun vc-dir-marked-files ()
 762   "Return the list of marked files."
 763   (mapcar
 764    (lambda (elem) (expand-file-name (vc-dir-fileinfo->name elem)))
 765    (ewoc-collect vc-ewoc 'vc-dir-fileinfo->marked)))
 766
 767 (defun vc-dir-marked-only-files-and-states ()
 768   "Return the list of conses (FILE . STATE) for the marked files.
 769 For marked directories return the corresponding conses for the
 770 child files."
 771   (let ((crt (ewoc-nth vc-ewoc 0))
 772         result)
 773     (while crt
 774       (let ((crt-data (ewoc-data crt)))
 775         (if (vc-dir-fileinfo->marked crt-data)
 776             ;; FIXME: use vc-dir-child-files-and-states here instead of duplicating it.
 777             (if (vc-dir-fileinfo->directory crt-data)
 778                 (let* ((dir (vc-dir-fileinfo->directory crt-data))
 779                        (dirlen (length dir))
 780                        data)
 781                   (while
 782                       (and (setq crt (ewoc-next vc-ewoc crt))
 783                            (vc-string-prefix-p dir
 784                                                (progn
 785                                                  (setq data (ewoc-data crt))
 786                                                  (vc-dir-node-directory crt))))
 787                     (unless (vc-dir-fileinfo->directory data)
 788                       (push
 789                        (cons (expand-file-name (vc-dir-fileinfo->name data))
 790                              (vc-dir-fileinfo->state data))
 791                        result))))
 792               (push (cons (expand-file-name (vc-dir-fileinfo->name crt-data))
 793                           (vc-dir-fileinfo->state crt-data))
 794                     result)
 795               (setq crt (ewoc-next vc-ewoc crt)))
 796           (setq crt (ewoc-next vc-ewoc crt)))))
 797     (nreverse result)))
 798
 799 (defun vc-dir-child-files-and-states ()
 800   "Return the list of conses (FILE . STATE) for child files of the current entry if it's a directory.
 801 If it is a file, return the corresponding cons for the file itself."
 802   (let* ((crt (ewoc-locate vc-ewoc))
 803          (crt-data (ewoc-data crt))
 804          result)
 805     (if (vc-dir-fileinfo->directory crt-data)
 806         (let* ((dir (vc-dir-fileinfo->directory crt-data))
 807                (dirlen (length dir))
 808                data)
 809           (while
 810               (and (setq crt (ewoc-next vc-ewoc crt))
 811                    (vc-string-prefix-p dir (progn
 812                                              (setq data (ewoc-data crt))
 813                                              (vc-dir-node-directory crt))))
 814             (unless (vc-dir-fileinfo->directory data)
 815               (push
 816                (cons (expand-file-name (vc-dir-fileinfo->name data))
 817                      (vc-dir-fileinfo->state data))
 818                result))))
 819       (push
 820        (cons (expand-file-name (vc-dir-fileinfo->name crt-data))
 821              (vc-dir-fileinfo->state crt-data)) result))
 822     (nreverse result)))
 823
 824 (defun vc-dir-recompute-file-state (fname def-dir)
 825   (let* ((file-short (file-relative-name fname def-dir))
 826          (remove-me-when-CVS-works
 827           (when (eq vc-dir-backend 'CVS)
 828             ;; FIXME: Warning: UGLY HACK.  The CVS backend caches the state
 829             ;; info, this forces the backend to update it.
 830             (vc-call-backend vc-dir-backend 'registered fname)))
 831          (state (vc-call-backend vc-dir-backend 'state fname))
 832          (extra (vc-call-backend vc-dir-backend
 833                                  'status-fileinfo-extra fname)))
 834     (list file-short state extra)))
 835
 836 (defun vc-dir-find-child-files (dirname)
 837   ;; Give a DIRNAME string return the list of all child files shown in
 838   ;; the current *vc-dir* buffer.
 839   (let ((crt (ewoc-nth vc-ewoc 0))
 840         children
 841         dname)
 842     ;; Find DIR
 843     (while (and crt (not (vc-string-prefix-p
 844                           dirname (vc-dir-node-directory crt))))
 845       (setq crt (ewoc-next vc-ewoc crt)))
 846     (while (and crt (vc-string-prefix-p
 847                      dirname
 848                      (setq dname (vc-dir-node-directory crt))))
 849       (let ((data (ewoc-data crt)))
 850         (unless (vc-dir-fileinfo->directory data)
 851           (push (expand-file-name (vc-dir-fileinfo->name data)) children)))
 852       (setq crt (ewoc-next vc-ewoc crt)))
 853     children))
 854
 855 (defun vc-dir-resync-directory-files (dirname)
 856   ;; Update the entries for all the child files of DIRNAME shown in
 857   ;; the current *vc-dir* buffer.
 858   (let ((files (vc-dir-find-child-files dirname))
 859         (ddir default-directory)
 860         fileentries)
 861     (when files
 862       (dolist (crt files)
 863         (push (vc-dir-recompute-file-state crt ddir)
 864               fileentries))
 865       (vc-dir-update fileentries (current-buffer)))))
 866
 867 (defun vc-dir-resynch-file (&optional fname)
 868   "Update the entries for FNAME in any directory buffers that list it."
 869   (let ((file (or fname (expand-file-name buffer-file-name)))
 870         (drop '()))
 871     (save-current-buffer
 872       ;; look for a vc-dir buffer that might show this file.
 873       (dolist (status-buf vc-dir-buffers)
 874         (if (not (buffer-live-p status-buf))
 875             (push status-buf drop)
 876           (set-buffer status-buf)
 877           (if (not (derived-mode-p 'vc-dir-mode))
 878               (push status-buf drop)
 879             (let ((ddir default-directory))
 880               (when (vc-string-prefix-p ddir file)
 881                 (if (file-directory-p file)
 882                     (progn
 883                       (vc-dir-resync-directory-files file)
 884                       (ewoc-set-hf vc-ewoc
 885                                    (vc-dir-headers vc-dir-backend default-directory) ""))
 886                   (let ((state (vc-dir-recompute-file-state file ddir)))
 887                     (vc-dir-update
 888                      (list state)
 889                      status-buf (eq (cadr state) 'up-to-date))))))))))
 890     ;; Remove out-of-date entries from vc-dir-buffers.
 891     (dolist (b drop) (setq vc-dir-buffers (delq b vc-dir-buffers)))))
 892
 893 (defvar use-vc-backend)  ;; dynamically bound
 894
 895 (define-derived-mode vc-dir-mode special-mode "VC dir"
 896   "Major mode for VC directory buffers.
 897 Marking/Unmarking key bindings and actions:
 898 m - mark a file/directory
 899   - if the region is active, mark all the files in region.
 900     Restrictions: - a file cannot be marked if any parent directory is marked
 901                   - a directory cannot be marked if any child file or
 902                     directory is marked
 903 u - unmark a file/directory
 904   - if the region is active, unmark all the files in region.
 905 M - if the cursor is on a file: mark all the files with the same state as
 906       the current file
 907   - if the cursor is on a directory: mark all child files
 908   - with a prefix argument: mark all files
 909 U - if the cursor is on a file: unmark all the files with the same state
 910       as the current file
 911   - if the cursor is on a directory: unmark all child files
 912   - with a prefix argument: unmark all files
 913 mouse-2  - toggles the mark state
 914
 915 VC commands
 916 VC commands in the `C-x v' prefix can be used.
 917 VC commands act on the marked entries.  If nothing is marked, VC
 918 commands act on the current entry.
 919
 920 Search & Replace
 921 S - searches the marked files
 922 Q - does a query replace on the marked files
 923 M-s a C-s - does an isearch on the marked files
 924 M-s a C-M-s - does a regexp isearch on the marked files
 925 If nothing is marked, these commands act on the current entry.
 926 When a directory is current or marked, the Search & Replace
 927 commands act on the child files of that directory that are displayed in
 928 the *vc-dir* buffer.
 929
 930 \\{vc-dir-mode-map}"
 931   (set (make-local-variable 'vc-dir-backend) use-vc-backend)
 932   (setq buffer-read-only t)
 933   (when (boundp 'tool-bar-map)
 934     (set (make-local-variable 'tool-bar-map) vc-dir-tool-bar-map))
 935   (let ((buffer-read-only nil))
 936     (erase-buffer)
 937     (set (make-local-variable 'vc-dir-process-buffer) nil)
 938     (set (make-local-variable 'vc-ewoc) (ewoc-create #'vc-dir-printer))
 939     (set (make-local-variable 'revert-buffer-function)
 940          'vc-dir-revert-buffer-function)
 941     (setq list-buffers-directory (expand-file-name "*vc-dir*" default-directory))
 942     (add-to-list 'vc-dir-buffers (current-buffer))
 943     ;; Make sure that if the directory buffer is killed, the update
 944     ;; process running in the background is also killed.
 945     (add-hook 'kill-buffer-query-functions 'vc-dir-kill-query nil t)
 946     (hack-dir-local-variables-non-file-buffer)
 947     (vc-dir-refresh)))
 948
 949 (defun vc-dir-headers (backend dir)
 950   "Display the headers in the *VC dir* buffer.
 951 It calls the `dir-extra-headers' backend method to display backend
 952 specific headers."
 953   (concat
 954    ;; First layout the common headers.
 955    (propertize "VC backend : " 'face 'font-lock-type-face)
 956    (propertize (format "%s\n" backend) 'face 'font-lock-variable-name-face)
 957    (propertize "Working dir: " 'face 'font-lock-type-face)
 958    (propertize (format "%s\n" (abbreviate-file-name dir))
 959                'face 'font-lock-variable-name-face)
 960    ;; Then the backend specific ones.
 961    (vc-call-backend backend 'dir-extra-headers dir)
 962    "\n"))
 963
 964 (defun vc-dir-refresh-files (files default-state)
 965   "Refresh some files in the *VC-dir* buffer."
 966   (let ((def-dir default-directory)
 967         (backend vc-dir-backend))
 968     (vc-set-mode-line-busy-indicator)
 969     ;; Call the `dir-status-file' backend function.
 970     ;; `dir-status-file' is supposed to be asynchronous.
 971     ;; It should compute the results, and then call the function
 972     ;; passed as an argument in order to update the vc-dir buffer
 973     ;; with the results.
 974     (unless (buffer-live-p vc-dir-process-buffer)
 975       (setq vc-dir-process-buffer
 976             (generate-new-buffer (format " *VC-%s* tmp status" backend))))
 977     (lexical-let ((buffer (current-buffer)))
 978       (with-current-buffer vc-dir-process-buffer
 979         (cd def-dir)
 980         (erase-buffer)
 981         (vc-call-backend
 982          backend 'dir-status-files def-dir files default-state
 983          (lambda (entries &optional more-to-come)
 984            ;; ENTRIES is a list of (FILE VC_STATE EXTRA) items.
 985            ;; If MORE-TO-COME is true, then more updates will come from
 986            ;; the asynchronous process.
 987            (with-current-buffer buffer
 988              (vc-dir-update entries buffer)
 989              (unless more-to-come
 990                (setq mode-line-process nil)
 991                ;; Remove the ones that haven't been updated at all.
 992                ;; Those not-updated are those whose state is nil because the
 993                ;; file/dir doesn't exist and isn't versioned.
 994                (ewoc-filter vc-ewoc
 995                             (lambda (info)
 996                               ;; The state for directory entries might
 997                               ;; have been changed to 'up-to-date,
 998                               ;; reset it, othewise it will be removed when doing 'x'
 999                               ;; next time.
1000                               ;; FIXME: There should be a more elegant way to do this.
1001                               (when (and (vc-dir-fileinfo->directory info)
1002                                          (eq (vc-dir-fileinfo->state info)
1003                                              'up-to-date))
1004                                 (setf (vc-dir-fileinfo->state info) nil))
1005
1006                               (not (vc-dir-fileinfo->needs-update info))))))))))))
1007
1008 (defun vc-dir-revert-buffer-function (&optional ignore-auto noconfirm)
1009   (vc-dir-refresh))
1010
1011 (defun vc-dir-refresh ()
1012   "Refresh the contents of the *VC-dir* buffer.
1013 Throw an error if another update process is in progress."
1014   (interactive)
1015   (if (vc-dir-busy)
1016       (error "Another update process is in progress, cannot run two at a time")
1017     (let ((def-dir default-directory)
1018           (backend vc-dir-backend))
1019       (vc-set-mode-line-busy-indicator)
1020       ;; Call the `dir-status' backend function.
1021       ;; `dir-status' is supposed to be asynchronous.
1022       ;; It should compute the results, and then call the function
1023       ;; passed as an argument in order to update the vc-dir buffer
1024       ;; with the results.
1025
1026       ;; Create a buffer that can be used by `dir-status' and call
1027       ;; `dir-status' with this buffer as the current buffer.  Use
1028       ;; `vc-dir-process-buffer' to remember this buffer, so that
1029       ;; it can be used later to kill the update process in case it
1030       ;; takes too long.
1031       (unless (buffer-live-p vc-dir-process-buffer)
1032         (setq vc-dir-process-buffer
1033               (generate-new-buffer (format " *VC-%s* tmp status" backend))))
1034       ;; set the needs-update flag on all non-directory entries
1035       (ewoc-map (lambda (info)
1036                   (unless (vc-dir-fileinfo->directory info)
1037                     (setf (vc-dir-fileinfo->needs-update info) t) nil))
1038                 vc-ewoc)
1039       (lexical-let ((buffer (current-buffer)))
1040         (with-current-buffer vc-dir-process-buffer
1041           (cd def-dir)
1042           (erase-buffer)
1043           (vc-call-backend
1044            backend 'dir-status def-dir
1045            (lambda (entries &optional more-to-come)
1046              ;; ENTRIES is a list of (FILE VC_STATE EXTRA) items.
1047              ;; If MORE-TO-COME is true, then more updates will come from
1048              ;; the asynchronous process.
1049              (with-current-buffer buffer
1050                (vc-dir-update entries buffer)
1051                (unless more-to-come
1052                  (let ((remaining
1053                         (ewoc-collect
1054                          vc-ewoc 'vc-dir-fileinfo->needs-update)))
1055                    (if remaining
1056                        (vc-dir-refresh-files
1057                         (mapcar 'vc-dir-fileinfo->name remaining)
1058                         'up-to-date)
1059                      (setq mode-line-process nil)))))))))
1060       (ewoc-set-hf vc-ewoc (vc-dir-headers backend def-dir) ""))))
1061
1062 (defun vc-dir-show-fileentry (file)
1063   "Insert an entry for a specific file into the current *VC-dir* listing.
1064 This is typically used if the file is up-to-date (or has been added
1065 outside of VC) and one wants to do some operation on it."
1066   (interactive "fShow file: ")
1067   (vc-dir-update (list (list (file-relative-name file) (vc-state file))) (current-buffer)))
1068
1069 (defun vc-dir-hide-up-to-date ()
1070   "Hide up-to-date items from display."
1071   (interactive)
1072   (let ((crt (ewoc-nth vc-ewoc -1))
1073         (first (ewoc-nth vc-ewoc 0)))
1074     ;; Go over from the last item to the first and remove the
1075     ;; up-to-date files and directories with no child files.
1076     (while (not (eq crt first))
1077       (let* ((data (ewoc-data crt))
1078              (dir (vc-dir-fileinfo->directory data))
1079              (next (ewoc-next vc-ewoc crt))
1080              (prev (ewoc-prev vc-ewoc crt))
1081              ;; ewoc-delete does not work without this...
1082              (inhibit-read-only t))
1083           (when (or
1084                  ;; Remove directories with no child files.
1085                  (and dir
1086                       (or
1087                        ;; Nothing follows this directory.
1088                        (not next)
1089                        ;; Next item is a directory.
1090                        (vc-dir-fileinfo->directory (ewoc-data next))))
1091                  ;; Remove files in the up-to-date state.
1092                  (eq (vc-dir-fileinfo->state data) 'up-to-date))
1093             (ewoc-delete vc-ewoc crt))
1094           (setq crt prev)))))
1095
1096 (defun vc-dir-kill-line ()
1097   "Remove the current line from display."
1098   (interactive)
1099   (let ((crt (ewoc-locate vc-ewoc))
1100         (inhibit-read-only t))
1101     (ewoc-delete vc-ewoc crt)))
1102
1103 (defun vc-dir-printer (fileentry)
1104   (vc-call-backend vc-dir-backend 'dir-printer fileentry))
1105
1106 (defun vc-dir-deduce-fileset (&optional state-model-only-files)
1107   (let ((marked (vc-dir-marked-files))
1108         files
1109         only-files-list
1110         state
1111         model)
1112     (if marked
1113         (progn
1114           (setq files marked)
1115           (when state-model-only-files
1116             (setq only-files-list (vc-dir-marked-only-files-and-states))))
1117       (let ((crt (vc-dir-current-file)))
1118         (setq files (list crt))
1119         (when state-model-only-files
1120           (setq only-files-list (vc-dir-child-files-and-states)))))
1121
1122     (when state-model-only-files
1123       (setq state (cdar only-files-list))
1124       ;; Check that all files are in a consistent state, since we use that
1125       ;; state to decide which operation to perform.
1126       (dolist (crt (cdr only-files-list))
1127         (unless (vc-compatible-state (cdr crt) state)
1128           (error "When applying VC operations to multiple files, the files are required\nto  be in similar VC states.\n%s in state %s clashes with %s in state %s"
1129                  (car crt) (cdr crt) (caar only-files-list) state)))
1130       (setq only-files-list (mapcar 'car only-files-list))
1131       (when (and state (not (eq state 'unregistered)))
1132         (setq model (vc-checkout-model vc-dir-backend only-files-list))))
1133     (list vc-dir-backend files only-files-list state model)))
1134
1135 ;;;###autoload
1136 (defun vc-dir (dir &optional backend)
1137   "Show the VC status for \"interesting\" files in and below DIR.
1138 This allows you to mark files and perform VC operations on them.
1139 The list omits files which are up to date, with no changes in your copy
1140 or the repository, if there is nothing in particular to say about them.
1141
1142 Preparing the list of file status takes time; when the buffer
1143 first appears, it has only the first few lines of summary information.
1144 The file lines appear later.
1145
1146 Optional second argument BACKEND specifies the VC backend to use.
1147 Interactively, a prefix argument means to ask for the backend.
1148
1149 These are the commands available for use in the file status buffer:
1150
1151 \\{vc-dir-mode-map}"
1152
1153   (interactive
1154    (list
1155     ;; When you hit C-x v d in a visited VC file,
1156     ;; the *vc-dir* buffer visits the directory under its truename;
1157     ;; therefore it makes sense to always do that.
1158     ;; Otherwise if you do C-x v d -> C-x C-f -> C-c v d
1159     ;; you may get a new *vc-dir* buffer, different from the original
1160     (file-truename (read-file-name "VC status for directory: "
1161                                    default-directory default-directory t
1162                                    nil #'file-directory-p))
1163     (if current-prefix-arg
1164         (intern
1165          (completing-read
1166           "Use VC backend: "
1167           (mapcar (lambda (b) (list (symbol-name b)))
1168                   vc-handled-backends)
1169           nil t nil nil)))))
1170   (unless backend
1171     (setq backend (vc-responsible-backend dir)))
1172   (let (pop-up-windows)               ; based on cvs-examine; bug#6204
1173     (pop-to-buffer (vc-dir-prepare-status-buffer "*vc-dir*" dir backend)))
1174   (if (derived-mode-p 'vc-dir-mode)
1175       (vc-dir-refresh)
1176     ;; FIXME: find a better way to pass the backend to `vc-dir-mode'.
1177     (let ((use-vc-backend backend))
1178       (vc-dir-mode))))
1179
1180 (defun vc-default-dir-extra-headers (backend dir)
1181   ;; Be loud by default to remind people to add code to display
1182   ;; backend specific headers.
1183   ;; XXX: change this to return nil before the release.
1184   (concat
1185    (propertize "Extra      : " 'face 'font-lock-type-face)
1186    (propertize "Please add backend specific headers here.  It's easy!"
1187                'face 'font-lock-warning-face)))
1188
1189 (defvar vc-dir-filename-mouse-map
1190    (let ((map (make-sparse-keymap)))
1191      (define-key map [mouse-2] 'vc-dir-find-file-other-window)
1192     map)
1193   "Local keymap for visiting a file.")
1194
1195 (defun vc-default-dir-printer (backend fileentry)
1196   "Pretty print FILEENTRY."
1197   ;; If you change the layout here, change vc-dir-move-to-goal-column.
1198   ;; VC backends can implement backend specific versions of this
1199   ;; function.  Changes here might need to be reflected in the
1200   ;; vc-BACKEND-dir-printer functions.
1201   (let* ((isdir (vc-dir-fileinfo->directory fileentry))
1202         (state (if isdir "" (vc-dir-fileinfo->state fileentry)))
1203         (filename (vc-dir-fileinfo->name fileentry)))
1204     (insert
1205      (propertize
1206       (format "%c" (if (vc-dir-fileinfo->marked fileentry) ?* ? ))
1207       'face 'font-lock-type-face)
1208      "   "
1209      (propertize
1210       (format "%-20s" state)
1211       'face (cond ((eq state 'up-to-date) 'font-lock-builtin-face)
1212                   ((memq state '(missing conflict)) 'font-lock-warning-face)
1213                   (t 'font-lock-variable-name-face))
1214       'mouse-face 'highlight)
1215      " "
1216      (propertize
1217       (format "%s" filename)
1218       'face
1219       (if isdir 'font-lock-comment-delimiter-face 'font-lock-function-name-face)
1220       'help-echo
1221       (if isdir
1222           "Directory\nVC operations can be applied to it\nmouse-3: Pop-up menu"
1223         "File\nmouse-3: Pop-up menu")
1224       'mouse-face 'highlight
1225       'keymap vc-dir-filename-mouse-map))))
1226
1227 (defun vc-default-extra-status-menu (backend)
1228   nil)
1229
1230 (defun vc-default-status-fileinfo-extra (backend file)
1231   "Default absence of extra information returned for a file."
1232   nil)
1233
1234 (provide 'vc-dir)
1235
1236 ;; arch-tag: 0274a2e3-e8e9-4b1a-a73c-e8b9129d5d15
1237 ;;; vc-dir.el ends here