lisp/progmodes/inf-lisp.el

   1 ;;; inf-lisp.el --- an inferior-lisp mode
   2
   3 ;; Copyright (C) 1988, 1993, 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: Olin Shivers <shivers@cs.cmu.edu>
   6 ;; Keywords: processes, lisp
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Hacked from tea.el by Olin Shivers (shivers@cs.cmu.edu). 8/88
  28
  29 ;; This file defines a lisp-in-a-buffer package (inferior-lisp mode)
  30 ;; built on top of comint mode.  This version is more featureful,
  31 ;; robust, and uniform than the Emacs 18 version.  The key bindings are
  32 ;; also more compatible with the bindings of Hemlock and Zwei (the
  33 ;; Lisp Machine emacs).
  34
  35 ;; Since this mode is built on top of the general command-interpreter-in-
  36 ;; a-buffer mode (comint mode), it shares a common base functionality,
  37 ;; and a common set of bindings, with all modes derived from comint mode.
  38 ;; This makes these modes easier to use.
  39
  40 ;; For documentation on the functionality provided by comint mode, and
  41 ;; the hooks available for customising it, see the file comint.el.
  42 ;; For further information on inferior-lisp mode, see the comments below.
  43
  44 ;; Needs fixin:
  45 ;; The load-file/compile-file default mechanism could be smarter -- it
  46 ;; doesn't know about the relationship between filename extensions and
  47 ;; whether the file is source or executable. If you compile foo.lisp
  48 ;; with compile-file, then the next load-file should use foo.bin for
  49 ;; the default, not foo.lisp. This is tricky to do right, particularly
  50 ;; because the extension for executable files varies so much (.o, .bin,
  51 ;; .lbin, .mo, .vo, .ao, ...).
  52 ;;
  53 ;; It would be nice if inferior-lisp (and inferior scheme, T, ...) modes
  54 ;; had a verbose minor mode wherein sending or compiling defuns, etc.
  55 ;; would be reflected in the transcript with suitable comments, e.g.
  56 ;; ";;; redefining fact". Several ways to do this. Which is right?
  57 ;;
  58 ;; When sending text from a source file to a subprocess, the process-mark can
  59 ;; move off the window, so you can lose sight of the process interactions.
  60 ;; Maybe I should ensure the process mark is in the window when I send
  61 ;; text to the process? Switch selectable?
  62
  63 ;;; Code:
  64
  65 (require 'comint)
  66 (require 'lisp-mode)
  67
  68 \f
  69 (defgroup inferior-lisp nil
  70   "Run an outside Lisp in an Emacs buffer."
  71   :group 'lisp
  72   :version "22.1")
  73
  74 ;;;###autoload
  75 (defcustom inferior-lisp-filter-regexp
  76   "\\`\\s *\\(:\\(\\w\\|\\s_\\)\\)?\\s *\\'"
  77   "*What not to save on inferior Lisp's input history.
  78 Input matching this regexp is not saved on the input history in Inferior Lisp
  79 mode.  Default is whitespace followed by 0 or 1 single-letter colon-keyword
  80 \(as in :a, :c, etc.)"
  81   :type 'regexp
  82   :group 'inferior-lisp)
  83
  84 (defvar inferior-lisp-mode-map nil)
  85 (unless inferior-lisp-mode-map
  86   (setq inferior-lisp-mode-map (copy-keymap comint-mode-map))
  87   (set-keymap-parent inferior-lisp-mode-map lisp-mode-shared-map)
  88   (define-key inferior-lisp-mode-map "\C-x\C-e" 'lisp-eval-last-sexp)
  89   (define-key inferior-lisp-mode-map "\C-c\C-l" 'lisp-load-file)
  90   (define-key inferior-lisp-mode-map "\C-c\C-k" 'lisp-compile-file)
  91   (define-key inferior-lisp-mode-map "\C-c\C-a" 'lisp-show-arglist)
  92   (define-key inferior-lisp-mode-map "\C-c\C-d" 'lisp-describe-sym)
  93   (define-key inferior-lisp-mode-map "\C-c\C-f"
  94     'lisp-show-function-documentation)
  95   (define-key inferior-lisp-mode-map "\C-c\C-v"
  96     'lisp-show-variable-documentation))
  97
  98 ;;; These commands augment Lisp mode, so you can process Lisp code in
  99 ;;; the source files.
 100 (define-key lisp-mode-map "\M-\C-x"  'lisp-eval-defun)     ; Gnu convention
 101 (define-key lisp-mode-map "\C-x\C-e" 'lisp-eval-last-sexp) ; Gnu convention
 102 (define-key lisp-mode-map "\C-c\C-e" 'lisp-eval-defun)
 103 (define-key lisp-mode-map "\C-c\C-r" 'lisp-eval-region)
 104 (define-key lisp-mode-map "\C-c\C-c" 'lisp-compile-defun)
 105 (define-key lisp-mode-map "\C-c\C-z" 'switch-to-lisp)
 106 (define-key lisp-mode-map "\C-c\C-l" 'lisp-load-file)
 107 (define-key lisp-mode-map "\C-c\C-k" 'lisp-compile-file)  ; "kompile" file
 108 (define-key lisp-mode-map "\C-c\C-a" 'lisp-show-arglist)
 109 (define-key lisp-mode-map "\C-c\C-d" 'lisp-describe-sym)
 110 (define-key lisp-mode-map "\C-c\C-f" 'lisp-show-function-documentation)
 111 (define-key lisp-mode-map "\C-c\C-v" 'lisp-show-variable-documentation)
 112
 113
 114 ;;; This function exists for backwards compatibility.
 115 ;;; Previous versions of this package bound commands to C-c <letter>
 116 ;;; bindings, which is not allowed by the gnumacs standard.
 117
 118 ;;;  "This function binds many inferior-lisp commands to C-c <letter> bindings,
 119 ;;;where they are more accessible. C-c <letter> bindings are reserved for the
 120 ;;;user, so these bindings are non-standard. If you want them, you should
 121 ;;;have this function called by the inferior-lisp-load-hook:
 122 ;;;  (add-hook 'inferior-lisp-load-hook 'inferior-lisp-install-letter-bindings)
 123 ;;;You can modify this function to install just the bindings you want."
 124 (defun inferior-lisp-install-letter-bindings ()
 125   (define-key lisp-mode-map "\C-ce" 'lisp-eval-defun-and-go)
 126   (define-key lisp-mode-map "\C-cr" 'lisp-eval-region-and-go)
 127   (define-key lisp-mode-map "\C-cc" 'lisp-compile-defun-and-go)
 128   (define-key lisp-mode-map "\C-cz" 'switch-to-lisp)
 129   (define-key lisp-mode-map "\C-cl" 'lisp-load-file)
 130   (define-key lisp-mode-map "\C-ck" 'lisp-compile-file)
 131   (define-key lisp-mode-map "\C-ca" 'lisp-show-arglist)
 132   (define-key lisp-mode-map "\C-cd" 'lisp-describe-sym)
 133   (define-key lisp-mode-map "\C-cf" 'lisp-show-function-documentation)
 134   (define-key lisp-mode-map "\C-cv" 'lisp-show-variable-documentation)
 135
 136   (define-key inferior-lisp-mode-map "\C-cl" 'lisp-load-file)
 137   (define-key inferior-lisp-mode-map "\C-ck" 'lisp-compile-file)
 138   (define-key inferior-lisp-mode-map "\C-ca" 'lisp-show-arglist)
 139   (define-key inferior-lisp-mode-map "\C-cd" 'lisp-describe-sym)
 140   (define-key inferior-lisp-mode-map "\C-cf" 'lisp-show-function-documentation)
 141   (define-key inferior-lisp-mode-map "\C-cv"
 142     'lisp-show-variable-documentation))
 143
 144 ;;;###autoload
 145 (defcustom inferior-lisp-program "lisp"
 146   "*Program name for invoking an inferior Lisp in Inferior Lisp mode."
 147   :type 'string
 148   :group 'inferior-lisp)
 149
 150 ;;;###autoload
 151 (defcustom inferior-lisp-load-command "(load \"%s\")\n"
 152   "*Format-string for building a Lisp expression to load a file.
 153 This format string should use `%s' to substitute a file name
 154 and should result in a Lisp expression that will command the inferior Lisp
 155 to load that file.  The default works acceptably on most Lisps.
 156 The string \"(progn (load \\\"%s\\\" :verbose nil :print t) (values))\\n\"
 157 produces cosmetically superior output for this application,
 158 but it works only in Common Lisp."
 159   :type 'string
 160   :group 'inferior-lisp)
 161
 162 ;;;###autoload
 163 (defcustom inferior-lisp-prompt "^[^> \n]*>+:? *"
 164   "Regexp to recognise prompts in the Inferior Lisp mode.
 165 Defaults to \"^[^> \\n]*>+:? *\", which works pretty good for Lucid, kcl,
 166 and franz.  This variable is used to initialize `comint-prompt-regexp' in the
 167 Inferior Lisp buffer.
 168
 169 This variable is only used if the variable
 170 `comint-use-prompt-regexp' is non-nil.
 171
 172 More precise choices:
 173 Lucid Common Lisp: \"^\\\\(>\\\\|\\\\(->\\\\)+\\\\) *\"
 174 franz: \"^\\\\(->\\\\|<[0-9]*>:\\\\) *\"
 175 kcl: \"^>+ *\"
 176
 177 This is a fine thing to set in your .emacs file or through Custom."
 178   :type 'regexp
 179   :group 'inferior-lisp)
 180
 181 (defvar inferior-lisp-buffer nil "*The current inferior-lisp process buffer.
 182
 183 MULTIPLE PROCESS SUPPORT
 184 ===========================================================================
 185 To run multiple Lisp processes, you start the first up
 186 with \\[inferior-lisp].  It will be in a buffer named `*inferior-lisp*'.
 187 Rename this buffer with \\[rename-buffer].  You may now start up a new
 188 process with another \\[inferior-lisp].  It will be in a new buffer,
 189 named `*inferior-lisp*'.  You can switch between the different process
 190 buffers with \\[switch-to-buffer].
 191
 192 Commands that send text from source buffers to Lisp processes --
 193 like `lisp-eval-defun' or `lisp-show-arglist' -- have to choose a process
 194 to send to, when you have more than one Lisp process around.  This
 195 is determined by the global variable `inferior-lisp-buffer'.  Suppose you
 196 have three inferior Lisps running:
 197     Buffer              Process
 198     foo                 inferior-lisp
 199     bar                 inferior-lisp<2>
 200     *inferior-lisp*     inferior-lisp<3>
 201 If you do a \\[lisp-eval-defun] command on some Lisp source code,
 202 what process do you send it to?
 203
 204 - If you're in a process buffer (foo, bar, or *inferior-lisp*),
 205   you send it to that process.
 206 - If you're in some other buffer (e.g., a source file), you
 207   send it to the process attached to buffer `inferior-lisp-buffer'.
 208 This process selection is performed by function `inferior-lisp-proc'.
 209
 210 Whenever \\[inferior-lisp] fires up a new process, it resets
 211 `inferior-lisp-buffer' to be the new process's buffer.  If you only run
 212 one process, this does the right thing.  If you run multiple
 213 processes, you can change `inferior-lisp-buffer' to another process
 214 buffer with \\[set-variable].")
 215
 216 ;;;###autoload
 217 (defvar inferior-lisp-mode-hook '()
 218   "*Hook for customising Inferior Lisp mode.")
 219
 220 (put 'inferior-lisp-mode 'mode-class 'special)
 221
 222 (defun inferior-lisp-mode ()
 223   "Major mode for interacting with an inferior Lisp process.
 224 Runs a Lisp interpreter as a subprocess of Emacs, with Lisp I/O through an
 225 Emacs buffer.  Variable `inferior-lisp-program' controls which Lisp interpreter
 226 is run.  Variables `inferior-lisp-prompt', `inferior-lisp-filter-regexp' and
 227 `inferior-lisp-load-command' can customize this mode for different Lisp
 228 interpreters.
 229
 230 For information on running multiple processes in multiple buffers, see
 231 documentation for variable `inferior-lisp-buffer'.
 232
 233 \\{inferior-lisp-mode-map}
 234
 235 Customisation: Entry to this mode runs the hooks on `comint-mode-hook' and
 236 `inferior-lisp-mode-hook' (in that order).
 237
 238 You can send text to the inferior Lisp process from other buffers containing
 239 Lisp source.
 240     switch-to-lisp switches the current buffer to the Lisp process buffer.
 241     lisp-eval-defun sends the current defun to the Lisp process.
 242     lisp-compile-defun compiles the current defun.
 243     lisp-eval-region sends the current region to the Lisp process.
 244     lisp-compile-region compiles the current region.
 245
 246     Prefixing the lisp-eval/compile-defun/region commands with
 247     a \\[universal-argument] causes a switch to the Lisp process buffer after sending
 248     the text.
 249
 250 Commands:
 251 Return after the end of the process' output sends the text from the
 252     end of process to point.
 253 Return before the end of the process' output copies the sexp ending at point
 254     to the end of the process' output, and sends it.
 255 Delete converts tabs to spaces as it moves back.
 256 Tab indents for Lisp; with argument, shifts rest
 257     of expression rigidly with the current line.
 258 C-M-q does Tab on each line starting within following expression.
 259 Paragraphs are separated only by blank lines.  Semicolons start comments.
 260 If you accidentally suspend your process, use \\[comint-continue-subjob]
 261 to continue it."
 262   (interactive)
 263   (delay-mode-hooks
 264     (comint-mode))
 265   (setq comint-prompt-regexp inferior-lisp-prompt)
 266   (setq major-mode 'inferior-lisp-mode)
 267   (setq mode-name "Inferior Lisp")
 268   (setq mode-line-process '(":%s"))
 269   (lisp-mode-variables t)
 270   (use-local-map inferior-lisp-mode-map)    ;c-c c-k for "kompile" file
 271   (setq comint-get-old-input (function lisp-get-old-input))
 272   (setq comint-input-filter (function lisp-input-filter))
 273   (run-mode-hooks 'inferior-lisp-mode-hook))
 274
 275 (defun lisp-get-old-input ()
 276   "Return a string containing the sexp ending at point."
 277   (save-excursion
 278     (let ((end (point)))
 279       (backward-sexp)
 280       (buffer-substring (point) end))))
 281
 282 (defun lisp-input-filter (str)
 283   "t if STR does not match `inferior-lisp-filter-regexp'."
 284   (not (string-match inferior-lisp-filter-regexp str)))
 285
 286 ;;;###autoload
 287 (defun inferior-lisp (cmd)
 288   "Run an inferior Lisp process, input and output via buffer `*inferior-lisp*'.
 289 If there is a process already running in `*inferior-lisp*', just switch
 290 to that buffer.
 291 With argument, allows you to edit the command line (default is value
 292 of `inferior-lisp-program').  Runs the hooks from
 293 `inferior-lisp-mode-hook' (after the `comint-mode-hook' is run).
 294 \(Type \\[describe-mode] in the process buffer for a list of commands.)"
 295   (interactive (list (if current-prefix-arg
 296                          (read-string "Run lisp: " inferior-lisp-program)
 297                        inferior-lisp-program)))
 298   (if (not (comint-check-proc "*inferior-lisp*"))
 299       (let ((cmdlist (split-string cmd)))
 300         (set-buffer (apply (function make-comint)
 301                            "inferior-lisp" (car cmdlist) nil (cdr cmdlist)))
 302         (inferior-lisp-mode)))
 303   (setq inferior-lisp-buffer "*inferior-lisp*")
 304   (pop-to-buffer "*inferior-lisp*"))
 305 ;;;###autoload (add-hook 'same-window-buffer-names "*inferior-lisp*")
 306
 307 ;;;###autoload
 308 (defalias 'run-lisp 'inferior-lisp)
 309
 310 (defun lisp-eval-region (start end &optional and-go)
 311   "Send the current region to the inferior Lisp process.
 312 Prefix argument means switch to the Lisp buffer afterwards."
 313   (interactive "r\nP")
 314   (comint-send-region (inferior-lisp-proc) start end)
 315   (comint-send-string (inferior-lisp-proc) "\n")
 316   (if and-go (switch-to-lisp t)))
 317
 318 (defun lisp-eval-defun (&optional and-go)
 319   "Send the current defun to the inferior Lisp process.
 320 Prefix argument means switch to the Lisp buffer afterwards."
 321   (interactive "P")
 322   (save-excursion
 323     (end-of-defun)
 324     (skip-chars-backward " \t\n\r\f") ;  Makes allegro happy
 325     (let ((end (point)))
 326       (beginning-of-defun)
 327       (lisp-eval-region (point) end)))
 328   (if and-go (switch-to-lisp t)))
 329
 330 (defun lisp-eval-last-sexp (&optional and-go)
 331   "Send the previous sexp to the inferior Lisp process.
 332 Prefix argument means switch to the Lisp buffer afterwards."
 333   (interactive "P")
 334   (lisp-eval-region (save-excursion (backward-sexp) (point)) (point) and-go))
 335
 336 ;;; Common Lisp COMPILE sux.
 337 (defun lisp-compile-region (start end &optional and-go)
 338   "Compile the current region in the inferior Lisp process.
 339 Prefix argument means switch to the Lisp buffer afterwards."
 340   (interactive "r\nP")
 341   (comint-send-string
 342    (inferior-lisp-proc)
 343    (format "(funcall (compile nil `(lambda () (progn 'compile %s))))\n"
 344            (buffer-substring start end)))
 345   (if and-go (switch-to-lisp t)))
 346
 347 (defun lisp-compile-defun (&optional and-go)
 348   "Compile the current defun in the inferior Lisp process.
 349 Prefix argument means switch to the Lisp buffer afterwards."
 350   (interactive "P")
 351   (save-excursion
 352     (end-of-defun)
 353     (skip-chars-backward " \t\n\r\f") ;  Makes allegro happy
 354     (let ((e (point)))
 355       (beginning-of-defun)
 356       (lisp-compile-region (point) e)))
 357   (if and-go (switch-to-lisp t)))
 358
 359 (defun switch-to-lisp (eob-p)
 360   "Switch to the inferior Lisp process buffer.
 361 With argument, positions cursor at end of buffer."
 362   (interactive "P")
 363   (if (get-buffer-process inferior-lisp-buffer)
 364       (let ((pop-up-frames
 365              ;; Be willing to use another frame
 366              ;; that already has the window in it.
 367              (or pop-up-frames
 368                  (get-buffer-window inferior-lisp-buffer t))))
 369         (pop-to-buffer inferior-lisp-buffer))
 370       (run-lisp inferior-lisp-program))
 371   (when eob-p
 372          (push-mark)
 373     (goto-char (point-max))))
 374
 375
 376 ;;; Now that lisp-compile/eval-defun/region takes an optional prefix arg,
 377 ;;; these commands are redundant. But they are kept around for the user
 378 ;;; to bind if he wishes, for backwards functionality, and because it's
 379 ;;; easier to type C-c e than C-u C-c C-e.
 380
 381 (defun lisp-eval-region-and-go (start end)
 382   "Send the current region to the inferior Lisp, and switch to its buffer."
 383   (interactive "r")
 384   (lisp-eval-region start end t))
 385
 386 (defun lisp-eval-defun-and-go ()
 387   "Send the current defun to the inferior Lisp, and switch to its buffer."
 388   (interactive)
 389   (lisp-eval-defun t))
 390
 391 (defun lisp-compile-region-and-go (start end)
 392   "Compile the current region in the inferior Lisp, and switch to its buffer."
 393   (interactive "r")
 394   (lisp-compile-region start end t))
 395
 396 (defun lisp-compile-defun-and-go ()
 397   "Compile the current defun in the inferior Lisp, and switch to its buffer."
 398   (interactive)
 399   (lisp-compile-defun t))
 400
 401 ;;; A version of the form in H. Shevis' soar-mode.el package. Less robust.
 402 ;;; (defun lisp-compile-sexp (start end)
 403 ;;;   "Compile the s-expression bounded by START and END in the inferior lisp.
 404 ;;; If the sexp isn't a DEFUN form, it is evaluated instead."
 405 ;;;   (cond ((looking-at "(defun\\s +")
 406 ;;;      (goto-char (match-end 0))
 407 ;;;      (let ((name-start (point)))
 408 ;;;        (forward-sexp 1)
 409 ;;;        (process-send-string "inferior-lisp"
 410 ;;;                             (format "(compile '%s #'(lambda "
 411 ;;;                                     (buffer-substring name-start
 412 ;;;                                                       (point)))))
 413 ;;;      (let ((body-start (point)))
 414 ;;;        (goto-char start) (forward-sexp 1) ; Can't use end-of-defun.
 415 ;;;        (process-send-region "inferior-lisp"
 416 ;;;                             (buffer-substring body-start (point))))
 417 ;;;      (process-send-string "inferior-lisp" ")\n"))
 418 ;;;     (t (lisp-eval-region start end)))))
 419 ;;;
 420 ;;; (defun lisp-compile-region (start end)
 421 ;;;   "Each s-expression in the current region is compiled (if a DEFUN)
 422 ;;; or evaluated (if not) in the inferior lisp."
 423 ;;;   (interactive "r")
 424 ;;;   (save-excursion
 425 ;;;     (goto-char start) (end-of-defun) (beginning-of-defun) ; error check
 426 ;;;     (if (< (point) start) (error "region begins in middle of defun"))
 427 ;;;     (goto-char start)
 428 ;;;     (let ((s start))
 429 ;;;       (end-of-defun)
 430 ;;;       (while (<= (point) end) ; Zip through
 431 ;;;     (lisp-compile-sexp s (point)) ; compiling up defun-sized chunks.
 432 ;;;     (setq s (point))
 433 ;;;     (end-of-defun))
 434 ;;;       (if (< s end) (lisp-compile-sexp s end)))))
 435 ;;;
 436 ;;; End of HS-style code
 437
 438
 439 (defvar lisp-prev-l/c-dir/file nil
 440   "Record last directory and file used in loading or compiling.
 441 This holds a cons cell of the form `(DIRECTORY . FILE)'
 442 describing the last `lisp-load-file' or `lisp-compile-file' command.")
 443
 444 (defcustom lisp-source-modes '(lisp-mode)
 445   "*Used to determine if a buffer contains Lisp source code.
 446 If it's loaded into a buffer that is in one of these major modes, it's
 447 considered a Lisp source file by `lisp-load-file' and `lisp-compile-file'.
 448 Used by these commands to determine defaults."
 449   :type '(repeat symbol)
 450   :group 'inferior-lisp)
 451
 452 (defun lisp-load-file (file-name)
 453   "Load a Lisp file into the inferior Lisp process."
 454   (interactive (comint-get-source "Load Lisp file: " lisp-prev-l/c-dir/file
 455                                   lisp-source-modes nil)) ; nil because LOAD
 456                                         ; doesn't need an exact name
 457   (comint-check-source file-name) ; Check to see if buffer needs saved.
 458   (setq lisp-prev-l/c-dir/file (cons (file-name-directory    file-name)
 459                                      (file-name-nondirectory file-name)))
 460   (comint-send-string (inferior-lisp-proc)
 461                       (format inferior-lisp-load-command file-name))
 462   (switch-to-lisp t))
 463
 464
 465 (defun lisp-compile-file (file-name)
 466   "Compile a Lisp file in the inferior Lisp process."
 467   (interactive (comint-get-source "Compile Lisp file: " lisp-prev-l/c-dir/file
 468                                   lisp-source-modes nil)) ; nil = don't need
 469                                         ; suffix .lisp
 470   (comint-check-source file-name) ; Check to see if buffer needs saved.
 471   (setq lisp-prev-l/c-dir/file (cons (file-name-directory    file-name)
 472                                      (file-name-nondirectory file-name)))
 473   (comint-send-string (inferior-lisp-proc) (concat "(compile-file \""
 474                                                    file-name
 475                                                    "\"\)\n"))
 476   (switch-to-lisp t))
 477
 478
 479 \f
 480 ;;; Documentation functions: function doc, var doc, arglist, and
 481 ;;; describe symbol.
 482 ;;; ===========================================================================
 483
 484 ;;; Command strings
 485 ;;; ===============
 486
 487 (defvar lisp-function-doc-command
 488   "(let ((fn '%s))
 489      (format t \"Documentation for ~a:~&~a\"
 490              fn (documentation fn 'function))
 491      (values))\n"
 492   "Command to query inferior Lisp for a function's documentation.")
 493
 494 (defvar lisp-var-doc-command
 495   "(let ((v '%s))
 496      (format t \"Documentation for ~a:~&~a\"
 497              v (documentation v 'variable))
 498      (values))\n"
 499   "Command to query inferior Lisp for a variable's documentation.")
 500
 501 (defvar lisp-arglist-command
 502   "(let ((fn '%s))
 503      (format t \"Arglist for ~a: ~a\" fn (arglist fn))
 504      (values))\n"
 505   "Command to query inferior Lisp for a function's arglist.")
 506
 507 (defvar lisp-describe-sym-command
 508   "(describe '%s)\n"
 509   "Command to query inferior Lisp for a variable's documentation.")
 510
 511
 512 ;;; Ancillary functions
 513 ;;; ===================
 514
 515 ;;; Reads a string from the user.
 516 (defun lisp-symprompt (prompt default)
 517   (list (let* ((prompt (if default
 518                            (format "%s (default %s): " prompt default)
 519                          (concat prompt ": ")))
 520                (ans (read-string prompt)))
 521           (if (zerop (length ans)) default ans))))
 522
 523
 524 ;;; Adapted from function-called-at-point in help.el.
 525 (defun lisp-fn-called-at-pt ()
 526   "Returns the name of the function called in the current call.
 527 The value is nil if it can't find one."
 528   (condition-case nil
 529       (save-excursion
 530         (save-restriction
 531           (narrow-to-region (max (point-min) (- (point) 1000)) (point-max))
 532           (backward-up-list 1)
 533           (forward-char 1)
 534           (let ((obj (read (current-buffer))))
 535             (and (symbolp obj) obj))))
 536     (error nil)))
 537
 538
 539 ;;; Adapted from variable-at-point in help.el.
 540 (defun lisp-var-at-pt ()
 541   (condition-case ()
 542       (save-excursion
 543         (forward-sexp -1)
 544         (skip-chars-forward "'")
 545         (let ((obj (read (current-buffer))))
 546           (and (symbolp obj) obj)))
 547     (error nil)))
 548
 549
 550 ;;; Documentation functions: fn and var doc, arglist, and symbol describe.
 551 ;;; ======================================================================
 552
 553 (defun lisp-show-function-documentation (fn)
 554   "Send a command to the inferior Lisp to give documentation for function FN.
 555 See variable `lisp-function-doc-command'."
 556   (interactive (lisp-symprompt "Function doc" (lisp-fn-called-at-pt)))
 557   (comint-proc-query (inferior-lisp-proc)
 558                      (format lisp-function-doc-command fn)))
 559
 560 (defun lisp-show-variable-documentation (var)
 561   "Send a command to the inferior Lisp to give documentation for function FN.
 562 See variable `lisp-var-doc-command'."
 563   (interactive (lisp-symprompt "Variable doc" (lisp-var-at-pt)))
 564   (comint-proc-query (inferior-lisp-proc) (format lisp-var-doc-command var)))
 565
 566 (defun lisp-show-arglist (fn)
 567   "Send a query to the inferior Lisp for the arglist for function FN.
 568 See variable `lisp-arglist-command'."
 569   (interactive (lisp-symprompt "Arglist" (lisp-fn-called-at-pt)))
 570   (comint-proc-query (inferior-lisp-proc) (format lisp-arglist-command fn)))
 571
 572 (defun lisp-describe-sym (sym)
 573   "Send a command to the inferior Lisp to describe symbol SYM.
 574 See variable `lisp-describe-sym-command'."
 575   (interactive (lisp-symprompt "Describe" (lisp-var-at-pt)))
 576   (comint-proc-query (inferior-lisp-proc)
 577                      (format lisp-describe-sym-command sym)))
 578
 579 \f
 580 ;;  "Returns the current inferior Lisp process.
 581 ;; See variable `inferior-lisp-buffer'."
 582 (defun inferior-lisp-proc ()
 583   (let ((proc (get-buffer-process (if (eq major-mode 'inferior-lisp-mode)
 584                                       (current-buffer)
 585                                     inferior-lisp-buffer))))
 586     (or proc
 587         (error "No Lisp subprocess; see variable `inferior-lisp-buffer'"))))
 588
 589
 590 ;;; Do the user's customisation...
 591 ;;;===============================
 592 (defvar inferior-lisp-load-hook nil
 593   "This hook is run when the library `inf-lisp' is loaded.")
 594
 595 (run-hooks 'inferior-lisp-load-hook)
 596
 597 ;;; CHANGE LOG
 598 ;;; ===========================================================================
 599 ;;; 7/21/92 Jim Blandy
 600 ;;; - Changed all uses of the cmulisp name or prefix to inferior-lisp;
 601 ;;;   this is now the official inferior lisp package.  Use the global
 602 ;;;   ChangeLog from now on.
 603 ;;; 5/24/90 Olin
 604 ;;; - Split cmulisp and cmushell modes into separate files.
 605 ;;;   Not only is this a good idea, it's apparently the way it'll be rel 19.
 606 ;;; - Upgraded process sends to use comint-send-string instead of
 607 ;;;   process-send-string.
 608 ;;; - Explicit references to process "cmulisp" have been replaced with
 609 ;;;   (cmulisp-proc). This allows better handling of multiple process bufs.
 610 ;;; - Added process query and var/function/symbol documentation
 611 ;;;   commands. Based on code written by Douglas Roberts.
 612 ;;; - Added lisp-eval-last-sexp, bound to C-x C-e.
 613 ;;;
 614 ;;; 9/20/90 Olin
 615 ;;; Added a save-restriction to lisp-fn-called-at-pt. This bug and fix
 616 ;;; reported by Lennart Staflin.
 617 ;;;
 618 ;;; 3/12/90 Olin
 619 ;;; - lisp-load-file and lisp-compile-file no longer switch-to-lisp.
 620 ;;;   Tale suggested this.
 621 ;;; - Reversed this decision 7/15/91. You need the visual feedback.
 622 ;;;
 623 ;;; 7/25/91 Olin
 624 ;;; Changed all keybindings of the form C-c <letter>. These are
 625 ;;; supposed to be reserved for the user to bind. This affected
 626 ;;; mainly the compile/eval-defun/region[-and-go] commands.
 627 ;;; This was painful, but necessary to adhere to the gnumacs standard.
 628 ;;; For some backwards compatibility, see the
 629 ;;;     cmulisp-install-letter-bindings
 630 ;;; function.
 631 ;;;
 632 ;;; 8/2/91 Olin
 633 ;;; - The lisp-compile/eval-defun/region commands now take a prefix arg,
 634 ;;;   which means switch-to-lisp after sending the text to the Lisp process.
 635 ;;;   This obsoletes all the -and-go commands. The -and-go commands are
 636 ;;;   kept around for historical reasons, and because the user can bind
 637 ;;;   them to key sequences shorter than C-u C-c C-<letter>.
 638 ;;; - If M-x cmulisp is invoked with a prefix arg, it allows you to
 639 ;;;   edit the command line.
 640
 641 (provide 'inf-lisp)
 642
 643 ;;; arch-tag: 5b74abc3-a085-4b91-8ab8-8da6899d3b92
 644 ;;; inf-lisp.el ends here