lisp/gnus/gnus-spec.el

   1 ;;; gnus-spec.el --- format spec functions for Gnus
   2 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32
  33 (defcustom gnus-use-correct-string-widths (featurep 'xemacs)
  34   "*If non-nil, use correct functions for dealing with wide characters."
  35   :version "22.1"
  36   :group 'gnus-format
  37   :type 'boolean)
  38
  39 (defcustom gnus-make-format-preserve-properties (featurep 'xemacs)
  40   "*If non-nil, use a replacement `format' function which preserves
  41 text properties. This is only needed on XEmacs, as FSF Emacs does this anyway."
  42   :version "22.1"
  43   :group 'gnus-format
  44   :type 'boolean)
  45
  46 ;;; Internal variables.
  47
  48 (defvar gnus-summary-mark-positions nil)
  49 (defvar gnus-group-mark-positions nil)
  50 (defvar gnus-group-indentation "")
  51
  52 ;; Format specs.  The chunks below are the machine-generated forms
  53 ;; that are to be evaled as the result of the default format strings.
  54 ;; We write them in here to get them byte-compiled.  That way the
  55 ;; default actions will be quite fast, while still retaining the full
  56 ;; flexibility of the user-defined format specs.
  57
  58 ;; First we have lots of dummy defvars to let the compiler know these
  59 ;; are really dynamic variables.
  60
  61 (defvar gnus-tmp-unread)
  62 (defvar gnus-tmp-replied)
  63 (defvar gnus-tmp-score-char)
  64 (defvar gnus-tmp-indentation)
  65 (defvar gnus-tmp-opening-bracket)
  66 (defvar gnus-tmp-lines)
  67 (defvar gnus-tmp-name)
  68 (defvar gnus-tmp-closing-bracket)
  69 (defvar gnus-tmp-subject-or-nil)
  70 (defvar gnus-tmp-subject)
  71 (defvar gnus-tmp-marked)
  72 (defvar gnus-tmp-marked-mark)
  73 (defvar gnus-tmp-subscribed)
  74 (defvar gnus-tmp-process-marked)
  75 (defvar gnus-tmp-number-of-unread)
  76 (defvar gnus-tmp-group-name)
  77 (defvar gnus-tmp-group)
  78 (defvar gnus-tmp-article-number)
  79 (defvar gnus-tmp-unread-and-unselected)
  80 (defvar gnus-tmp-news-method)
  81 (defvar gnus-tmp-news-server)
  82 (defvar gnus-tmp-article-number)
  83 (defvar gnus-mouse-face)
  84 (defvar gnus-mouse-face-prop)
  85 (defvar gnus-tmp-header)
  86 (defvar gnus-tmp-from)
  87
  88 (defun gnus-summary-line-format-spec ()
  89   (insert gnus-tmp-unread gnus-tmp-replied
  90           gnus-tmp-score-char gnus-tmp-indentation)
  91   (gnus-put-text-property
  92    (point)
  93    (progn
  94      (insert
  95       (format "%c%4s: %-23s%c" gnus-tmp-opening-bracket gnus-tmp-lines
  96               (let ((val
  97                      (inline
  98                        (gnus-summary-from-or-to-or-newsgroups
  99                         gnus-tmp-header gnus-tmp-from))))
 100                 (if (> (length val) 23)
 101                     (substring val 0 23)
 102                   val))
 103               gnus-tmp-closing-bracket))
 104      (point))
 105    gnus-mouse-face-prop gnus-mouse-face)
 106   (insert " " gnus-tmp-subject-or-nil "\n"))
 107
 108 (defvar gnus-summary-line-format-spec
 109   (gnus-byte-code 'gnus-summary-line-format-spec))
 110
 111 (defun gnus-summary-dummy-line-format-spec ()
 112   (insert "*  ")
 113   (gnus-put-text-property
 114    (point)
 115    (progn
 116      (insert ":                          :")
 117      (point))
 118    gnus-mouse-face-prop gnus-mouse-face)
 119   (insert " " gnus-tmp-subject "\n"))
 120
 121 (defvar gnus-summary-dummy-line-format-spec
 122   (gnus-byte-code 'gnus-summary-dummy-line-format-spec))
 123
 124 (defun gnus-group-line-format-spec ()
 125   (insert gnus-tmp-marked-mark gnus-tmp-subscribed
 126           gnus-tmp-process-marked
 127           gnus-group-indentation
 128           (format "%5s: " gnus-tmp-number-of-unread))
 129   (gnus-put-text-property
 130    (point)
 131    (progn
 132      (insert gnus-tmp-group "\n")
 133      (1- (point)))
 134    gnus-mouse-face-prop gnus-mouse-face))
 135 (defvar gnus-group-line-format-spec
 136   (gnus-byte-code 'gnus-group-line-format-spec))
 137
 138 (defvar gnus-format-specs
 139   `((version . ,emacs-version)
 140     (gnus-version . ,(gnus-continuum-version))
 141     (group "%M\%S\%p\%P\%5y: %(%g%)%l\n" ,gnus-group-line-format-spec)
 142     (summary-dummy "*  %(:                          :%) %S\n"
 143                    ,gnus-summary-dummy-line-format-spec)
 144     (summary "%U%R%z%I%(%[%4L: %-23,23f%]%) %s\n"
 145              ,gnus-summary-line-format-spec))
 146   "Alist of format specs.")
 147
 148 (defvar gnus-default-format-specs gnus-format-specs)
 149
 150 (defvar gnus-article-mode-line-format-spec nil)
 151 (defvar gnus-summary-mode-line-format-spec nil)
 152 (defvar gnus-group-mode-line-format-spec nil)
 153
 154 ;;; Phew.  All that gruft is over with, fortunately.
 155
 156 ;;;###autoload
 157 (defun gnus-update-format (var)
 158   "Update the format specification near point."
 159   (interactive
 160    (list
 161     (save-excursion
 162       (eval-defun nil)
 163       ;; Find the end of the current word.
 164       (re-search-forward "[ \t\n]" nil t)
 165       ;; Search backward.
 166       (when (re-search-backward "\\(gnus-[-a-z]+-line-format\\)" nil t)
 167         (match-string 1)))))
 168   (let* ((type (intern (progn (string-match "gnus-\\([-a-z]+\\)-line" var)
 169                               (match-string 1 var))))
 170          (entry (assq type gnus-format-specs))
 171          value spec)
 172     (when entry
 173       (setq gnus-format-specs (delq entry gnus-format-specs)))
 174     (set
 175      (intern (format "%s-spec" var))
 176      (gnus-parse-format (setq value (symbol-value (intern var)))
 177                         (symbol-value (intern (format "%s-alist" var)))
 178                         (not (string-match "mode" var))))
 179     (setq spec (symbol-value (intern (format "%s-spec" var))))
 180     (push (list type value spec) gnus-format-specs)
 181
 182     (pop-to-buffer "*Gnus Format*")
 183     (erase-buffer)
 184     (lisp-interaction-mode)
 185     (insert (gnus-pp-to-string spec))))
 186
 187 (defun gnus-update-format-specifications (&optional force &rest types)
 188   "Update all (necessary) format specifications.
 189 Return a list of updated types."
 190   ;; Make the indentation array.
 191   ;; See whether all the stored info needs to be flushed.
 192   (when (or force
 193             (not gnus-newsrc-file-version)
 194             (not (equal (gnus-continuum-version)
 195                         (gnus-continuum-version gnus-newsrc-file-version)))
 196             (not (equal emacs-version
 197                         (cdr (assq 'version gnus-format-specs)))))
 198     (setq gnus-format-specs nil))
 199   ;; Flush the group format spec cache if it doesn't support decoded
 200   ;; group names.
 201   (when (memq 'group types)
 202     (let ((spec (assq 'group gnus-format-specs)))
 203       (unless (string-match " gnus-tmp-decoded-group[ )]"
 204                             (gnus-prin1-to-string (nth 2 spec)))
 205         (setq gnus-format-specs (delq spec gnus-format-specs)))))
 206
 207   ;; Go through all the formats and see whether they need updating.
 208   (let (new-format entry type val updated)
 209     (while (setq type (pop types))
 210       ;; Jump to the proper buffer to find out the value of the
 211       ;; variable, if possible.  (It may be buffer-local.)
 212       (save-excursion
 213         (let ((buffer (intern (format "gnus-%s-buffer" type))))
 214           (when (and (boundp buffer)
 215                      (setq val (symbol-value buffer))
 216                      (gnus-buffer-exists-p val))
 217             (set-buffer val))
 218           (setq new-format (symbol-value
 219                             (intern (format "gnus-%s-line-format" type)))))
 220         (setq entry (cdr (assq type gnus-format-specs)))
 221         (if (and (car entry)
 222                  (equal (car entry) new-format))
 223             ;; Use the old format.
 224             (set (intern (format "gnus-%s-line-format-spec" type))
 225                  (cadr entry))
 226           ;; This is a new format.
 227           (setq val
 228                 (if (not (stringp new-format))
 229                     ;; This is a function call or something.
 230                     new-format
 231                   ;; This is a "real" format.
 232                   (gnus-parse-format
 233                    new-format
 234                    (symbol-value
 235                     (intern (format "gnus-%s-line-format-alist" type)))
 236                    (not (string-match "mode$" (symbol-name type))))))
 237           ;; Enter the new format spec into the list.
 238           (if entry
 239               (progn
 240                 (setcar (cdr entry) val)
 241                 (setcar entry new-format))
 242             (push (list type new-format val) gnus-format-specs))
 243           (set (intern (format "gnus-%s-line-format-spec" type)) val)
 244           (push type updated))))
 245
 246     (unless (assq 'version gnus-format-specs)
 247       (push (cons 'version emacs-version) gnus-format-specs))
 248     updated))
 249
 250 (defvar gnus-mouse-face-0 'highlight)
 251 (defvar gnus-mouse-face-1 'highlight)
 252 (defvar gnus-mouse-face-2 'highlight)
 253 (defvar gnus-mouse-face-3 'highlight)
 254 (defvar gnus-mouse-face-4 'highlight)
 255
 256 (defun gnus-mouse-face-function (form type)
 257   `(gnus-put-text-property
 258     (point) (progn ,@form (point))
 259     gnus-mouse-face-prop
 260     ,(if (equal type 0)
 261          'gnus-mouse-face
 262        `(quote ,(symbol-value (intern (format "gnus-mouse-face-%d" type)))))))
 263
 264 (defvar gnus-face-0 'bold)
 265 (defvar gnus-face-1 'italic)
 266 (defvar gnus-face-2 'bold-italic)
 267 (defvar gnus-face-3 'bold)
 268 (defvar gnus-face-4 'bold)
 269
 270 (defun gnus-face-face-function (form type)
 271   `(gnus-add-text-properties
 272     (point) (progn ,@form (point))
 273     '(gnus-face t face ,(symbol-value (intern (format "gnus-face-%d" type))))))
 274
 275 (defun gnus-balloon-face-function (form type)
 276   `(gnus-put-text-property
 277     (point) (progn ,@form (point))
 278     ,(if (fboundp 'balloon-help-mode)
 279          ''balloon-help
 280        ''help-echo)
 281     ,(intern (format "gnus-balloon-face-%d" type))))
 282
 283 (defun gnus-spec-tab (column)
 284   (if (> column 0)
 285       `(insert-char ?  (max (- ,column (current-column)) 0))
 286     (let ((column (abs column)))
 287       `(if (> (current-column) ,column)
 288            (let ((end (point)))
 289              (if (= (move-to-column ,column) ,column)
 290                  (delete-region (point) end)
 291                (delete-region (1- (point)) end)
 292                (insert " ")))
 293          (insert-char ?  (max (- ,column (current-column)) 0))))))
 294
 295 (defun gnus-correct-length (string)
 296   "Return the correct width of STRING."
 297   (let ((length 0))
 298     (mapcar (lambda (char) (incf length (gnus-char-width char))) string)
 299     length))
 300
 301 (defun gnus-correct-substring (string start &optional end)
 302   (let ((wstart 0)
 303         (wend 0)
 304         (wseek 0)
 305         (seek 0)
 306         (length (length string))
 307         (string (concat string "\0")))
 308     ;; Find the start position.
 309     (while (and (< seek length)
 310                 (< wseek start))
 311       (incf wseek (gnus-char-width (aref string seek)))
 312       (incf seek))
 313     (setq wstart seek)
 314     ;; Find the end position.
 315     (while (and (<= seek length)
 316                 (or (not end)
 317                     (<= wseek end)))
 318       (incf wseek (gnus-char-width (aref string seek)))
 319       (incf seek))
 320     (setq wend seek)
 321     (substring string wstart (1- wend))))
 322
 323 (defun gnus-string-width-function ()
 324   (cond
 325    (gnus-use-correct-string-widths
 326     'gnus-correct-length)
 327    ((fboundp 'string-width)
 328     'string-width)
 329    (t
 330     'length)))
 331
 332 (defun gnus-substring-function ()
 333   (cond
 334    (gnus-use-correct-string-widths
 335     'gnus-correct-substring)
 336    ((fboundp 'string-width)
 337     'gnus-correct-substring)
 338    (t
 339     'substring)))
 340
 341 (defun gnus-tilde-max-form (el max-width)
 342   "Return a form that limits EL to MAX-WIDTH."
 343   (let ((max (abs max-width))
 344         (length-fun (gnus-string-width-function))
 345         (substring-fun (gnus-substring-function)))
 346     (if (symbolp el)
 347         `(if (> (,length-fun ,el) ,max)
 348              ,(if (< max-width 0)
 349                   `(,substring-fun ,el (- (,length-fun ,el) ,max))
 350                 `(,substring-fun ,el 0 ,max))
 351            ,el)
 352       `(let ((val (eval ,el)))
 353          (if (> (,length-fun val) ,max)
 354              ,(if (< max-width 0)
 355                   `(,substring-fun val (- (,length-fun val) ,max))
 356                 `(,substring-fun val 0 ,max))
 357            val)))))
 358
 359 (defun gnus-tilde-cut-form (el cut-width)
 360   "Return a form that cuts CUT-WIDTH off of EL."
 361   (let ((cut (abs cut-width))
 362         (length-fun (gnus-string-width-function))
 363         (substring-fun (gnus-substring-function)))
 364     (if (symbolp el)
 365         `(if (> (,length-fun ,el) ,cut)
 366              ,(if (< cut-width 0)
 367                   `(,substring-fun ,el 0 (- (,length-fun ,el) ,cut))
 368                 `(,substring-fun ,el ,cut))
 369            ,el)
 370       `(let ((val (eval ,el)))
 371          (if (> (,length-fun val) ,cut)
 372              ,(if (< cut-width 0)
 373                   `(,substring-fun val 0 (- (,length-fun val) ,cut))
 374                 `(,substring-fun val ,cut))
 375            val)))))
 376
 377 (defun gnus-tilde-ignore-form (el ignore-value)
 378   "Return a form that is blank when EL is IGNORE-VALUE."
 379   (if (symbolp el)
 380       `(if (equal ,el ,ignore-value)
 381            "" ,el)
 382     `(let ((val (eval ,el)))
 383        (if (equal val ,ignore-value)
 384            "" val))))
 385
 386 (defun gnus-pad-form (el pad-width)
 387   "Return a form that pads EL to PAD-WIDTH accounting for multi-column
 388 characters correctly. This is because `format' may pad to columns or to
 389 characters when given a pad value."
 390   (let ((pad (abs pad-width))
 391         (side (< 0 pad-width))
 392         (length-fun (gnus-string-width-function)))
 393     (if (symbolp el)
 394         `(let ((need (- ,pad (,length-fun ,el))))
 395            (if (> need 0)
 396                (concat ,(when side '(make-string need ?\ ))
 397                        ,el
 398                        ,(when (not side) '(make-string need ?\ )))
 399              ,el))
 400       `(let* ((val (eval ,el))
 401               (need (- ,pad (,length-fun val))))
 402          (if (> need 0)
 403              (concat ,(when side '(make-string need ?\ ))
 404                      val
 405                      ,(when (not side) '(make-string need ?\ )))
 406            val)))))
 407
 408 (defun gnus-parse-format (format spec-alist &optional insert)
 409   ;; This function parses the FORMAT string with the help of the
 410   ;; SPEC-ALIST and returns a list that can be eval'ed to return the
 411   ;; string.  If the FORMAT string contains the specifiers %( and %)
 412   ;; the text between them will have the mouse-face text property.
 413   ;; If the FORMAT string contains the specifiers %[ and %], the text between
 414   ;; them will have the balloon-help text property.
 415   (let ((case-fold-search nil))
 416     (if (string-match
 417          "\\`\\(.*\\)%[0-9]?[{(«]\\(.*\\)%[0-9]?[»})]\\(.*\n?\\)\\'\\|%[-0-9]*=\\|%[-0-9]*\\*"
 418          format)
 419         (gnus-parse-complex-format format spec-alist)
 420       ;; This is a simple format.
 421       (gnus-parse-simple-format format spec-alist insert))))
 422
 423 (defun gnus-parse-complex-format (format spec-alist)
 424   (let ((cursor-spec nil))
 425     (save-excursion
 426       (gnus-set-work-buffer)
 427       (insert format)
 428       (goto-char (point-min))
 429       (while (re-search-forward "\"" nil t)
 430         (replace-match "\\\"" nil t))
 431       (goto-char (point-min))
 432       (insert "(\"")
 433       ;; Convert all font specs into font spec lists.
 434       (while (re-search-forward "%\\([0-9]+\\)?\\([«»{}()]\\)" nil t)
 435         (let ((number (if (match-beginning 1)
 436                           (match-string 1) "0"))
 437               (delim (aref (match-string 2) 0)))
 438           (if (or (= delim ?\()
 439                   (= delim ?\{)
 440                   (= delim ?\«))
 441               (replace-match (concat "\"("
 442                                      (cond ((= delim ?\() "mouse")
 443                                            ((= delim ?\{) "face")
 444                                            (t "balloon"))
 445                                      " " number " \"")
 446                              t t)
 447             (replace-match "\")\""))))
 448       (goto-char (point-max))
 449       (insert "\")")
 450       ;; Convert point position commands.
 451       (goto-char (point-min))
 452       (let ((case-fold-search nil))
 453         (while (re-search-forward "%\\([-0-9]+\\)?\\*" nil t)
 454           (replace-match "\"(point)\"" t t)
 455           (setq cursor-spec t)))
 456       ;; Convert TAB commands.
 457       (goto-char (point-min))
 458       (while (re-search-forward "%\\([-0-9]+\\)=" nil t)
 459         (replace-match (format "\"(tab %s)\"" (match-string 1)) t t))
 460       ;; Convert the buffer into the spec.
 461       (goto-char (point-min))
 462       (let ((form (read (current-buffer))))
 463         (if cursor-spec
 464             `(let (gnus-position)
 465                ,@(gnus-complex-form-to-spec form spec-alist)
 466                (if gnus-position
 467                    (gnus-put-text-property gnus-position (1+ gnus-position)
 468                                            'gnus-position t)))
 469           `(progn
 470              ,@(gnus-complex-form-to-spec form spec-alist)))))))
 471
 472 (defun gnus-complex-form-to-spec (form spec-alist)
 473   (delq nil
 474         (mapcar
 475          (lambda (sform)
 476            (cond
 477             ((stringp sform)
 478              (gnus-parse-simple-format sform spec-alist t))
 479             ((eq (car sform) 'point)
 480              '(setq gnus-position (point)))
 481             ((eq (car sform) 'tab)
 482              (gnus-spec-tab (cadr sform)))
 483             (t
 484              (funcall (intern (format "gnus-%s-face-function" (car sform)))
 485                       (gnus-complex-form-to-spec (cddr sform) spec-alist)
 486                       (nth 1 sform)))))
 487          form)))
 488
 489
 490 (defun gnus-xmas-format (fstring &rest args)
 491   "A version of `format' which preserves text properties.
 492
 493 Required for XEmacs, where the built in `format' function strips all text
 494 properties from both the format string and any inserted strings.
 495
 496 Only supports the format sequence %s, and %% for inserting
 497 literal % characters. A pad width and an optional - (to right pad)
 498 are supported for %s."
 499   (let ((re "%%\\|%\\(-\\)?\\([1-9][0-9]*\\)?s")
 500         (n (length args)))
 501     (with-temp-buffer
 502       (insert fstring)
 503       (goto-char (point-min))
 504       (while (re-search-forward re nil t)
 505         (goto-char (match-end 0))
 506         (cond
 507          ((string= (match-string 0) "%%")
 508           (delete-char -1))
 509          (t
 510           (if (null args)
 511               (error 'wrong-number-of-arguments #'my-format n fstring))
 512           (let* ((minlen (string-to-number (or (match-string 2) "")))
 513                  (arg (car args))
 514                  (str (if (stringp arg) arg (format "%s" arg)))
 515                  (lpad (null (match-string 1)))
 516                  (padlen (max 0 (- minlen (length str)))))
 517             (replace-match "")
 518             (if lpad (insert-char ?\  padlen))
 519             (insert str)
 520             (unless lpad (insert-char ?\  padlen))
 521             (setq args (cdr args))))))
 522       (buffer-string))))
 523
 524 (defun gnus-parse-simple-format (format spec-alist &optional insert)
 525   ;; This function parses the FORMAT string with the help of the
 526   ;; SPEC-ALIST and returns a list that can be eval'ed to return a
 527   ;; string.
 528   (let ((max-width 0)
 529         spec flist fstring elem result dontinsert user-defined
 530         type value pad-width spec-beg cut-width ignore-value
 531         tilde-form tilde elem-type extended-spec)
 532     (save-excursion
 533       (gnus-set-work-buffer)
 534       (insert format)
 535       (goto-char (point-min))
 536       (while (re-search-forward "%" nil t)
 537         (setq user-defined nil
 538               spec-beg nil
 539               pad-width nil
 540               max-width nil
 541               cut-width nil
 542               ignore-value nil
 543               tilde-form nil
 544               extended-spec nil)
 545         (setq spec-beg (1- (point)))
 546
 547         ;; Parse this spec fully.
 548         (while
 549             (cond
 550              ((looking-at "\\([-.0-9]+\\)\\(,[-0-9]+\\)?")
 551               (setq pad-width (string-to-number (match-string 1)))
 552               (when (match-beginning 2)
 553                 (setq max-width (string-to-number (buffer-substring
 554                                                    (1+ (match-beginning 2))
 555                                                    (match-end 2)))))
 556               (goto-char (match-end 0)))
 557              ((looking-at "~")
 558               (forward-char 1)
 559               (setq tilde (read (current-buffer))
 560                     type (car tilde)
 561                     value (cadr tilde))
 562               (cond
 563                ((memq type '(pad pad-left))
 564                 (setq pad-width value))
 565                ((eq type 'pad-right)
 566                 (setq pad-width (- value)))
 567                ((memq type '(max-right max))
 568                 (setq max-width value))
 569                ((eq type 'max-left)
 570                 (setq max-width (- value)))
 571                ((memq type '(cut cut-left))
 572                 (setq cut-width value))
 573                ((eq type 'cut-right)
 574                 (setq cut-width (- value)))
 575                ((eq type 'ignore)
 576                 (setq ignore-value
 577                       (if (stringp value) value (format "%s" value))))
 578                ((eq type 'form)
 579                 (setq tilde-form value))
 580                (t
 581                 (error "Unknown tilde type: %s" tilde)))
 582               t)
 583              (t
 584               nil)))
 585         (cond
 586          ;; User-defined spec -- find the spec name.
 587          ((eq (setq spec (char-after)) ?u)
 588           (forward-char 1)
 589           (when (and (eq (setq user-defined (char-after)) ?&)
 590                      (looking-at "&\\([^;]+\\);"))
 591             (setq user-defined (match-string 1))
 592             (goto-char (match-end 1))))
 593          ;; extended spec
 594          ((and (eq spec ?&) (looking-at "&\\([^;]+\\);"))
 595           (setq extended-spec (intern (match-string 1)))
 596           (goto-char (match-end 1))))
 597         (forward-char 1)
 598         (delete-region spec-beg (point))
 599
 600         ;; Now we have all the relevant data on this spec, so
 601         ;; we start doing stuff.
 602         (insert "%")
 603         (if (eq spec ?%)
 604             ;; "%%" just results in a "%".
 605             (insert "%")
 606           (cond
 607            ;; Do tilde forms.
 608            ((eq spec ?@)
 609             (setq elem (list tilde-form ?s)))
 610            ;; Treat user defined format specifiers specially.
 611            (user-defined
 612             (setq elem
 613                   (list
 614                    (list (intern (format
 615                                   (if (stringp user-defined)
 616                                       "gnus-user-format-function-%s"
 617                                     "gnus-user-format-function-%c")
 618                                   user-defined))
 619                          'gnus-tmp-header)
 620                    ?s)))
 621            ;; Find the specification from `spec-alist'.
 622            ((setq elem (cdr (assq (or extended-spec spec) spec-alist))))
 623            (t
 624             (setq elem '("*" ?s))))
 625           (setq elem-type (cadr elem))
 626           ;; Insert the new format elements.
 627           (when (and pad-width
 628                      (not (and (featurep 'xemacs)
 629                                gnus-use-correct-string-widths)))
 630             (insert (number-to-string pad-width)))
 631           ;; Create the form to be evaled.
 632           (if (or max-width cut-width ignore-value
 633                   (and (featurep 'xemacs)
 634                        gnus-use-correct-string-widths))
 635               (progn
 636                 (insert ?s)
 637                 (let ((el (car elem)))
 638                   (cond ((= (cadr elem) ?c)
 639                          (setq el (list 'char-to-string el)))
 640                         ((= (cadr elem) ?d)
 641                          (setq el (list 'int-to-string el))))
 642                   (when ignore-value
 643                     (setq el (gnus-tilde-ignore-form el ignore-value)))
 644                   (when cut-width
 645                     (setq el (gnus-tilde-cut-form el cut-width)))
 646                   (when max-width
 647                     (setq el (gnus-tilde-max-form el max-width)))
 648                   (when pad-width
 649                     (setq el (gnus-pad-form el pad-width)))
 650                   (push el flist)))
 651             (insert elem-type)
 652             (push (car elem) flist))))
 653       (setq fstring (buffer-substring-no-properties (point-min) (point-max))))
 654
 655     ;; Do some postprocessing to increase efficiency.
 656     (setq
 657      result
 658      (cond
 659       ;; Emptiness.
 660       ((string= fstring "")
 661        nil)
 662       ;; Not a format string.
 663       ((not (string-match "%" fstring))
 664        (list fstring))
 665       ;; A format string with just a single string spec.
 666       ((string= fstring "%s")
 667        (list (car flist)))
 668       ;; A single character.
 669       ((string= fstring "%c")
 670        (list (car flist)))
 671       ;; A single number.
 672       ((string= fstring "%d")
 673        (setq dontinsert)
 674        (if insert
 675            (list `(princ ,(car flist)))
 676          (list `(int-to-string ,(car flist)))))
 677       ;; Just lots of chars and strings.
 678       ((string-match "\\`\\(%[cs]\\)+\\'" fstring)
 679        (nreverse flist))
 680       ;; A single string spec at the beginning of the spec.
 681       ((string-match "\\`%[sc][^%]+\\'" fstring)
 682        (list (car flist) (substring fstring 2)))
 683       ;; A single string spec in the middle of the spec.
 684       ((string-match "\\`\\([^%]+\\)%[sc]\\([^%]+\\)\\'" fstring)
 685        (list (match-string 1 fstring) (car flist) (match-string 2 fstring)))
 686       ;; A single string spec in the end of the spec.
 687       ((string-match "\\`\\([^%]+\\)%[sc]\\'" fstring)
 688        (list (match-string 1 fstring) (car flist)))
 689       ;; Only string (and %) specs (XEmacs only!)
 690       ((and (featurep 'xemacs)
 691             gnus-make-format-preserve-properties
 692             (string-match
 693              "\\`\\([^%]*\\(%%\\|%-?\\([1-9][0-9]*\\)?s\\)\\)*[^%]*\\'"
 694              fstring))
 695        (list (cons 'gnus-xmas-format (cons fstring (nreverse flist)))))
 696       ;; A more complex spec.
 697       (t
 698        (list (cons 'format (cons fstring (nreverse flist)))))))
 699
 700     (if insert
 701         (when result
 702           (if dontinsert
 703               result
 704             (cons 'insert result)))
 705       (cond ((stringp result)
 706              result)
 707             ((consp result)
 708              (cons 'concat result))
 709             (t "")))))
 710
 711 (defun gnus-eval-format (format &optional alist props)
 712   "Eval the format variable FORMAT, using ALIST.
 713 If PROPS, insert the result."
 714   (let ((form (gnus-parse-format format alist props)))
 715     (if props
 716         (gnus-add-text-properties (point) (progn (eval form) (point)) props)
 717       (eval form))))
 718
 719 (defun gnus-compile ()
 720   "Byte-compile the user-defined format specs."
 721   (interactive)
 722   (require 'bytecomp)
 723   (let ((entries gnus-format-specs)
 724         (byte-compile-warnings '(unresolved callargs redefine))
 725         entry gnus-tmp-func)
 726     (save-excursion
 727       (gnus-message 7 "Compiling format specs...")
 728
 729       (while entries
 730         (setq entry (pop entries))
 731         (if (memq (car entry) '(gnus-version version))
 732             (setq gnus-format-specs (delq entry gnus-format-specs))
 733           (let ((form (caddr entry)))
 734             (when (and (listp form)
 735                        ;; Under GNU Emacs, it's (byte-code ...)
 736                        (not (eq 'byte-code (car form)))
 737                        ;; Under XEmacs, it's (funcall #<compiled-function ...>)
 738                        (not (and (eq 'funcall (car form))
 739                                  (byte-code-function-p (cadr form)))))
 740               (defalias 'gnus-tmp-func `(lambda () ,form))
 741               (byte-compile 'gnus-tmp-func)
 742               (setcar (cddr entry) (gnus-byte-code 'gnus-tmp-func))))))
 743
 744       (push (cons 'version emacs-version) gnus-format-specs)
 745       ;; Mark the .newsrc.eld file as "dirty".
 746       (gnus-dribble-touch)
 747       (gnus-message 7 "Compiling user specs...done"))))
 748
 749 (defun gnus-set-format (type &optional insertable)
 750   (set (intern (format "gnus-%s-line-format-spec" type))
 751        (gnus-parse-format
 752         (symbol-value (intern (format "gnus-%s-line-format" type)))
 753         (symbol-value (intern (format "gnus-%s-line-format-alist" type)))
 754         insertable)))
 755
 756 (provide 'gnus-spec)
 757
 758 ;; Local Variables:
 759 ;; coding: iso-8859-1
 760 ;; End:
 761
 762 ;;; arch-tag: a4328fa1-1f84-4b09-97ad-4b5767cfd50f
 763 ;;; gnus-spec.el ends here