lisp/net/goto-addr.el

   1 ;;; goto-addr.el --- click to browse URL or to send to e-mail address
   2
   3 ;; Copyright (C) 1995, 2000, 2001, 2005  Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Ding <ericding@alum.mit.edu>
   6 ;; Maintainer: FSF
   7 ;; Created: 15 Aug 1995
   8 ;; Keywords: mh-e, www, mouse, mail
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; This package allows you to click or hit a key sequence while on a
  30 ;; URL or e-mail address, and either load the URL into a browser of
  31 ;; your choice using the browse-url package, or if it's an e-mail
  32 ;; address, to send an e-mail to that address.  By default, we bind to
  33 ;; the [mouse-2] and the [C-c return] key sequences.
  34
  35 ;; INSTALLATION
  36 ;;
  37 ;; To use goto-address in a particular mode (for example, while
  38 ;; reading mail in mh-e), add something like this in your .emacs file:
  39 ;;
  40 ;; (add-hook 'mh-show-mode-hook 'goto-address)
  41 ;;
  42 ;; The mouse click method is bound to [mouse-2] on highlighted URLs or
  43 ;; e-mail addresses only; it functions normally everywhere else.  To bind
  44 ;; another mouse click to the function, add the following to your .emacs
  45 ;; (for example):
  46 ;;
  47 ;; (setq goto-address-highlight-keymap
  48 ;;   (let ((m (make-sparse-keymap)))
  49 ;;     (define-key m [S-mouse-2] 'goto-address-at-point)
  50 ;;     m))
  51 ;;
  52
  53 ;; Known bugs/features:
  54 ;; * goto-address-mail-regexp only catches foo@bar.org style addressing,
  55 ;;   not stuff like X.400 addresses, etc.
  56 ;; * regexp also catches Message-Id line, since it is in the format of
  57 ;;   an Internet e-mail address (like Compuserve addresses)
  58 ;; * If the buffer is fontified after goto-address-fontify is run
  59 ;;   (say, using font-lock-fontify-buffer), then font-lock faces will
  60 ;;   override goto-address faces.
  61
  62 ;;; Code:
  63
  64 (require 'thingatpt)
  65 (autoload 'browse-url-url-at-point "browse-url")
  66
  67 ;; XEmacs needs the following definitions.
  68 (unless (fboundp 'overlays-in)
  69   (require 'overlay))
  70 (unless (fboundp 'line-beginning-position)
  71   (defalias 'line-beginning-position 'point-at-bol))
  72 (unless (fboundp 'line-end-position)
  73   (defalias 'line-end-position 'point-at-eol))
  74 (unless (fboundp 'match-string-no-properties)
  75   (defalias 'match-string-no-properties 'match-string))
  76
  77 (defgroup goto-address nil
  78   "Click to browse URL or to send to e-mail address."
  79   :group 'mouse
  80   :group 'hypermedia)
  81
  82
  83 ;; I don't expect users to want fontify'ing without highlighting.
  84 (defcustom goto-address-fontify-p t
  85   "*Non-nil means URLs and e-mail addresses in buffer are fontified.
  86 But only if `goto-address-highlight-p' is also non-nil."
  87   :type 'boolean
  88   :group 'goto-address)
  89
  90 (defcustom goto-address-highlight-p t
  91   "*Non-nil means URLs and e-mail addresses in buffer are highlighted."
  92   :type 'boolean
  93   :group 'goto-address)
  94
  95 (defcustom goto-address-fontify-maximum-size 30000
  96   "*Maximum size of file in which to fontify and/or highlight URLs.
  97 A value of t means there is no limit--fontify regardless of the size."
  98   :type '(choice (integer :tag "Maximum size") (const :tag "No limit" t))
  99   :group 'goto-address)
 100
 101 (defvar goto-address-mail-regexp
 102   ;; Actually pretty much any char could appear in the username part.  -stef
 103   "[-a-zA-Z0-9=._+]+@\\([-a-zA-z0-9_]+\\.\\)+[a-zA-Z0-9]+"
 104   "A regular expression probably matching an e-mail address.")
 105
 106 (defvar goto-address-url-regexp
 107   (concat "\\<\\("
 108           (mapconcat 'identity
 109                      (delete "mailto:" (copy-sequence thing-at-point-uri-schemes))
 110                      "\\|")
 111           "\\)"
 112           thing-at-point-url-path-regexp)
 113   ;; (concat "\\b\\(s?https?\\|ftp\\|file\\|gopher\\|news\\|"
 114   ;;      "telnet\\|wais\\):\\(//[-a-zA-Z0-9_.]+:"
 115   ;;      "[0-9]*\\)?[-a-zA-Z0-9_=?#$@~`%&*+|\\/.,]*"
 116   ;;      "[-a-zA-Z0-9_=#$@~`%&*+|\\/]")
 117   "A regular expression probably matching a URL.")
 118
 119 (defvar goto-address-highlight-keymap
 120   (let ((m (make-sparse-keymap)))
 121     (define-key m (if (featurep 'xemacs) (kbd "<button2>") (kbd "<mouse-2>"))
 122       'goto-address-at-point)
 123     (define-key m (kbd "C-c RET") 'goto-address-at-point)
 124     m)
 125   "keymap to hold goto-addr's mouse key defs under highlighted URLs.")
 126
 127 (defcustom goto-address-url-face 'bold
 128   "Face to use for URLs."
 129   :type 'face
 130   :group 'goto-address)
 131
 132 (defcustom goto-address-url-mouse-face 'highlight
 133   "Face to use for URLs when the mouse is on them."
 134   :type 'face
 135   :group 'goto-address)
 136
 137 (defcustom goto-address-mail-face 'italic
 138   "Face to use for e-mail addresses."
 139   :type 'face
 140   :group 'goto-address)
 141
 142 (defcustom goto-address-mail-mouse-face 'secondary-selection
 143   "Face to use for e-mail addresses when the mouse is on them."
 144   :type 'face
 145   :group 'goto-address)
 146
 147 (defun goto-address-fontify ()
 148   "Fontify the URLs and e-mail addresses in the current buffer.
 149 This function implements `goto-address-highlight-p'
 150 and `goto-address-fontify-p'."
 151   ;; Clean up from any previous go.
 152   (dolist (overlay (overlays-in (point-min) (point-max)))
 153     (if (overlay-get overlay 'goto-address)
 154         (delete-overlay overlay)))
 155   (save-excursion
 156     (let ((inhibit-point-motion-hooks t))
 157       (goto-char (point-min))
 158       (if (or (eq t goto-address-fontify-maximum-size)
 159               (< (- (point-max) (point)) goto-address-fontify-maximum-size))
 160           (progn
 161             (while (re-search-forward goto-address-url-regexp nil t)
 162               (let* ((s (match-beginning 0))
 163                      (e (match-end 0))
 164                      (this-overlay (make-overlay s e)))
 165                 (and goto-address-fontify-p
 166                      (overlay-put this-overlay 'face goto-address-url-face))
 167                 (overlay-put this-overlay 'evaporate t)
 168                 (overlay-put this-overlay
 169                              'mouse-face goto-address-url-mouse-face)
 170                 (overlay-put this-overlay
 171                              'help-echo "mouse-2, C-c RET: follow URL")
 172                 (overlay-put this-overlay
 173                              'keymap goto-address-highlight-keymap)
 174                 (overlay-put this-overlay 'goto-address t)))
 175             (goto-char (point-min))
 176             (while (re-search-forward goto-address-mail-regexp nil t)
 177               (let* ((s (match-beginning 0))
 178                      (e (match-end 0))
 179                      (this-overlay (make-overlay s e)))
 180                 (and goto-address-fontify-p
 181                      (overlay-put this-overlay 'face goto-address-mail-face))
 182                 (overlay-put this-overlay 'evaporate t)
 183                 (overlay-put this-overlay 'mouse-face
 184                              goto-address-mail-mouse-face)
 185                 (overlay-put this-overlay
 186                              'help-echo "mouse-2, C-c RET: mail this address")
 187                 (overlay-put this-overlay
 188                              'keymap goto-address-highlight-keymap)
 189                 (overlay-put this-overlay 'goto-address t))))))))
 190
 191 ;; code to find and goto addresses; much of this has been blatantly
 192 ;; snarfed from browse-url.el
 193
 194 ;;;###autoload
 195 (define-obsolete-function-alias
 196   'goto-address-at-mouse 'goto-address-at-point "22.1")
 197
 198 ;;;###autoload
 199 (defun goto-address-at-point (&optional event)
 200   "Send to the e-mail address or load the URL at point.
 201 Send mail to address at point.  See documentation for
 202 `goto-address-find-address-at-point'.  If no address is found
 203 there, then load the URL at or before point."
 204   (interactive (list last-input-event))
 205   (save-excursion
 206     (if event (mouse-set-point event))
 207     (let ((address (save-excursion (goto-address-find-address-at-point))))
 208       (if (and address
 209                (save-excursion
 210                  (goto-char (previous-single-char-property-change
 211                              (point) 'goto-address nil
 212                              (line-beginning-position)))
 213                  (not (looking-at goto-address-url-regexp))))
 214           (compose-mail address)
 215         (let ((url (browse-url-url-at-point)))
 216           (if url
 217               (browse-url url)
 218             (error "No e-mail address or URL found")))))))
 219
 220 (defun goto-address-find-address-at-point ()
 221   "Find e-mail address around or before point.
 222 Then search backwards to beginning of line for the start of an e-mail
 223 address.  If no e-mail address found, return nil."
 224   (re-search-backward "[^-_A-z0-9.@]" (line-beginning-position) 'lim)
 225   (if (or (looking-at goto-address-mail-regexp) ; already at start
 226           (and (re-search-forward goto-address-mail-regexp
 227                                   (line-end-position) 'lim)
 228                (goto-char (match-beginning 0))))
 229       (match-string-no-properties 0)))
 230
 231 ;;;###autoload
 232 (defun goto-address ()
 233   "Sets up goto-address functionality in the current buffer.
 234 Allows user to use mouse/keyboard command to click to go to a URL
 235 or to send e-mail.
 236 By default, goto-address binds to mouse-2 and C-c RET.
 237
 238 Also fontifies the buffer appropriately (see `goto-address-fontify-p' and
 239 `goto-address-highlight-p' for more information)."
 240   (interactive)
 241   (if goto-address-highlight-p
 242       (goto-address-fontify)))
 243
 244 (provide 'goto-addr)
 245
 246 ;; arch-tag: ca47c505-5661-425d-a471-62bc6e75cf0a
 247 ;;; goto-addr.el ends here