lisp/vc-annotate.el

   1 ;;; vc-annotate.el --- VC Annotate Support
   2
   3 ;; Copyright (C) 1997, 1998, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   4 ;;   2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author:     Martin Lorentzson  <emwson@emw.ericsson.se>
   7 ;; Maintainer: FSF
   8 ;; Keywords: tools
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26 ;;
  27
  28 (require 'vc-hooks)
  29 (require 'vc)
  30
  31 ;;; Code:
  32 (eval-when-compile
  33   (require 'cl))
  34
  35 (defcustom vc-annotate-display-mode 'fullscale
  36   "Which mode to color the output of \\[vc-annotate] with by default."
  37   :type '(choice (const :tag "By Color Map Range" nil)
  38                  (const :tag "Scale to Oldest" scale)
  39                  (const :tag "Scale Oldest->Newest" fullscale)
  40                  (number :tag "Specify Fractional Number of Days"
  41                          :value "20.5"))
  42   :group 'vc)
  43
  44 (defcustom vc-annotate-color-map
  45   (if (and (tty-display-color-p) (<= (display-color-cells) 8))
  46       ;; A custom sorted TTY colormap
  47       (let* ((colors
  48               (sort
  49                (delq nil
  50                      (mapcar (lambda (x)
  51                                (if (not (or
  52                                          (string-equal (car x) "white")
  53                                          (string-equal (car x) "black") ))
  54                                    (car x)))
  55                              (tty-color-alist)))
  56                (lambda (a b)
  57                  (cond
  58                   ((or (string-equal a "red") (string-equal b "blue")) t)
  59                   ((or (string-equal b "red") (string-equal a "blue")) nil)
  60                   ((string-equal a "yellow") t)
  61                   ((string-equal b "yellow") nil)
  62                   ((string-equal a "cyan") t)
  63                   ((string-equal b "cyan") nil)
  64                   ((string-equal a "green") t)
  65                   ((string-equal b "green") nil)
  66                   ((string-equal a "magenta") t)
  67                   ((string-equal b "magenta") nil)
  68                   (t (string< a b))))))
  69              (date 20.)
  70              (delta (/ (- 360. date) (1- (length colors)))))
  71         (mapcar (lambda (x)
  72                   (prog1
  73                       (cons date x)
  74                     (setq date (+ date delta)))) colors))
  75     ;; Normal colormap: hue stepped from 0-240deg, value=1., saturation=0.75
  76     '(( 20. . "#FF3F3F")
  77       ( 40. . "#FF6C3F")
  78       ( 60. . "#FF993F")
  79       ( 80. . "#FFC63F")
  80       (100. . "#FFF33F")
  81       (120. . "#DDFF3F")
  82       (140. . "#B0FF3F")
  83       (160. . "#83FF3F")
  84       (180. . "#56FF3F")
  85       (200. . "#3FFF56")
  86       (220. . "#3FFF83")
  87       (240. . "#3FFFB0")
  88       (260. . "#3FFFDD")
  89       (280. . "#3FF3FF")
  90       (300. . "#3FC6FF")
  91       (320. . "#3F99FF")
  92       (340. . "#3F6CFF")
  93       (360. . "#3F3FFF")))
  94   "Association list of age versus color, for \\[vc-annotate].
  95 Ages are given in units of fractional days.  Default is eighteen
  96 steps using a twenty day increment, from red to blue.  For TTY
  97 displays with 8 or fewer colors, the default is red to blue with
  98 all other colors between (excluding black and white)."
  99   :type 'alist
 100   :group 'vc)
 101
 102 (defcustom vc-annotate-very-old-color "#3F3FFF"
 103   "Color for lines older than the current color range in \\[vc-annotate]."
 104   :type 'string
 105   :group 'vc)
 106
 107 (defcustom vc-annotate-background "black"
 108   "Background color for \\[vc-annotate].
 109 Default color is used if nil."
 110   :type '(choice (const :tag "Default background" nil) (color))
 111   :group 'vc)
 112
 113 (defcustom vc-annotate-menu-elements '(2 0.5 0.1 0.01)
 114   "Menu elements for the mode-specific menu of VC-Annotate mode.
 115 List of factors, used to expand/compress the time scale.  See `vc-annotate'."
 116   :type '(repeat number)
 117   :group 'vc)
 118
 119 (defvar vc-annotate-mode-map
 120   (let ((m (make-sparse-keymap)))
 121     (define-key m "a" 'vc-annotate-revision-previous-to-line)
 122     (define-key m "d" 'vc-annotate-show-diff-revision-at-line)
 123     (define-key m "D" 'vc-annotate-show-changeset-diff-revision-at-line)
 124     (define-key m "f" 'vc-annotate-find-revision-at-line)
 125     (define-key m "j" 'vc-annotate-revision-at-line)
 126     (define-key m "l" 'vc-annotate-show-log-revision-at-line)
 127     (define-key m "n" 'vc-annotate-next-revision)
 128     (define-key m "p" 'vc-annotate-prev-revision)
 129     (define-key m "w" 'vc-annotate-working-revision)
 130     (define-key m "v" 'vc-annotate-toggle-annotation-visibility)
 131     m)
 132   "Local keymap used for VC-Annotate mode.")
 133
 134 ;;; Annotate functionality
 135
 136 ;; Declare globally instead of additional parameter to
 137 ;; temp-buffer-show-function (not possible to pass more than one
 138 ;; parameter).  The use of annotate-ratio is deprecated in favor of
 139 ;; annotate-mode, which replaces it with the more sensible "span-to
 140 ;; days", along with autoscaling support.
 141 (defvar vc-annotate-ratio nil "Global variable.")
 142
 143 ;; internal buffer-local variables
 144 (defvar vc-annotate-backend nil)
 145 (defvar vc-annotate-parent-file nil)
 146 (defvar vc-annotate-parent-rev nil)
 147 (defvar vc-annotate-parent-display-mode nil)
 148
 149 (defconst vc-annotate-font-lock-keywords
 150   ;; The fontification is done by vc-annotate-lines instead of font-lock.
 151   '((vc-annotate-lines)))
 152
 153 (define-derived-mode vc-annotate-mode special-mode "Annotate"
 154   "Major mode for output buffers of the `vc-annotate' command.
 155
 156 You can use the mode-specific menu to alter the time-span of the used
 157 colors.  See variable `vc-annotate-menu-elements' for customizing the
 158 menu items."
 159   ;; Frob buffer-invisibility-spec so that if it is originally a naked t,
 160   ;; it will become a list, to avoid initial annotations being invisible.
 161   (add-to-invisibility-spec 'foo)
 162   (remove-from-invisibility-spec 'foo)
 163   (set (make-local-variable 'truncate-lines) t)
 164   (set (make-local-variable 'font-lock-defaults)
 165        '(vc-annotate-font-lock-keywords t))
 166   (hack-dir-local-variables-non-file-buffer))
 167
 168 (defun vc-annotate-toggle-annotation-visibility ()
 169   "Toggle whether or not the annotation is visible."
 170   (interactive)
 171   (funcall (if (memq 'vc-annotate-annotation buffer-invisibility-spec)
 172                'remove-from-invisibility-spec
 173              'add-to-invisibility-spec)
 174            'vc-annotate-annotation)
 175   (force-window-update (current-buffer)))
 176
 177 (defun vc-annotate-display-default (ratio)
 178   "Display the output of \\[vc-annotate] using the default color range.
 179 The color range is given by `vc-annotate-color-map', scaled by RATIO.
 180 The current time is used as the offset."
 181   (interactive (progn (kill-local-variable 'vc-annotate-color-map) '(1.0)))
 182   (message "Redisplaying annotation...")
 183   (vc-annotate-display ratio)
 184   (message "Redisplaying annotation...done"))
 185
 186 (defun vc-annotate-oldest-in-map (color-map)
 187   "Return the oldest time in the COLOR-MAP."
 188   ;; Since entries should be sorted, we can just use the last one.
 189   (caar (last color-map)))
 190
 191 (defun vc-annotate-get-time-set-line-props ()
 192   (let ((bol (point))
 193         (date (vc-call-backend vc-annotate-backend 'annotate-time))
 194         (inhibit-read-only t))
 195     (assert (>= (point) bol))
 196     (put-text-property bol (point) 'invisible 'vc-annotate-annotation)
 197     date))
 198
 199 (defun vc-annotate-display-autoscale (&optional full)
 200   "Highlight the output of \\[vc-annotate] using an autoscaled color map.
 201 Autoscaling means that the map is scaled from the current time to the
 202 oldest annotation in the buffer, or, with prefix argument FULL, to
 203 cover the range from the oldest annotation to the newest."
 204   (interactive "P")
 205   (let ((newest 0.0)
 206         (oldest 999999.)                ;Any CVS users at the founding of Rome?
 207         (current (vc-annotate-convert-time (current-time)))
 208         date)
 209     (message "Redisplaying annotation...")
 210     ;; Run through this file and find the oldest and newest dates annotated.
 211     (save-excursion
 212       (goto-char (point-min))
 213       (while (not (eobp))
 214         (when (setq date (vc-annotate-get-time-set-line-props))
 215           (when (> date newest)
 216             (setq newest date))
 217           (when (< date oldest)
 218             (setq oldest date)))
 219         (forward-line 1)))
 220     (vc-annotate-display
 221      (/ (- (if full newest current) oldest)
 222         (vc-annotate-oldest-in-map vc-annotate-color-map))
 223      (if full newest))
 224     (message "Redisplaying annotation...done \(%s\)"
 225              (if full
 226                  (format "Spanned from %.1f to %.1f days old"
 227                          (- current oldest)
 228                          (- current newest))
 229                (format "Spanned to %.1f days old" (- current oldest))))))
 230
 231 ;; Menu -- Using easymenu.el
 232 (easy-menu-define vc-annotate-mode-menu vc-annotate-mode-map
 233   "VC Annotate Display Menu"
 234   `("VC-Annotate"
 235     ["By Color Map Range" (unless (null vc-annotate-display-mode)
 236                  (setq vc-annotate-display-mode nil)
 237                  (vc-annotate-display-select))
 238      :style toggle :selected (null vc-annotate-display-mode)]
 239     ,@(let ((oldest-in-map (vc-annotate-oldest-in-map vc-annotate-color-map)))
 240         (mapcar (lambda (element)
 241                   (let ((days (* element oldest-in-map)))
 242                     `[,(format "Span %.1f days" days)
 243                       (vc-annotate-display-select nil ,days)
 244                       :style toggle :selected
 245                       (eql vc-annotate-display-mode ,days) ]))
 246                 vc-annotate-menu-elements))
 247     ["Span ..."
 248      (vc-annotate-display-select
 249       nil (float (string-to-number (read-string "Span how many days? "))))]
 250     "--"
 251     ["Span to Oldest"
 252      (unless (eq vc-annotate-display-mode 'scale)
 253        (vc-annotate-display-select nil 'scale))
 254      :help
 255      "Use an autoscaled color map from the oldest annotation to the current time"
 256      :style toggle :selected
 257      (eq vc-annotate-display-mode 'scale)]
 258     ["Span Oldest->Newest"
 259      (unless (eq vc-annotate-display-mode 'fullscale)
 260        (vc-annotate-display-select nil 'fullscale))
 261      :help
 262      "Use an autoscaled color map from the oldest to the newest annotation"
 263      :style toggle :selected
 264      (eq vc-annotate-display-mode 'fullscale)]
 265     "--"
 266     ["Toggle annotation visibility" vc-annotate-toggle-annotation-visibility
 267      :help
 268      "Toggle whether the annotation is visible or not"]
 269     ["Annotate previous revision" vc-annotate-prev-revision
 270      :help "Visit the annotation of the revision previous to this one"]
 271     ["Annotate next revision" vc-annotate-next-revision
 272      :help "Visit the annotation of the revision after this one"]
 273     ["Annotate revision at line" vc-annotate-revision-at-line
 274      :help
 275      "Visit the annotation of the revision identified in the current line"]
 276     ["Annotate revision previous to line" vc-annotate-revision-previous-to-line
 277      :help "Visit the annotation of the revision before the revision at line"]
 278     ["Annotate latest revision" vc-annotate-working-revision
 279      :help "Visit the annotation of the working revision of this file"]
 280     "--"
 281     ["Show log of revision at line" vc-annotate-show-log-revision-at-line
 282      :help "Visit the log of the revision at line"]
 283     ["Show diff of revision at line" vc-annotate-show-diff-revision-at-line
 284      :help "Visit the diff of the revision at line from its previous revision"]
 285     ["Show changeset diff of revision at line"
 286      vc-annotate-show-changeset-diff-revision-at-line
 287      :enable
 288      (eq 'repository (vc-call-backend ,vc-annotate-backend 'revision-granularity))
 289      :help "Visit the diff of the revision at line from its previous revision"]
 290     ["Visit revision at line" vc-annotate-find-revision-at-line
 291      :help "Visit the revision identified in the current line"]))
 292
 293 (defun vc-annotate-display-select (&optional buffer mode)
 294   "Highlight the output of \\[vc-annotate].
 295 By default, the current buffer is highlighted, unless overridden by
 296 BUFFER.  `vc-annotate-display-mode' specifies the highlighting mode to
 297 use; you may override this using the second optional arg MODE."
 298   (interactive)
 299   (when mode (setq vc-annotate-display-mode mode))
 300   (pop-to-buffer (or buffer (current-buffer)))
 301   (cond ((null vc-annotate-display-mode)
 302          ;; The ratio is global, thus relative to the global color-map.
 303          (kill-local-variable 'vc-annotate-color-map)
 304          (vc-annotate-display-default (or vc-annotate-ratio 1.0)))
 305         ;; One of the auto-scaling modes
 306         ((eq vc-annotate-display-mode 'scale)
 307          (vc-exec-after `(vc-annotate-display-autoscale)))
 308         ((eq vc-annotate-display-mode 'fullscale)
 309          (vc-exec-after `(vc-annotate-display-autoscale t)))
 310         ((numberp vc-annotate-display-mode) ; A fixed number of days lookback
 311          (vc-annotate-display-default
 312           (/ vc-annotate-display-mode
 313              (vc-annotate-oldest-in-map vc-annotate-color-map))))
 314         (t (error "No such display mode: %s"
 315                   vc-annotate-display-mode))))
 316
 317 ;;;###autoload
 318 (defun vc-annotate (file rev &optional display-mode buf move-point-to)
 319   "Display the edit history of the current file using colors.
 320
 321 This command creates a buffer that shows, for each line of the current
 322 file, when it was last edited and by whom.  Additionally, colors are
 323 used to show the age of each line--blue means oldest, red means
 324 youngest, and intermediate colors indicate intermediate ages.  By
 325 default, the time scale stretches back one year into the past;
 326 everything that is older than that is shown in blue.
 327
 328 With a prefix argument, this command asks two questions in the
 329 minibuffer.  First, you may enter a revision number; then the buffer
 330 displays and annotates that revision instead of the working revision
 331 \(type RET in the minibuffer to leave that default unchanged).  Then,
 332 you are prompted for the time span in days which the color range
 333 should cover.  For example, a time span of 20 days means that changes
 334 over the past 20 days are shown in red to blue, according to their
 335 age, and everything that is older than that is shown in blue.
 336
 337 If MOVE-POINT-TO is given, move the point to that line.
 338
 339 Customization variables:
 340
 341 `vc-annotate-menu-elements' customizes the menu elements of the
 342 mode-specific menu.  `vc-annotate-color-map' and
 343 `vc-annotate-very-old-color' define the mapping of time to colors.
 344 `vc-annotate-background' specifies the background color."
 345   (interactive
 346    (save-current-buffer
 347      (vc-ensure-vc-buffer)
 348      (list buffer-file-name
 349            (let ((def (vc-working-revision buffer-file-name)))
 350              (if (null current-prefix-arg) def
 351                (read-string
 352                 (format "Annotate from revision (default %s): " def)
 353                 nil nil def)))
 354            (if (null current-prefix-arg)
 355                vc-annotate-display-mode
 356              (float (string-to-number
 357                      (read-string "Annotate span days (default 20): "
 358                                   nil nil "20")))))))
 359   (vc-ensure-vc-buffer)
 360   (setq vc-annotate-display-mode display-mode) ;Not sure why.  --Stef
 361   (let* ((temp-buffer-name (format "*Annotate %s (rev %s)*" (buffer-name) rev))
 362          (temp-buffer-show-function 'vc-annotate-display-select)
 363          ;; If BUF is specified, we presume the caller maintains current line,
 364          ;; so we don't need to do it here.  This implementation may give
 365          ;; strange results occasionally in the case of REV != WORKFILE-REV.
 366          (current-line (or move-point-to (unless buf
 367                                            (save-restriction
 368                                              (widen)
 369                                              (line-number-at-pos))))))
 370     (message "Annotating...")
 371     ;; If BUF is specified it tells in which buffer we should put the
 372     ;; annotations.  This is used when switching annotations to another
 373     ;; revision, so we should update the buffer's name.
 374     (when buf (with-current-buffer buf
 375                 (rename-buffer temp-buffer-name t)
 376                 ;; In case it had to be uniquified.
 377                 (setq temp-buffer-name (buffer-name))))
 378     (with-output-to-temp-buffer temp-buffer-name
 379       (let ((backend (vc-backend file))
 380             (coding-system-for-read buffer-file-coding-system))
 381         (vc-call-backend backend 'annotate-command file
 382                          (get-buffer temp-buffer-name) rev)
 383         ;; we must setup the mode first, and then set our local
 384         ;; variables before the show-function is called at the exit of
 385         ;; with-output-to-temp-buffer
 386         (with-current-buffer temp-buffer-name
 387           (unless (equal major-mode 'vc-annotate-mode)
 388             (vc-annotate-mode))
 389           (set (make-local-variable 'vc-annotate-backend) backend)
 390           (set (make-local-variable 'vc-annotate-parent-file) file)
 391           (set (make-local-variable 'vc-annotate-parent-rev) rev)
 392           (set (make-local-variable 'vc-annotate-parent-display-mode)
 393                display-mode))))
 394
 395     (with-current-buffer temp-buffer-name
 396       (vc-exec-after
 397        `(progn
 398           ;; Ideally, we'd rather not move point if the user has already
 399           ;; moved it elsewhere, but really point here is not the position
 400           ;; of the user's cursor :-(
 401           (when ,current-line           ;(and (bobp))
 402             (goto-line ,current-line)
 403             (setq vc-sentinel-movepoint (point)))
 404           (unless (active-minibuffer-window)
 405             (message "Annotating... done")))))))
 406
 407 (defun vc-annotate-prev-revision (prefix)
 408   "Visit the annotation of the revision previous to this one.
 409
 410 With a numeric prefix argument, annotate the revision that many
 411 revisions previous."
 412   (interactive "p")
 413   (vc-annotate-warp-revision (- 0 prefix)))
 414
 415 (defun vc-annotate-next-revision (prefix)
 416   "Visit the annotation of the revision after this one.
 417
 418 With a numeric prefix argument, annotate the revision that many
 419 revisions after."
 420   (interactive "p")
 421   (vc-annotate-warp-revision prefix))
 422
 423 (defun vc-annotate-working-revision ()
 424   "Visit the annotation of the working revision of this file."
 425   (interactive)
 426   (if (not (equal major-mode 'vc-annotate-mode))
 427       (message "Cannot be invoked outside of a vc annotate buffer")
 428     (let ((warp-rev (vc-working-revision vc-annotate-parent-file)))
 429       (if (equal warp-rev vc-annotate-parent-rev)
 430           (message "Already at revision %s" warp-rev)
 431         (vc-annotate-warp-revision warp-rev)))))
 432
 433 (defun vc-annotate-extract-revision-at-line ()
 434   "Extract the revision number of the current line.
 435 Return a cons (REV . FILENAME)."
 436   ;; This function must be invoked from a buffer in vc-annotate-mode
 437   (let ((rev (vc-call-backend vc-annotate-backend
 438                               'annotate-extract-revision-at-line)))
 439     (if (or (null rev) (consp rev))
 440         rev
 441       (cons rev vc-annotate-parent-file))))
 442
 443 (defun vc-annotate-revision-at-line ()
 444   "Visit the annotation of the revision identified in the current line."
 445   (interactive)
 446   (if (not (equal major-mode 'vc-annotate-mode))
 447       (message "Cannot be invoked outside of a vc annotate buffer")
 448     (let ((rev-at-line (vc-annotate-extract-revision-at-line)))
 449       (if (not rev-at-line)
 450           (message "Cannot extract revision number from the current line")
 451         (if (and (equal (car rev-at-line) vc-annotate-parent-rev)
 452                  (string= (cdr rev-at-line) vc-annotate-parent-file))
 453             (message "Already at revision %s" rev-at-line)
 454           (vc-annotate-warp-revision (car rev-at-line) (cdr rev-at-line)))))))
 455
 456 (defun vc-annotate-find-revision-at-line ()
 457   "Visit the revision identified in the current line."
 458   (interactive)
 459   (if (not (equal major-mode 'vc-annotate-mode))
 460       (message "Cannot be invoked outside of a vc annotate buffer")
 461     (let ((rev-at-line (vc-annotate-extract-revision-at-line)))
 462       (if (not rev-at-line)
 463           (message "Cannot extract revision number from the current line")
 464         (switch-to-buffer-other-window
 465          (vc-find-revision (cdr rev-at-line) (car rev-at-line)))))))
 466
 467 (defun vc-annotate-revision-previous-to-line ()
 468   "Visit the annotation of the revision before the revision at line."
 469   (interactive)
 470   (if (not (equal major-mode 'vc-annotate-mode))
 471       (message "Cannot be invoked outside of a vc annotate buffer")
 472     (let* ((rev-at-line (vc-annotate-extract-revision-at-line))
 473            (prev-rev nil)
 474            (rev (car rev-at-line))
 475            (fname (cdr rev-at-line)))
 476       (if (not rev-at-line)
 477           (message "Cannot extract revision number from the current line")
 478         (setq prev-rev
 479               (vc-call-backend vc-annotate-backend 'previous-revision
 480                                fname rev))
 481         (vc-annotate-warp-revision prev-rev fname)))))
 482
 483 (defvar log-view-vc-backend)
 484 (defvar log-view-vc-fileset)
 485
 486 (defun vc-annotate-show-log-revision-at-line ()
 487   "Visit the log of the revision at line.
 488 If the VC backend supports it, only show the log entry for the revision.
 489 If a *vc-change-log* buffer exists and already shows a log for
 490 the file in question, search for the log entry required and move point ."
 491   (interactive)
 492   (if (not (equal major-mode 'vc-annotate-mode))
 493       (message "Cannot be invoked outside of a vc annotate buffer")
 494     (let ((rev-at-line (vc-annotate-extract-revision-at-line)))
 495       (if (not rev-at-line)
 496           (message "Cannot extract revision number from the current line")
 497         (let ((backend vc-annotate-backend)
 498               (log-buf (get-buffer "*vc-change-log*"))
 499               pos)
 500           (if (and
 501                log-buf
 502                ;; Look for a log buffer that already displays the correct file.
 503                (with-current-buffer log-buf
 504                  (and (eq backend log-view-vc-backend)
 505                       (null (cdr log-view-vc-fileset))
 506                       (string= (car log-view-vc-fileset) (cdr rev-at-line))
 507                       ;; Check if the entry we require can be found.
 508                       (vc-call-backend
 509                        backend 'show-log-entry (car rev-at-line))
 510                       (setq pos (point)))))
 511               (progn
 512                 (pop-to-buffer log-buf)
 513                 (goto-char pos))
 514             ;; Ask the backend to display a single log entry.
 515             (vc-print-log-internal
 516              vc-annotate-backend (list (cdr rev-at-line))
 517              (car rev-at-line) t 1)))))))
 518
 519 (defun vc-annotate-show-diff-revision-at-line-internal (filediff)
 520   (if (not (equal major-mode 'vc-annotate-mode))
 521       (message "Cannot be invoked outside of a vc annotate buffer")
 522     (let* ((rev-at-line (vc-annotate-extract-revision-at-line))
 523           (prev-rev nil)
 524           (rev (car rev-at-line))
 525           (fname (cdr rev-at-line)))
 526       (if (not rev-at-line)
 527           (message "Cannot extract revision number from the current line")
 528         (setq prev-rev
 529               (vc-call-backend vc-annotate-backend 'previous-revision
 530                                fname rev))
 531         (if (not prev-rev)
 532             (message "Cannot diff from any revision prior to %s" rev)
 533           (save-window-excursion
 534             (vc-diff-internal
 535              nil
 536              ;; The value passed here should follow what
 537              ;; `vc-deduce-fileset' returns.
 538              (list vc-annotate-backend
 539                    (if filediff
 540                        (list fname)
 541                      nil))
 542              prev-rev rev))
 543           (switch-to-buffer "*vc-diff*"))))))
 544
 545 (defun vc-annotate-show-diff-revision-at-line ()
 546   "Visit the diff of the revision at line from its previous revision."
 547   (interactive)
 548   (vc-annotate-show-diff-revision-at-line-internal t))
 549
 550 (defun vc-annotate-show-changeset-diff-revision-at-line ()
 551   "Visit the diff of the revision at line from its previous revision for all files in the changeset."
 552   (interactive)
 553   (when (eq 'file (vc-call-backend vc-annotate-backend 'revision-granularity))
 554     (error "The %s backend does not support changeset diffs" vc-annotate-backend))
 555   (vc-annotate-show-diff-revision-at-line-internal nil))
 556
 557 (defun vc-annotate-warp-revision (revspec &optional file)
 558   "Annotate the revision described by REVSPEC.
 559
 560 If REVSPEC is a positive integer, warp that many revisions forward,
 561 if possible, otherwise echo a warning message.  If REVSPEC is a
 562 negative integer, warp that many revisions backward, if possible,
 563 otherwise echo a warning message.  If REVSPEC is a string, then it
 564 describes a revision number, so warp to that revision."
 565   (if (not (equal major-mode 'vc-annotate-mode))
 566       (message "Cannot be invoked outside of a vc annotate buffer")
 567     (let* ((buf (current-buffer))
 568            (oldline (line-number-at-pos))
 569            (revspeccopy revspec)
 570            (newrev nil))
 571       (cond
 572        ((and (integerp revspec) (> revspec 0))
 573         (setq newrev vc-annotate-parent-rev)
 574         (while (and (> revspec 0) newrev)
 575           (setq newrev (vc-call-backend vc-annotate-backend 'next-revision
 576                                         (or file vc-annotate-parent-file) newrev))
 577           (setq revspec (1- revspec)))
 578         (unless newrev
 579           (message "Cannot increment %d revisions from revision %s"
 580                    revspeccopy vc-annotate-parent-rev)))
 581        ((and (integerp revspec) (< revspec 0))
 582         (setq newrev vc-annotate-parent-rev)
 583         (while (and (< revspec 0) newrev)
 584           (setq newrev (vc-call-backend vc-annotate-backend 'previous-revision
 585                                         (or file vc-annotate-parent-file) newrev))
 586           (setq revspec (1+ revspec)))
 587         (unless newrev
 588           (message "Cannot decrement %d revisions from revision %s"
 589                    (- 0 revspeccopy) vc-annotate-parent-rev)))
 590        ((stringp revspec) (setq newrev revspec))
 591        (t (error "Invalid argument to vc-annotate-warp-revision")))
 592       (when newrev
 593         (vc-annotate (or file vc-annotate-parent-file) newrev
 594                      vc-annotate-parent-display-mode
 595                      buf
 596                      ;; Pass the current line so that vc-annotate will
 597                      ;; place the point in the line.
 598                      (min oldline (progn (goto-char (point-max))
 599                                          (forward-line -1)
 600                                          (line-number-at-pos))))))))
 601
 602 (defun vc-annotate-compcar (threshold a-list)
 603   "Test successive cons cells of A-LIST against THRESHOLD.
 604 Return the first cons cell with a car that is not less than THRESHOLD,
 605 nil if no such cell exists."
 606  (let ((i 1)
 607        (tmp-cons (car a-list)))
 608    (while (and tmp-cons (< (car tmp-cons) threshold))
 609      (setq tmp-cons (car (nthcdr i a-list)))
 610      (setq i (+ i 1)))
 611    tmp-cons))                           ; Return the appropriate value
 612
 613 (defun vc-annotate-convert-time (time)
 614   "Convert a time value to a floating-point number of days.
 615 The argument TIME is a list as returned by `current-time' or
 616 `encode-time', only the first two elements of that list are considered."
 617   (/ (+ (* (float (car time)) (lsh 1 16)) (cadr time)) 24 3600))
 618
 619 (defun vc-annotate-difference (&optional offset)
 620   "Return the time span in days to the next annotation.
 621 This calls the backend function annotate-time, and returns the
 622 difference in days between the time returned and the current time,
 623 or OFFSET if present."
 624    (let ((next-time (vc-annotate-get-time-set-line-props)))
 625      (when next-time
 626        (- (or offset
 627               (vc-call-backend vc-annotate-backend 'annotate-current-time))
 628           next-time))))
 629
 630 (defun vc-default-annotate-current-time (backend)
 631   "Return the current time, encoded as fractional days."
 632   (vc-annotate-convert-time (current-time)))
 633
 634 (defvar vc-annotate-offset nil)
 635
 636 (defun vc-annotate-display (ratio &optional offset)
 637   "Highlight `vc-annotate' output in the current buffer.
 638 RATIO is the expansion that should be applied to `vc-annotate-color-map'.
 639 The annotations are relative to the current time, unless overridden by OFFSET."
 640   (when (/= ratio 1.0)
 641     (set (make-local-variable 'vc-annotate-color-map)
 642          (mapcar (lambda (elem) (cons (* (car elem) ratio) (cdr elem)))
 643                  vc-annotate-color-map)))
 644   (set (make-local-variable 'vc-annotate-offset) offset)
 645   (font-lock-mode 1))
 646
 647 (defun vc-annotate-lines (limit)
 648   (while (< (point) limit)
 649     (let ((difference (vc-annotate-difference vc-annotate-offset))
 650           (start (point))
 651           (end (progn (forward-line 1) (point))))
 652       (when difference
 653         (let* ((color (or (vc-annotate-compcar difference vc-annotate-color-map)
 654                           (cons nil vc-annotate-very-old-color)))
 655                ;; substring from index 1 to remove any leading `#' in the name
 656                (face-name (concat "vc-annotate-face-"
 657                                   (if (string-equal
 658                                        (substring (cdr color) 0 1) "#")
 659                                       (substring (cdr color) 1)
 660                                     (cdr color))))
 661                ;; Make the face if not done.
 662                (face (or (intern-soft face-name)
 663                          (let ((tmp-face (make-face (intern face-name))))
 664                            (set-face-foreground tmp-face (cdr color))
 665                            (when vc-annotate-background
 666                              (set-face-background tmp-face
 667                                                   vc-annotate-background))
 668                            tmp-face)))) ; Return the face
 669           (put-text-property start end 'face face)))))
 670   ;; Pretend to font-lock there were no matches.
 671   nil)
 672
 673 (provide 'vc-annotate)
 674
 675 ;; arch-tag: c3454a89-80e5-4ffd-8993-671b59612898
 676 ;;; vc-annotate.el ends here