lisp/xml.el

   1 ;;; xml.el --- XML parser
   2
   3 ;; Copyright (C) 2000, 01, 03, 2004  Free Software Foundation, Inc.
   4
   5 ;; Author: Emmanuel Briot  <briot@gnat.com>
   6 ;; Maintainer: Mark A. Hershberger <mah@everybody.org>
   7 ;; Keywords: xml, data
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This file contains a somewhat incomplete non-validating XML parser.  It
  29 ;; parses a file, and returns a list that can be used internally by
  30 ;; any other Lisp libraries.
  31
  32 ;;; FILE FORMAT
  33
  34 ;; The document type declaration may either be ignored or (optionally)
  35 ;; parsed, but currently the parsing will only accept element
  36 ;; declarations.  The XML file is assumed to be well-formed.  In case
  37 ;; of error, the parsing stops and the XML file is shown where the
  38 ;; parsing stopped.
  39 ;;
  40 ;; It also knows how to ignore comments and processing instructions.
  41 ;;
  42 ;; The XML file should have the following format:
  43 ;;    <node1 attr1="name1" attr2="name2" ...>value
  44 ;;       <node2 attr3="name3" attr4="name4">value2</node2>
  45 ;;       <node3 attr5="name5" attr6="name6">value3</node3>
  46 ;;    </node1>
  47 ;; Of course, the name of the nodes and attributes can be anything.  There can
  48 ;; be any number of attributes (or none), as well as any number of children
  49 ;; below the nodes.
  50 ;;
  51 ;; There can be only top level node, but with any number of children below.
  52
  53 ;;; LIST FORMAT
  54
  55 ;; The functions `xml-parse-file', `xml-parse-region' and
  56 ;; `xml-parse-tag' return a list with the following format:
  57 ;;
  58 ;;    xml-list   ::= (node node ...)
  59 ;;    node       ::= (qname attribute-list . child_node_list)
  60 ;;    child_node_list ::= child_node child_node ...
  61 ;;    child_node ::= node | string
  62 ;;    qname      ::= (:namespace-uri . "name") | "name"
  63 ;;    attribute_list ::= ((qname . "value") (qname . "value") ...)
  64 ;;                       | nil
  65 ;;    string     ::= "..."
  66 ;;
  67 ;; Some macros are provided to ease the parsing of this list.
  68 ;; Whitespace is preserved.  Fixme: There should be a tree-walker that
  69 ;; can remove it.
  70
  71 ;; TODO:
  72 ;;  * xml:base, xml:space support
  73 ;;  * more complete DOCTYPE parsing
  74 ;;  * pi support
  75
  76 ;;; Code:
  77
  78 ;; Note that {buffer-substring,match-string}-no-properties were
  79 ;; formerly used in several places, but that removes composition info.
  80
  81 ;;*******************************************************************
  82 ;;**
  83 ;;**  Macros to parse the list
  84 ;;**
  85 ;;*******************************************************************
  86
  87 (defconst xml-undefined-entity "?"
  88   "What to substitute for undefined entities")
  89
  90 (defvar xml-entity-alist
  91   '(("lt"   . "<")
  92     ("gt"   . ">")
  93     ("apos" . "'")
  94     ("quot" . "\"")
  95     ("amp"  . "&"))
  96   "The defined entities.  Entities are added to this when the DTD is parsed.")
  97
  98 (defvar xml-sub-parser nil
  99   "Dynamically set this to a non-nil value if you want to parse an XML fragment.")
 100
 101 (defvar xml-validating-parser nil
 102   "Set to non-nil to get validity checking.")
 103
 104 (defsubst xml-node-name (node)
 105   "Return the tag associated with NODE.
 106 Without namespace-aware parsing, the tag is a symbol.
 107
 108 With namespace-aware parsing, the tag is a cons of a string
 109 representing the uri of the namespace with the local name of the
 110 tag.  For example,
 111
 112     <foo>
 113
 114 would be represented by
 115
 116     '(\"\" . \"foo\")."
 117
 118   (car node))
 119
 120 (defsubst xml-node-attributes (node)
 121   "Return the list of attributes of NODE.
 122 The list can be nil."
 123   (nth 1 node))
 124
 125 (defsubst xml-node-children (node)
 126   "Return the list of children of NODE.
 127 This is a list of nodes, and it can be nil."
 128   (cddr node))
 129
 130 (defun xml-get-children (node child-name)
 131   "Return the children of NODE whose tag is CHILD-NAME.
 132 CHILD-NAME should match the value returned by `xml-node-name'."
 133   (let ((match ()))
 134     (dolist (child (xml-node-children node))
 135       (if (and (listp child)
 136                (equal (xml-node-name child) child-name))
 137           (push child match)))
 138     (nreverse match)))
 139
 140 (defun xml-get-attribute-or-nil (node attribute)
 141   "Get from NODE the value of ATTRIBUTE.
 142 Return nil if the attribute was not found.
 143
 144 See also `xml-get-attribute'."
 145   (cdr (assoc attribute (xml-node-attributes node))))
 146
 147 (defsubst xml-get-attribute (node attribute)
 148   "Get from NODE the value of ATTRIBUTE.
 149 An empty string is returned if the attribute was not found.
 150
 151 See also `xml-get-attribute-or-nil'."
 152   (or (xml-get-attribute-or-nil node attribute) ""))
 153
 154 ;;*******************************************************************
 155 ;;**
 156 ;;**  Creating the list
 157 ;;**
 158 ;;*******************************************************************
 159
 160 ;;;###autoload
 161 (defun xml-parse-file (file &optional parse-dtd parse-ns)
 162   "Parse the well-formed XML file FILE.
 163 If FILE is already visited, use its buffer and don't kill it.
 164 Returns the top node with all its children.
 165 If PARSE-DTD is non-nil, the DTD is parsed rather than skipped.
 166 If PARSE-NS is non-nil, then QNAMES are expanded."
 167   (let ((keep))
 168     (if (get-file-buffer file)
 169         (progn
 170           (set-buffer (get-file-buffer file))
 171           (setq keep (point)))
 172       (let (auto-mode-alist)            ; no need for xml-mode
 173         (find-file file)))
 174
 175     (let ((xml (xml-parse-region (point-min)
 176                                  (point-max)
 177                                  (current-buffer)
 178                                  parse-dtd parse-ns)))
 179       (if keep
 180           (goto-char keep)
 181         (kill-buffer (current-buffer)))
 182       xml)))
 183
 184
 185 (defvar xml-name-re)
 186 (defvar xml-entity-value-re)
 187 (let* ((start-chars (concat "[:alpha:]:_"))
 188        (name-chars  (concat "-[:digit:]." start-chars))
 189 ;;[3]           S          ::=          (#x20 | #x9 | #xD | #xA)+
 190        (whitespace  "[ \t\n\r]"))
 191 ;;[4] NameStartChar ::= ":" | [A-Z] | "_" | [a-z] | [#xC0-#xD6]
 192 ;;                      | [#xD8-#xF6] | [#xF8-#x2FF] | [#x370-#x37D] | [#x37F-#x1FFF]
 193 ;;                      | [#x200C-#x200D] | [#x2070-#x218F] | [#x2C00-#x2FEF] | [#x3001-#xD7FF]
 194 ;;                      | [#xF900-#xFDCF] | [#xFDF0-#xFFFD] | [#x10000-#xEFFFF]
 195   (defvar xml-name-start-char-re (concat "[" start-chars "]"))
 196 ;;[4a] NameChar ::= NameStartChar | "-" | "." | [0-9] | #xB7 | [#x0300-#x036F] | [#x203F-#x2040]
 197   (defvar xml-name-char-re       (concat "[" name-chars  "]"))
 198 ;;[5] Name     ::= NameStartChar (NameChar)*
 199   (defvar xml-name-re            (concat xml-name-start-char-re xml-name-char-re "*"))
 200 ;;[6] Names    ::= Name (#x20 Name)*
 201   (defvar xml-names-re           (concat xml-name-re "\\(?: " xml-name-re "\\)*"))
 202 ;;[7] Nmtoken ::= (NameChar)+
 203   (defvar xml-nmtoken-re         (concat xml-name-char-re "+"))
 204 ;;[8] Nmtokens ::= Nmtoken (#x20 Nmtoken)*
 205   (defvar xml-nmtokens-re        (concat xml-nmtoken-re "\\(?: " xml-name-re "\\)*"))
 206 ;;[66] CharRef ::= '&#' [0-9]+ ';' | '&#x' [0-9a-fA-F]+ ';'
 207   (defvar xml-char-ref-re        "\\(?:&#[0-9]+;\\|&#x[0-9a-fA-F]+;\\)")
 208 ;;[68] EntityRef   ::= '&' Name ';'
 209   (defvar xml-entity-ref         (concat "&" xml-name-re ";"))
 210 ;;[69] PEReference ::= '%' Name ';'
 211   (defvar xml-pe-reference-re    (concat "%" xml-name-re ";"))
 212 ;;[67] Reference   ::= EntityRef | CharRef
 213   (defvar xml-reference-re       (concat "\\(?:" xml-entity-ref "\\|" xml-char-ref-re "\\)"))
 214 ;;[9] EntityValue ::= '"' ([^%&"] | PEReference | Reference)* '"'
 215 ;;                 |  "'" ([^%&'] | PEReference | Reference)* "'"
 216   (defvar xml-entity-value-re    (concat "\\(?:\"\\(?:[^%&\"]\\|" xml-pe-reference-re
 217                                          "\\|" xml-reference-re "\\)*\"\\|'\\(?:[^%&']\\|"
 218                                          xml-pe-reference-re "\\|" xml-reference-re "\\)*'\\)")))
 219 ;;[75] ExternalID ::= 'SYSTEM' S SystemLiteral
 220 ;;                 | 'PUBLIC' S PubidLiteral S SystemLiteral
 221 ;;[76] NDataDecl ::=    S 'NDATA' S
 222 ;;[73] EntityDef  ::= EntityValue| (ExternalID NDataDecl?)
 223 ;;[71] GEDecl     ::= '<!ENTITY' S Name S EntityDef S? '>'
 224 ;;[74] PEDef      ::= EntityValue | ExternalID
 225 ;;[72] PEDecl     ::= '<!ENTITY' S '%' S Name S PEDef S? '>'
 226 ;;[70] EntityDecl ::= GEDecl | PEDecl
 227
 228 ;; Note that this is setup so that we can do whitespace-skipping with
 229 ;; `(skip-syntax-forward " ")', inter alia.  Previously this was slow
 230 ;; compared with `re-search-forward', but that has been fixed.  Also
 231 ;; note that the standard syntax table contains other characters with
 232 ;; whitespace syntax, like NBSP, but they are invalid in contexts in
 233 ;; which we might skip whitespace -- specifically, they're not
 234 ;; NameChars [XML 4].
 235
 236 (defvar xml-syntax-table
 237   (let ((table (make-syntax-table)))
 238     ;; Get space syntax correct per XML [3].
 239     (dotimes (c 31)
 240       (modify-syntax-entry c "." table)) ; all are space in standard table
 241     (dolist (c '(?\t ?\n ?\r))          ; these should be space
 242       (modify-syntax-entry c " " table))
 243     ;; For skipping attributes.
 244     (modify-syntax-entry ?\" "\"" table)
 245     (modify-syntax-entry ?' "\"" table)
 246     ;; Non-alnum name chars should be symbol constituents (`-' and `_'
 247     ;; are OK by default).
 248     (modify-syntax-entry ?. "_" table)
 249     (modify-syntax-entry ?: "_" table)
 250     ;; XML [89]
 251     (dolist (c '(#x00B7 #x02D0 #x02D1 #x0387 #x0640 #x0E46 #x0EC6 #x3005
 252                  #x3031 #x3032 #x3033 #x3034 #x3035 #x309D #x309E #x30FC
 253                  #x30FD #x30FE))
 254       (modify-syntax-entry (decode-char 'ucs c) "w" table))
 255     ;; Fixme: rest of [4]
 256     table)
 257   "Syntax table used by `xml-parse-region'.")
 258
 259 ;; XML [5]
 260 ;; Note that [:alpha:] matches all multibyte chars with word syntax.
 261 (eval-and-compile
 262   (defconst xml-name-regexp "[[:alpha:]_:][[:alnum:]._:-]*"))
 263
 264 ;; Fixme:  This needs re-writing to deal with the XML grammar properly, i.e.
 265 ;;   document    ::=    prolog element Misc*
 266 ;;   prolog    ::=    XMLDecl? Misc* (doctypedecl Misc*)?
 267
 268 ;;;###autoload
 269 (defun xml-parse-region (beg end &optional buffer parse-dtd parse-ns)
 270   "Parse the region from BEG to END in BUFFER.
 271 If BUFFER is nil, it defaults to the current buffer.
 272 Returns the XML list for the region, or raises an error if the region
 273 is not well-formed XML.
 274 If PARSE-DTD is non-nil, the DTD is parsed rather than skipped,
 275 and returned as the first element of the list.
 276 If PARSE-NS is non-nil, then QNAMES are expanded."
 277   (save-restriction
 278     (narrow-to-region beg end)
 279     ;; Use fixed syntax table to ensure regexp char classes and syntax
 280     ;; specs DTRT.
 281     (with-syntax-table (standard-syntax-table)
 282       (let ((case-fold-search nil)      ; XML is case-sensitive.
 283             xml result dtd)
 284         (save-excursion
 285           (if buffer
 286               (set-buffer buffer))
 287           (goto-char (point-min))
 288           (while (not (eobp))
 289             (if (search-forward "<" nil t)
 290                 (progn
 291                   (forward-char -1)
 292                   (setq result (xml-parse-tag parse-dtd parse-ns))
 293                   (if (and xml result (not xml-sub-parser))
 294                       ;;  translation of rule [1] of XML specifications
 295                       (error "XML: (Not Well-Formed) Only one root tag allowed")
 296                     (cond
 297                      ((null result))
 298                      ((and (listp (car result))
 299                            parse-dtd)
 300                       (setq dtd (car result))
 301                       (if (cdr result)  ; possible leading comment
 302                           (add-to-list 'xml (cdr result))))
 303                      (t
 304                       (add-to-list 'xml result)))))
 305               (goto-char (point-max))))
 306           (if parse-dtd
 307               (cons dtd (nreverse xml))
 308             (nreverse xml)))))))
 309
 310 (defun xml-maybe-do-ns (name default xml-ns)
 311   "Perform any namespace expansion.
 312 NAME is the name to perform the expansion on.
 313 DEFAULT is the default namespace.  XML-NS is a cons of namespace
 314 names to uris.  When namespace-aware parsing is off, then XML-NS
 315 is nil.
 316
 317 During namespace-aware parsing, any name without a namespace is
 318 put into the namespace identified by DEFAULT.  nil is used to
 319 specify that the name shouldn't be given a namespace."
 320   (if (consp xml-ns)
 321       (let* ((nsp (string-match ":" name))
 322              (lname (if nsp (substring name (match-end 0)) name))
 323              (prefix (if nsp (substring name 0 (match-beginning 0)) default))
 324              (special (and (string-equal lname "xmlns") (not prefix)))
 325              ;; Setting default to nil will insure that there is not
 326              ;; matching cons in xml-ns.  In which case we
 327              (ns (or (cdr (assoc (if special "xmlns" prefix)
 328                                  xml-ns))
 329                      "")))
 330         (cons ns (if special "" lname)))
 331     (intern name)))
 332
 333 (defun xml-parse-fragment (&optional parse-dtd parse-ns)
 334   "Parse xml-like fragments."
 335   (let ((xml-sub-parser t)
 336         children)
 337     (while (not (eobp))
 338       (let ((bit (xml-parse-tag
 339                   parse-dtd parse-ns)))
 340         (if children
 341             (setq children (append (list bit) children))
 342           (if (stringp bit)
 343               (setq children (list bit))
 344             (setq children bit)))))
 345     (reverse children)))
 346
 347 (defun xml-parse-tag (&optional parse-dtd parse-ns)
 348   "Parse the tag at point.
 349 If PARSE-DTD is non-nil, the DTD of the document, if any, is parsed and
 350 returned as the first element in the list.
 351 If PARSE-NS is non-nil, then QNAMES are expanded.
 352 Returns one of:
 353  - a list : the matching node
 354  - nil    : the point is not looking at a tag.
 355  - a pair : the first element is the DTD, the second is the node."
 356   (let ((xml-validating-parser (or parse-dtd xml-validating-parser))
 357         (xml-ns (if (consp parse-ns)
 358                     parse-ns
 359                   (if parse-ns
 360                       (list
 361                        ;; Default for empty prefix is no namespace
 362                        (cons ""      "")
 363                        ;; "xml" namespace
 364                        (cons "xml"   "http://www.w3.org/XML/1998/namespace")
 365                        ;; We need to seed the xmlns namespace
 366                        (cons "xmlns" "http://www.w3.org/2000/xmlns/"))))))
 367     (cond
 368      ;; Processing instructions (like the <?xml version="1.0"?> tag at the
 369      ;; beginning of a document).
 370      ((looking-at "<\\?")
 371       (search-forward "?>")
 372       (skip-syntax-forward " ")
 373       (xml-parse-tag parse-dtd xml-ns))
 374      ;;  Character data (CDATA) sections, in which no tag should be interpreted
 375      ((looking-at "<!\\[CDATA\\[")
 376       (let ((pos (match-end 0)))
 377         (unless (search-forward "]]>" nil t)
 378           (error "XML: (Not Well Formed) CDATA section does not end anywhere in the document"))
 379         (concat
 380          (buffer-substring pos (match-beginning 0))
 381          (xml-parse-string))))
 382      ;;  DTD for the document
 383      ((looking-at "<!DOCTYPE")
 384       (let ((dtd (xml-parse-dtd parse-ns)))
 385         (skip-syntax-forward " ")
 386         (if xml-validating-parser
 387             (cons dtd (xml-parse-tag nil xml-ns))
 388           (xml-parse-tag nil xml-ns))))
 389      ;;  skip comments
 390      ((looking-at "<!--")
 391       (search-forward "-->")
 392       nil)
 393      ;;  end tag
 394      ((looking-at "</")
 395       '())
 396      ;;  opening tag
 397      ((looking-at "<\\([^/>[:space:]]+\\)")
 398       (goto-char (match-end 1))
 399
 400       ;; Parse this node
 401       (let* ((node-name (match-string 1))
 402              ;; Parse the attribute list.
 403              (attrs (xml-parse-attlist xml-ns))
 404              children pos)
 405
 406         ;; add the xmlns:* attrs to our cache
 407         (when (consp xml-ns)
 408           (dolist (attr attrs)
 409             (when (and (consp (car attr))
 410                        (equal "http://www.w3.org/2000/xmlns/"
 411                               (caar attr)))
 412               (push (cons (cdar attr) (cdr attr))
 413                     xml-ns))))
 414
 415         (setq children (list attrs (xml-maybe-do-ns node-name "" xml-ns)))
 416
 417         ;; is this an empty element ?
 418         (if (looking-at "/>")
 419             (progn
 420               (forward-char 2)
 421               (nreverse children))
 422
 423           ;; is this a valid start tag ?
 424           (if (eq (char-after) ?>)
 425               (progn
 426                 (forward-char 1)
 427                 ;;  Now check that we have the right end-tag. Note that this
 428                 ;;  one might contain spaces after the tag name
 429                 (let ((end (concat "</" node-name "\\s-*>")))
 430                   (while (not (looking-at end))
 431                     (cond
 432                      ((looking-at "</")
 433                       (error "XML: (Not Well-Formed) Invalid end tag (expecting %s) at pos %d"
 434                              node-name (point)))
 435                      ((= (char-after) ?<)
 436                       (let ((tag (xml-parse-tag nil xml-ns)))
 437                         (when tag
 438                           (push tag children))))
 439                      (t
 440                       (let ((expansion (xml-parse-string)))
 441                         (setq children
 442                               (if (stringp expansion)
 443                                   (if (stringp (car children))
 444                                       ;; The two strings were separated by a comment.
 445                                       (setq children (append (concat (car children) expansion)
 446                                                              (cdr children)))
 447                                     (setq children (append (list expansion) children)))
 448                                 (setq children (append expansion children))))))))
 449
 450                   (goto-char (match-end 0))
 451                   (nreverse children)))
 452             ;;  This was an invalid start tag (Expected ">", but didn't see it.)
 453             (error "XML: (Well-Formed) Couldn't parse tag: %s"
 454                    (buffer-substring (- (point) 10) (+ (point) 1)))))))
 455      (t ;; (Not one of PI, CDATA, Comment, End tag, or Start tag)
 456       (unless xml-sub-parser            ; Usually, we error out.
 457         (error "XML: (Well-Formed) Invalid character"))
 458
 459       ;; However, if we're parsing incrementally, then we need to deal
 460       ;; with stray CDATA.
 461       (xml-parse-string)))))
 462
 463 (defun xml-parse-string ()
 464   "Parse the next whatever.  Could be a string, or an element."
 465     (let* ((pos (point))
 466            (string (progn (if (search-forward "<" nil t)
 467                               (forward-char -1)
 468                             (goto-char (point-max)))
 469                           (buffer-substring pos (point)))))
 470       ;; Clean up the string.  As per XML specifications, the XML
 471       ;; processor should always pass the whole string to the
 472       ;; application.  But \r's should be replaced:
 473       ;; http://www.w3.org/TR/2000/REC-xml-20001006#sec-line-ends
 474       (setq pos 0)
 475       (while (string-match "\r\n?" string pos)
 476         (setq string (replace-match "\n" t t string))
 477         (setq pos (1+ (match-beginning 0))))
 478
 479       (xml-substitute-special string)))
 480
 481 (defun xml-parse-attlist (&optional xml-ns)
 482   "Return the attribute-list after point.
 483 Leave point at the first non-blank character after the tag."
 484   (let ((attlist ())
 485         end-pos name)
 486     (skip-syntax-forward " ")
 487     (while (looking-at (eval-when-compile
 488                          (concat "\\(" xml-name-regexp "\\)\\s-*=\\s-*")))
 489       (setq end-pos (match-end 0))
 490       (setq name (xml-maybe-do-ns (match-string 1) nil xml-ns))
 491       (goto-char end-pos)
 492
 493       ;; See also: http://www.w3.org/TR/2000/REC-xml-20001006#AVNormalize
 494
 495       ;; Do we have a string between quotes (or double-quotes),
 496       ;;  or a simple word ?
 497       (if (looking-at "\"\\([^\"]*\\)\"")
 498           (setq end-pos (match-end 0))
 499         (if (looking-at "'\\([^']*\\)'")
 500             (setq end-pos (match-end 0))
 501           (error "XML: (Not Well-Formed) Attribute values must be given between quotes")))
 502
 503       ;; Each attribute must be unique within a given element
 504       (if (assoc name attlist)
 505           (error "XML: (Not Well-Formed) Each attribute must be unique within an element"))
 506
 507       ;; Multiple whitespace characters should be replaced with a single one
 508       ;; in the attributes
 509       (let ((string (match-string 1))
 510             (pos 0))
 511         (replace-regexp-in-string "\\s-\\{2,\\}" " " string)
 512         (let ((expansion (xml-substitute-special string)))
 513           (unless (stringp expansion)
 514             ; We say this is the constraint.  It is acctually that
 515             ; external entities nor "<" can be in an attribute value.
 516             (error "XML: (Not Well-Formed) Entities in attributes cannot expand into elements"))
 517           (push (cons name expansion) attlist)))
 518
 519       (goto-char end-pos)
 520       (skip-syntax-forward " "))
 521     (nreverse attlist)))
 522
 523 ;;*******************************************************************
 524 ;;**
 525 ;;**  The DTD (document type declaration)
 526 ;;**  The following functions know how to skip or parse the DTD of
 527 ;;**  a document
 528 ;;**
 529 ;;*******************************************************************
 530
 531 ;; Fixme: This fails at least if the DTD contains conditional sections.
 532
 533 (defun xml-skip-dtd ()
 534   "Skip the DTD at point.
 535 This follows the rule [28] in the XML specifications."
 536   (let ((xml-validating-parser nil))
 537     (xml-parse-dtd)))
 538
 539 (defun xml-parse-dtd (&optional parse-ns)
 540   "Parse the DTD at point."
 541   (forward-char (eval-when-compile (length "<!DOCTYPE")))
 542   (skip-syntax-forward " ")
 543   (if (and (looking-at ">")
 544            xml-validating-parser)
 545       (error "XML: (Validity) Invalid DTD (expecting name of the document)"))
 546
 547   ;;  Get the name of the document
 548   (looking-at xml-name-regexp)
 549   (let ((dtd (list (match-string 0) 'dtd))
 550         type element end-pos)
 551     (goto-char (match-end 0))
 552
 553     (skip-syntax-forward " ")
 554     ;; XML [75]
 555     (cond ((looking-at "PUBLIC\\s-+")
 556            (goto-char (match-end 0))
 557            (unless (or (re-search-forward
 558                         "\\=\"\\([[:space:][:alnum:]-'()+,./:=?;!*#@$_%]*\\)\""
 559                         nil t)
 560                        (re-search-forward
 561                         "\\='\\([[:space:][:alnum:]-()+,./:=?;!*#@$_%]*\\)'"
 562                         nil t))
 563              (error "XML: Missing Public ID"))
 564            (let ((pubid (match-string 1)))
 565              (skip-syntax-forward " ")
 566              (unless (or (re-search-forward "\\='\\([^']*\\)'" nil t)
 567                          (re-search-forward "\\=\"\\([^\"]*\\)\"" nil t))
 568                (error "XML: Missing System ID"))
 569              (push (list pubid (match-string 1) 'public) dtd)))
 570           ((looking-at "SYSTEM\\s-+")
 571            (goto-char (match-end 0))
 572            (unless (or (re-search-forward "\\='\\([^']*\\)'" nil t)
 573                        (re-search-forward "\\=\"\\([^\"]*\\)\"" nil t))
 574              (error "XML: Missing System ID"))
 575            (push (list (match-string 1) 'system) dtd)))
 576     (skip-syntax-forward " ")
 577     (if (eq ?> (char-after))
 578         (forward-char)
 579       (if (not (eq (char-after) ?\[))
 580           (error "XML: Bad DTD")
 581         (forward-char)
 582         ;;  Parse the rest of the DTD
 583         ;;  Fixme: Deal with ATTLIST, NOTATION, PIs.
 584         (while (not (looking-at "\\s-*\\]"))
 585           (skip-syntax-forward " ")
 586           (cond
 587
 588            ;;  Translation of rule [45] of XML specifications
 589            ((looking-at
 590              "<!ELEMENT\\s-+\\([[:alnum:].%;]+\\)\\s-+\\([^>]+\\)>")
 591
 592             (setq element (match-string 1)
 593                   type    (match-string-no-properties 2))
 594             (setq end-pos (match-end 0))
 595
 596             ;;  Translation of rule [46] of XML specifications
 597             (cond
 598              ((string-match "^EMPTY[ \t\n\r]*$" type) ;; empty declaration
 599               (setq type 'empty))
 600              ((string-match "^ANY[ \t\n\r]*$" type) ;; any type of contents
 601               (setq type 'any))
 602              ((string-match "^(\\(.*\\))[ \t\n\r]*$" type) ;; children ([47])
 603               (setq type (xml-parse-elem-type (match-string 1 type))))
 604              ((string-match "^%[^;]+;[ \t\n\r]*$" type) ;; substitution
 605               nil)
 606              (t
 607               (if xml-validating-parser
 608                   (error "XML: (Validity) Invalid element type in the DTD"))))
 609
 610             ;;  rule [45]: the element declaration must be unique
 611             (if (and (assoc element dtd)
 612                      xml-validating-parser)
 613                 (error "XML: (Validity) Element declarations must be unique in a DTD (<%s>)"
 614                        element))
 615
 616             ;;  Store the element in the DTD
 617             (push (list element type) dtd)
 618             (goto-char end-pos))
 619            ((looking-at "<!--")
 620             (search-forward "-->"))
 621            ((looking-at (concat "<!ENTITY[ \t\n\r]*\\(" xml-name-re
 622                                 "\\)[ \t\n\r]*\\(" xml-entity-value-re
 623                                 "\\)[ \t\n\r]*>"))
 624             (let ((name  (buffer-substring (nth 2 (match-data))
 625                                            (nth 3 (match-data))))
 626                   (value (buffer-substring (+ (nth 4 (match-data)) 1)
 627                                            (- (nth 5 (match-data)) 1))))
 628               (goto-char (nth 1 (match-data)))
 629               (setq xml-entity-alist
 630                     (append xml-entity-alist
 631                             (list (cons name
 632                                         (with-temp-buffer
 633                                           (insert value)
 634                                           (goto-char (point-min))
 635                                           (xml-parse-fragment
 636                                            xml-validating-parser
 637                                            parse-ns))))))))
 638            ((or (looking-at (concat "<!ENTITY[ \t\n\r]+\\(" xml-name-re
 639                                     "\\)[ \t\n\r]+SYSTEM[ \t\n\r]+"
 640                                     "\\(\"[^\"]*\"\\|'[^']*'\\)[ \t\n\r]*>"))
 641                 (looking-at (concat "<!ENTITY[ \t\n\r]+\\(" xml-name-re
 642                                     "\\)[ \t\n\r]+PUBLIC[ \t\n\r]+"
 643                                     "\"[- \r\na-zA-Z0-9'()+,./:=?;!*#@$_%]*\""
 644                                     "\\|'[- \r\na-zA-Z0-9()+,./:=?;!*#@$_%]*'"
 645                                     "[ \t\n\r]+\\(\"[^\"]*\"\\|'[^']*'\\)"
 646                                     "[ \t\n\r]*>")))
 647             (let ((name  (buffer-substring (nth 2 (match-data))
 648                                            (nth 3 (match-data))))
 649                   (file  (buffer-substring (+ (nth 4 (match-data)) 1)
 650                                            (- (nth 5 (match-data)) 1))))
 651               (goto-char (nth 1 (match-data)))
 652               (setq xml-entity-alist
 653                     (append xml-entity-alist
 654                             (list (cons name (with-temp-buffer
 655                                                (insert-file-contents file)
 656                                                (goto-char (point-min))
 657                                                (xml-parse-fragment
 658                                                 xml-validating-parser
 659                                                 parse-ns))))))))
 660            ;; skip parameter entity declarations
 661            ((or (looking-at (concat "<!ENTITY[ \t\n\r]+%[ \t\n\r]+\\(" xml-name-re
 662                                     "\\)[ \t\n\r]+SYSTEM[ \t\n\r]+"
 663                                     "\\(\"[^\"]*\"\\|'[^']*'\\)[ \t\n\r]*>"))
 664                 (looking-at (concat "<!ENTITY[ \t\n\r]+"
 665                                     "%[ \t\n\r]+"
 666                                     "\\(" xml-name-re "\\)[ \t\n\r]+"
 667                                     "PUBLIC[ \t\n\r]+"
 668                                     "\\(\"[- \r\na-zA-Z0-9'()+,./:=?;!*#@$_%]*\""
 669                                     "\\|'[- \r\na-zA-Z0-9()+,./:=?;!*#@$_%]*'\\)[ \t\n\r]+"
 670                                     "\\(\"[^\"]+\"\\|'[^']+'\\)"
 671                                     "[ \t\n\r]*>")))
 672             (goto-char (match-end 0)))
 673            ;; skip parameter entities
 674            ((looking-at (concat "%" xml-name-re ";"))
 675             (goto-char (match-end 0)))
 676            (t
 677             (when xml-validating-parser
 678               (error "XML: (Validity) Invalid DTD item"))))))
 679       (if (looking-at "\\s-*]>")
 680           (goto-char (nth 1 (match-data)))))
 681     (nreverse dtd)))
 682
 683 (defun xml-parse-elem-type (string)
 684   "Convert element type STRING into a Lisp structure."
 685
 686   (let (elem modifier)
 687     (if (string-match "(\\([^)]+\\))\\([+*?]?\\)" string)
 688         (progn
 689           (setq elem     (match-string 1 string)
 690                 modifier (match-string 2 string))
 691           (if (string-match "|" elem)
 692               (setq elem (cons 'choice
 693                                (mapcar 'xml-parse-elem-type
 694                                        (split-string elem "|"))))
 695             (if (string-match "," elem)
 696                 (setq elem (cons 'seq
 697                                  (mapcar 'xml-parse-elem-type
 698                                          (split-string elem ",")))))))
 699       (if (string-match "[ \t\n\r]*\\([^+*?]+\\)\\([+*?]?\\)" string)
 700           (setq elem     (match-string 1 string)
 701                 modifier (match-string 2 string))))
 702
 703     (if (and (stringp elem) (string= elem "#PCDATA"))
 704         (setq elem 'pcdata))
 705
 706     (cond
 707      ((string= modifier "+")
 708       (list '+ elem))
 709      ((string= modifier "*")
 710       (list '* elem))
 711      ((string= modifier "?")
 712       (list '\? elem))
 713      (t
 714       elem))))
 715
 716 ;;*******************************************************************
 717 ;;**
 718 ;;**  Substituting special XML sequences
 719 ;;**
 720 ;;*******************************************************************
 721
 722 (defun xml-substitute-special (string)
 723   "Return STRING, after subsituting entity references."
 724   ;; This originally made repeated passes through the string from the
 725   ;; beginning, which isn't correct, since then either "&amp;amp;" or
 726   ;; "&#38;amp;" won't DTRT.
 727
 728   (let ((point 0)
 729         children end-point)
 730     (while (string-match "&\\([^;]*\\);" string point)
 731       (setq end-point (match-end 0))
 732       (let* ((this-part (match-string 1 string))
 733              (prev-part (substring string point (match-beginning 0)))
 734              (entity (assoc this-part xml-entity-alist))
 735              (expansion
 736               (cond ((string-match "#\\([0-9]+\\)" this-part)
 737                      (let ((c (decode-char
 738                                'ucs
 739                                (string-to-number (match-string 1 this-part)))))
 740                        (if c (string c))))
 741                     ((string-match "#x\\([[:xdigit:]]+\\)" this-part)
 742                      (let ((c (decode-char
 743                                'ucs
 744                                (string-to-number (match-string 1 this-part) 16))))
 745                        (if c (string c))))
 746                     (entity
 747                      (cdr entity))
 748                     ((eq (length this-part) 0)
 749                      (error "XML: (Not Well-Formed) No entity given"))
 750                     (t
 751                      (if xml-validating-parser
 752                          (error "XML: (Validity) Undefined entity `%s'"
 753                                 this-part)
 754                        xml-undefined-entity)))))
 755
 756         (cond ((null children)
 757                ;; FIXME: If we have an entity that expands into XML, this won't work.
 758                (setq children
 759                      (concat prev-part expansion)))
 760               ((stringp children)
 761                (if (stringp expansion)
 762                    (setq children (concat children prev-part expansion))
 763                  (setq children (list expansion (concat prev-part children)))))
 764               ((and (stringp expansion)
 765                     (stringp (car children)))
 766                (setcar children (concat prev-part expansion (car children))))
 767               ((stringp expansion)
 768                (setq children (append (concat prev-part expansion)
 769                                       children)))
 770               ((stringp (car children))
 771                (setcar children (concat (car children) prev-part))
 772                (setq children (append expansion children)))
 773               (t
 774                (setq children (list expansion
 775                                     prev-part
 776                                     children))))
 777         (setq point end-point)))
 778     (cond ((stringp children)
 779            (concat children (substring string point)))
 780           ((stringp (car (last children)))
 781            (concat (car (last children)) (substring string point)))
 782           ((null children)
 783            string)
 784           (t
 785            (concat (mapconcat 'identity
 786                               (nreverse children)
 787                               "")
 788                    (substring string point))))))
 789
 790 ;;*******************************************************************
 791 ;;**
 792 ;;**  Printing a tree.
 793 ;;**  This function is intended mainly for debugging purposes.
 794 ;;**
 795 ;;*******************************************************************
 796
 797 (defun xml-debug-print (xml &optional indent-string)
 798   "Outputs the XML in the current buffer.
 799 XML can be a tree or a list of nodes.
 800 The first line is indented with the optional INDENT-STRING."
 801   (setq indent-string (or indent-string ""))
 802   (dolist (node xml)
 803     (xml-debug-print-internal node indent-string)))
 804
 805 (defalias 'xml-print 'xml-debug-print)
 806
 807 (defun xml-debug-print-internal (xml indent-string)
 808   "Outputs the XML tree in the current buffer.
 809 The first line is indented with INDENT-STRING."
 810   (let ((tree xml)
 811         attlist)
 812     (insert indent-string ?< (symbol-name (xml-node-name tree)))
 813
 814     ;;  output the attribute list
 815     (setq attlist (xml-node-attributes tree))
 816     (while attlist
 817       (insert ?\  (symbol-name (caar attlist)) "=\"" (cdar attlist) ?\")
 818       (setq attlist (cdr attlist)))
 819
 820     (setq tree (xml-node-children tree))
 821
 822     (if (null tree)
 823         (insert ?/ ?>)
 824       (insert ?>)
 825
 826       ;;  output the children
 827       (dolist (node tree)
 828         (cond
 829          ((listp node)
 830           (insert ?\n)
 831           (xml-debug-print-internal node (concat indent-string "  ")))
 832          ((stringp node) (insert node))
 833          (t
 834           (error "Invalid XML tree"))))
 835
 836       (when (not (and (null (cdr tree))
 837                       (stringp (car tree))))
 838         (insert ?\n indent-string))
 839       (insert ?< ?/ (symbol-name (xml-node-name xml)) ?>))))
 840
 841 (provide 'xml)
 842
 843 ;; arch-tag: 5864b283-5a68-4b59-a20d-36a72b353b9b
 844 ;;; xml.el ends here