lisp/vms-patch.el

   1 ;;; vms-patch.el --- override parts of files.el for VMS
   2
   3 ;; Copyright (C) 1986, 1992 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: vms
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (setq auto-mode-alist (cons '(("\\.com\\'" . dcl-mode)) auto-mode-alist))
  30
  31 ;;; Functions that need redefinition
  32
  33 ;;; VMS file names are upper case, but buffer names are more
  34 ;;; convenient in lower case.
  35
  36 (defun create-file-buffer (filename)
  37   "Create a suitably named buffer for visiting FILENAME, and return it.
  38 FILENAME (sans directory) is used unchanged if that name is free;
  39 otherwise a string <2> or <3> or ... is appended to get an unused name."
  40   (generate-new-buffer (downcase (file-name-nondirectory filename))))
  41
  42 ;;; Given a string FN, return a similar name which is a legal VMS filename.
  43 ;;; This is used to avoid invalid auto save file names.
  44 (defun make-legal-file-name (fn)
  45   (setq fn (copy-sequence fn))
  46   (let ((dot nil) (indx 0) (len (length fn)) chr)
  47     (while (< indx len)
  48       (setq chr (aref fn indx))
  49       (cond
  50        ((eq chr ?.) (if dot (aset fn indx ?_) (setq dot t)))
  51        ((not (or (and (>= chr ?a) (<= chr ?z)) (and (>= chr ?A) (<= chr ?Z))
  52                  (and (>= chr ?0) (<= chr ?9))
  53                  (eq chr ?$) (eq chr ?_) (and (eq chr ?-) (> indx 0))))
  54         (aset fn indx ?_)))
  55       (setq indx (1+ indx))))
  56   fn)
  57
  58 ;;; Auto save filesnames start with _$ and end with $.
  59
  60 (defun make-auto-save-file-name ()
  61   "Return file name to use for auto-saves of current buffer.
  62 This function does not consider `auto-save-visited-file-name';
  63 the caller should check that before calling this function.
  64 This is a separate function so that your `.emacs' file or the site's
  65 `site-init.el' can redefine it.
  66 See also `auto-save-file-name-p'."
  67   (if buffer-file-name
  68       (concat (file-name-directory buffer-file-name)
  69               "_$"
  70               (file-name-nondirectory buffer-file-name)
  71               "$")
  72     (expand-file-name (concat "_$_" (make-legal-file-name (buffer-name)) "$"))))
  73
  74 (defun auto-save-file-name-p (filename)
  75   "Return t if FILENAME can be yielded by `make-auto-save-file-name'.
  76 FILENAME should lack slashes.
  77 This is a separate function so that your `.emacs' file or the site's
  78 `site-init.el' can redefine it."
  79   (string-match "^_\\$.*\\$" filename))
  80
  81 ;;;
  82 ;;; This goes along with kepteditor.com which defines these logicals
  83 ;;; If EMACS_COMMAND_ARGS is defined, it supersedes EMACS_FILE_NAME,
  84 ;;;   which is probably set up incorrectly anyway.
  85 ;;; The function command-line-again is a kludge, but it does the job.
  86 ;;;
  87 (defun vms-suspend-resume-hook ()
  88   "When resuming suspended Emacs, check for file to be found.
  89 If the logical name `EMACS_FILE_NAME' is defined, `find-file' that file."
  90   (let ((file (vms-system-info "LOGICAL" "EMACS_FILE_NAME"))
  91         (args (vms-system-info "LOGICAL" "EMACS_COMMAND_ARGS"))
  92         (line (vms-system-info "LOGICAL" "EMACS_FILE_LINE")))
  93     (if (not args)
  94         (if file
  95             (progn (find-file file)
  96                    (if line (goto-line (string-to-number line)))))
  97       (cd (file-name-directory file))
  98       (vms-command-line-again))))
  99
 100 (setq suspend-resume-hook 'vms-suspend-resume-hook)
 101
 102 (defun vms-suspend-hook ()
 103   "Don't allow suspending if logical name `DONT_SUSPEND_EMACS' is defined."
 104   (if (vms-system-info "LOGICAL" "DONT_SUSPEND_EMACS")
 105       (error "Can't suspend this emacs"))
 106   nil)
 107
 108 (setq suspend-hook 'vms-suspend-hook)
 109
 110 ;;;
 111 ;;; A kludge that allows reprocessing of the command line.  This is mostly
 112 ;;;   to allow a spawned VMS mail process to do something reasonable when
 113 ;;;   used in conjunction with the modifications to sysdep.c that allow
 114 ;;;   Emacs to attach to a "foster" parent.
 115 ;;;
 116 (defun vms-command-line-again ()
 117   "Reprocess command line arguments.  VMS specific.
 118 Command line arguments are initialized from the logical EMACS_COMMAND_ARGS
 119 which is defined by kepteditor.com.  On VMS this allows attaching to a
 120 spawned Emacs and doing things like \"emacs -l myfile.el -f doit\""
 121   (let* ((args (downcase (vms-system-info "LOGICAL" "EMACS_COMMAND_ARGS")))
 122          (command-line-args (list "emacs"))
 123          (beg 0)
 124          (end 0)
 125          (len (length args))
 126          this-char)
 127     (if args
 128         (progn
 129 ;;; replace non-printable stuff with spaces
 130           (while (< beg (length args))
 131             (if (or (> 33 (setq this-char (aref args beg)))
 132                     (< 127 this-char))
 133                 (aset args beg 32))
 134             (setq beg (1+ beg)))
 135           (setq beg (1- (length args)))
 136           (while (= 32 (aref args beg)) (setq beg (1- beg)))
 137           (setq args (substring args 0 (1+ beg)))
 138           (setq beg 0)
 139 ;;; now start parsing args
 140           (while (< beg (length args))
 141             (while (and (< beg (length args))
 142                         (or (> 33 (setq this-char (aref args beg)))
 143                             (< 127 this-char))
 144                         (setq beg (1+ beg))))
 145             (setq end (1+ beg))
 146             (while (and (< end (length args))
 147                         (< 32 (setq this-char (aref args end)))
 148                         (> 127 this-char))
 149               (setq end (1+ end)))
 150             (setq command-line-args (append
 151                                      command-line-args
 152                                      (list (substring args beg end))))
 153             (setq beg (1+ end)))
 154           (command-line)))))
 155
 156 (defun vms-read-directory (dirname switches buffer)
 157   (save-excursion
 158     (set-buffer buffer)
 159     (subprocess-command-to-buffer
 160      (concat "DIRECTORY " switches " " dirname)
 161      buffer)
 162     (goto-char (point-min))
 163     ;; Remove all the trailing blanks.
 164     (while (search-forward " \n")
 165       (forward-char -1)
 166       (delete-horizontal-space))
 167     (goto-char (point-min))))
 168
 169 (setq dired-listing-switches
 170       "/SIZE/DATE/OWNER/WIDTH=(FILENAME=32,SIZE=5)")
 171
 172 (setq print-region-function
 173       (lambda (start end command ign1 ign2 ign3 &rest switches)
 174          (write-region start end "sys$login:delete-me.txt")
 175          (send-command-to-subprocess
 176           1
 177           (concat command
 178                   " sys$login:delete-me.txt/name=\"GNUprintbuffer\" "
 179                   (mapconcat 'identity switches " "))
 180           nil nil nil)))
 181
 182 ;;;
 183 ;;; Fuctions for using Emacs as a VMS Mail editor
 184 ;;;
 185 (autoload 'vms-pmail-setup "vms-pmail"
 186   "Set up file assuming use by VMS Mail utility.
 187 The buffer is put into text-mode, auto-save is turned off and the
 188 following bindings are established.
 189
 190 \\[vms-pmail-save-and-exit]     vms-pmail-save-and-exit
 191 \\[vms-pmail-abort]     vms-pmail-abort
 192
 193 All other Emacs commands are still available."
 194   t)
 195
 196 ;;;
 197 ;;; Filename handling in the minibuffer
 198 ;;;
 199 (defun vms-magic-right-square-brace ()
 200   "\
 201 Insert a right square brace, but do other things first depending on context.
 202 During filename completion, when point is at the end of the line and the
 203 character before is not a right square brace, do one of three things before
 204 inserting the brace:
 205  - If there are already two left square braces preceding, do nothing special.
 206  - If there is a previous right-square-brace, convert it to dot.
 207  - If the character before is dot, delete it.
 208 Additionally, if the preceding chars are right-square-brace followed by
 209 either \"-\" or \"..\", strip one level of directory hierarchy."
 210   (interactive)
 211   (when (and minibuffer-completing-file-name
 212              (= (point) (point-max))
 213              (not (= 93 (char-before))))
 214     (cond
 215      ;; Avoid clobbering: user:[one.path][another.path
 216      ((search-backward "[" (field-beginning) t 2))
 217      ((search-backward "]" (field-beginning) t)
 218       (delete-char 1)
 219       (insert ".")
 220       (goto-char (point-max)))
 221      ((= ?. (char-before))
 222       (delete-char -1)))
 223     (goto-char (point-max))
 224     (let ((specs '(".." "-"))
 225           (pmax (point-max)))
 226       (while specs
 227         (let* ((up (car specs))
 228                (len (length up))
 229                (cut (- (point) len)))
 230           (when (and (< (1+ len) pmax)
 231                      (= ?. (char-before cut))
 232                      (string= up (buffer-substring cut (point))))
 233             (delete-char (- (1+ len)))
 234             (while (not (let ((c (char-before)))
 235                           (or (= ?. c) (= 91 c))))
 236               (delete-char -1))
 237             (when (= ?. (char-before)) (delete-char -1))
 238             (setq specs nil)))
 239         (setq specs (cdr specs)))))
 240   (insert "]"))
 241
 242 (defun vms-magic-colon ()
 243   "\
 244 Insert a colon, but do other things first depending on context.
 245 During filename completion, when point is at the end of the line
 246 and the line contains a right square brace, remove all characters
 247 from the beginning of the line up to and including such brace.
 248 This enables one to type a new filespec without having to delete
 249 the old one."
 250   (interactive)
 251   (when (and minibuffer-completing-file-name
 252              (= (point) (point-max))
 253              (search-backward "]" (field-beginning) t))
 254     (delete-region (field-beginning) (1+ (point)))
 255     (goto-char (point-max)))
 256   (insert ":"))
 257
 258 (let ((m minibuffer-local-completion-map))
 259   (define-key m "]" 'vms-magic-right-square-brace)
 260   (define-key m "/" 'vms-magic-right-square-brace)
 261   (define-key m ":" 'vms-magic-colon))
 262
 263 ;;; arch-tag: c178494e-2c37-4d02-99b7-e47e615656cf
 264 ;;; vms-patch.el ends here