lisp/font-core.el

   1 ;;; font-core.el --- Core interface to font-lock
   2
   3 ;; Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001,
   4 ;;   2002, 2003, 2005  Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: languages, faces
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Code:
  27
  28 ;; This variable is used by mode packages that support Font Lock mode by
  29 ;; defining their own keywords to use for `font-lock-keywords'.  (The mode
  30 ;; command should make it buffer-local and set it to provide the set up.)
  31 (defvar font-lock-defaults nil
  32   "Defaults for Font Lock mode specified by the major mode.
  33 Defaults should be of the form:
  34
  35  (KEYWORDS [KEYWORDS-ONLY [CASE-FOLD [SYNTAX-ALIST [SYNTAX-BEGIN ...]]]])
  36
  37 KEYWORDS may be a symbol (a variable or function whose value is the keywords to
  38 use for fontification) or a list of symbols.  If KEYWORDS-ONLY is non-nil,
  39 syntactic fontification (strings and comments) is not performed.
  40 If CASE-FOLD is non-nil, the case of the keywords is ignored when fontifying.
  41 If SYNTAX-ALIST is non-nil, it should be a list of cons pairs of the form
  42 \(CHAR-OR-STRING . STRING) used to set the local Font Lock syntax table, for
  43 keyword and syntactic fontification (see `modify-syntax-entry').
  44
  45 If SYNTAX-BEGIN is non-nil, it should be a function with no args used to move
  46 backwards outside any enclosing syntactic block, for syntactic fontification.
  47 Typical values are `beginning-of-line' (i.e., the start of the line is known to
  48 be outside a syntactic block), or `beginning-of-defun' for programming modes or
  49 `backward-paragraph' for textual modes (i.e., the mode-dependent function is
  50 known to move outside a syntactic block).  If nil, the beginning of the buffer
  51 is used as a position outside of a syntactic block, in the worst case.
  52
  53 These item elements are used by Font Lock mode to set the variables
  54 `font-lock-keywords', `font-lock-keywords-only',
  55 `font-lock-keywords-case-fold-search', `font-lock-syntax-table' and
  56 `font-lock-beginning-of-syntax-function', respectively.
  57
  58 Further item elements are alists of the form (VARIABLE . VALUE) and are in no
  59 particular order.  Each VARIABLE is made buffer-local before set to VALUE.
  60
  61 Currently, appropriate variables include `font-lock-mark-block-function'.
  62 If this is non-nil, it should be a function with no args used to mark any
  63 enclosing block of text, for fontification via \\[font-lock-fontify-block].
  64 Typical values are `mark-defun' for programming modes or `mark-paragraph' for
  65 textual modes (i.e., the mode-dependent function is known to put point and mark
  66 around a text block relevant to that mode).
  67
  68 Other variables include that for syntactic keyword fontification,
  69 `font-lock-syntactic-keywords' and those for buffer-specialized fontification
  70 functions, `font-lock-fontify-buffer-function',
  71 `font-lock-unfontify-buffer-function', `font-lock-fontify-region-function',
  72 `font-lock-unfontify-region-function', and `font-lock-inhibit-thing-lock'.")
  73 (make-variable-buffer-local 'font-lock-defaults)
  74
  75 (defvar font-lock-defaults-alist nil
  76   "Alist of fall-back Font Lock defaults for major modes.
  77
  78 Each item should be a list of the form:
  79
  80  (MAJOR-MODE . FONT-LOCK-DEFAULTS)
  81
  82 where MAJOR-MODE is a symbol and FONT-LOCK-DEFAULTS is a list of default
  83 settings.  See the variable `font-lock-defaults', which takes precedence.")
  84 (make-obsolete-variable 'font-lock-defaults-alist 'font-lock-defaults)
  85
  86 (defvar font-lock-function 'font-lock-default-function
  87   "A function which is called when `font-lock-mode' is toggled.
  88 It will be passed one argument, which is the current value of
  89 `font-lock-mode'.")
  90
  91 (define-minor-mode font-lock-mode
  92   "Toggle Font Lock mode.
  93 With arg, turn Font Lock mode off if and only if arg is a non-positive
  94 number; if arg is nil, toggle Font Lock mode; anything else turns Font
  95 Lock on.
  96 \(Font Lock is also known as \"syntax highlighting\".)
  97
  98 When Font Lock mode is enabled, text is fontified as you type it:
  99
 100  - Comments are displayed in `font-lock-comment-face';
 101  - Strings are displayed in `font-lock-string-face';
 102  - Certain other expressions are displayed in other faces according to the
 103    value of the variable `font-lock-keywords'.
 104
 105 To customize the faces (colors, fonts, etc.) used by Font Lock for
 106 fontifying different parts of buffer text, use \\[customize-face].
 107
 108 You can enable Font Lock mode in any major mode automatically by turning on in
 109 the major mode's hook.  For example, put in your ~/.emacs:
 110
 111  (add-hook 'c-mode-hook 'turn-on-font-lock)
 112
 113 Alternatively, you can use Global Font Lock mode to automagically turn on Font
 114 Lock mode in buffers whose major mode supports it and whose major mode is one
 115 of `font-lock-global-modes'.  For example, put in your ~/.emacs:
 116
 117  (global-font-lock-mode t)
 118
 119 There are a number of support modes that may be used to speed up Font Lock mode
 120 in various ways, specified via the variable `font-lock-support-mode'.  Where
 121 major modes support different levels of fontification, you can use the variable
 122 `font-lock-maximum-decoration' to specify which level you generally prefer.
 123 When you turn Font Lock mode on/off the buffer is fontified/defontified, though
 124 fontification occurs only if the buffer is less than `font-lock-maximum-size'.
 125
 126 For example, to specify that Font Lock mode use use Lazy Lock mode as a support
 127 mode and use maximum levels of fontification, put in your ~/.emacs:
 128
 129  (setq font-lock-support-mode 'lazy-lock-mode)
 130  (setq font-lock-maximum-decoration t)
 131
 132 To add your own highlighting for some major mode, and modify the highlighting
 133 selected automatically via the variable `font-lock-maximum-decoration', you can
 134 use `font-lock-add-keywords'.
 135
 136 To fontify a buffer, without turning on Font Lock mode and regardless of buffer
 137 size, you can use \\[font-lock-fontify-buffer].
 138
 139 To fontify a block (the function or paragraph containing point, or a number of
 140 lines around point), perhaps because modification on the current line caused
 141 syntactic change on other lines, you can use \\[font-lock-fontify-block].
 142
 143 See the variable `font-lock-defaults-alist' for the Font Lock mode default
 144 settings.  You can set your own default settings for some mode, by setting a
 145 buffer local value for `font-lock-defaults', via its mode hook.
 146
 147 The above is the default behavior of `font-lock-mode'; you may specify
 148 your own function which is called when `font-lock-mode' is toggled via
 149 `font-lock-function'. "
 150   :group 'font-lock
 151   ;; Don't turn on Font Lock mode if we don't have a display (we're running a
 152   ;; batch job) or if the buffer is invisible (the name starts with a space).
 153   (when (or noninteractive (eq (aref (buffer-name) 0) ?\ ))
 154     (setq font-lock-mode nil))
 155   (funcall font-lock-function font-lock-mode)
 156   ;; Arrange to unfontify this buffer if we change major mode later.
 157   (if font-lock-mode
 158       (add-hook 'change-major-mode-hook 'font-lock-change-mode nil t)
 159     (remove-hook 'change-major-mode-hook 'font-lock-change-mode t)))
 160
 161 ;; Get rid of fontification for the old major mode.
 162 ;; We do this when changing major modes.
 163 (defun font-lock-change-mode ()
 164   (font-lock-mode -1))
 165
 166 (defun font-lock-defontify ()
 167   "Clear out all `font-lock-face' properties in current buffer.
 168 A major mode that uses `font-lock-face' properties might want to put
 169 this function onto `change-major-mode-hook'."
 170   (let ((modp (buffer-modified-p))
 171         (inhibit-read-only t))
 172     (save-restriction
 173       (widen)
 174       (remove-list-of-text-properties (point-min) (point-max)
 175                                       '(font-lock-face)))
 176     (restore-buffer-modified-p modp)))
 177
 178 (defun font-lock-default-function (mode)
 179   ;; Turn on Font Lock mode.
 180   (when mode
 181     (set (make-local-variable 'char-property-alias-alist)
 182          (copy-tree char-property-alias-alist))
 183     ;; Add `font-lock-face' as an alias for the `face' property.
 184     (let ((elt (assq 'face char-property-alias-alist)))
 185       (if elt
 186           (unless (memq 'font-lock-face (cdr elt))
 187             (setcdr elt (nconc (cdr elt) (list 'font-lock-face))))
 188         (push (list 'face 'font-lock-face) char-property-alias-alist))))
 189   ;; Turn off Font Lock mode.
 190   (unless mode
 191     ;; Remove `font-lock-face' as an alias for the `face' property.
 192     (set (make-local-variable 'char-property-alias-alist)
 193          (copy-tree char-property-alias-alist))
 194     (let ((elt (assq 'face char-property-alias-alist)))
 195       (when elt
 196         (setcdr elt (remq 'font-lock-face (cdr elt)))
 197         (when (null (cdr elt))
 198           (setq char-property-alias-alist
 199                 (delq elt char-property-alias-alist))))))
 200
 201   ;; Only do hard work if the mode has specified stuff in
 202   ;; `font-lock-defaults'.
 203   (when (or font-lock-defaults
 204             (and (boundp 'font-lock-keywords) font-lock-keywords)
 205             (with-no-warnings
 206              (cdr (assq major-mode font-lock-defaults-alist))))
 207     (font-lock-mode-internal mode)))
 208
 209 (defun turn-on-font-lock ()
 210   "Turn on Font Lock mode (only if the terminal can display it)."
 211   (unless font-lock-mode
 212     (font-lock-mode)))
 213
 214 ;;; Global Font Lock mode.
 215
 216 ;; A few people have hassled in the past for a way to make it easier to turn on
 217 ;; Font Lock mode, without the user needing to know for which modes s/he has to
 218 ;; turn it on, perhaps the same way hilit19.el/hl319.el does.  I've always
 219 ;; balked at that way, as I see it as just re-moulding the same problem in
 220 ;; another form.  That is; some person would still have to keep track of which
 221 ;; modes (which may not even be distributed with Emacs) support Font Lock mode.
 222 ;; The list would always be out of date.  And that person might have to be me.
 223
 224 ;; Implementation.
 225 ;;
 226 ;; In a previous discussion the following hack came to mind.  It is a gross
 227 ;; hack, but it generally works.  We use the convention that major modes start
 228 ;; by calling the function `kill-all-local-variables', which in turn runs
 229 ;; functions on the hook variable `change-major-mode-hook'.  We attach our
 230 ;; function `font-lock-change-major-mode' to that hook.  Of course, when this
 231 ;; hook is run, the major mode is in the process of being changed and we do not
 232 ;; know what the final major mode will be.  So, `font-lock-change-major-mode'
 233 ;; only (a) notes the name of the current buffer, and (b) adds our function
 234 ;; `turn-on-font-lock-if-enabled' to the hook variables
 235 ;; `after-change-major-mode-hook' and `post-command-hook' (for modes
 236 ;; that do not yet run `after-change-major-mode-hook').  By the time
 237 ;; the functions on the first of these hooks to be run are run, the new major
 238 ;; mode is assumed to be in place.  This way we get a Font Lock function run
 239 ;; when a major mode is turned on, without knowing major modes or their hooks.
 240 ;;
 241 ;; Naturally this requires that major modes run `kill-all-local-variables'
 242 ;; and `after-change-major-mode-hook', as they are supposed to.  For modes
 243 ;; that do not run `after-change-major-mode-hook' yet, `post-command-hook'
 244 ;; takes care of things if the mode is set directly or indirectly by
 245 ;; an interactive command; however, problems can occur if the mode is
 246 ;; set by a timer or process: in that case, proper handling of Font Lock mode
 247 ;; may be delayed until the next interactive command.
 248
 249 ;; User interface.
 250 ;;
 251 ;; Although Global Font Lock mode is a pseudo-mode, I think that the user
 252 ;; interface should conform to the usual Emacs convention for modes, i.e., a
 253 ;; command to toggle the feature (`global-font-lock-mode') with a variable for
 254 ;; finer control of the mode's behaviour (`font-lock-global-modes').
 255 ;;
 256 ;; The feature should not be enabled by loading font-lock.el, since other
 257 ;; mechanisms for turning on Font Lock mode, such as M-x font-lock-mode RET or
 258 ;; (add-hook 'c-mode-hook 'turn-on-font-lock), would cause Font Lock mode to be
 259 ;; turned on everywhere.  That would not be intuitive or informative because
 260 ;; loading a file tells you nothing about the feature or how to control it.  It
 261 ;; would also be contrary to the Principle of Least Surprise.  sm.
 262
 263 (defcustom font-lock-global-modes t
 264   "*Modes for which Font Lock mode is automagically turned on.
 265 Global Font Lock mode is controlled by the command `global-font-lock-mode'.
 266 If nil, means no modes have Font Lock mode automatically turned on.
 267 If t, all modes that support Font Lock mode have it automatically turned on.
 268 If a list, it should be a list of `major-mode' symbol names for which Font Lock
 269 mode should be automatically turned on.  The sense of the list is negated if it
 270 begins with `not'.  For example:
 271  (c-mode c++-mode)
 272 means that Font Lock mode is turned on for buffers in C and C++ modes only."
 273   :type '(choice (const :tag "none" nil)
 274                  (const :tag "all" t)
 275                  (set :menu-tag "mode specific" :tag "modes"
 276                       :value (not)
 277                       (const :tag "Except" not)
 278                       (repeat :inline t (symbol :tag "mode"))))
 279   :group 'font-lock)
 280
 281 (defun turn-on-font-lock-if-enabled ()
 282   (unless (and (eq (car-safe font-lock-global-modes) 'not)
 283                (memq major-mode (cdr font-lock-global-modes)))
 284     (let (inhibit-quit)
 285       (turn-on-font-lock))))
 286
 287 (easy-mmode-define-global-mode
 288  global-font-lock-mode font-lock-mode turn-on-font-lock-if-enabled
 289  :extra-args (dummy))
 290
 291 ;;; End of Global Font Lock mode.
 292
 293 (provide 'font-core)
 294
 295 ;; arch-tag: f8c286e1-02f7-41d9-b89b-1b67780aed71
 296 ;;; font-core.el ends here