lisp/select.el

   1 ;;; select.el --- lisp portion of standard selection support
   2
   3 ;; Maintainer: FSF
   4 ;; Keywords: internal
   5
   6 ;; Copyright (c) 1993, 1994, 2004 Free Software Foundation, Inc.
   7 ;; Based partially on earlier release by Lucid.
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 ;; This is for temporary compatibility with pre-release Emacs 19.
  31 (defalias 'x-selection 'x-get-selection)
  32 (defun x-get-selection (&optional type data-type)
  33   "Return the value of an X Windows selection.
  34 The argument TYPE (default `PRIMARY') says which selection,
  35 and the argument DATA-TYPE (default `STRING') says
  36 how to convert the data.
  37
  38 TYPE may be any symbol \(but nil stands for `PRIMARY').  However,
  39 only a few symbols are commonly used.  They conventionally have
  40 all upper-case names.  The most often used ones, in addition to
  41 `PRIMARY', are `SECONDARY' and `CLIPBOARD'.
  42
  43 DATA-TYPE is usually `STRING', but can also be one of the symbols
  44 in `selection-converter-alist', which see."
  45   (let ((data (x-get-selection-internal (or type 'PRIMARY)
  46                                         (or data-type 'STRING)))
  47         coding)
  48     (when (and (stringp data)
  49                (setq data-type (get-text-property 0 'foreign-selection data)))
  50       (setq coding (if (eq data-type 'UTF8_STRING)
  51                        'utf-8
  52                      (or next-selection-coding-system
  53                          selection-coding-system))
  54             data (decode-coding-string data coding))
  55       (put-text-property 0 (length data) 'foreign-selection data-type data))
  56     data))
  57
  58 (defun x-get-clipboard ()
  59   "Return text pasted to the clipboard."
  60   (x-get-selection-internal 'CLIPBOARD 'STRING))
  61
  62 (defun x-set-selection (type data)
  63   "Make an X Windows selection of type TYPE and value DATA.
  64 The argument TYPE (nil means `PRIMARY') says which selection, and
  65 DATA specifies the contents.  TYPE must be a symbol.  \(It can also
  66 be a string, which stands for the symbol with that name, but this
  67 is considered obsolete.)  DATA may be a string, a symbol, an
  68 integer (or a cons of two integers or list of two integers).
  69
  70 The selection may also be a cons of two markers pointing to the same buffer,
  71 or an overlay.  In these cases, the selection is considered to be the text
  72 between the markers *at whatever time the selection is examined*.
  73 Thus, editing done in the buffer after you specify the selection
  74 can alter the effective value of the selection.
  75
  76 The data may also be a vector of valid non-vector selection values.
  77
  78 The return value is DATA.
  79
  80 Interactively, this command sets the primary selection.  Without
  81 prefix argument, it reads the selection in the minibuffer.  With
  82 prefix argument, it uses the text of the region as the selection value ."
  83   (interactive (if (not current-prefix-arg)
  84                    (list 'PRIMARY (read-string "Set text for pasting: "))
  85                  (list 'PRIMARY (buffer-substring (region-beginning) (region-end)))))
  86   ;; This is for temporary compatibility with pre-release Emacs 19.
  87   (if (stringp type)
  88       (setq type (intern type)))
  89   (or (x-valid-simple-selection-p data)
  90       (and (vectorp data)
  91            (let ((valid t)
  92                  (i (1- (length data))))
  93              (while (>= i 0)
  94                (or (x-valid-simple-selection-p (aref data i))
  95                    (setq valid nil))
  96                (setq i (1- i)))
  97              valid))
  98       (signal 'error (list "invalid selection" data)))
  99   (or type (setq type 'PRIMARY))
 100   (if data
 101       (x-own-selection-internal type data)
 102     (x-disown-selection-internal type))
 103   data)
 104
 105 (defun x-valid-simple-selection-p (data)
 106   (or (stringp data)
 107       (symbolp data)
 108       (integerp data)
 109       (and (consp data)
 110            (integerp (car data))
 111            (or (integerp (cdr data))
 112                (and (consp (cdr data))
 113                     (integerp (car (cdr data))))))
 114       (overlayp data)
 115       (and (consp data)
 116            (markerp (car data))
 117            (markerp (cdr data))
 118            (marker-buffer (car data))
 119            (marker-buffer (cdr data))
 120            (eq (marker-buffer (car data))
 121                (marker-buffer (cdr data)))
 122            (buffer-name (marker-buffer (car data)))
 123            (buffer-name (marker-buffer (cdr data))))))
 124 \f
 125 ;;; Cut Buffer support
 126
 127 (defun x-get-cut-buffer (&optional which-one)
 128   "Returns the value of one of the 8 X server cut-buffers.
 129 Optional arg WHICH-ONE should be a number from 0 to 7, defaulting to 0.
 130 Cut buffers are considered obsolete; you should use selections instead."
 131   (x-get-cut-buffer-internal
 132    (if which-one
 133        (aref [CUT_BUFFER0 CUT_BUFFER1 CUT_BUFFER2 CUT_BUFFER3
 134               CUT_BUFFER4 CUT_BUFFER5 CUT_BUFFER6 CUT_BUFFER7]
 135              which-one)
 136      'CUT_BUFFER0)))
 137
 138 (defun x-set-cut-buffer (string &optional push)
 139   "Store STRING into the X server's primary cut buffer.
 140 If PUSH is non-nil, also rotate the cut buffers:
 141 this means the previous value of the primary cut buffer moves to the second
 142 cut buffer, and the second to the third, and so on (there are 8 buffers.)
 143 Cut buffers are considered obsolete; you should use selections instead."
 144   (or (stringp string) (signal 'wrong-type-argument (list 'string string)))
 145   (if push
 146       (x-rotate-cut-buffers-internal 1))
 147   (x-store-cut-buffer-internal 'CUT_BUFFER0 string))
 148
 149 \f
 150 ;;; Functions to convert the selection into various other selection types.
 151 ;;; Every selection type that Emacs handles is implemented this way, except
 152 ;;; for TIMESTAMP, which is a special case.
 153
 154 (defun xselect-convert-to-string (selection type value)
 155   (let (str coding)
 156     ;; Get the actual string from VALUE.
 157     (cond ((stringp value)
 158            (setq str value))
 159
 160           ((overlayp value)
 161            (save-excursion
 162              (or (buffer-name (overlay-buffer value))
 163                  (error "selection is in a killed buffer"))
 164              (set-buffer (overlay-buffer value))
 165              (setq str (buffer-substring (overlay-start value)
 166                                          (overlay-end value)))))
 167           ((and (consp value)
 168                 (markerp (car value))
 169                 (markerp (cdr value)))
 170            (or (eq (marker-buffer (car value)) (marker-buffer (cdr value)))
 171                (signal 'error
 172                        (list "markers must be in the same buffer"
 173                              (car value) (cdr value))))
 174            (save-excursion
 175              (set-buffer (or (marker-buffer (car value))
 176                              (error "selection is in a killed buffer")))
 177              (setq str (buffer-substring (car value) (cdr value))))))
 178
 179     (when str
 180       ;; If TYPE is nil, this is a local request, thus return STR as
 181       ;; is.  Otherwise, encode STR.
 182       (if (not type)
 183           str
 184         (setq coding (or next-selection-coding-system selection-coding-system))
 185         (if coding
 186             (setq coding (coding-system-base coding))
 187           (setq coding 'raw-text))
 188         (let ((inhibit-read-only t))
 189           ;; Suppress producing escape sequences for compositions.
 190           (remove-text-properties 0 (length str) '(composition nil) str)
 191           (cond
 192            ((eq type 'TEXT)
 193             (if (not (multibyte-string-p str))
 194                 ;; Don't have to encode unibyte string.
 195                 (setq type 'STRING)
 196               ;; If STR contains only ASCII, Latin-1, and raw bytes,
 197               ;; encode STR by iso-latin-1, and return it as type
 198               ;; `STRING'.  Otherwise, encode STR by CODING.  In that
 199               ;; case, the returing type depends on CODING.
 200               (let ((charsets (find-charset-string str)))
 201                 (setq charsets
 202                       (delq 'ascii
 203                             (delq 'latin-iso8859-1
 204                                   (delq 'eight-bit-control
 205                                         (delq 'eight-bit-graphic charsets)))))
 206                 (if charsets
 207                     (setq str (encode-coding-string str coding)
 208                           type (if (memq coding '(compound-text
 209                                                   compound-text-with-extensions))
 210                                    'COMPOUND_TEXT
 211                                  'STRING))
 212                   (setq type 'STRING
 213                         str (encode-coding-string str 'iso-latin-1))))))
 214
 215            ((eq type 'COMPOUND_TEXT)
 216             (setq str (encode-coding-string str coding)))
 217
 218            ((eq type 'STRING)
 219             (if (memq coding '(compound-text
 220                                compound-text-with-extensions))
 221                 (setq str (string-make-unibyte str))
 222               (setq str (encode-coding-string str coding))))
 223
 224            ((eq type 'UTF8_STRING)
 225             (setq str (encode-coding-string str 'utf-8)))
 226
 227            (t
 228             (error "Unknow selection type: %S" type))
 229            )))
 230
 231       (setq next-selection-coding-system nil)
 232       (cons type str))))
 233
 234
 235 (defun xselect-convert-to-length (selection type value)
 236   (let ((value
 237          (cond ((stringp value)
 238                 (length value))
 239                ((overlayp value)
 240                 (abs (- (overlay-end value) (overlay-start value))))
 241                ((and (consp value)
 242                      (markerp (car value))
 243                      (markerp (cdr value)))
 244                 (or (eq (marker-buffer (car value))
 245                         (marker-buffer (cdr value)))
 246                     (signal 'error
 247                             (list "markers must be in the same buffer"
 248                                   (car value) (cdr value))))
 249                 (abs (- (car value) (cdr value)))))))
 250     (if value ; force it to be in 32-bit format.
 251         (cons (ash value -16) (logand value 65535))
 252       nil)))
 253
 254 (defun xselect-convert-to-targets (selection type value)
 255   ;; return a vector of atoms, but remove duplicates first.
 256   (let* ((all (cons 'TIMESTAMP (mapcar 'car selection-converter-alist)))
 257          (rest all))
 258     (while rest
 259       (cond ((memq (car rest) (cdr rest))
 260              (setcdr rest (delq (car rest) (cdr rest))))
 261             ((eq (car (cdr rest)) '_EMACS_INTERNAL)  ; shh, it's a secret
 262              (setcdr rest (cdr (cdr rest))))
 263             (t
 264              (setq rest (cdr rest)))))
 265     (apply 'vector all)))
 266
 267 (defun xselect-convert-to-delete (selection type value)
 268   (x-disown-selection-internal selection)
 269   ;; A return value of nil means that we do not know how to do this conversion,
 270   ;; and replies with an "error".  A return value of NULL means that we have
 271   ;; done the conversion (and any side-effects) but have no value to return.
 272   'NULL)
 273
 274 (defun xselect-convert-to-filename (selection type value)
 275   (cond ((overlayp value)
 276          (buffer-file-name (or (overlay-buffer value)
 277                                (error "selection is in a killed buffer"))))
 278         ((and (consp value)
 279               (markerp (car value))
 280               (markerp (cdr value)))
 281          (buffer-file-name (or (marker-buffer (car value))
 282                                (error "selection is in a killed buffer"))))
 283         (t nil)))
 284
 285 (defun xselect-convert-to-charpos (selection type value)
 286   (let (a b tmp)
 287     (cond ((cond ((overlayp value)
 288                   (setq a (overlay-start value)
 289                         b (overlay-end value)))
 290                  ((and (consp value)
 291                        (markerp (car value))
 292                        (markerp (cdr value)))
 293                   (setq a (car value)
 294                         b (cdr value))))
 295            (setq a (1- a) b (1- b)) ; zero-based
 296            (if (< b a) (setq tmp a a b b tmp))
 297            (cons 'SPAN
 298                  (vector (cons (ash a -16) (logand a 65535))
 299                          (cons (ash b -16) (logand b 65535))))))))
 300
 301 (defun xselect-convert-to-lineno (selection type value)
 302   (let (a b buf tmp)
 303     (cond ((cond ((and (consp value)
 304                        (markerp (car value))
 305                        (markerp (cdr value)))
 306                   (setq a (marker-position (car value))
 307                         b (marker-position (cdr value))
 308                         buf (marker-buffer (car value))))
 309                  ((overlayp value)
 310                   (setq buf (overlay-buffer value)
 311                         a (overlay-start value)
 312                         b (overlay-end value)))
 313                  )
 314            (save-excursion
 315              (set-buffer buf)
 316              (setq a (count-lines 1 a)
 317                    b (count-lines 1 b)))
 318            (if (< b a) (setq tmp a a b b tmp))
 319            (cons 'SPAN
 320                  (vector (cons (ash a -16) (logand a 65535))
 321                          (cons (ash b -16) (logand b 65535))))))))
 322
 323 (defun xselect-convert-to-colno (selection type value)
 324   (let (a b buf tmp)
 325     (cond ((cond ((and (consp value)
 326                        (markerp (car value))
 327                        (markerp (cdr value)))
 328                   (setq a (car value)
 329                         b (cdr value)
 330                         buf (marker-buffer a)))
 331                  ((overlayp value)
 332                   (setq buf (overlay-buffer value)
 333                         a (overlay-start value)
 334                         b (overlay-end value)))
 335                  )
 336            (save-excursion
 337              (set-buffer buf)
 338              (goto-char a)
 339              (setq a (current-column))
 340              (goto-char b)
 341              (setq b (current-column)))
 342            (if (< b a) (setq tmp a a b b tmp))
 343            (cons 'SPAN
 344                  (vector (cons (ash a -16) (logand a 65535))
 345                          (cons (ash b -16) (logand b 65535))))))))
 346
 347 (defun xselect-convert-to-os (selection type size)
 348   (symbol-name system-type))
 349
 350 (defun xselect-convert-to-host (selection type size)
 351   (system-name))
 352
 353 (defun xselect-convert-to-user (selection type size)
 354   (user-full-name))
 355
 356 (defun xselect-convert-to-class (selection type size)
 357   "Convert selection to class.
 358 This function returns the string \"Emacs\"."
 359   "Emacs")
 360
 361 ;; We do not try to determine the name Emacs was invoked with,
 362 ;; because it is not clean for a program's behavior to depend on that.
 363 (defun xselect-convert-to-name (selection type size)
 364   "Convert selection to name.
 365 This function returns the string \"emacs\"."
 366   "emacs")
 367
 368 (defun xselect-convert-to-integer (selection type value)
 369   (and (integerp value)
 370        (cons (ash value -16) (logand value 65535))))
 371
 372 (defun xselect-convert-to-atom (selection type value)
 373   (and (symbolp value) value))
 374
 375 (defun xselect-convert-to-identity (selection type value) ; used internally
 376   (vector value))
 377
 378 (setq selection-converter-alist
 379       '((TEXT . xselect-convert-to-string)
 380         (COMPOUND_TEXT . xselect-convert-to-string)
 381         (STRING . xselect-convert-to-string)
 382         (UTF8_STRING . xselect-convert-to-string)
 383         (TARGETS . xselect-convert-to-targets)
 384         (LENGTH . xselect-convert-to-length)
 385         (DELETE . xselect-convert-to-delete)
 386         (FILE_NAME . xselect-convert-to-filename)
 387         (CHARACTER_POSITION . xselect-convert-to-charpos)
 388         (LINE_NUMBER . xselect-convert-to-lineno)
 389         (COLUMN_NUMBER . xselect-convert-to-colno)
 390         (OWNER_OS . xselect-convert-to-os)
 391         (HOST_NAME . xselect-convert-to-host)
 392         (USER . xselect-convert-to-user)
 393         (CLASS . xselect-convert-to-class)
 394         (NAME . xselect-convert-to-name)
 395         (ATOM . xselect-convert-to-atom)
 396         (INTEGER . xselect-convert-to-integer)
 397         (_EMACS_INTERNAL . xselect-convert-to-identity)
 398         ))
 399
 400 (provide 'select)
 401
 402 ;;; arch-tag: bb634f97-8a3b-4b0a-b940-f6e09982328c
 403 ;;; select.el ends here