lisp/mail/rmailedit.el

   1 ;;; rmailedit.el --- "RMAIL edit mode"  Edit the current message
   2
   3 ;; Copyright (C) 1985, 1994, 2001 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'rmail)
  30
  31 (defcustom rmail-edit-mode-hook nil
  32   "List of functions to call when editing an RMAIL message."
  33   :type 'hook
  34   :version "21.1"
  35   :group 'rmail-edit)
  36
  37 (defvar rmail-old-text)
  38
  39 (defvar rmail-edit-map nil)
  40 (if rmail-edit-map
  41     nil
  42   ;; Make a keymap that inherits text-mode-map.
  43   (setq rmail-edit-map (make-sparse-keymap))
  44   (set-keymap-parent rmail-edit-map text-mode-map)
  45   (define-key rmail-edit-map "\C-c\C-c" 'rmail-cease-edit)
  46   (define-key rmail-edit-map "\C-c\C-]" 'rmail-abort-edit))
  47
  48 ;; Rmail Edit mode is suitable only for specially formatted data.
  49 (put 'rmail-edit-mode 'mode-class 'special)
  50
  51 (defun rmail-edit-mode ()
  52   "Major mode for editing the contents of an RMAIL message.
  53 The editing commands are the same as in Text mode, together with two commands
  54 to return to regular RMAIL:
  55   *  \\[rmail-abort-edit] cancels the changes
  56      you have made and returns to RMAIL
  57   *  \\[rmail-cease-edit] makes them permanent.
  58 This functions runs the normal hook `rmail-edit-mode-hook'.
  59 \\{rmail-edit-map}"
  60   (text-mode)
  61   (use-local-map rmail-edit-map)
  62   (setq major-mode 'rmail-edit-mode)
  63   (setq mode-name "RMAIL Edit")
  64   (if (boundp 'mode-line-modified)
  65       (setq mode-line-modified (default-value 'mode-line-modified))
  66     (setq mode-line-format (default-value 'mode-line-format)))
  67   (if (rmail-summary-exists)
  68       (save-excursion
  69         (set-buffer rmail-summary-buffer)
  70         (rmail-summary-disable)))
  71   (run-mode-hooks 'rmail-edit-mode-hook))
  72
  73 (defvar rmail-old-pruned nil)
  74 (put 'rmail-old-pruned 'permanent-local t)
  75
  76 (defvar rmail-edit-saved-coding-system nil)
  77 (put 'rmail-edit-saved-coding-system 'permanent-local t)
  78
  79 ;;;###autoload
  80 (defun rmail-edit-current-message ()
  81   "Edit the contents of this message."
  82   (interactive)
  83   (make-local-variable 'rmail-old-pruned)
  84   (setq rmail-old-pruned (rmail-msg-is-pruned))
  85   (make-local-variable 'rmail-edit-saved-coding-system)
  86   (setq rmail-edit-saved-coding-system save-buffer-coding-system)
  87   (rmail-toggle-header 0)
  88   (rmail-edit-mode)
  89   ;; As the local value of save-buffer-coding-system is deleted by
  90   ;; rmail-edit-mode, we restore the original value.
  91   (make-local-variable 'save-buffer-coding-system)
  92   (setq save-buffer-coding-system rmail-edit-saved-coding-system)
  93   (make-local-variable 'rmail-old-text)
  94   (setq rmail-old-text (buffer-substring (point-min) (point-max)))
  95   (setq buffer-read-only nil)
  96   (force-mode-line-update)
  97   (if (and (eq (key-binding "\C-c\C-c") 'rmail-cease-edit)
  98            (eq (key-binding "\C-c\C-]") 'rmail-abort-edit))
  99       (message "Editing: Type C-c C-c to return to Rmail, C-c C-] to abort")
 100     (message "%s" (substitute-command-keys
 101                    "Editing: Type \\[rmail-cease-edit] to return to Rmail, \\[rmail-abort-edit] to abort"))))
 102
 103 (defun rmail-cease-edit ()
 104   "Finish editing message; switch back to Rmail proper."
 105   (interactive)
 106   (if (rmail-summary-exists)
 107       (save-excursion
 108         (set-buffer rmail-summary-buffer)
 109         (rmail-summary-enable)))
 110   ;; Make sure buffer ends with a newline.
 111   (save-excursion
 112     (goto-char (point-max))
 113     (if (/= (preceding-char) ?\n)
 114         (insert "\n"))
 115     ;; Adjust the marker that points to the end of this message.
 116     (set-marker (aref rmail-message-vector (1+ rmail-current-message))
 117                 (point)))
 118   (let ((old rmail-old-text))
 119     (force-mode-line-update)
 120     (kill-all-local-variables)
 121     (rmail-mode-1)
 122     (rmail-variables)
 123     ;; As the local value of save-buffer-coding-system is changed by
 124     ;; rmail-variables, we restore the original value.
 125     (setq save-buffer-coding-system rmail-edit-saved-coding-system)
 126     (if (and (= (length old) (- (point-max) (point-min)))
 127              (string= old (buffer-substring (point-min) (point-max))))
 128         ()
 129       (setq old nil)
 130       (rmail-set-attribute "edited" t)
 131       (if (boundp 'rmail-summary-vector)
 132           (progn
 133             (aset rmail-summary-vector (1- rmail-current-message) nil)
 134             (save-excursion
 135               (rmail-widen-to-current-msgbeg
 136                 (function (lambda ()
 137                             (forward-line 2)
 138                             (if (looking-at "Summary-line: ")
 139                                 (let ((buffer-read-only nil))
 140                                   (delete-region (point)
 141                                                  (progn (forward-line 1)
 142                                                         (point))))))))))))
 143     (save-excursion
 144       (rmail-show-message)
 145       (rmail-toggle-header (if rmail-old-pruned 1 0))))
 146   (run-hooks 'rmail-mode-hook)
 147   (setq buffer-read-only t))
 148
 149 (defun rmail-abort-edit ()
 150   "Abort edit of current message; restore original contents."
 151   (interactive)
 152   (delete-region (point-min) (point-max))
 153   (insert rmail-old-text)
 154   (rmail-cease-edit)
 155   (rmail-highlight-headers))
 156
 157 (provide 'rmailedit)
 158
 159 ;;; arch-tag: 93c22709-a14a-46c1-ab91-52c3f5a0ec12
 160 ;;; rmailedit.el ends here