lisp/textmodes/spell.el

   1 ;;; spell.el --- spelling correction interface for Emacs
   2
   3 ;; Copyright (C) 1985 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: wp, unix
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This mode provides an Emacs interface to the UNIX spell(1) program.
  28 ;; Entry points are `spell-buffer', `spell-word', `spell-region' and
  29 ;; `spell-string'.
  30
  31 ;; See also ispell.el for an interface to the ispell program.
  32
  33 ;;; Code:
  34
  35 (defgroup spell nil
  36   "Interface to the UNIX spell(1) program."
  37   :prefix "spell-"
  38   :group 'applications)
  39
  40 (defcustom spell-command "spell"
  41   "*Command to run the spell program."
  42   :type 'string
  43   :group 'spell)
  44
  45 (defcustom spell-filter nil
  46   "*Filter function to process text before passing it to spell program.
  47 This function might remove text-processor commands.
  48 nil means don't alter the text before checking it."
  49   :type '(choice (const nil) function)
  50   :group 'spell)
  51
  52 ;;;###autoload
  53 (put 'spell-filter 'risky-local-variable t)
  54
  55 ;;;###autoload
  56 (defun spell-buffer ()
  57   "Check spelling of every word in the buffer.
  58 For each incorrect word, you are asked for the correct spelling
  59 and then put into a query-replace to fix some or all occurrences.
  60 If you do not want to change a word, just give the same word
  61 as its \"correct\" spelling; then the query replace is skipped."
  62   (interactive)
  63   (spell-region (point-min) (point-max) "buffer"))
  64
  65 ;;;###autoload
  66 (defun spell-word ()
  67   "Check spelling of word at or before point.
  68 If it is not correct, ask user for the correct spelling
  69 and `query-replace' the entire buffer to substitute it."
  70   (interactive)
  71   (let (beg end spell-filter)
  72     (save-excursion
  73      (if (not (looking-at "\\<"))
  74          (forward-word -1))
  75      (setq beg (point))
  76      (forward-word 1)
  77      (setq end (point)))
  78     (spell-region beg end (buffer-substring beg end))))
  79
  80 ;;;###autoload
  81 (defun spell-region (start end &optional description)
  82   "Like `spell-buffer' but applies only to region.
  83 Used in a program, applies from START to END.
  84 DESCRIPTION is an optional string naming the unit being checked:
  85 for example, \"word\"."
  86   (interactive "r")
  87   (let ((filter spell-filter)
  88         (buf (get-buffer-create " *temp*")))
  89     (save-excursion
  90      (set-buffer buf)
  91      (widen)
  92      (erase-buffer))
  93     (message "Checking spelling of %s..." (or description "region"))
  94     (if (and (null filter) (= ?\n (char-after (1- end))))
  95         (if (string= "spell" spell-command)
  96             (call-process-region start end "spell" nil buf)
  97           (call-process-region start end shell-file-name
  98                                nil buf nil "-c" spell-command))
  99       (let ((oldbuf (current-buffer)))
 100         (save-excursion
 101          (set-buffer buf)
 102          (insert-buffer-substring oldbuf start end)
 103          (or (bolp) (insert ?\n))
 104          (if filter (funcall filter))
 105          (if (string= "spell" spell-command)
 106              (call-process-region (point-min) (point-max) "spell" t buf)
 107            (call-process-region (point-min) (point-max) shell-file-name
 108                                 t buf nil "-c" spell-command)))))
 109     (message "Checking spelling of %s...%s"
 110              (or description "region")
 111              (if (save-excursion
 112                   (set-buffer buf)
 113                   (> (buffer-size) 0))
 114                  "not correct"
 115                "correct"))
 116     (let (word newword
 117           (case-fold-search t)
 118           (case-replace t))
 119       (while (save-excursion
 120               (set-buffer buf)
 121               (> (buffer-size) 0))
 122         (save-excursion
 123          (set-buffer buf)
 124          (goto-char (point-min))
 125          (setq word (downcase
 126                      (buffer-substring (point)
 127                                        (progn (end-of-line) (point)))))
 128          (forward-char 1)
 129          (delete-region (point-min) (point))
 130          (setq newword
 131                (read-string (concat "`" word
 132                                     "' not recognized; edit a replacement: ")
 133                             word))
 134          (flush-lines (concat "^" (regexp-quote word) "$")))
 135         (if (not (equal word newword))
 136             (progn
 137              (goto-char (point-min))
 138              (query-replace-regexp (concat "\\b" (regexp-quote word) "\\b")
 139                                    newword)))))))
 140
 141
 142 ;;;###autoload
 143 (defun spell-string (string)
 144   "Check spelling of string supplied as argument."
 145   (interactive "sSpell string: ")
 146   (let ((buf (get-buffer-create " *temp*")))
 147     (save-excursion
 148      (set-buffer buf)
 149      (widen)
 150      (erase-buffer)
 151      (insert string "\n")
 152      (if (string= "spell" spell-command)
 153          (call-process-region (point-min) (point-max) "spell"
 154                               t t)
 155        (call-process-region (point-min) (point-max) shell-file-name
 156                             t t nil "-c" spell-command))
 157      (if (= 0 (buffer-size))
 158          (message "%s is correct" string)
 159        (goto-char (point-min))
 160        (while (search-forward "\n" nil t)
 161          (replace-match " "))
 162        (message "%sincorrect" (buffer-substring 1 (point-max)))))))
 163
 164 (provide 'spell)
 165
 166 ;;; arch-tag: 7eabb848-9c76-431a-bcdb-0e0592d2db04
 167 ;;; spell.el ends here