lisp/textmodes/tex-mode.el

   1 ;;; tex-mode.el --- TeX, LaTeX, and SliTeX mode commands.
   2
   3 ;; Copyright (C) 1985, 1986, 1989, 1992 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: Edward M. Reingold <reingold@cs.uiuc.edu>
   6 ;; Keywords: tex
   7
   8 ;; Contributions over the years by William F. Schelter, Dick King,
   9 ;; Stephen Gildea, Michael Prange, and Edward M. Reingold.
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  25 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  26
  27 ;;; Code:
  28
  29 ;; This was a pain.  Now, make-comint should autoload comint.
  30 ;; (require 'comint)
  31
  32 ;;;###autoload
  33 (defvar tex-shell-file-name nil
  34   "*If non-nil, is file name to use for the subshell in which TeX is run.")
  35
  36 ;;;###autoload
  37 (defvar tex-directory "."
  38   "*Directory in which temporary files are left.
  39 You can make this /tmp if your TEXINPUTS has no relative directories in it
  40 and you don't try to apply \\[tex-region] or \\[tex-buffer] when there are
  41 \\input commands with relative directories.")
  42
  43 ;;;###autoload
  44 (defvar tex-offer-save t
  45   "*If non-nil, ask about saving modified buffers before \\[tex-file] is run.")
  46
  47 ;;;###autoload
  48 (defvar tex-run-command "tex"
  49   "*Command used to run TeX subjob.
  50 If this string contains an asterisk (*), it will be replaced by the
  51 filename; if not, the name of the file, preceded by blank, will be added to
  52 this string.")
  53
  54 ;;;###autoload
  55 (defvar latex-run-command "latex"
  56   "*Command used to run LaTeX subjob.
  57 If this string contains an asterisk (*), it will be replaced by the
  58 filename; if not, the name of the file, preceded by blank, will be added to
  59 this string.")
  60
  61 (defvar standard-latex-block-names
  62       '("abstract"         "array"            "center"       "description"
  63         "displaymath"      "document"         "enumerate"    "eqnarray"
  64         "eqnarray*"        "equation"         "figure"       "figure*"
  65         "flushleft"        "flushright"       "itemize"      "letter"
  66         "list"             "minipage"         "picture"      "quotation"
  67         "quote"            "slide"            "sloppypar"     "tabbing"
  68         "table"            "table*"           "tabular"       "tabular*"
  69         "thebibliography"  "theindex*"        "titlepage"     "trivlist"
  70         "verbatim"         "verbatim*"        "verse")
  71   "Standard LaTeX block names.")
  72
  73 ;;;###autoload
  74 (defvar latex-block-names nil
  75   "*User defined LaTeX block names.
  76 Combined with `standard-latex-block-names' for minibuffer completion.")
  77
  78 ;;;###autoload
  79 (defvar slitex-run-command "slitex"
  80   "*Command used to run SliTeX subjob.
  81 If this string contains an asterisk (*), it will be replaced by the
  82 filename; if not, the name of the file, preceded by blank, will be added to
  83 this string.")
  84
  85 ;;;###autoload
  86 (defvar tex-bibtex-command "bibtex"
  87   "*Command used by `tex-bibtex-file' to gather bibliographic data.
  88 If this string contains an asterisk (*), it will be replaced by the
  89 filename; if not, the name of the file, preceded by blank, will be added to
  90 this string.")
  91
  92 ;;;###autoload
  93 (defvar tex-dvi-print-command "lpr -d"
  94   "*Command used by \\[tex-print] to print a .dvi file.
  95 If this string contains an asterisk (*), it will be replaced by the
  96 filename; if not, the name of the file, preceded by blank, will be added to
  97 this string.")
  98
  99 ;;;###autoload
 100 (defvar tex-alt-dvi-print-command "lpr -d"
 101   "*Command used by \\[tex-print] with a prefix arg to print a .dvi file.
 102 If this string contains an asterisk (*), it will be replaced by the
 103 filename; if not, the name of the file, preceded by blank, will be added to
 104 this string.
 105
 106 If two printers are not enough of a choice, you can define the value
 107 of tex-alt-dvi-print-command to be an expression that asks what you want;
 108 for example,
 109
 110     (setq tex-alt-dvi-print-command
 111          '(format \"lpr -P%s\" (read-string \"Use printer: \")))
 112
 113 would tell \\[tex-print] with a prefix argument to ask you which printer to
 114 use.")
 115
 116 ;;;###autoload
 117 (defvar tex-dvi-view-command nil
 118   "*Command used by \\[tex-view] to display a .dvi file.
 119 If this string contains an asterisk (*), it will be replaced by the
 120 filename; if not, the name of the file, preceded by blank, will be added to
 121 this string.
 122
 123 This can be set conditionally so that the previewer used is suitable for the
 124 window system being used.  For example,
 125
 126     (setq tex-dvi-view-command
 127           (if (eq window-system 'x) \"xdvi\" \"dvi2tty * | cat -s\"))
 128
 129 would tell \\[tex-view] use xdvi under X windows and to use dvi2tty
 130 otherwise.")
 131
 132 ;;;###autoload
 133 (defvar tex-show-queue-command "lpq"
 134   "*Command used by \\[tex-show-print-queue] to show the print queue.
 135 Should show the queue(s) that \\[tex-print] puts jobs on.")
 136
 137 ;;;###autoload
 138 (defvar tex-default-mode 'plain-tex-mode
 139   "*Mode to enter for a new file that might be either TeX or LaTeX.
 140 This variable is used when it can't be determined whether the file
 141 is plain TeX or LaTeX or what because the file contains no commands.
 142 Normally set to either 'plain-tex-mode or 'latex-mode.")
 143
 144 ;;;###autoload
 145 (defvar tex-open-quote "``"
 146   "*String inserted by typing \\[tex-insert-quote] to open a quotation.")
 147
 148 ;;;###autoload
 149 (defvar tex-close-quote "''"
 150   "*String inserted by typing \\[tex-insert-quote] to close a quotation.")
 151
 152 (defvar tex-last-temp-file nil
 153   "Latest temporary file generated by \\[tex-region] and \\[tex-buffer].
 154 Deleted when the \\[tex-region] or \\[tex-buffer] is next run, or when the
 155 tex-shell goes away.")
 156
 157 (defvar tex-command nil
 158   "Command to run TeX.
 159 The name of the file, preceded by a blank, will be added to this string.")
 160
 161 (defvar tex-trailer nil
 162   "String appended after the end of a region sent to TeX by \\[tex-region].")
 163
 164 (defvar tex-start-of-header nil
 165   "String used by \\[tex-region] to delimit the start of the file's header.")
 166
 167 (defvar tex-end-of-header nil
 168   "String used by \\[tex-region] to delimit the end of the file's header.")
 169
 170 (defvar tex-shell-cd-command "cd"
 171   "Command to give to shell running TeX to change directory.
 172 The value of tex-directory will be appended to this, separated by a space.")
 173
 174 (defvar tex-zap-file nil
 175   "Temporary file name used for text being sent as input to TeX.
 176 Should be a simple file name with no extension or directory specification.")
 177
 178 (defvar tex-last-buffer-texed nil
 179   "Buffer which was last TeXed.")
 180
 181 (defvar tex-print-file nil
 182   "File name that \\[tex-print] prints.
 183 Set by \\[tex-region], \\[tex-buffer], and \\[tex-file].")
 184
 185 (defvar tex-mode-syntax-table nil
 186   "Syntax table used while in TeX mode.")
 187
 188 (defun tex-define-common-keys (keymap)
 189   "Define the keys that we want defined both in TeX mode and in the tex-shell."
 190   (define-key keymap "\C-c\C-k" 'tex-kill-job)
 191   (define-key keymap "\C-c\C-l" 'tex-recenter-output-buffer)
 192   (define-key keymap "\C-c\C-q" 'tex-show-print-queue)
 193   (define-key keymap "\C-c\C-p" 'tex-print)
 194   (define-key keymap "\C-c\C-v" 'tex-view)
 195   )
 196
 197 (defvar tex-mode-map nil "Keymap for TeX mode.")
 198
 199 (if tex-mode-map
 200     nil
 201   (setq tex-mode-map (make-sparse-keymap))
 202   (tex-define-common-keys tex-mode-map)
 203   (define-key tex-mode-map "\"" 'tex-insert-quote)
 204   (define-key tex-mode-map "\n" 'tex-terminate-paragraph)
 205   (define-key tex-mode-map "\C-c}" 'up-list)
 206   (define-key tex-mode-map "\C-c{" 'tex-insert-braces)
 207   (define-key tex-mode-map "\C-c\C-r" 'tex-region)
 208   (define-key tex-mode-map "\C-c\C-b" 'tex-buffer)
 209   (define-key tex-mode-map "\C-c\C-f" 'tex-file)
 210   (define-key tex-mode-map "\C-c\C-i" 'tex-bibtex-file)
 211   (define-key tex-mode-map "\C-c\C-o" 'tex-latex-block)
 212   (define-key tex-mode-map "\C-c\C-e" 'tex-close-latex-block))
 213
 214 (defvar tex-shell-map nil
 215   "Keymap for the tex-shell.  A comint-mode-map with a few additions.")
 216
 217 ;(fset 'TeX-mode 'tex-mode)             ;in loaddefs.
 218
 219 ;;; This would be a lot simpler if we just used a regexp search,
 220 ;;; but then it would be too slow.
 221 ;;;###autoload
 222 (defun tex-mode ()
 223   "Major mode for editing files of input for TeX, LaTeX, or SliTeX.
 224 Tries to determine (by looking at the beginning of the file) whether
 225 this file is for plain TeX, LaTeX, or SliTeX and calls plain-tex-mode,
 226 latex-mode, or slitex-mode, respectively.  If it cannot be determined,
 227 such as if there are no commands in the file, the value of tex-default-mode
 228 is used."
 229   (interactive)
 230   (let (mode slash comment)
 231     (save-excursion
 232       (goto-char (point-min))
 233       (while (and (setq slash (search-forward "\\" nil t))
 234                   (setq comment (let ((search-end (point)))
 235                                   (save-excursion
 236                                     (beginning-of-line)
 237                                     (search-forward "%" search-end t))))))
 238       (if (and slash (not comment))
 239           (setq mode (if (looking-at "documentstyle")
 240                          (if (looking-at "documentstyle{slides}")
 241                              'slitex-mode
 242                            'latex-mode)
 243                        'plain-tex-mode))))
 244     (if mode (funcall mode)
 245       (funcall tex-default-mode))))
 246 ;;;###autoload
 247 (fset 'TeX-mode 'tex-mode)
 248 ;;;###autoload
 249 (fset 'LaTeX-mode 'latex-mode)
 250
 251 ;;;###autoload
 252 (defun plain-tex-mode ()
 253   "Major mode for editing files of input for plain TeX.
 254 Makes $ and } display the characters they match.
 255 Makes \" insert `` when it seems to be the beginning of a quotation,
 256 and '' when it appears to be the end; it inserts \" only after a \\.
 257
 258 Use \\[tex-region] to run TeX on the current region, plus a \"header\"
 259 copied from the top of the file (containing macro definitions, etc.),
 260 running TeX under a special subshell.  \\[tex-buffer] does the whole buffer.
 261 \\[tex-file] saves the buffer and then processes the file.
 262 \\[tex-print] prints the .dvi file made by any of these.
 263 \\[tex-view] previews the .dvi file made by any of these.
 264 \\[tex-bibtex-file] runs bibtex on the file of the current buffer.
 265
 266 Use \\[validate-tex-buffer] to check buffer for paragraphs containing
 267 mismatched $'s or braces.
 268
 269 Special commands:
 270 \\{tex-mode-map}
 271
 272 Mode variables:
 273 tex-run-command
 274         Command string used by \\[tex-region] or \\[tex-buffer].
 275 tex-directory
 276         Directory in which to create temporary files for TeX jobs
 277         run by \\[tex-region] or \\[tex-buffer].
 278 tex-dvi-print-command
 279         Command string used by \\[tex-print] to print a .dvi file.
 280 tex-alt-dvi-print-command
 281         Alternative command string used by \\[tex-print] (when given a prefix
 282         argument) to print a .dvi file.
 283 tex-dvi-view-command
 284         Command string used by \\[tex-view] to preview a .dvi file.
 285 tex-show-queue-command
 286         Command string used by \\[tex-show-print-queue] to show the print
 287         queue that \\[tex-print] put your job on.
 288
 289 Entering Plain-tex mode calls the value of text-mode-hook, then the value of
 290 tex-mode-hook, and then the value of plain-tex-mode-hook.  When the special
 291 subshell is initiated, the value of tex-shell-hook is called."
 292   (interactive)
 293   (tex-common-initialization)
 294   (setq mode-name "TeX")
 295   (setq major-mode 'plain-tex-mode)
 296   (setq tex-command tex-run-command)
 297   (setq tex-start-of-header "%**start of header")
 298   (setq tex-end-of-header "%**end of header")
 299   (setq tex-trailer "\\bye\n")
 300   (run-hooks 'text-mode-hook 'tex-mode-hook 'plain-tex-mode-hook))
 301 ;;;###autoload
 302 (fset 'plain-TeX-mode 'plain-tex-mode)
 303
 304 ;;;###autoload
 305 (defun latex-mode ()
 306   "Major mode for editing files of input for LaTeX.
 307 Makes $ and } display the characters they match.
 308 Makes \" insert `` when it seems to be the beginning of a quotation,
 309 and '' when it appears to be the end; it inserts \" only after a \\.
 310
 311 Use \\[tex-region] to run LaTeX on the current region, plus the preamble
 312 copied from the top of the file (containing \\documentstyle, etc.),
 313 running LaTeX under a special subshell.  \\[tex-buffer] does the whole buffer.
 314 \\[tex-file] saves the buffer and then processes the file.
 315 \\[tex-print] prints the .dvi file made by any of these.
 316 \\[tex-view] previews the .dvi file made by any of these.
 317 \\[tex-bibtex-file] runs bibtex on the file of the current buffer.
 318
 319 Use \\[validate-tex-buffer] to check buffer for paragraphs containing
 320 mismatched $'s or braces.
 321
 322 Special commands:
 323 \\{tex-mode-map}
 324
 325 Mode variables:
 326 latex-run-command
 327         Command string used by \\[tex-region] or \\[tex-buffer].
 328 tex-directory
 329         Directory in which to create temporary files for LaTeX jobs
 330         run by \\[tex-region] or \\[tex-buffer].
 331 tex-dvi-print-command
 332         Command string used by \\[tex-print] to print a .dvi file.
 333 tex-alt-dvi-print-command
 334         Alternative command string used by \\[tex-print] (when given a prefix
 335         argument) to print a .dvi file.
 336 tex-dvi-view-command
 337         Command string used by \\[tex-view] to preview a .dvi file.
 338 tex-show-queue-command
 339         Command string used by \\[tex-show-print-queue] to show the print
 340         queue that \\[tex-print] put your job on.
 341
 342 Entering Latex mode calls the value of text-mode-hook, then the value of
 343 tex-mode-hook, and then the value of latex-mode-hook.  When the special
 344 subshell is initiated, the value of tex-shell-hook is called."
 345   (interactive)
 346   (tex-common-initialization)
 347   (setq mode-name "LaTeX")
 348   (setq major-mode 'latex-mode)
 349   (setq tex-command latex-run-command)
 350   (setq tex-start-of-header "\\documentstyle")
 351   (setq tex-end-of-header "\\begin{document}")
 352   (setq tex-trailer "\\end{document}\n")
 353   (run-hooks 'text-mode-hook 'tex-mode-hook 'latex-mode-hook))
 354
 355 (defun slitex-mode ()
 356   "Major mode for editing files of input for SliTeX.
 357 Makes $ and } display the characters they match.
 358 Makes \" insert `` when it seems to be the beginning of a quotation,
 359 and '' when it appears to be the end; it inserts \" only after a \\.
 360
 361 Use \\[tex-region] to run SliTeX on the current region, plus the preamble
 362 copied from the top of the file (containing \\documentstyle, etc.),
 363 running SliTeX under a special subshell.  \\[tex-buffer] does the whole buffer.
 364 \\[tex-file] saves the buffer and then processes the file.
 365 \\[tex-print] prints the .dvi file made by any of these.
 366 \\[tex-view] previews the .dvi file made by any of these.
 367 \\[tex-bibtex-file] runs bibtex on the file of the current buffer.
 368
 369 Use \\[validate-tex-buffer] to check buffer for paragraphs containing
 370 mismatched $'s or braces.
 371
 372 Special commands:
 373 \\{tex-mode-map}
 374
 375 Mode variables:
 376 slitex-run-command
 377         Command string used by \\[tex-region] or \\[tex-buffer].
 378 tex-directory
 379         Directory in which to create temporary files for SliTeX jobs
 380         run by \\[tex-region] or \\[tex-buffer].
 381 tex-dvi-print-command
 382         Command string used by \\[tex-print] to print a .dvi file.
 383 tex-alt-dvi-print-command
 384         Alternative command string used by \\[tex-print] (when given a prefix
 385         argument) to print a .dvi file.
 386 tex-dvi-view-command
 387         Command string used by \\[tex-view] to preview a .dvi file.
 388 tex-show-queue-command
 389         Command string used by \\[tex-show-print-queue] to show the print
 390         queue that \\[tex-print] put your job on.
 391
 392 Entering SliTeX mode calls the value of text-mode-hook, then the value of
 393 tex-mode-hook, then the value of latex-mode-hook, and then the value of
 394 slitex-mode-hook.  When the special subshell is initiated, the value of
 395 tex-shell-hook is called."
 396   (interactive)
 397   (tex-common-initialization)
 398   (setq mode-name "SliTeX")
 399   (setq major-mode 'slitex-mode)
 400   (setq tex-command slitex-run-command)
 401   (setq tex-start-of-header "\\documentstyle{slides}")
 402   (setq tex-end-of-header "\\begin{document}")
 403   (setq tex-trailer "\\end{document}\n")
 404   (run-hooks
 405    'text-mode-hook 'tex-mode-hook 'latex-mode-hook 'slitex-mode-hook))
 406
 407 (defun tex-common-initialization ()
 408   (kill-all-local-variables)
 409   (use-local-map tex-mode-map)
 410   (setq local-abbrev-table text-mode-abbrev-table)
 411   (if (null tex-mode-syntax-table)
 412       (let ((char 0))
 413         (setq tex-mode-syntax-table (make-syntax-table))
 414         (set-syntax-table tex-mode-syntax-table)
 415         (while (< char ? )
 416           (modify-syntax-entry char ".")
 417           (setq char (1+ char)))
 418         (modify-syntax-entry ?\C-@ "w")
 419         (modify-syntax-entry ?\t " ")
 420         (modify-syntax-entry ?\n ">")
 421         (modify-syntax-entry ?\f ">")
 422         (modify-syntax-entry ?$ "$$")
 423         (modify-syntax-entry ?% "<")
 424         (modify-syntax-entry ?\\ "/")
 425         (modify-syntax-entry ?\" ".")
 426         (modify-syntax-entry ?& ".")
 427         (modify-syntax-entry ?_ ".")
 428         (modify-syntax-entry ?@ "_")
 429         (modify-syntax-entry ?~ " ")
 430         (modify-syntax-entry ?' "w"))
 431     (set-syntax-table tex-mode-syntax-table))
 432   (make-local-variable 'paragraph-start)
 433   (setq paragraph-start "^[ \t]*$\\|^[\f\\\\%]")
 434   (make-local-variable 'paragraph-separate)
 435   (setq paragraph-separate paragraph-start)
 436   (make-local-variable 'comment-start)
 437   (setq comment-start "%")
 438   (make-local-variable 'comment-start-skip)
 439   (setq comment-start-skip "\\(\\(^\\|[^\\]\\)\\(\\\\\\\\\\)*\\)\\(%+ *\\)")
 440   (make-local-variable 'comment-indent-hook)
 441   (setq comment-indent-hook 'tex-comment-indent)
 442   (make-local-variable 'compare-windows-whitespace)
 443   (setq compare-windows-whitespace 'tex-categorize-whitespace)
 444   (make-local-variable 'tex-command)
 445   (make-local-variable 'tex-start-of-header)
 446   (make-local-variable 'tex-end-of-header)
 447   (make-local-variable 'tex-trailer))
 448
 449 (defun tex-comment-indent ()
 450   (if (looking-at "%%%")
 451       (current-column)
 452     (skip-chars-backward " \t")
 453     (max (if (bolp) 0 (1+ (current-column)))
 454          comment-column)))
 455
 456 (defun tex-categorize-whitespace (backward-limit)
 457   ;; compare-windows-whitespace is set to this.
 458   ;; This is basically a finite-state machine.
 459   ;; Returns a symbol telling how TeX would treat
 460   ;; the whitespace we are looking at: null, space, or par.
 461   (let ((category 'null)
 462         (not-finished t))
 463     (skip-chars-backward " \t\n\f" backward-limit)
 464     (while not-finished
 465       (cond ((looking-at "[ \t]+")
 466              (goto-char (match-end 0))
 467              (if (eql category 'null)
 468                  (setq category 'space)))
 469             ((looking-at "\n")
 470              (cond ((eql category 'newline)
 471                     (setq category 'par)
 472                     (setq not-finished nil))
 473                    (t
 474                     (setq category 'newline) ;a strictly internal state
 475                     (goto-char (match-end 0)))))
 476             ((looking-at "\f+")
 477              (setq category 'par)
 478              (setq not-finished nil))
 479             (t
 480              (setq not-finished nil))))
 481     (skip-chars-forward " \t\n\f")
 482     (if (eql category 'newline)
 483         'space                          ;TeX doesn't distinguish
 484       category)))
 485
 486 (defun tex-insert-quote (arg)
 487   "Insert the appropriate quote marks for TeX.
 488 Inserts the value of tex-open-quote (normally ``) or tex-close-quote
 489 (normally '') depending on the context.  With prefix argument, always
 490 inserts \" characters."
 491   (interactive "*P")
 492   (if arg
 493       (self-insert-command (prefix-numeric-value arg))
 494     (insert
 495      (cond ((or (bobp)
 496                 (save-excursion
 497                   (forward-char -1)
 498                   (looking-at "\\s(\\|\\s \\|\\s>")))
 499             tex-open-quote)
 500            ((= (preceding-char) ?\\)
 501             ?\")
 502            (t
 503             tex-close-quote)))))
 504
 505 (defun validate-tex-buffer ()
 506   "Check current buffer for paragraphs containing mismatched $'s.
 507 As each such paragraph is found, a mark is pushed at its beginning,
 508 and the location is displayed for a few seconds."
 509   (interactive)
 510   (let ((opoint (point)))
 511     (goto-char (point-max))
 512     ;; Does not use save-excursion
 513     ;; because we do not want to save the mark.
 514     (unwind-protect
 515         (while (and (not (input-pending-p)) (not (bobp)))
 516           (let ((end (point)))
 517             (search-backward "\n\n" nil 'move)
 518             (or (tex-validate-region (point) end)
 519                 (progn
 520                   (push-mark (point))
 521                   (message "Mismatch found in pararaph starting here")
 522                   (sit-for 4)))))
 523       (goto-char opoint))))
 524
 525 (defun tex-validate-region (start end)
 526   "Check for mismatched braces or $'s in region.
 527 Returns t if no mismatches.  Returns nil and moves point to suspect
 528 area if a mismatch is found."
 529   (interactive "r")
 530   (let ((failure-point nil) (max-possible-sexps (- end start)))
 531     (save-excursion
 532       (condition-case ()
 533           (save-restriction
 534             (narrow-to-region start end)
 535             (goto-char start)
 536             (while (< 0 (setq max-possible-sexps (1- max-possible-sexps)))
 537               (forward-sexp 1)))
 538         (error
 539           (setq failure-point (point)))))
 540     (if failure-point
 541         (progn
 542           (goto-char failure-point)
 543           nil)
 544       t)))
 545
 546 (defun tex-terminate-paragraph (inhibit-validation)
 547   "Insert two newlines, breaking a paragraph for TeX.
 548 Check for mismatched braces/$'s in paragraph being terminated.
 549 A prefix arg inhibits the checking."
 550   (interactive "*P")
 551   (or inhibit-validation
 552       (save-excursion
 553         (tex-validate-region
 554           (save-excursion
 555             (search-backward "\n\n" nil 'move)
 556             (point))
 557           (point)))
 558       (message "Paragraph being closed appears to contain a mismatch"))
 559   (insert "\n\n"))
 560
 561 (defun tex-insert-braces ()
 562   "Make a pair of braces and be poised to type inside of them."
 563   (interactive "*")
 564   (insert ?\{)
 565   (save-excursion
 566     (insert ?})))
 567
 568 ;;; Like tex-insert-braces, but for LaTeX.
 569 (defun tex-latex-block (name)
 570   "Creates a matching pair of lines \\begin{NAME} and \\end{NAME} at point.
 571 Puts point on a blank line between them."
 572   (interactive
 573    (prog2
 574       (barf-if-buffer-read-only)
 575       (list
 576        (completing-read "LaTeX block name: "
 577                         (mapcar 'list
 578                                 (append standard-latex-block-names
 579                                         latex-block-names))))))
 580   (let ((col (current-column)))
 581     (insert (format "\\begin{%s}\n" name))
 582     (indent-to col)
 583     (save-excursion
 584       (insert ?\n)
 585       (indent-to col)
 586       (insert-string (format "\\end{%s}" name))
 587       (if (eobp) (insert ?\n)))))
 588
 589 (defun tex-last-unended-begin ()
 590   "Leave point at the beginning of the last \\begin{...} that is unended."
 591   (while (and (re-search-backward "\\(\\\\begin\\s *{\\)\\|\\(\\\\end\\s *{\\)")
 592               (looking-at "\\\\end{"))
 593     (tex-last-unended-begin)))
 594
 595 (defun tex-close-latex-block ()
 596   "Creates an \\end{...} to match the last unclosed \\begin{...}."
 597   (interactive "*")
 598   (let ((new-line-needed (bolp))
 599         text indentation)
 600     (save-excursion
 601       (condition-case nil
 602           (tex-last-unended-begin)
 603         (error (error "Couldn't find unended \\begin")))
 604       (setq indentation (current-column))
 605       (re-search-forward "\\\\begin\\(\\s *{[^}\n]*}\\)")
 606       (setq text (buffer-substring (match-beginning 1) (match-end 1))))
 607     (indent-to indentation)
 608     (insert "\\end" text)
 609     (if new-line-needed (insert ?\n))))
 610 \f
 611 ;;; Invoking TeX in an inferior shell.
 612
 613 ;;; Why use a shell instead of running TeX directly?  Because if TeX
 614 ;;; gets stuck, the user can switch to the shell window and type at it.
 615
 616 ;;; The utility functions:
 617
 618 (defun tex-start-shell ()
 619   (save-excursion
 620     (set-buffer
 621      (make-comint
 622       "tex-shell"
 623       (or tex-shell-file-name (getenv "ESHELL") (getenv "SHELL") "/bin/sh")
 624       nil "-v"))
 625     (let ((proc (get-process "tex-shell")))
 626       (set-process-sentinel proc 'tex-shell-sentinel)
 627       (process-kill-without-query proc)
 628       (setq tex-shell-map (copy-keymap comint-mode-map))
 629       (tex-define-common-keys tex-shell-map)
 630       (use-local-map tex-shell-map)
 631       (run-hooks 'tex-shell-hook)
 632       (while (zerop (buffer-size))
 633           (sleep-for 1)))))
 634
 635 (defun tex-shell-sentinel (proc msg)
 636   (cond ((null (buffer-name (process-buffer proc)))
 637          ;; buffer killed
 638          (set-process-buffer proc nil)
 639          (tex-delete-last-temp-files))
 640         ((memq (process-status proc) '(signal exit))
 641          (tex-delete-last-temp-files))))
 642
 643 (defun tex-set-buffer-directory (buffer directory)
 644   "Set BUFFER's default directory to be DIRECTORY."
 645   (setq directory (file-name-as-directory (expand-file-name directory)))
 646   (if (not (file-directory-p directory))
 647       (error "%s is not a directory" directory)
 648     (save-excursion
 649       (set-buffer buffer)
 650       (setq default-directory directory))))
 651
 652 (defun tex-send-command (command &optional file background)
 653   "Send COMMAND to tex-shell, substituting optional FILE for *; in background
 654 if optional BACKGROUND is t.   If COMMAND has no *, FILE will be appended,
 655 preceded by a blank, to COMMAND.  If FILE is nil, no substitution will be made
 656 in COMMAND.  COMMAND can be any expression that evaluates to a command string."
 657   (save-excursion
 658     (let* ((cmd (eval command))
 659            (star (string-match "\\*" cmd)))
 660       (comint-proc-query (get-process "tex-shell")
 661                          (concat (substring cmd 0 star)
 662                                  (if file (concat " " file) "")
 663                                  (if star (substring cmd (1+ star) nil) "")
 664                                  (if background "&\n" "\n"))))))
 665
 666 (defun tex-delete-last-temp-files ()
 667   "Delete any junk files from last temp file."
 668   (if tex-last-temp-file
 669       (let* ((dir (file-name-directory tex-last-temp-file))
 670              (list (file-name-all-completions
 671                     (file-name-nondirectory tex-last-temp-file) dir)))
 672         (while list
 673           (delete-file (concat dir (car list)))
 674           (setq list (cdr list))))))
 675
 676 (add-hook 'kill-emacs-hook 'tex-delete-last-temp-files)
 677
 678 ;;; The commands:
 679
 680 (defun tex-region (beg end)
 681   "Run TeX on the current region, via a temporary file.
 682 The file's name comes from the variable `tex-zap-file' and the
 683 variable `tex-directory' says where to put it.
 684
 685 If the buffer has a header, the header is given to TeX before the
 686 region itself.  The buffer's header is all lines between the strings
 687 defined by `tex-start-of-header' and `tex-end-of-header' inclusive.
 688 The header must start in the first 100 lines of the buffer.
 689
 690 The value of `tex-trailer' is given to TeX as input after the region.
 691
 692 The value of `tex-command' specifies the command to use to run TeX."
 693   (interactive "r")
 694   (if (tex-shell-running)
 695       (tex-kill-job)
 696     (tex-start-shell))
 697   (or tex-zap-file
 698       (setq tex-zap-file (tex-generate-zap-file-name)))
 699   (let* ((temp-buffer (get-buffer-create " TeX-Output-Buffer"))
 700          ; Temp file will be written and TeX will be run in zap-directory.
 701          ; If the TEXINPUTS file has relative directories or if the region has
 702          ; \input of files, this must be the same directory as the file for
 703          ; TeX to access the correct inputs.  That's why it's safest if
 704          ; tex-directory is ".".
 705          (zap-directory
 706           (file-name-as-directory (expand-file-name tex-directory)))
 707          (tex-out-file (concat zap-directory tex-zap-file)))
 708     (tex-delete-last-temp-files)
 709     ;; Write the new temp file.
 710     (save-excursion
 711       (save-restriction
 712         (widen)
 713         (goto-char (point-min))
 714         (forward-line 100)
 715         (let ((search-end (point))
 716               (hbeg (point-min)) (hend (point-min))
 717               (default-directory zap-directory))
 718           (goto-char (point-min))
 719           ;; Initialize the temp file with either the header or nothing
 720           (if (search-forward tex-start-of-header search-end t)
 721               (progn
 722                 (beginning-of-line)
 723                 (setq hbeg (point))     ;mark beginning of header
 724                 (if (search-forward tex-end-of-header nil t)
 725                     (progn (forward-line 1)
 726                            (setq hend (point))) ;mark end of header
 727                   (setq hbeg (point-min))))) ;no header
 728           (write-region (min hbeg beg) hend
 729                         (concat tex-out-file ".tex") nil nil)
 730           (write-region (max beg hend) end (concat tex-out-file ".tex") t nil))
 731         (let ((local-tex-trailer tex-trailer))
 732           (set-buffer temp-buffer)
 733           (erase-buffer)
 734           ;; make sure trailer isn't hidden by a comment
 735           (insert-string "\n")
 736           (if local-tex-trailer (insert-string local-tex-trailer))
 737           (tex-set-buffer-directory temp-buffer zap-directory)
 738           (write-region (point-min) (point-max)
 739                         (concat tex-out-file ".tex") t nil))))
 740     ;; Record the file name to be deleted afterward.
 741     (setq tex-last-temp-file tex-out-file)
 742     (tex-send-command tex-shell-cd-command zap-directory)
 743     (tex-send-command tex-command tex-out-file)
 744     (setq tex-print-file tex-out-file)
 745     (setq tex-last-buffer-texed (current-buffer))))
 746
 747 (defun tex-buffer ()
 748   "Run TeX on current buffer.  See \\[tex-region] for more information.
 749 Does not save the buffer, so it's useful for trying experimental versions.
 750 See \\[tex-file] for an alternative."
 751   (interactive)
 752   (tex-region (point-min) (point-max)))
 753
 754 (defun tex-file ()
 755   "Prompt to save all buffers and run TeX (or LaTeX) on current buffer's file.
 756 This function is more useful than \\[tex-buffer] when you need the
 757 `.aux' file of LaTeX to have the correct name."
 758   (interactive)
 759   (let ((tex-out-file
 760          (if (buffer-file-name)
 761              (file-name-nondirectory (buffer-file-name))
 762            (error "Buffer does not seem to be associated with any file")))
 763         (file-dir (file-name-directory (buffer-file-name))))
 764     (if tex-offer-save
 765         (save-some-buffers))
 766     (if (tex-shell-running)
 767         (tex-kill-job)
 768       (tex-start-shell))
 769     (tex-send-command tex-shell-cd-command file-dir)
 770     (tex-send-command tex-command tex-out-file))
 771   (setq tex-last-buffer-texed (current-buffer))
 772   (setq tex-print-file (buffer-file-name)))
 773
 774 (defun tex-generate-zap-file-name ()
 775   "Generate a unique name suitable for use as a file name."
 776   ;; Include the shell process number and host name
 777   ;; in case there are multiple shells (for same or different user).
 778   (format "#tz%d%s"
 779           (process-id (get-buffer-process "*tex-shell*"))
 780           (tex-strip-dots (system-name))))
 781
 782 (defun tex-strip-dots (s)
 783   (setq s (copy-sequence s))
 784   (while (string-match "\\." s)
 785     (aset s (match-beginning 0) ?-))
 786   s)
 787
 788 ;; This will perhaps be useful for modifying TEXINPUTS.
 789 ;; Expand each file name, separated by colons, in the string S.
 790 (defun tex-expand-files (s)
 791   (let (elts (start 0))
 792     (while (string-match ":" s start)
 793       (setq elts (cons (substring s start (match-beginning 0)) elts))
 794       (setq start (match-end 0)))
 795     (or (= start 0)
 796         (setq elts (cons (substring s start) elts)))
 797     (mapconcat 'expand-file-name (nreverse elts) ":")))
 798
 799 (defun tex-shell-running ()
 800   (and (get-process "tex-shell")
 801        (eq (process-status (get-process "tex-shell")) 'run)))
 802
 803 (defun tex-kill-job ()
 804   "Kill the currently running TeX job."
 805   (interactive)
 806   (quit-process (get-process "tex-shell") t))
 807
 808 (defun tex-recenter-output-buffer (linenum)
 809   "Redisplay buffer of TeX job output so that most recent output can be seen.
 810 The last line of the buffer is displayed on
 811 line LINE of the window, or centered if LINE is nil."
 812   (interactive "P")
 813   (let ((tex-shell (get-buffer "*tex-shell*"))
 814         (old-buffer (current-buffer)))
 815     (if (null tex-shell)
 816         (message "No TeX output buffer")
 817       (pop-to-buffer tex-shell)
 818       (bury-buffer tex-shell)
 819       (goto-char (point-max))
 820       (recenter (if linenum
 821                     (prefix-numeric-value linenum)
 822                   (/ (window-height) 2)))
 823       (pop-to-buffer old-buffer))))
 824
 825 (defun tex-print (&optional alt)
 826   "Print the .dvi file made by \\[tex-region], \\[tex-buffer] or \\[tex-file].
 827 Runs the shell command defined by `tex-dvi-print-command'.  If prefix argument
 828 is provided, use the alternative command, `tex-alt-dvi-print-command'."
 829   (interactive "P")
 830   (let ((print-file-name-dvi (tex-append tex-print-file ".dvi"))
 831         test-name)
 832     (if (and (not (equal (current-buffer) tex-last-buffer-texed))
 833              (file-newer-than-file-p
 834               (setq test-name (tex-append (buffer-file-name) ".dvi"))
 835               print-file-name-dvi))
 836         (setq print-file-name-dvi test-name))
 837     (if (not (file-exists-p print-file-name-dvi))
 838         (error "No appropriate `.dvi' file could be found")
 839       (tex-send-command
 840         (if alt tex-alt-dvi-print-command tex-dvi-print-command)
 841         print-file-name-dvi t))))
 842
 843 (defun tex-view ()
 844   "Preview the last `.dvi' file made by running TeX under Emacs.
 845 This means, made using \\[tex-region], \\[tex-buffer] or \\[tex-file].
 846 The variable `tex-dvi-view-command' specifies the shell command for preview."
 847   (interactive)
 848   (let ((tex-dvi-print-command tex-dvi-view-command))
 849     (tex-print)))
 850
 851 (defun tex-append (file-name suffix)
 852   "Append to FILENAME the suffix SUFFIX, using same algorithm TeX uses.
 853 Scans for the first (not last) period.
 854 No period is retained immediately before SUFFIX,
 855 so normally SUFFIX starts with one."
 856   (if (stringp file-name)
 857       (let ((file (file-name-nondirectory file-name)))
 858         (concat (file-name-directory file-name)
 859                 (substring file 0
 860                            (string-match "\\." file))
 861                 suffix))
 862     " "))
 863
 864 (defun tex-show-print-queue ()
 865   "Show the print queue that \\[tex-print] put your job on.
 866 Runs the shell command defined by `tex-show-queue-command'."
 867   (interactive)
 868   (if (tex-shell-running)
 869       (tex-kill-job)
 870     (tex-start-shell))
 871   (tex-send-command tex-show-queue-command))
 872
 873 (defun tex-bibtex-file ()
 874   "Run BibTeX on the current buffer's file."
 875   (interactive)
 876   (if (tex-shell-running)
 877       (tex-kill-job)
 878     (tex-start-shell))
 879   (let ((tex-out-file
 880          (tex-append (file-name-nondirectory (buffer-file-name)) ""))
 881         (file-dir (file-name-directory (buffer-file-name))))
 882     (tex-send-command tex-shell-cd-command file-dir)
 883     (tex-send-command bibtex-command tex-out-file)))
 884
 885 (run-hooks 'tex-mode-load-hook)
 886
 887 (provide 'tex-mode)
 888
 889 ;;; tex-mode.el ends here
 890