lisp/gnus/gnus-cache.el

   1 ;;; gnus-cache.el --- cache interface for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   3 ;; 2004, 2005 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32 (require 'gnus-int)
  33 (require 'gnus-range)
  34 (require 'gnus-start)
  35 (eval-when-compile
  36   (if (not (fboundp 'gnus-agent-load-alist))
  37       (defun gnus-agent-load-alist (group)))
  38   (require 'gnus-sum))
  39
  40 (defcustom gnus-cache-active-file
  41   (expand-file-name "active" gnus-cache-directory)
  42   "*The cache active file."
  43   :group 'gnus-cache
  44   :type 'file)
  45
  46 (defcustom gnus-cache-enter-articles '(ticked dormant)
  47   "Classes of articles to enter into the cache."
  48   :group 'gnus-cache
  49   :type '(set (const ticked) (const dormant) (const unread) (const read)))
  50
  51 (defcustom gnus-cache-remove-articles '(read)
  52   "Classes of articles to remove from the cache."
  53   :group 'gnus-cache
  54   :type '(set (const ticked) (const dormant) (const unread) (const read)))
  55
  56 (defcustom gnus-cacheable-groups nil
  57   "*Groups that match this regexp will be cached.
  58
  59 If you only want to cache your nntp groups, you could set this
  60 variable to \"^nntp\".
  61
  62 If a group matches both gnus-cacheable-groups and gnus-uncacheable-groups
  63 it's not cached."
  64   :group 'gnus-cache
  65   :type '(choice (const :tag "off" nil)
  66                  regexp))
  67
  68 (defcustom gnus-uncacheable-groups nil
  69   "*Groups that match this regexp will not be cached.
  70
  71 If you want to avoid caching your nnml groups, you could set this
  72 variable to \"^nnml\".
  73
  74 If a group matches both gnus-cacheable-groups and gnus-uncacheable-groups
  75 it's not cached."
  76   :group 'gnus-cache
  77   :type '(choice (const :tag "off" nil)
  78                  regexp))
  79
  80 (defvar gnus-cache-overview-coding-system 'raw-text
  81   "Coding system used on Gnus cache files.")
  82
  83 (defvar gnus-cache-coding-system 'raw-text
  84   "Coding system used on Gnus cache files.")
  85
  86 \f
  87
  88 ;;; Internal variables.
  89
  90 (defvar gnus-cache-removable-articles nil)
  91 (defvar gnus-cache-buffer nil)
  92 (defvar gnus-cache-active-hashtb nil)
  93 (defvar gnus-cache-active-altered nil)
  94
  95 (eval-and-compile
  96   (autoload 'nnml-generate-nov-databases-1 "nnml")
  97   (autoload 'nnvirtual-find-group-art "nnvirtual"))
  98
  99 \f
 100
 101 ;;; Functions called from Gnus.
 102
 103 (defun gnus-cache-open ()
 104   "Initialize the cache."
 105   (when (or (file-exists-p gnus-cache-directory)
 106             (and gnus-use-cache
 107                  (not (eq gnus-use-cache 'passive))))
 108     (gnus-cache-read-active)))
 109
 110 ;; Complexities of byte-compiling make this kludge necessary.  Eeek.
 111 (ignore-errors
 112   (gnus-add-shutdown 'gnus-cache-close 'gnus))
 113
 114 (defun gnus-cache-close ()
 115   "Shut down the cache."
 116   (gnus-cache-write-active)
 117   (gnus-cache-save-buffers)
 118   (setq gnus-cache-active-hashtb nil))
 119
 120 (defun gnus-cache-save-buffers ()
 121   ;; save the overview buffer if it exists and has been modified
 122   ;; delete empty cache subdirectories
 123   (when gnus-cache-buffer
 124     (let ((buffer (cdr gnus-cache-buffer))
 125           (overview-file (gnus-cache-file-name
 126                           (car gnus-cache-buffer) ".overview")))
 127       ;; write the overview only if it was modified
 128       (when (and (buffer-live-p buffer) (buffer-modified-p buffer))
 129         (with-current-buffer buffer
 130           (if (> (buffer-size) 0)
 131               ;; Non-empty overview, write it to a file.
 132               (let ((coding-system-for-write
 133                      gnus-cache-overview-coding-system))
 134                 (gnus-write-buffer overview-file))
 135             ;; Empty overview file, remove it
 136             (when (file-exists-p overview-file)
 137               (delete-file overview-file))
 138             ;; If possible, remove group's cache subdirectory.
 139             (condition-case nil
 140                 ;; FIXME: we can detect the error type and warn the user
 141                 ;; of any inconsistencies (articles w/o nov entries?).
 142                 ;; for now, just be conservative...delete only if safe -- sj
 143                 (delete-directory (file-name-directory overview-file))
 144               (error nil)))))
 145       ;; Kill the buffer -- it's either unmodified or saved.
 146       (gnus-kill-buffer buffer)
 147       (setq gnus-cache-buffer nil))))
 148
 149 (defun gnus-cache-possibly-enter-article
 150   (group article ticked dormant unread &optional force)
 151   (when (and (or force (not (eq gnus-use-cache 'passive)))
 152              (numberp article)
 153              (> article 0))             ; This might be a dummy article.
 154     (let ((number article) file headers)
 155       ;; If this is a virtual group, we find the real group.
 156       (when (gnus-virtual-group-p group)
 157         (let ((result (nnvirtual-find-group-art
 158                        (gnus-group-real-name group) article)))
 159           (setq group (car result)
 160                 number (cdr result))))
 161       (when (and number
 162                  (> number 0)           ; Reffed article.
 163                  (or force
 164                      (and (gnus-cache-fully-p group)
 165                           (gnus-cache-member-of-class
 166                            gnus-cache-enter-articles ticked dormant unread)))
 167                  (not (file-exists-p (setq file (gnus-cache-file-name
 168                                                  group number)))))
 169         ;; Possibly create the cache directory.
 170         (gnus-make-directory (file-name-directory file))
 171         ;; Save the article in the cache.
 172         (if (file-exists-p file)
 173             t                           ; The article already is saved.
 174           (save-excursion
 175             (set-buffer nntp-server-buffer)
 176             (require 'gnus-art)
 177             (let ((gnus-use-cache nil)
 178                   (gnus-article-decode-hook nil))
 179               (gnus-request-article-this-buffer number group))
 180             (when (> (buffer-size) 0)
 181               (let ((coding-system-for-write gnus-cache-coding-system))
 182                 (gnus-write-buffer file))
 183               (nnheader-remove-body)
 184               (setq headers (nnheader-parse-naked-head))
 185               (mail-header-set-number headers number)
 186               (gnus-cache-change-buffer group)
 187               (set-buffer (cdr gnus-cache-buffer))
 188               (goto-char (point-max))
 189               (forward-line -1)
 190               (while (condition-case ()
 191                          (when (not (bobp))
 192                            (> (read (current-buffer)) number))
 193                        (error
 194                         ;; The line was malformed, so we just remove it!!
 195                         (gnus-delete-line)
 196                         t))
 197                 (forward-line -1))
 198               (if (bobp)
 199                   (if (not (eobp))
 200                       (progn
 201                         (beginning-of-line)
 202                         (when (< (read (current-buffer)) number)
 203                           (forward-line 1)))
 204                     (beginning-of-line))
 205                 (forward-line 1))
 206               (beginning-of-line)
 207               (nnheader-insert-nov headers)
 208               ;; Update the active info.
 209               (set-buffer gnus-summary-buffer)
 210               (gnus-cache-possibly-update-active group (cons number number))
 211               (setq gnus-newsgroup-cached
 212                     (gnus-add-to-sorted-list gnus-newsgroup-cached article))
 213               (gnus-summary-update-secondary-mark article))
 214             t))))))
 215
 216 (defun gnus-cache-enter-remove-article (article)
 217   "Mark ARTICLE for later possible removal."
 218   (when article
 219     (push article gnus-cache-removable-articles)))
 220
 221 (defun gnus-cache-possibly-remove-articles ()
 222   "Possibly remove some of the removable articles."
 223   (if (not (gnus-virtual-group-p gnus-newsgroup-name))
 224       (gnus-cache-possibly-remove-articles-1)
 225     (let ((arts gnus-cache-removable-articles)
 226           ga)
 227       (while arts
 228         (when (setq ga (nnvirtual-find-group-art
 229                         (gnus-group-real-name gnus-newsgroup-name) (pop arts)))
 230           (let ((gnus-cache-removable-articles (list (cdr ga)))
 231                 (gnus-newsgroup-name (car ga)))
 232             (gnus-cache-possibly-remove-articles-1)))))
 233     (setq gnus-cache-removable-articles nil)))
 234
 235 (defun gnus-cache-possibly-remove-articles-1 ()
 236   "Possibly remove some of the removable articles."
 237   (when (gnus-cache-fully-p gnus-newsgroup-name)
 238     (let ((articles gnus-cache-removable-articles)
 239           (cache-articles gnus-newsgroup-cached)
 240           article)
 241       (gnus-cache-change-buffer gnus-newsgroup-name)
 242       (while articles
 243         (when (memq (setq article (pop articles)) cache-articles)
 244           ;; The article was in the cache, so we see whether we are
 245           ;; supposed to remove it from the cache.
 246           (gnus-cache-possibly-remove-article
 247            article (memq article gnus-newsgroup-marked)
 248            (memq article gnus-newsgroup-dormant)
 249            (or (memq article gnus-newsgroup-unreads)
 250                (memq article gnus-newsgroup-unselected))))))
 251     ;; The overview file might have been modified, save it
 252     ;; safe because we're only called at group exit anyway.
 253     (gnus-cache-save-buffers)))
 254
 255 (defun gnus-cache-request-article (article group)
 256   "Retrieve ARTICLE in GROUP from the cache."
 257   (let ((file (gnus-cache-file-name group article))
 258         (buffer-read-only nil))
 259     (when (file-exists-p file)
 260       (erase-buffer)
 261       (gnus-kill-all-overlays)
 262       (let ((coding-system-for-read gnus-cache-coding-system))
 263         (insert-file-contents file))
 264       t)))
 265
 266 (defun gnus-cache-possibly-alter-active (group active)
 267   "Alter the ACTIVE info for GROUP to reflect the articles in the cache."
 268   (when gnus-cache-active-hashtb
 269     (let ((cache-active (gnus-gethash group gnus-cache-active-hashtb)))
 270       (when cache-active
 271         (when (< (car cache-active) (car active))
 272           (setcar active (car cache-active)))
 273         (when (> (cdr cache-active) (cdr active))
 274           (setcdr active (cdr cache-active)))))))
 275
 276 (defun gnus-cache-retrieve-headers (articles group &optional fetch-old)
 277   "Retrieve the headers for ARTICLES in GROUP."
 278   (let ((cached
 279          (setq gnus-newsgroup-cached (gnus-cache-articles-in-group group))))
 280     (if (not cached)
 281         ;; No cached articles here, so we just retrieve them
 282         ;; the normal way.
 283         (let ((gnus-use-cache nil))
 284           (gnus-retrieve-headers articles group fetch-old))
 285       (let ((uncached-articles (gnus-sorted-difference articles cached))
 286             (cache-file (gnus-cache-file-name group ".overview"))
 287             type)
 288         ;; We first retrieve all the headers that we don't have in
 289         ;; the cache.
 290         (let ((gnus-use-cache nil))
 291           (when uncached-articles
 292             (setq type (and articles
 293                             (gnus-retrieve-headers
 294                              uncached-articles group fetch-old)))))
 295         (gnus-cache-save-buffers)
 296         ;; Then we insert the cached headers.
 297         (save-excursion
 298           (cond
 299            ((not (file-exists-p cache-file))
 300             ;; There are no cached headers.
 301             type)
 302            ((null type)
 303             ;; There were no uncached headers (or retrieval was
 304             ;; unsuccessful), so we use the cached headers exclusively.
 305             (set-buffer nntp-server-buffer)
 306             (erase-buffer)
 307             (let ((coding-system-for-read
 308                    gnus-cache-overview-coding-system))
 309               (insert-file-contents cache-file))
 310             'nov)
 311            ((eq type 'nov)
 312             ;; We have both cached and uncached NOV headers, so we
 313             ;; braid them.
 314             (gnus-cache-braid-nov group cached)
 315             type)
 316            (t
 317             ;; We braid HEADs.
 318             (gnus-cache-braid-heads group (gnus-sorted-intersection
 319                                            cached articles))
 320             type)))))))
 321
 322 (defun gnus-cache-enter-article (&optional n)
 323   "Enter the next N articles into the cache.
 324 If not given a prefix, use the process marked articles instead.
 325 Returns the list of articles entered."
 326   (interactive "P")
 327   (let ((articles (gnus-summary-work-articles n))
 328         article out)
 329     (while (setq article (pop articles))
 330       (gnus-summary-remove-process-mark article)
 331       (if (natnump article)
 332           (when (gnus-cache-possibly-enter-article
 333                  gnus-newsgroup-name article
 334                  nil nil nil t)
 335             (setq gnus-newsgroup-undownloaded (delq article gnus-newsgroup-undownloaded))
 336             (push article out))
 337         (gnus-message 2 "Can't cache article %d" article))
 338       (gnus-summary-update-download-mark article)
 339       (gnus-summary-update-secondary-mark article))
 340     (gnus-summary-next-subject 1)
 341     (gnus-summary-position-point)
 342     (nreverse out)))
 343
 344 (defun gnus-cache-remove-article (&optional n)
 345   "Remove the next N articles from the cache.
 346 If not given a prefix, use the process marked articles instead.
 347 Returns the list of articles removed."
 348   (interactive "P")
 349   (gnus-cache-change-buffer gnus-newsgroup-name)
 350   (let ((articles (gnus-summary-work-articles n))
 351         article out)
 352     (while articles
 353       (setq article (pop articles))
 354       (gnus-summary-remove-process-mark article)
 355       (when (gnus-cache-possibly-remove-article article nil nil nil t)
 356         (when gnus-newsgroup-agentized
 357           (let ((alist (gnus-agent-load-alist gnus-newsgroup-name)))
 358             (unless (cdr (assoc article alist))
 359               (setq gnus-newsgroup-undownloaded
 360                     (gnus-add-to-sorted-list
 361                      gnus-newsgroup-undownloaded article)))))
 362         (push article out))
 363       (gnus-summary-update-download-mark article)
 364       (gnus-summary-update-secondary-mark article))
 365     (gnus-summary-next-subject 1)
 366     (gnus-summary-position-point)
 367     (nreverse out)))
 368
 369 (defun gnus-cached-article-p (article)
 370   "Say whether ARTICLE is cached in the current group."
 371   (memq article gnus-newsgroup-cached))
 372
 373 (defun gnus-summary-insert-cached-articles ()
 374   "Insert all the articles cached for this group into the current buffer."
 375   (interactive)
 376   (let ((gnus-verbose (max 6 gnus-verbose)))
 377     (if (not gnus-newsgroup-cached)
 378         (gnus-message 3 "No cached articles for this group")
 379       (gnus-summary-goto-subjects gnus-newsgroup-cached))))
 380
 381 (defun gnus-summary-limit-include-cached ()
 382   "Limit the summary buffer to articles that are cached."
 383   (interactive)
 384   (let ((gnus-verbose (max 6 gnus-verbose)))
 385     (if gnus-newsgroup-cached
 386         (progn
 387           (gnus-summary-limit gnus-newsgroup-cached)
 388           (gnus-summary-position-point))
 389       (gnus-message 3 "No cached articles for this group"))))
 390
 391 ;;; Internal functions.
 392
 393 (defun gnus-cache-change-buffer (group)
 394   (and gnus-cache-buffer
 395        ;; See if the current group's overview cache has been loaded.
 396        (or (string= group (car gnus-cache-buffer))
 397            ;; Another overview cache is current, save it.
 398            (gnus-cache-save-buffers)))
 399   ;; if gnus-cache buffer is nil, create it
 400   (unless gnus-cache-buffer
 401     ;; Create cache buffer
 402     (save-excursion
 403       (setq gnus-cache-buffer
 404             (cons group
 405                   (set-buffer (gnus-get-buffer-create
 406                                " *gnus-cache-overview*"))))
 407       ;; Insert the contents of this group's cache overview.
 408       (erase-buffer)
 409       (let ((file (gnus-cache-file-name group ".overview")))
 410         (when (file-exists-p file)
 411           (nnheader-insert-file-contents file)))
 412       ;; We have a fresh (empty/just loaded) buffer,
 413       ;; mark it as unmodified to save a redundant write later.
 414       (set-buffer-modified-p nil))))
 415
 416 ;; Return whether an article is a member of a class.
 417 (defun gnus-cache-member-of-class (class ticked dormant unread)
 418   (or (and ticked (memq 'ticked class))
 419       (and dormant (memq 'dormant class))
 420       (and unread (memq 'unread class))
 421       (and (not unread) (not ticked) (not dormant) (memq 'read class))))
 422
 423 (defun gnus-cache-file-name (group article)
 424   (setq group (gnus-group-decoded-name group))
 425   (expand-file-name
 426    (if (stringp article) article (int-to-string article))
 427    (file-name-as-directory
 428     (expand-file-name
 429      (nnheader-translate-file-chars
 430       (if (gnus-use-long-file-name 'not-cache)
 431           group
 432         (let ((group (nnheader-replace-duplicate-chars-in-string
 433                       (nnheader-replace-chars-in-string group ?/ ?_)
 434                       ?. ?_)))
 435           ;; Translate the first colon into a slash.
 436           (when (string-match ":" group)
 437                   (setq group (concat (substring group 0 (match-beginning 0))
 438                                       "/" (substring group (match-end 0)))))
 439           (nnheader-replace-chars-in-string group ?. ?/)))
 440       t)
 441      gnus-cache-directory))))
 442
 443 (defun gnus-cache-update-article (group article)
 444   "If ARTICLE is in the cache, remove it and re-enter it."
 445   (gnus-cache-change-buffer group)
 446   (when (gnus-cache-possibly-remove-article article nil nil nil t)
 447     (let ((gnus-use-cache nil))
 448       (gnus-cache-possibly-enter-article
 449        gnus-newsgroup-name article
 450        nil nil nil t))))
 451
 452 (defun gnus-cache-possibly-remove-article (article ticked dormant unread
 453                                                    &optional force)
 454   "Possibly remove ARTICLE from the cache."
 455   (let ((group gnus-newsgroup-name)
 456         (number article)
 457         file)
 458     ;; If this is a virtual group, we find the real group.
 459     (when (gnus-virtual-group-p group)
 460       (let ((result (nnvirtual-find-group-art
 461                      (gnus-group-real-name group) article)))
 462         (setq group (car result)
 463               number (cdr result))))
 464     (setq file (gnus-cache-file-name group number))
 465     (when (and (file-exists-p file)
 466                (or force
 467                    (gnus-cache-member-of-class
 468                     gnus-cache-remove-articles ticked dormant unread)))
 469       (save-excursion
 470         (delete-file file)
 471         (set-buffer (cdr gnus-cache-buffer))
 472         (goto-char (point-min))
 473         (when (or (looking-at (concat (int-to-string number) "\t"))
 474                   (search-forward (concat "\n" (int-to-string number) "\t")
 475                                   (point-max) t))
 476           (gnus-delete-line)))
 477       (unless (setq gnus-newsgroup-cached
 478                     (delq article gnus-newsgroup-cached))
 479         (gnus-sethash gnus-newsgroup-name nil gnus-cache-active-hashtb)
 480         (setq gnus-cache-active-altered t))
 481       (gnus-summary-update-secondary-mark article)
 482       t)))
 483
 484 (defun gnus-cache-articles-in-group (group)
 485   "Return a sorted list of cached articles in GROUP."
 486   (let ((dir (file-name-directory (gnus-cache-file-name group 1)))
 487         articles)
 488     (when (file-exists-p dir)
 489       (setq articles
 490             (sort (mapcar (lambda (name) (string-to-number name))
 491                           (directory-files dir nil "^[0-9]+$" t))
 492                   '<))
 493       ;; Update the cache active file, just to synch more.
 494       (if articles
 495           (progn
 496             (gnus-cache-update-active group (car articles) t)
 497             (gnus-cache-update-active group (car (last articles))))
 498         (when (gnus-gethash group gnus-cache-active-hashtb)
 499           (gnus-sethash group nil gnus-cache-active-hashtb)
 500           (setq gnus-cache-active-altered t)))
 501       articles)))
 502
 503 (defun gnus-cache-braid-nov (group cached &optional file)
 504   (let ((cache-buf (gnus-get-buffer-create " *gnus-cache*"))
 505         beg end)
 506     (gnus-cache-save-buffers)
 507     (save-excursion
 508       (set-buffer cache-buf)
 509       (erase-buffer)
 510       (let ((coding-system-for-read
 511              gnus-cache-overview-coding-system))
 512         (insert-file-contents
 513          (or file (gnus-cache-file-name group ".overview"))))
 514       (goto-char (point-min))
 515       (insert "\n")
 516       (goto-char (point-min)))
 517     (set-buffer nntp-server-buffer)
 518     (goto-char (point-min))
 519     (while cached
 520       (while (and (not (eobp))
 521                   (< (read (current-buffer)) (car cached)))
 522         (forward-line 1))
 523       (beginning-of-line)
 524       (set-buffer cache-buf)
 525       (if (search-forward (concat "\n" (int-to-string (car cached)) "\t")
 526                           nil t)
 527           (setq beg (gnus-point-at-bol)
 528                 end (progn (end-of-line) (point)))
 529         (setq beg nil))
 530       (set-buffer nntp-server-buffer)
 531       (when beg
 532         (insert-buffer-substring cache-buf beg end)
 533         (insert "\n"))
 534       (setq cached (cdr cached)))
 535     (kill-buffer cache-buf)))
 536
 537 (defun gnus-cache-braid-heads (group cached)
 538   (let ((cache-buf (gnus-get-buffer-create " *gnus-cache*")))
 539     (save-excursion
 540       (set-buffer cache-buf)
 541       (erase-buffer))
 542     (set-buffer nntp-server-buffer)
 543     (goto-char (point-min))
 544     (while cached
 545       (while (and (not (eobp))
 546                   (looking-at "2.. +\\([0-9]+\\) ")
 547                   (< (progn (goto-char (match-beginning 1))
 548                             (read (current-buffer)))
 549                      (car cached)))
 550         (search-forward "\n.\n" nil 'move))
 551       (beginning-of-line)
 552       (set-buffer cache-buf)
 553       (erase-buffer)
 554       (let ((coding-system-for-read
 555              gnus-cache-coding-system))
 556         (insert-file-contents (gnus-cache-file-name group (car cached))))
 557       (goto-char (point-min))
 558       (insert "220 ")
 559       (princ (car cached) (current-buffer))
 560       (insert " Article retrieved.\n")
 561       (search-forward "\n\n" nil 'move)
 562       (delete-region (point) (point-max))
 563       (forward-char -1)
 564       (insert ".")
 565       (set-buffer nntp-server-buffer)
 566       (insert-buffer-substring cache-buf)
 567       (setq cached (cdr cached)))
 568     (kill-buffer cache-buf)))
 569
 570 ;;;###autoload
 571 (defun gnus-jog-cache ()
 572   "Go through all groups and put the articles into the cache.
 573
 574 Usage:
 575 $ emacs -batch -l ~/.emacs -l gnus -f gnus-jog-cache"
 576   (interactive)
 577   (let ((gnus-mark-article-hook nil)
 578         (gnus-expert-user t)
 579         (nnmail-spool-file nil)
 580         (mail-sources nil)
 581         (gnus-use-dribble-file nil)
 582         (gnus-novice-user nil)
 583         (gnus-large-newsgroup nil))
 584     ;; Start Gnus.
 585     (gnus)
 586     ;; Go through all groups...
 587     (gnus-group-mark-buffer)
 588     (gnus-group-iterate nil
 589       (lambda (group)
 590         (let (gnus-auto-select-next)
 591           (gnus-summary-read-group group nil t)
 592           ;; ... and enter the articles into the cache.
 593           (when (eq major-mode 'gnus-summary-mode)
 594             (gnus-uu-mark-buffer)
 595             (gnus-cache-enter-article)
 596             (kill-buffer (current-buffer))))))))
 597
 598 (defun gnus-cache-read-active (&optional force)
 599   "Read the cache active file."
 600   (gnus-make-directory gnus-cache-directory)
 601   (if (or (not (file-exists-p gnus-cache-active-file))
 602           (zerop (nth 7 (file-attributes gnus-cache-active-file)))
 603           force)
 604       ;; There is no active file, so we generate one.
 605       (gnus-cache-generate-active)
 606     ;; We simply read the active file.
 607     (save-excursion
 608       (gnus-set-work-buffer)
 609       (nnheader-insert-file-contents gnus-cache-active-file)
 610       (gnus-active-to-gnus-format
 611        nil (setq gnus-cache-active-hashtb
 612                  (gnus-make-hashtable
 613                   (count-lines (point-min) (point-max)))))
 614       (setq gnus-cache-active-altered nil))))
 615
 616 (defun gnus-cache-write-active (&optional force)
 617   "Write the active hashtb to the active file."
 618   (when (or force
 619             (and gnus-cache-active-hashtb
 620                  gnus-cache-active-altered))
 621     (gnus-write-active-file gnus-cache-active-file gnus-cache-active-hashtb t)
 622     ;; Mark the active hashtb as unaltered.
 623     (setq gnus-cache-active-altered nil)))
 624
 625 (defun gnus-cache-possibly-update-active (group active)
 626   "Update active info bounds of GROUP with ACTIVE if necessary.
 627 The update is performed if ACTIVE contains a higher or lower bound
 628 than the current."
 629   (let ((lower t) (higher t))
 630     (if gnus-cache-active-hashtb
 631         (let ((cache-active (gnus-gethash group gnus-cache-active-hashtb)))
 632           (when cache-active
 633             (unless (< (car active) (car cache-active))
 634               (setq lower nil))
 635             (unless (> (cdr active) (cdr cache-active))
 636               (setq higher nil))))
 637       (gnus-cache-read-active))
 638     (when lower
 639       (gnus-cache-update-active group (car active) t))
 640     (when higher
 641       (gnus-cache-update-active group (cdr active)))))
 642
 643 (defun gnus-cache-update-active (group number &optional low)
 644   "Update the upper bound of the active info of GROUP to NUMBER.
 645 If LOW, update the lower bound instead."
 646   (let ((active (gnus-gethash group gnus-cache-active-hashtb)))
 647     (if (null active)
 648         ;; We just create a new active entry for this group.
 649         (gnus-sethash group (cons number number) gnus-cache-active-hashtb)
 650       ;; Update the lower or upper bound.
 651       (if low
 652           (setcar active number)
 653         (setcdr active number)))
 654     ;; Mark the active hashtb as altered.
 655     (setq gnus-cache-active-altered t)))
 656
 657 ;;;###autoload
 658 (defun gnus-cache-generate-active (&optional directory)
 659   "Generate the cache active file."
 660   (interactive)
 661   (let* ((top (null directory))
 662          (directory (expand-file-name (or directory gnus-cache-directory)))
 663          (files (directory-files directory 'full))
 664          (group
 665           (if top
 666               ""
 667             (string-match
 668              (concat "^" (regexp-quote
 669                           (file-name-as-directory
 670                            (expand-file-name gnus-cache-directory))))
 671              (directory-file-name directory))
 672             (nnheader-replace-chars-in-string
 673              (substring (directory-file-name directory) (match-end 0))
 674              ?/ ?.)))
 675          nums alphs)
 676     (when top
 677       (gnus-message 5 "Generating the cache active file...")
 678       (setq gnus-cache-active-hashtb (gnus-make-hashtable 123)))
 679     (when (string-match "^\\(nn[^_]+\\)_" group)
 680       (setq group (replace-match "\\1:" t nil group)))
 681     ;; Separate articles from all other files and directories.
 682     (while files
 683       (if (string-match "^[0-9]+$" (file-name-nondirectory (car files)))
 684           (push (string-to-number (file-name-nondirectory (pop files))) nums)
 685         (push (pop files) alphs)))
 686     ;; If we have nums, then this is probably a valid group.
 687     (when (setq nums (sort nums '<))
 688       (gnus-sethash group (cons (car nums) (gnus-last-element nums))
 689                     gnus-cache-active-hashtb))
 690     ;; Go through all the other files.
 691     (while alphs
 692       (when (and (file-directory-p (car alphs))
 693                  (not (string-match "^\\."
 694                                     (file-name-nondirectory (car alphs)))))
 695         ;; We descend directories.
 696         (gnus-cache-generate-active (car alphs)))
 697       (setq alphs (cdr alphs)))
 698     ;; Write the new active file.
 699     (when top
 700       (gnus-cache-write-active t)
 701       (gnus-message 5 "Generating the cache active file...done"))))
 702
 703 ;;;###autoload
 704 (defun gnus-cache-generate-nov-databases (dir)
 705   "Generate NOV files recursively starting in DIR."
 706   (interactive (list gnus-cache-directory))
 707   (gnus-cache-close)
 708   (let ((nnml-generate-active-function 'identity))
 709     (nnml-generate-nov-databases-1 dir))
 710   (gnus-cache-open))
 711
 712 (defun gnus-cache-move-cache (dir)
 713   "Move the cache tree to somewhere else."
 714   (interactive "FMove the cache tree to: ")
 715   (rename-file gnus-cache-directory dir))
 716
 717 (defun gnus-cache-fully-p (&optional group)
 718   "Returns non-nil if the cache should be fully used.
 719 If GROUP is non-nil, also cater to `gnus-cacheable-groups' and
 720 `gnus-uncacheable-groups'."
 721   (and gnus-use-cache
 722        (not (eq gnus-use-cache 'passive))
 723        (if (null group)
 724            t
 725          (and (or (not gnus-cacheable-groups)
 726                   (string-match gnus-cacheable-groups group))
 727               (or (not gnus-uncacheable-groups)
 728                   (not (string-match gnus-uncacheable-groups group)))))))
 729
 730 ;;;###autoload
 731 (defun gnus-cache-rename-group (old-group new-group)
 732   "Rename OLD-GROUP as NEW-GROUP.  Always updates the cache, even when
 733 disabled, as the old cache files would corrupt gnus when the cache was
 734 next enabled. Depends upon the caller to determine whether group renaming is supported."
 735   (let ((old-dir (gnus-cache-file-name old-group ""))
 736         (new-dir (gnus-cache-file-name new-group "")))
 737     (gnus-rename-file old-dir new-dir t))
 738
 739   (let ((no-save gnus-cache-active-hashtb))
 740     (unless gnus-cache-active-hashtb
 741       (gnus-cache-read-active))
 742     (let* ((old-group-hash-value (gnus-gethash old-group gnus-cache-active-hashtb))
 743            (new-group-hash-value (gnus-gethash new-group gnus-cache-active-hashtb))
 744            (delta                (or old-group-hash-value new-group-hash-value)))
 745       (gnus-sethash new-group old-group-hash-value gnus-cache-active-hashtb)
 746       (gnus-sethash old-group nil gnus-cache-active-hashtb)
 747
 748       (if no-save
 749           (setq gnus-cache-active-altered delta)
 750         (gnus-cache-write-active delta)))))
 751
 752 ;;;###autoload
 753 (defun gnus-cache-delete-group (group)
 754   "Delete GROUP.  Always updates the cache, even when
 755 disabled, as the old cache files would corrupt gnus when the cache was
 756 next enabled. Depends upon the caller to determine whether group deletion is supported."
 757   (let ((dir (gnus-cache-file-name group "")))
 758     (gnus-delete-directory dir))
 759
 760   (let ((no-save gnus-cache-active-hashtb))
 761     (unless gnus-cache-active-hashtb
 762       (gnus-cache-read-active))
 763     (let* ((group-hash-value (gnus-gethash group gnus-cache-active-hashtb)))
 764       (gnus-sethash group nil gnus-cache-active-hashtb)
 765
 766       (if no-save
 767           (setq gnus-cache-active-altered group-hash-value)
 768         (gnus-cache-write-active group-hash-value)))))
 769
 770 (provide 'gnus-cache)
 771
 772 ;;; arch-tag: 05a79442-8c58-4e65-bd0a-3cbb1b89a33a
 773 ;;; gnus-cache.el ends here