lisp/faces.el

   1 ;;; faces.el --- Lisp faces
   2
   3 ;; Copyright (C) 1992, 1993, 1994, 1995, 1996, 1998, 1999, 2000
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile
  28   (require 'cl)
  29   ;; Warning suppression -- can't require x-win in batch:
  30   (autoload 'xw-defined-colors "x-win"))
  31
  32 (require 'cus-face)
  33
  34 \f
  35 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  36 ;;; Font selection.
  37 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  38
  39 (defgroup font-selection nil
  40   "Influencing face font selection."
  41   :group 'faces)
  42
  43
  44 (defcustom face-font-selection-order
  45   '(:width :height :weight :slant)
  46   "*A list specifying how face font selection chooses fonts.
  47 Each of the four symbols `:width', `:height', `:weight', and `:slant'
  48 must appear once in the list, and the list must not contain any other
  49 elements.  Font selection tries to find a best matching font for
  50 those face attributes first that appear first in the list.  For
  51 example, if `:slant' appears before `:height', font selection first
  52 tries to find a font with a suitable slant, even if this results in
  53 a font height that isn't optimal."
  54   :tag "Font selection order."
  55   :type '(list symbol symbol symbol symbol)
  56   :group 'font-selection
  57   :set #'(lambda (symbol value)
  58            (set-default symbol value)
  59            (internal-set-font-selection-order value)))
  60
  61 ;; This is defined originally in {w32,x}faces.c.
  62 (defcustom face-font-family-alternatives
  63   '(("courier" "fixed")
  64     ("helv" "helvetica" "arial" "fixed"))
  65   "*Alist of alternative font family names.
  66 Each element has the the form (FAMILY ALTERNATIVE1 ALTERNATIVE2 ...).
  67 If fonts of family FAMILY can't be loaded, try ALTERNATIVE1, then
  68 ALTERNATIVE2 etc."
  69   :tag "Alternative font families to try."
  70   :type '(repeat (repeat string))
  71   :group 'font-selection
  72   :set #'(lambda (symbol value)
  73            (set-default symbol value)
  74            (internal-set-alternative-font-family-alist value)))
  75
  76
  77 \f
  78 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  79 ;;; Creation, copying.
  80 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  81
  82
  83 (defun face-list ()
  84   "Return a list of all defined face names."
  85   (mapcar #'car face-new-frame-defaults))
  86
  87
  88 ;;; ### If not frame-local initialize by what X resources?
  89
  90 (defun make-face (face &optional no-init-from-resources)
  91   "Define a new face with name FACE, a symbol.
  92 NO-INIT-FROM-RESOURCES non-nil means don't initialize frame-local
  93 variants of FACE from X resources.  (X resources recognized are found
  94 in the global variable `face-x-resources'.)  If FACE is already known
  95 as a face, leave it unmodified.  Value is FACE."
  96   (interactive "SMake face: ")
  97   (unless (facep face)
  98     ;; Make frame-local faces (this also makes the global one).
  99     (dolist (frame (frame-list))
 100       (internal-make-lisp-face face frame))
 101     ;; Add the face to the face menu.
 102     (when (fboundp 'facemenu-add-new-face)
 103       (facemenu-add-new-face face))
 104     ;; Define frame-local faces for all frames from X resources.
 105     (unless no-init-from-resources
 106       (make-face-x-resource-internal face)))
 107   face)
 108
 109
 110 (defun make-empty-face (face)
 111   "Define a new, empty face with name FACE.
 112 If the face already exists, it is left unmodified.  Value is FACE."
 113   (interactive "SMake empty face: ")
 114   (make-face face 'no-init-from-resources))
 115
 116
 117 (defun copy-face (old-face new-face &optional frame new-frame)
 118   "Define a face just like OLD-FACE, with name NEW-FACE.
 119
 120 If NEW-FACE already exists as a face, it is modified to be like
 121 OLD-FACE.  If it doesn't already exist, it is created.
 122
 123 If the optional argument FRAME is given as a frame,  NEW-FACE is
 124 changed on FRAME only.
 125 If FRAME is t, the frame-independent default specification for OLD-FACE
 126 is copied to NEW-FACE.
 127 If FRAME is nil, copying is done for the frame-independent defaults
 128 and for each existing frame.
 129
 130 If the optional fourth argument NEW-FRAME is given,
 131 copy the information from face OLD-FACE on frame FRAME
 132 to NEW-FACE on frame NEW-FRAME."
 133   (let ((inhibit-quit t))
 134     (if (null frame)
 135         (progn
 136           (dolist (frame (frame-list))
 137             (copy-face old-face new-face frame))
 138           (copy-face old-face new-face t))
 139       (internal-copy-lisp-face old-face new-face frame new-frame))
 140     new-face))
 141
 142
 143 \f
 144 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 145 ;;; Obsolete functions
 146 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 147
 148 ;; The functions in this section are defined because Lisp packages use
 149 ;; them, despite the prefix `internal-' suggesting that they are
 150 ;; private to the face implementation.
 151
 152 (defun internal-find-face (name &optional frame)
 153   "Retrieve the face named NAME.
 154 Return nil if there is no such face.
 155 If the optional argument FRAME is given, this gets the face NAME for
 156 that frame; otherwise, it uses the selected frame.
 157 If FRAME is the symbol t, then the global, non-frame face is returned.
 158 If NAME is already a face, it is simply returned.
 159
 160 This function is defined for compatibility with Emacs 20.2.  It
 161 should not be used anymore."
 162   (facep name))
 163 (make-obsolete 'internal-find-face 'facep "21.1")
 164
 165
 166 (defun internal-get-face (name &optional frame)
 167   "Retrieve the face named NAME; error if there is none.
 168 If the optional argument FRAME is given, this gets the face NAME for
 169 that frame; otherwise, it uses the selected frame.
 170 If FRAME is the symbol t, then the global, non-frame face is returned.
 171 If NAME is already a face, it is simply returned.
 172
 173 This function is defined for compatibility with Emacs 20.2.  It
 174 should not be used anymore."
 175   (or (internal-find-face name frame)
 176       (check-face name)))
 177 (make-obsolete 'internal-get-face "See `facep' and `check-face'." "21.1")
 178
 179 \f
 180 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 181 ;;; Predicates, type checks.
 182 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 183
 184 (defun facep (face)
 185   "Return non-nil if FACE is a face name."
 186   (internal-lisp-face-p face))
 187
 188
 189 (defun check-face (face)
 190   "Signal an error if FACE doesn't name a face.
 191 Value is FACE."
 192   (unless (facep face)
 193     (error "Not a face: %s" face))
 194   face)
 195
 196
 197 ;; The ID returned is not to be confused with the internally used IDs
 198 ;; of realized faces.  The ID assigned to Lisp faces is used to
 199 ;; support faces in display table entries.
 200
 201 (defun face-id (face &optional frame)
 202   "Return the interNal ID of face with name FACE.
 203 If optional argument FRAME is nil or omitted, use the selected frame."
 204   (check-face face)
 205   (get face 'face))
 206
 207
 208 (defun face-equal (face1 face2 &optional frame)
 209   "Non-nil if faces FACE1 and FACE2 are equal.
 210 Faces are considered equal if all their attributes are equal.
 211 If the optional argument FRAME is given, report on face FACE in that frame.
 212 If FRAME is t, report on the defaults for face FACE (for new frames).
 213 If FRAME is omitted or nil, use the selected frame."
 214   (internal-lisp-face-equal-p face1 face2 frame))
 215
 216
 217 (defun face-differs-from-default-p (face &optional frame)
 218   "Non-nil if FACE displays differently from the default face.
 219 If the optional argument FRAME is given, report on face FACE in that frame.
 220 If FRAME is t, report on the defaults for face FACE (for new frames).
 221 If FRAME is omitted or nil, use the selected frame.
 222 A face is considered to be ``the same'' as the default face if it is
 223 actually specified in the same way (equal attributes) or if it is
 224 fully-unspecified, and thus inherits the attributes of any face it
 225 is displayed on top of."
 226   (cond ((eq frame t) (setq frame nil))
 227         ((null frame) (setq frame (selected-frame))))
 228   (let* ((v1 (internal-lisp-face-p face frame))
 229          (n (if v1 (length v1) 0))
 230          (v2 (internal-lisp-face-p 'default frame))
 231          (i 1))
 232     (unless v1
 233       (error "Not a face: %S" face))
 234     (while (and (< i n)
 235                 (or (eq 'unspecified (aref v1 i))
 236                     (equal (aref v1 i) (aref v2 i))))
 237       (setq i (1+ i)))
 238     (< i n)))
 239
 240
 241 (defun face-nontrivial-p (face &optional frame)
 242   "True if face FACE has some non-nil attribute.
 243 If the optional argument FRAME is given, report on face FACE in that frame.
 244 If FRAME is t, report on the defaults for face FACE (for new frames).
 245 If FRAME is omitted or nil, use the selected frame."
 246   (not (internal-lisp-face-empty-p face frame)))
 247
 248
 249 \f
 250 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 251 ;;; Setting face attributes from X resources.
 252 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 253
 254 (defcustom face-x-resources
 255   '((:family (".attributeFamily" . "Face.AttributeFamily"))
 256     (:width (".attributeWidth" . "Face.AttributeWidth"))
 257     (:height (".attributeHeight" . "Face.AttributeHeight"))
 258     (:weight (".attributeWeight" . "Face.AttributeWeight"))
 259     (:slant (".attributeSlant" . "Face.AttributeSlant"))
 260     (:foreground (".attributeForeground" . "Face.AttributeForeground"))
 261     (:background (".attributeBackground" . "Face.AttributeBackground"))
 262     (:overline (".attributeOverline" . "Face.AttributeOverline"))
 263     (:strike-through (".attributeStrikeThrough" . "Face.AttributeStrikeThrough"))
 264     (:box (".attributeBox" . "Face.AttributeBox"))
 265     (:underline (".attributeUnderline" . "Face.AttributeUnderline"))
 266     (:inverse-video (".attributeInverse" . "Face.AttributeInverse"))
 267     (:stipple
 268      (".attributeStipple" . "Face.AttributeStipple")
 269      (".attributeBackgroundPixmap" . "Face.AttributeBackgroundPixmap"))
 270     (:bold (".attributeBold" . "Face.AttributeBold"))
 271     (:italic (".attributeItalic" . "Face.AttributeItalic"))
 272     (:font (".attributeFont" . "Face.AttributeFont"))
 273     (:inherit (".attributeInherit" . "Face.AttributeInherit")))
 274   "*List of X resources and classes for face attributes.
 275 Each element has the form (ATTRIBUTE ENTRY1 ENTRY2...) where ATTRIBUTE is
 276 the name of a face attribute, and each ENTRY is a cons of the form
 277 (RESOURCE . CLASS) with RESOURCE being the resource and CLASS being the
 278 X resource class for the attribute."
 279   :type '(repeat (cons symbol (repeat (cons string string))))
 280   :group 'faces)
 281
 282
 283 (defun set-face-attribute-from-resource (face attribute resource class frame)
 284   "Set FACE's ATTRIBUTE from X resource RESOURCE, class CLASS on FRAME.
 285 Value is the attribute value specified by the resource, or nil
 286 if not present.  This function displays a message if the resource
 287 specifies an invalid attribute."
 288   (let* ((face-name (face-name face))
 289          (value (internal-face-x-get-resource (concat face-name resource)
 290                                               class frame)))
 291     (when value
 292       (condition-case ()
 293           (internal-set-lisp-face-attribute-from-resource
 294            face attribute (downcase value) frame)
 295         (error
 296          (message "Face %s, frame %s: invalid attribute %s %s from X resource"
 297                   face-name frame attribute value))))
 298     value))
 299
 300
 301 (defun set-face-attributes-from-resources (face frame)
 302   "Set attributes of FACE from X resources for FRAME."
 303   (when (memq (framep frame) '(x w32))
 304     (dolist (definition face-x-resources)
 305       (let ((attribute (car definition)))
 306         (dolist (entry (cdr definition))
 307           (set-face-attribute-from-resource face attribute (car entry)
 308                                             (cdr entry) frame))))))
 309
 310
 311 (defun make-face-x-resource-internal (face &optional frame)
 312   "Fill frame-local FACE on FRAME from X resources.
 313 FRAME nil or not specified means do it for all frames."
 314   (if (null frame)
 315       (dolist (frame (frame-list))
 316         (set-face-attributes-from-resources face frame))
 317     (set-face-attributes-from-resources face frame)))
 318
 319
 320 \f
 321 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 322 ;;; Retrieving face attributes.
 323 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 324
 325 (defun face-name (face)
 326   "Return the name of face FACE."
 327   (symbol-name (check-face face)))
 328
 329
 330 (defun face-attribute (face attribute &optional frame)
 331   "Return the value of FACE's ATTRIBUTE on FRAME.
 332 If the optional argument FRAME is given, report on face FACE in that frame.
 333 If FRAME is t, report on the defaults for face FACE (for new frames).
 334 If FRAME is omitted or nil, use the selected frame."
 335   (internal-get-lisp-face-attribute face attribute frame))
 336
 337
 338 (defun face-foreground (face &optional frame)
 339   "Return the foreground color name of FACE, or nil if unspecified.
 340 If the optional argument FRAME is given, report on face FACE in that frame.
 341 If FRAME is t, report on the defaults for face FACE (for new frames).
 342 If FRAME is omitted or nil, use the selected frame."
 343   (internal-get-lisp-face-attribute face :foreground frame))
 344
 345
 346 (defun face-background (face &optional frame)
 347   "Return the background color name of FACE, or nil if unspecified.
 348 If the optional argument FRAME is given, report on face FACE in that frame.
 349 If FRAME is t, report on the defaults for face FACE (for new frames).
 350 If FRAME is omitted or nil, use the selected frame."
 351   (internal-get-lisp-face-attribute face :background frame))
 352
 353
 354 (defun face-stipple (face &optional frame)
 355  "Return the stipple pixmap name of FACE, or nil if unspecified.
 356 If the optional argument FRAME is given, report on face FACE in that frame.
 357 If FRAME is t, report on the defaults for face FACE (for new frames).
 358 If FRAME is omitted or nil, use the selected frame."
 359   (internal-get-lisp-face-attribute face :stipple frame))
 360
 361
 362 (defalias 'face-background-pixmap 'face-stipple)
 363
 364
 365 (defun face-underline-p (face &optional frame)
 366  "Return non-nil if FACE is underlined.
 367 If the optional argument FRAME is given, report on face FACE in that frame.
 368 If FRAME is t, report on the defaults for face FACE (for new frames).
 369 If FRAME is omitted or nil, use the selected frame."
 370  (eq (face-attribute face :underline frame) t))
 371
 372
 373 (defun face-inverse-video-p (face &optional frame)
 374  "Return non-nil if FACE is in inverse video on FRAME.
 375 If the optional argument FRAME is given, report on face FACE in that frame.
 376 If FRAME is t, report on the defaults for face FACE (for new frames).
 377 If FRAME is omitted or nil, use the selected frame."
 378  (eq (face-attribute face :inverse-video frame) t))
 379
 380
 381 (defun face-bold-p (face &optional frame)
 382   "Return non-nil if the font of FACE is bold on FRAME.
 383 If the optional argument FRAME is given, report on face FACE in that frame.
 384 If FRAME is t, report on the defaults for face FACE (for new frames).
 385 If FRAME is omitted or nil, use the selected frame.
 386 Use `face-attribute' for finer control."
 387   (let ((bold (face-attribute face :weight frame)))
 388     (memq bold '(semi-bold bold extra-bold ultra-bold))))
 389
 390
 391 (defun face-italic-p (face &optional frame)
 392   "Return non-nil if the font of FACE is italic on FRAME.
 393 If the optional argument FRAME is given, report on face FACE in that frame.
 394 If FRAME is t, report on the defaults for face FACE (for new frames).
 395 If FRAME is omitted or nil, use the selected frame.
 396 Use `face-attribute' for finer control."
 397   (let ((italic (face-attribute face :slant frame)))
 398     (memq italic '(italic oblique))))
 399
 400
 401
 402
 403 \f
 404 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 405 ;;; Face documentation.
 406 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 407
 408 (defun face-documentation (face)
 409   "Get the documentation string for FACE."
 410   (get face 'face-documentation))
 411
 412
 413 (defun set-face-documentation (face string)
 414   "Set the documentation string for FACE to STRING."
 415   ;; Perhaps the text should go in DOC.
 416   (put face 'face-documentation (purecopy string)))
 417
 418
 419 (defalias 'face-doc-string 'face-documentation)
 420 (defalias 'set-face-doc-string 'set-face-documentation)
 421
 422
 423 \f
 424 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 425 ;; Setting face attributes.
 426 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 427
 428
 429 (defun set-face-attribute (face frame &rest args)
 430   "Set attributes of FACE on FRAME from ARGS.
 431
 432 FRAME nil means change attributes on all frames.  FRAME t means change
 433 the default for new frames (this is done automatically each time an
 434 attribute is changed on all frames).
 435
 436 ARGS must come in pairs ATTRIBUTE VALUE.  ATTRIBUTE must be a valid
 437 face attribute name.  All attributes can be set to `unspecified';
 438 this fact is not further mentioned below.
 439
 440 The following attributes are recognized:
 441
 442 `:family'
 443
 444 VALUE must be a string specifying the font family, e.g. ``courier'',
 445 or a fontset alias name.  If a font family is specified, wild-cards `*'
 446 and `?' are allowed.
 447
 448 `:width'
 449
 450 VALUE specifies the relative proportionate width of the font to use.
 451 It must be one of the symbols `ultra-condensed', `extra-condensed',
 452 `condensed', `semi-condensed', `normal', `semi-expanded', `expanded',
 453 `extra-expanded', or `ultra-expanded'.
 454
 455 `:height'
 456
 457 VALUE must be either an integer specifying the height of the font to use
 458 in 1/10 pt, a floating point number specifying the amount by which to
 459 scale any underlying face, or a function, which is called with the old
 460 height (from the underlying face), and should return the new height.
 461
 462 `:weight'
 463
 464 VALUE specifies the weight of the font to use.  It must be one of the
 465 symbols `ultra-bold', `extra-bold', `bold', `semi-bold', `normal',
 466 `semi-light', `light', `extra-light', `ultra-light'.
 467
 468 `:slant'
 469
 470 VALUE specifies the slant of the font to use.  It must be one of the
 471 symbols `italic', `oblique', `normal', `reverse-italic', or
 472 `reverse-oblique'.
 473
 474 `:foreground', `:background'
 475
 476 VALUE must be a color name, a string.
 477
 478 `:underline'
 479
 480 VALUE specifies whether characters in FACE should be underlined.  If
 481 VALUE is t, underline with foreground color of the face.  If VALUE is
 482 a string, underline with that color.  If VALUE is nil, explicitly
 483 don't underline.
 484
 485 `:overline'
 486
 487 VALUE specifies whether characters in FACE should be overlined.  If
 488 VALUE is t, overline with foreground color of the face.  If VALUE is a
 489 string, overline with that color.  If VALUE is nil, explicitly don't
 490 overline.
 491
 492 `:strike-through'
 493
 494 VALUE specifies whether characters in FACE should be drawn with a line
 495 striking through them.  If VALUE is t, use the foreground color of the
 496 face.  If VALUE is a string, strike-through with that color.  If VALUE
 497 is nil, explicitly don't strike through.
 498
 499 `:box'
 500
 501 VALUE specifies whether characters in FACE should have a box drawn
 502 around them.  If VALUE is nil, explicitly don't draw boxes.  If
 503 VALUE is t, draw a box with lines of width 1 in the foreground color
 504 of the face.  If VALUE is a string, the string must be a color name,
 505 and the box is drawn in that color with a line width of 1.  Otherwise,
 506 VALUE must be a property list of the form `(:line-width WIDTH
 507 :color COLOR :style STYLE)'.  If a keyword/value pair is missing from
 508 the property list, a default value will be used for the value, as
 509 specified below.  WIDTH specifies the width of the lines to draw; it
 510 defaults to 1.  COLOR is the name of the color to draw in, default is
 511 the foreground color of the face for simple boxes, and the background
 512 color of the face for 3D boxes.  STYLE specifies whether a 3D box
 513 should be draw.  If STYLE is `released-button', draw a box looking
 514 like a released 3D button.  If STYLE is `pressed-button' draw a box
 515 that appears like a pressed button.  If STYLE is nil, the default if
 516 the property list doesn't contain a style specification, draw a 2D
 517 box.
 518
 519 `:inverse-video'
 520
 521 VALUE specifies whether characters in FACE should be displayed in
 522 inverse video.  VALUE must be one of t or nil.
 523
 524 `:stipple'
 525
 526 If VALUE is a string, it must be the name of a file of pixmap data.
 527 The directories listed in the `x-bitmap-file-path' variable are
 528 searched.  Alternatively, VALUE may be a list of the form (WIDTH
 529 HEIGHT DATA) where WIDTH and HEIGHT are the size in pixels, and DATA
 530 is a string containing the raw bits of the bitmap.  VALUE nil means
 531 explicitly don't use a stipple pattern.
 532
 533 For convenience, attributes `:family', `:width', `:height', `:weight',
 534 and `:slant' may also be set in one step from an X font name:
 535
 536 `:font'
 537
 538 Set font-related face attributes from VALUE.  VALUE must be a valid
 539 XLFD font name.  If it is a font name pattern, the first matching font
 540 will be used.
 541
 542 For compatibility with Emacs 20, keywords `:bold' and `:italic' can
 543 be used to specify that a bold or italic font should be used.  VALUE
 544 must be t or nil in that case.  A value of `unspecified' is not allowed.
 545
 546 `:inherit'
 547
 548 VALUE is the name of a face from which to inherit attributes, or a list
 549 of face names.  Attributes from inherited faces are merged into the face
 550 like an underlying face would be, with higher priority than underlying faces."
 551   (let ((where (if (null frame) 0 frame)))
 552     (setq args (purecopy args))
 553     (while args
 554       (internal-set-lisp-face-attribute face (car args)
 555                                         (purecopy (cadr args))
 556                                         where)
 557       (setq args (cdr (cdr args))))))
 558
 559
 560 (defun make-face-bold (face &optional frame noerror)
 561   "Make the font of FACE be bold, if possible.
 562 FRAME nil or not specified means change face on all frames.
 563 Argument NOERROR is ignored and retained for compatibility.
 564 Use `set-face-attribute' for finer control of the font weight."
 565   (interactive (list (read-face-name "Make which face bold ")))
 566   (set-face-attribute face frame :weight 'bold))
 567
 568
 569 (defun make-face-unbold (face &optional frame noerror)
 570   "Make the font of FACE be non-bold, if possible.
 571 FRAME nil or not specified means change face on all frames.
 572 Argument NOERROR is ignored and retained for compatibility."
 573   (interactive (list (read-face-name "Make which face non-bold ")))
 574   (set-face-attribute face frame :weight 'normal))
 575
 576
 577 (defun make-face-italic (face &optional frame noerror)
 578   "Make the font of FACE be italic, if possible.
 579 FRAME nil or not specified means change face on all frames.
 580 Argument NOERROR is ignored and retained for compatibility.
 581 Use `set-face-attribute' for finer control of the font slant."
 582   (interactive (list (read-face-name "Make which face italic ")))
 583   (set-face-attribute face frame :slant 'italic))
 584
 585
 586 (defun make-face-unitalic (face &optional frame noerror)
 587   "Make the font of FACE be non-italic, if possible.
 588 FRAME nil or not specified means change face on all frames.
 589 Argument NOERROR is ignored and retained for compatibility."
 590   (interactive (list (read-face-name "Make which face non-italic ")))
 591   (set-face-attribute face frame :slant 'normal))
 592
 593
 594 (defun make-face-bold-italic (face &optional frame noerror)
 595   "Make the font of FACE be bold and italic, if possible.
 596 FRAME nil or not specified means change face on all frames.
 597 Argument NOERROR is ignored and retained for compatibility.
 598 Use `set-face-attribute' for finer control of font weight and slant."
 599   (interactive (list (read-face-name "Make which face bold-italic: ")))
 600   (set-face-attribute face frame :weight 'bold :slant 'italic))
 601
 602
 603 (defun set-face-font (face font &optional frame)
 604   "Change font-related attributes of FACE to those of FONT (a string).
 605 FRAME nil or not specified means change face on all frames.
 606 This sets the attributes `:family', `:width', `:height', `:weight',
 607 and `:slant'.  When called interactively, prompt for the face and font."
 608   (interactive (read-face-and-attribute :font))
 609   (set-face-attribute face frame :font font))
 610
 611
 612 ;; Implementation note: Emulating gray background colors with a
 613 ;; stipple pattern is now part of the face realization process, and is
 614 ;; done in C depending on the frame on which the face is realized.
 615
 616 (defun set-face-background (face color &optional frame)
 617   "Change the background color of face FACE to COLOR (a string).
 618 FRAME nil or not specified means change face on all frames.
 619 When called interactively, prompt for the face and color."
 620   (interactive (read-face-and-attribute :background))
 621   (set-face-attribute face frame :background color))
 622
 623
 624 (defun set-face-foreground (face color &optional frame)
 625   "Change the foreground color of face FACE to COLOR (a string).
 626 FRAME nil or not specified means change face on all frames.
 627 When called interactively, prompt for the face and color."
 628   (interactive (read-face-and-attribute :foreground))
 629   (set-face-attribute face frame :foreground color))
 630
 631
 632 (defun set-face-stipple (face stipple &optional frame)
 633   "Change the stipple pixmap of face FACE to STIPPLE.
 634 FRAME nil or not specified means change face on all frames.
 635 STIPPLE should be a string, the name of a file of pixmap data.
 636 The directories listed in the `x-bitmap-file-path' variable are searched.
 637
 638 Alternatively, STIPPLE may be a list of the form (WIDTH HEIGHT DATA)
 639 where WIDTH and HEIGHT are the size in pixels,
 640 and DATA is a string, containing the raw bits of the bitmap."
 641   (interactive (read-face-and-attribute :stipple))
 642   (set-face-attribute face frame :stipple stipple))
 643
 644
 645 (defun set-face-underline (face underline &optional frame)
 646   "Specify whether face FACE is underlined.
 647 UNDERLINE nil means FACE explicitly doesn't underline.
 648 UNDERLINE non-nil means FACE explicitly does underlining
 649 with the same of the foreground color.
 650 If UNDERLINE is a string, underline with the color named UNDERLINE.
 651 FRAME nil or not specified means change face on all frames.
 652 Use `set-face-attribute' to ``unspecify'' underlining."
 653   (interactive
 654    (let ((list (read-face-and-attribute :underline)))
 655      (list (car list) (eq (car (cdr list)) t))))
 656   (set-face-attribute face frame :underline underline))
 657
 658
 659 (defun set-face-underline-p (face underline-p &optional frame)
 660   "Specify whether face FACE is underlined.
 661 UNDERLINE-P nil means FACE explicitly doesn't underline.
 662 UNDERLINE-P non-nil means FACE explicitly does underlining.
 663 FRAME nil or not specified means change face on all frames.
 664 Use `set-face-attribute' to ``unspecify'' underlining."
 665   (interactive
 666    (let ((list (read-face-and-attribute :underline)))
 667      (list (car list) (eq (car (cdr list)) t))))
 668   (set-face-attribute face frame :underline underline-p))
 669
 670
 671 (defun set-face-inverse-video-p (face inverse-video-p &optional frame)
 672   "Specify whether face FACE is in inverse video.
 673 INVERSE-VIDEO-P non-nil means FACE displays explicitly in inverse video.
 674 INVERSE-VIDEO-P nil means FACE explicitly is not in inverse video.
 675 FRAME nil or not specified means change face on all frames.
 676 Use `set-face-attribute' to ``unspecify'' the inverse video attribute."
 677   (interactive
 678    (let ((list (read-face-and-attribute :inverse-video)))
 679      (list (car list) (eq (car (cdr list)) t))))
 680   (set-face-attribute face frame :inverse-video inverse-video-p))
 681
 682
 683 (defun set-face-bold-p (face bold-p &optional frame)
 684   "Specify whether face FACE is bold.
 685 BOLD-P non-nil means FACE should explicitly display bold.
 686 BOLD-P nil means FACE should explicitly display non-bold.
 687 FRAME nil or not specified means change face on all frames.
 688 Use `set-face-attribute' or `modify-face' for finer control."
 689   (if (null bold-p)
 690       (make-face-unbold face frame)
 691     (make-face-bold face frame)))
 692
 693
 694 (defun set-face-italic-p (face italic-p &optional frame)
 695   "Specify whether face FACE is italic.
 696 ITALIC-P non-nil means FACE should explicitly display italic.
 697 ITALIC-P nil means FACE should explicitly display non-italic.
 698 FRAME nil or not specified means change face on all frames.
 699 Use `set-face-attribute' or `modify-face' for finer control."
 700   (if (null italic-p)
 701       (make-face-unitalic face frame)
 702     (make-face-italic face frame)))
 703
 704
 705 (defalias 'set-face-background-pixmap 'set-face-stipple)
 706
 707
 708 (defun invert-face (face &optional frame)
 709   "Swap the foreground and background colors of FACE.
 710 FRAME nil or not specified means change face on all frames.
 711 If FACE specifies neither foreground nor background color,
 712 set its foreground and background to the background and foreground
 713 of the default face.  Value is FACE."
 714   (interactive (list (read-face-name "Invert face ")))
 715   (let ((fg (face-attribute face :foreground frame))
 716         (bg (face-attribute face :background frame)))
 717     (if (or fg bg)
 718         (set-face-attribute face frame :foreground bg :background fg)
 719       (set-face-attribute face frame
 720                           :foreground
 721                           (face-attribute 'default :background frame)
 722                           :background
 723                           (face-attribute 'default :foreground frame))))
 724   face)
 725
 726 \f
 727 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 728 ;;; Interactively modifying faces.
 729 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 730
 731 (defun read-face-name (prompt)
 732   "Read and return a face symbol, prompting with PROMPT.
 733 Value is a symbol naming a known face."
 734   (let ((face-list (mapcar #'(lambda (x) (cons (symbol-name x) x))
 735                            (face-list)))
 736         (def (thing-at-point 'symbol))
 737         face)
 738     (cond ((assoc def face-list)
 739            (setq prompt (concat prompt " (default " def "): ")))
 740           (t (setq def nil)
 741              (setq prompt (concat prompt ": "))))
 742     (while (equal "" (setq face (completing-read
 743                                  prompt face-list nil t nil nil def))))
 744     (intern face)))
 745
 746
 747 (defun face-valid-attribute-values (attribute &optional frame)
 748   "Return valid values for face attribute ATTRIBUTE.
 749 The optional argument FRAME is used to determine available fonts
 750 and colors.  If it is nil or not specified, the selected frame is
 751 used.  Value is an alist of (NAME . VALUE) if ATTRIBUTE expects a value
 752 out of a set of discrete values.  Value is `integerp' if ATTRIBUTE expects
 753 an integer value."
 754   (let (valid)
 755     (setq valid
 756           (case attribute
 757             (:family
 758              (if window-system
 759                  (mapcar #'(lambda (x) (cons (car x) (car x)))
 760                          (x-font-family-list))
 761                ;; Only one font on TTYs.
 762                (list (cons "default" "default"))))
 763             ((:width :weight :slant :inverse-video)
 764              (mapcar #'(lambda (x) (cons (symbol-name x) x))
 765                      (internal-lisp-face-attribute-values attribute)))
 766             ((:underline :overline :strike-through :box)
 767              (if window-system
 768                  (nconc (mapcar #'(lambda (x) (cons (symbol-name x) x))
 769                                 (internal-lisp-face-attribute-values attribute))
 770                         (mapcar #'(lambda (c) (cons c c))
 771                                 (x-defined-colors frame)))
 772                (mapcar #'(lambda (x) (cons (symbol-name x) x))
 773                        (internal-lisp-face-attribute-values attribute))))
 774             ((:foreground :background)
 775              (mapcar #'(lambda (c) (cons c c))
 776                      (defined-colors frame)))
 777             ((:height)
 778              'integerp)
 779             (:stipple
 780              (and (memq window-system '(x w32))
 781                   (mapcar #'list
 782                           (apply #'nconc
 783                                  (mapcar (lambda (dir)
 784                                            (and (file-readable-p dir)
 785                                                 (file-directory-p dir)
 786                                                 (directory-files dir)))
 787                                          x-bitmap-file-path)))))
 788             (:inherit
 789              (cons '("none" . nil)
 790                    (mapcar #'(lambda (c) (cons (symbol-name c) c))
 791                            (face-list))))
 792             (t
 793              (error "Internal error"))))
 794     (if (and (listp valid) (not (memq attribute '(:inherit))))
 795         (nconc (list (cons "unspecified" 'unspecified)) valid)
 796       valid)))
 797
 798
 799
 800 (defvar face-attribute-name-alist
 801   '((:family . "font family")
 802     (:width . "character set width")
 803     (:height . "height in 1/10 pt")
 804     (:weight . "weight")
 805     (:slant . "slant")
 806     (:underline . "underline")
 807     (:overline . "overline")
 808     (:strike-through . "strike-through")
 809     (:box . "box")
 810     (:inverse-video . "inverse-video display")
 811     (:foreground . "foreground color")
 812     (:background . "background color")
 813     (:stipple . "background stipple")
 814     (:inherit . "inheritance"))
 815   "An alist of descriptive names for face attributes.
 816 Each element has the form (ATTRIBUTE-NAME . DESCRIPTION) where
 817 ATTRIBUTE-NAME is a face attribute name (a keyword symbol), and
 818 DESCRIPTION is a descriptive name for ATTRIBUTE-NAME.")
 819
 820
 821 (defun face-descriptive-attribute-name (attribute)
 822   "Return a descriptive name for ATTRIBUTE."
 823   (cdr (assq attribute face-attribute-name-alist)))
 824
 825
 826 (defun face-read-string (face default name &optional completion-alist)
 827   "Interactively read a face attribute string value.
 828 FACE is the face whose attribute is read.  If non-nil, DEFAULT is the
 829 default string to return if no new value is entered.  NAME is a
 830 descriptive name of the attribute for prompting.  COMPLETION-ALIST is an
 831 alist of valid values, if non-nil.
 832
 833 Entering nothing accepts the default string DEFAULT.
 834 Value is the new attribute value."
 835   ;; Capitalize NAME (we don't use `capitalize' because that capitalizes
 836   ;; each word in a string separately).
 837   (setq name (concat (upcase (substring name 0 1)) (substring name 1)))
 838   (let* ((completion-ignore-case t)
 839          (value (completing-read
 840                  (if default
 841                      (format "%s for face `%s' (default %s): "
 842                              name face default)
 843                    (format "%s for face `%s': " name face))
 844                  completion-alist)))
 845     (if (equal value "") default value)))
 846
 847
 848 (defun face-read-integer (face default name)
 849   "Interactively read an integer face attribute value.
 850 FACE is the face whose attribute is read.  DEFAULT is the default
 851 value to return if no new value is entered.  NAME is a descriptive
 852 name of the attribute for prompting.  Value is the new attribute value."
 853   (let ((new-value
 854          (face-read-string face
 855                            (format "%s" default)
 856                            name
 857                            (list (cons "unspecified" 'unspecified)))))
 858     (cond ((equal new-value "unspecified")
 859            'unspecified)
 860           ((member new-value '("unspecified-fg" "unspecified-bg"))
 861            new-value)
 862           (t
 863            (string-to-int new-value)))))
 864
 865
 866 (defun read-face-attribute (face attribute &optional frame)
 867   "Interactively read a new value for FACE's ATTRIBUTE.
 868 Optional argument FRAME nil or unspecified means read an attribute value
 869 of a global face.  Value is the new attribute value."
 870   (let* ((old-value (face-attribute face attribute frame))
 871          (attribute-name (face-descriptive-attribute-name attribute))
 872          (valid (face-valid-attribute-values attribute frame))
 873          new-value)
 874     ;; Represent complex attribute values as strings by printing them
 875     ;; out.  Stipple can be a vector; (WIDTH HEIGHT DATA).  Box can be
 876     ;; a list `(:width WIDTH :color COLOR)' or `(:width WIDTH :shadow
 877     ;; SHADOW)'.
 878     (when (and (or (eq attribute :stipple)
 879                    (eq attribute :box))
 880                (or (consp old-value)
 881                    (vectorp old-value)))
 882       (setq old-value (prin1-to-string old-value)))
 883     (cond ((listp valid)
 884            (let ((default
 885                    (or (car (rassoc old-value valid))
 886                        (format "%s" old-value))))
 887              (setq new-value
 888                    (face-read-string face default attribute-name valid))
 889              (if (equal new-value default)
 890                  ;; Nothing changed, so don't bother with all the stuff
 891                  ;; below.  In particular, this avoids a non-tty color
 892                  ;; from being canonicalized for a tty when the user
 893                  ;; just uses the default.
 894                  (setq new-value old-value)
 895                ;; Terminal frames can support colors that don't appear
 896                ;; explicitly in VALID, using color approximation code
 897                ;; in tty-colors.el.
 898                (if (and (memq attribute '(:foreground :background))
 899                         (not (memq window-system '(x w32 mac)))
 900                         (not (member new-value
 901                                      '("unspecified"
 902                                        "unspecified-fg" "unspecified-bg"))))
 903                    (setq new-value (car (tty-color-desc new-value frame))))
 904                (setq new-value (cdr (assoc new-value valid))))))
 905           ((eq valid 'integerp)
 906            (setq new-value (face-read-integer face old-value attribute-name)))
 907           (t (error "Internal error")))
 908     ;; Convert stipple and box value text we read back to a list or
 909     ;; vector if it looks like one.  This makes the assumption that a
 910     ;; pixmap file name won't start with an open-paren.
 911     (when (and (or (eq attribute :stipple)
 912                    (eq attribute :box))
 913                (stringp new-value)
 914                (string-match "^[[(]" new-value))
 915       (setq new-value (read new-value)))
 916     new-value))
 917
 918
 919 (defun read-face-font (face &optional frame)
 920   "Read the name of a font for FACE on FRAME.
 921 If optional argument FRAME Is nil or omitted, use the selected frame."
 922   (let ((completion-ignore-case t))
 923     (completing-read (format "Set font attributes of face `%s' from font: " face)
 924                      (mapcar 'list (x-list-fonts "*" nil frame)))))
 925
 926
 927 (defun read-all-face-attributes (face &optional frame)
 928   "Interactively read all attributes for FACE.
 929 If optional argument FRAME Is nil or omitted, use the selected frame.
 930 Value is a property list of attribute names and new values."
 931   (let (result)
 932     (dolist (attribute face-attribute-name-alist result)
 933       (setq result (cons (car attribute)
 934                          (cons (read-face-attribute face (car attribute) frame)
 935                                result))))))
 936
 937
 938 (defun modify-face (&optional frame)
 939   "Modify attributes of faces interactively.
 940 If optional argument FRAME is nil or omitted, modify the face used
 941 for newly created frame, i.e. the global face."
 942   (interactive)
 943   (let ((face (read-face-name "Modify face")))
 944     (apply #'set-face-attribute face frame
 945            (read-all-face-attributes face frame))))
 946
 947
 948 (defun read-face-and-attribute (attribute &optional frame)
 949   "Read face name and face attribute value.
 950 ATTRIBUTE is the attribute whose new value is read.
 951 FRAME nil or unspecified means read attribute value of global face.
 952 Value is a list (FACE NEW-VALUE) where FACE is the face read
 953 (a symbol), and NEW-VALUE is value read."
 954   (cond ((eq attribute :font)
 955          (let* ((prompt "Set font-related attributes of face")
 956                 (face (read-face-name prompt))
 957                 (font (read-face-font face frame)))
 958            (list face font)))
 959         (t
 960          (let* ((attribute-name (face-descriptive-attribute-name attribute))
 961                 (prompt (format "Set %s of face" attribute-name))
 962                 (face (read-face-name prompt))
 963                 (new-value (read-face-attribute face attribute frame)))
 964            (list face new-value)))))
 965
 966
 967 \f
 968 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 969 ;;; Listing faces.
 970 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 971
 972 (defvar list-faces-sample-text
 973   "abcdefghijklmnopqrstuvwxyz ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 974   "*Text string to display as the sample text for `list-faces-display'.")
 975
 976
 977 ;; The name list-faces would be more consistent, but let's avoid a
 978 ;; conflict with Lucid, which uses that name differently.
 979
 980 (defun list-faces-display ()
 981   "List all faces, using the same sample text in each.
 982 The sample text is a string that comes from the variable
 983 `list-faces-sample-text'."
 984   (interactive)
 985   (let ((faces (sort (face-list) #'string-lessp))
 986         (face nil)
 987         (frame (selected-frame))
 988         disp-frame window face-name)
 989     (with-output-to-temp-buffer "*Faces*"
 990       (save-excursion
 991         (set-buffer standard-output)
 992         (setq truncate-lines t)
 993         (insert
 994          (substitute-command-keys
 995           (concat
 996            "Use "
 997            (if (display-mouse-p) "\\[help-follow-mouse] or ")
 998            "\\[help-follow] on a face name to customize it\n"
 999            "or on its sample text for a decription of the face.\n\n")))
1000         (setq help-xref-stack nil)
1001         (while faces
1002           (setq face (car faces))
1003           (setq faces (cdr faces))
1004           (setq face-name (symbol-name face))
1005           (insert (format "%25s " face-name))
1006           ;; Hyperlink to a customization buffer for the face.  Using
1007           ;; the help xref mechanism may not be the best way.
1008           (save-excursion
1009             (save-match-data
1010               (search-backward face-name)
1011               (help-xref-button 0 (lambda (f)
1012                                     (if help-xref-stack
1013                                         (pop help-xref-stack))
1014                                     (customize-face f))
1015                                 face-name
1016                                 "mouse-2: customize this face")))
1017           (let ((beg (point)))
1018             (insert list-faces-sample-text)
1019             ;; Hyperlink to a help buffer for the face.
1020             (save-excursion
1021               (save-match-data
1022                 (search-backward list-faces-sample-text)
1023                 (help-xref-button 0 #'describe-face face
1024                                   "mouse-2: describe this face")))
1025             (insert "\n")
1026             (put-text-property beg (1- (point)) 'face face)
1027             ;; If the sample text has multiple lines, line up all of them.
1028             (goto-char beg)
1029             (forward-line 1)
1030             (while (not (eobp))
1031               (insert "                          ")
1032               (forward-line 1))))
1033         (goto-char (point-min)))
1034       (print-help-return-message))
1035     ;; If the *Faces* buffer appears in a different frame,
1036     ;; copy all the face definitions from FRAME,
1037     ;; so that the display will reflect the frame that was selected.
1038     (setq window (get-buffer-window (get-buffer "*Faces*") t))
1039     (setq disp-frame (if window (window-frame window)
1040                        (car (frame-list))))
1041     (or (eq frame disp-frame)
1042         (let ((faces (face-list)))
1043           (while faces
1044             (copy-face (car faces) (car faces) frame disp-frame)
1045             (setq faces (cdr faces)))))))
1046
1047
1048 (defun describe-face (face &optional frame)
1049   "Display the properties of face FACE on FRAME.
1050 If the optional argument FRAME is given, report on face FACE in that frame.
1051 If FRAME is t, report on the defaults for face FACE (for new frames).
1052 If FRAME is omitted or nil, use the selected frame."
1053   (interactive (list (read-face-name "Describe face")))
1054   (let* ((attrs '((:family . "Family")
1055                   (:width . "Width")
1056                   (:height . "Height")
1057                   (:weight . "Weight")
1058                   (:slant . "Slant")
1059                   (:foreground . "Foreground")
1060                   (:background . "Background")
1061                   (:underline . "Underline")
1062                   (:overline . "Overline")
1063                   (:strike-through . "Strike-through")
1064                   (:box . "Box")
1065                   (:inverse-video . "Inverse")
1066                   (:stipple . "Stipple")
1067                   (:font . "Font or fontset")
1068                   (:inherit . "Inherit")))
1069         (max-width (apply #'max (mapcar #'(lambda (x) (length (cdr x)))
1070                                         attrs))))
1071     (with-output-to-temp-buffer "*Help*"
1072       (save-excursion
1073         (set-buffer standard-output)
1074         (dolist (a attrs)
1075           (let ((attr (face-attribute face (car a) frame)))
1076             (insert (make-string (- max-width (length (cdr a))) ?\ )
1077                     (cdr a) ": " (format "%s" attr) "\n")))
1078         (insert "\nDocumentation:\n\n"
1079                 (or (face-documentation face)
1080                     "not documented as a face."))
1081         (let ((customize-label "customize"))
1082           (terpri)
1083           (terpri)
1084           (princ (concat "You can " customize-label " this face."))
1085           (with-current-buffer "*Help*"
1086             (save-excursion
1087               (re-search-backward
1088                (concat "\\(" customize-label "\\)") nil t)
1089               (help-xref-button 1 #'customize-face face
1090                                 "mouse-2, RET: customize face")))))
1091       (print-help-return-message)
1092       (with-current-buffer "*Help*"
1093         (help-setup-xref (list #'describe-face face) (interactive-p))
1094         (buffer-string)))))
1095 \f
1096 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1097 ;;; Face specifications (defface).
1098 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1099
1100 ;; Parameter FRAME Is kept for call compatibility to with previous
1101 ;; face implementation.
1102
1103 (defun face-attr-construct (face &optional frame)
1104   "Return a defface-style attribute list for FACE on FRAME.
1105 Value is a property list of pairs ATTRIBUTE VALUE for all specified
1106 face attributes of FACE where ATTRIBUTE is the attribute name and
1107 VALUE is the specified value of that attribute."
1108   (let (result)
1109     (dolist (entry face-attribute-name-alist result)
1110       (let* ((attribute (car entry))
1111              (value (face-attribute face attribute)))
1112         (unless (eq value 'unspecified)
1113           (setq result (nconc (list attribute value) result)))))))
1114
1115
1116 (defun face-spec-set-match-display (display frame)
1117   "Non-nil if DISPLAY matches FRAME.
1118 DISPLAY is part of a spec such as can be used in `defface'.
1119 If FRAME is nil, the current FRAME is used."
1120   (let* ((conjuncts display)
1121          conjunct req options
1122          ;; t means we have succeeded against all the conjuncts in
1123          ;; DISPLAY that have been tested so far.
1124          (match t))
1125     (if (eq conjuncts t)
1126         (setq conjuncts nil))
1127     (while (and conjuncts match)
1128       (setq conjunct (car conjuncts)
1129             conjuncts (cdr conjuncts)
1130             req (car conjunct)
1131             options (cdr conjunct)
1132             match (cond ((eq req 'type)
1133                          (or (memq window-system options)
1134                              (and (null window-system)
1135                                   (memq 'tty options))
1136                              (and (memq 'motif options)
1137                                   (featurep 'motif))
1138                              (and (memq 'lucid options)
1139                                   (featurep 'x-toolkit)
1140                                   (not (featurep 'motif)))
1141                              (and (memq 'x-toolkit options)
1142                                   (featurep 'x-toolkit))))
1143                         ((eq req 'class)
1144                          (memq (frame-parameter frame 'display-type) options))
1145                         ((eq req 'background)
1146                          (memq (frame-parameter frame 'background-mode)
1147                                options))
1148                         (t (error "Unknown req `%S' with options `%S'"
1149                                   req options)))))
1150     match))
1151
1152
1153 (defun face-spec-choose (spec &optional frame)
1154   "Choose the proper attributes for FRAME, out of SPEC."
1155   (unless frame
1156     (setq frame (selected-frame)))
1157   (let ((tail spec)
1158         result)
1159     (while tail
1160       (let* ((entry (car tail))
1161              (display (nth 0 entry))
1162              (attrs (nth 1 entry)))
1163         (setq tail (cdr tail))
1164         (when (face-spec-set-match-display display frame)
1165           (setq result attrs tail nil))))
1166     result))
1167
1168
1169 (defun face-spec-reset-face (face &optional frame)
1170   "Reset all attributes of FACE on FRAME to unspecified."
1171   (let ((attrs face-attribute-name-alist))
1172     (while attrs
1173       (let ((attr-and-name (car attrs)))
1174         (set-face-attribute face frame (car attr-and-name) 'unspecified))
1175       (setq attrs (cdr attrs)))))
1176
1177
1178 (defun face-spec-set (face spec &optional frame)
1179   "Set FACE's attributes according to the first matching entry in SPEC.
1180 FRAME is the frame whose frame-local face is set.  FRAME nil means
1181 do it on all frames.  See `defface' for information about SPEC."
1182   (let ((attrs (face-spec-choose spec frame)))
1183     (when attrs
1184       (face-spec-reset-face face frame))
1185     (while attrs
1186       (let ((attribute (car attrs))
1187             (value (car (cdr attrs))))
1188         ;; Support some old-style attribute names and values.
1189         (case attribute
1190           (:bold (setq attribute :weight value (if value 'bold 'normal)))
1191           (:italic (setq attribute :slant value (if value 'italic 'normal)))
1192           (t (unless (assq attribute face-x-resources)
1193                (setq attribute nil))))
1194         (when attribute
1195           (set-face-attribute face frame attribute value)))
1196       (setq attrs (cdr (cdr attrs))))))
1197
1198
1199 (defun face-attr-match-p (face attrs &optional frame)
1200   "Return t if attributes of FACE match values in plist ATTRS.
1201 Optional parameter FRAME is the frame whose definition of FACE
1202 is used.  If nil or omitted, use the selected frame."
1203   (unless frame
1204     (setq frame (selected-frame)))
1205   (let ((list face-attribute-name-alist)
1206         (match t))
1207     (while (and match (not (null list)))
1208       (let* ((attr (car (car list)))
1209              (specified-value
1210               (if (plist-member attrs attr)
1211                   (plist-get attrs attr)
1212                 'unspecified))
1213              (value-now (face-attribute face attr frame)))
1214         (setq match (equal specified-value value-now))
1215         (setq list (cdr list))))
1216     match))
1217
1218 (defun face-spec-match-p (face spec &optional frame)
1219   "Return t if FACE, on FRAME, matches what SPEC says it should look like."
1220   (face-attr-match-p face (face-spec-choose spec frame) frame))
1221
1222
1223 \f
1224 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1225 ;;; Frame-type independent color support.
1226 ;;; We keep the old x-* names as aliases for back-compatibility.
1227 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1228
1229 (defun defined-colors (&optional frame)
1230   "Return a list of colors supported for a particular frame.
1231 The argument FRAME specifies which frame to try.
1232 The value may be different for frames on different display types.
1233 If FRAME doesn't support colors, the value is nil."
1234   (if (memq (framep (or frame (selected-frame))) '(x w32))
1235       (xw-defined-colors frame)
1236     (mapcar 'car (tty-color-alist frame))))
1237 (defalias 'x-defined-colors 'defined-colors)
1238
1239 (defun color-defined-p (color &optional frame)
1240   "Return non-nil if color COLOR is supported on frame FRAME.
1241 If FRAME is omitted or nil, use the selected frame.
1242 If COLOR is the symbol `unspecified' or one of the strings
1243 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1244   (if (memq color '(unspecified "unspecified-bg" "unspecified-fg"))
1245       nil
1246     (if (memq (framep (or frame (selected-frame))) '(x w32))
1247         (xw-color-defined-p color frame)
1248       (numberp (tty-color-translate color frame)))))
1249 (defalias 'x-color-defined-p 'color-defined-p)
1250
1251 (defun color-values (color &optional frame)
1252   "Return a description of the color named COLOR on frame FRAME.
1253 The value is a list of integer RGB values--\(RED GREEN BLUE\).
1254 These values appear to range from 0 65535; white is \(65535 65535 65535\).
1255 If FRAME is omitted or nil, use the selected frame.
1256 If FRAME cannot display COLOR, the value is nil.
1257 If COLOR is the symbol `unspecified' or one of the strings
1258 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1259   (if (memq color '(unspecified "unspecified-fg" "unspecified-bg"))
1260       nil
1261     (if (memq (framep (or frame (selected-frame))) '(x w32))
1262         (xw-color-values color frame)
1263       (tty-color-values color frame))))
1264 (defalias 'x-color-values 'color-values)
1265
1266 (defun display-color-p (&optional display)
1267   "Return t if DISPLAY supports color.
1268 The optional argument DISPLAY specifies which display to ask about.
1269 DISPLAY should be either a frame or a display name (a string).
1270 If omitted or nil, that stands for the selected frame's display."
1271   (if (memq (framep-on-display display) '(x w32))
1272       (xw-display-color-p display)
1273     (tty-display-color-p display)))
1274 (defalias 'x-display-color-p 'display-color-p)
1275
1276 (defun display-grayscale-p (&optional display)
1277   "Return non-nil if frames on DISPLAY can display shades of gray."
1278   (let ((frame-type (framep-on-display display)))
1279     (cond
1280      ((memq frame-type '(x w32 mac))
1281       (x-display-grayscale-p display))
1282      (t
1283       (> (tty-color-gray-shades display) 2)))))
1284
1285 \f
1286 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1287 ;;; Background mode.
1288 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1289
1290 (defcustom frame-background-mode nil
1291   "*The brightness of the background.
1292 Set this to the symbol `dark' if your background color is dark, `light' if
1293 your background is light, or nil (default) if you want Emacs to
1294 examine the brightness for you.  Don't set this variable with `setq';
1295 this won't have the expected effect."
1296   :group 'faces
1297   :set #'(lambda (var value)
1298            (set-default var value)
1299            (mapc 'frame-set-background-mode (frame-list)))
1300   :initialize 'custom-initialize-changed
1301   :type '(choice (choice-item dark)
1302                  (choice-item light)
1303                  (choice-item :tag "default" nil)))
1304
1305
1306 (defun frame-set-background-mode (frame)
1307   "Set up the `background-mode' and `display-type' frame parameters for FRAME."
1308   (let* ((bg-resource
1309           (and window-system
1310                (x-get-resource ".backgroundMode" "BackgroundMode")))
1311          (bg-mode (cond (frame-background-mode)
1312                         ((null window-system)
1313                          ;; No way to determine this automatically (?).
1314                          'dark)
1315                         (bg-resource
1316                          (intern (downcase bg-resource)))
1317                         ((< (apply '+ (x-color-values
1318                                        (frame-parameter frame 'background-color)
1319                                        frame))
1320                             ;; Just looking at the screen, colors whose
1321                             ;; values add up to .6 of the white total
1322                             ;; still look dark to me.
1323                             (* (apply '+ (x-color-values "white" frame)) .6))
1324                          'dark)
1325                         (t 'light)))
1326          (display-type (cond ((null window-system)
1327                               (if (tty-display-color-p frame) 'color 'mono))
1328                              ((x-display-color-p frame)
1329                               'color)
1330                              ((x-display-grayscale-p frame)
1331                               'grayscale)
1332                              (t 'mono))))
1333     (modify-frame-parameters frame
1334                              (list (cons 'background-mode bg-mode)
1335                                    (cons 'display-type display-type))))
1336
1337   ;; For all named faces, choose face specs matching the new frame
1338   ;; parameters.
1339   (let ((face-list (face-list)))
1340     (while face-list
1341       (let* ((face (car face-list))
1342              (spec (get face 'face-defface-spec)))
1343         (when spec
1344           (face-spec-set face spec frame))
1345       (setq face-list (cdr face-list))))))
1346
1347
1348
1349 \f
1350 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1351 ;;; Frame creation.
1352 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1353
1354 (defun x-handle-named-frame-geometry (parameters)
1355   "Add geometry parameters for a named frame to parameter list PARAMETERS.
1356 Value is the new parameter list."
1357   (let* ((name (or (cdr (assq 'name parameters))
1358                    (cdr (assq 'name default-frame-alist))))
1359          (x-resource-name name)
1360          (res-geometry (if name (x-get-resource "geometry" "Geometry"))))
1361     (when res-geometry
1362       (let ((parsed (x-parse-geometry res-geometry)))
1363         ;; If the resource specifies a position, call the position
1364         ;; and size "user-specified".
1365         (when (or (assq 'top parsed)
1366                   (assq 'left parsed))
1367           (setq parsed (append '((user-position . t) (user-size . t)) parsed)))
1368         ;; Put the geometry parameters at the end.  Copy
1369         ;; default-frame-alist so that they go after it.
1370         (setq parameters (append parameters default-frame-alist parsed))))
1371     parameters))
1372
1373
1374 (defun x-handle-reverse-video (frame parameters)
1375   "Handle the reverse-video frame parameter and X resource.
1376 `x-create-frame' does not handle this one."
1377   (when (cdr (or (assq 'reverse parameters)
1378                  (assq 'reverse default-frame-alist)
1379                  (let ((resource (x-get-resource "reverseVideo"
1380                                                  "ReverseVideo")))
1381                    (if resource
1382                        (cons nil (member (downcase resource)
1383                                          '("on" "true")))))))
1384       (let* ((params (frame-parameters frame))
1385              (bg (cdr (assq 'foreground-color params)))
1386              (fg (cdr (assq 'background-color params))))
1387         (modify-frame-parameters frame
1388                                  (list (cons 'foreground-color fg)
1389                                        (cons 'background-color bg)))
1390         (if (equal bg (cdr (assq 'border-color params)))
1391             (modify-frame-parameters frame
1392                                      (list (cons 'border-color fg))))
1393         (if (equal bg (cdr (assq 'mouse-color params)))
1394             (modify-frame-parameters frame
1395                                      (list (cons 'mouse-color fg))))
1396         (if (equal bg (cdr (assq 'cursor-color params)))
1397             (modify-frame-parameters frame
1398                                      (list (cons 'cursor-color fg)))))))
1399
1400
1401 (defun x-create-frame-with-faces (&optional parameters)
1402   "Create a frame from optional frame parameters PARAMETERS.
1403 Parameters not specified by PARAMETERS are taken from
1404 `default-frame-alist'.  If PARAMETERS specify a frame name,
1405 handle X geometry resources for that name.  If either PARAMETERS
1406 or `default-frame-alist' contains a `reverse' parameter, or
1407 the X resource ``reverseVideo'' is present, handle that.
1408 Value is the new frame created."
1409   (setq parameters (x-handle-named-frame-geometry parameters))
1410   (let ((visibility-spec (assq 'visibility parameters))
1411         (frame-list (frame-list))
1412         (frame (x-create-frame (cons '(visibility . nil) parameters)))
1413         success)
1414     (unwind-protect
1415         (progn
1416           (x-handle-reverse-video frame parameters)
1417           (frame-set-background-mode frame)
1418           (face-set-after-frame-default frame)
1419           (if (or (null frame-list) (null visibility-spec))
1420               (make-frame-visible frame)
1421             (modify-frame-parameters frame (list visibility-spec)))
1422           (setq success t))
1423       (unless success
1424         (delete-frame frame)))
1425     frame))
1426
1427
1428 (defun face-set-after-frame-default (frame)
1429   "Set frame-local faces of FRAME from face specs and resources.
1430 Initialize colors of certain faces from frame parameters."
1431   (dolist (face (face-list))
1432     (let ((spec (or (get face 'saved-face)
1433                     (get face 'face-defface-spec))))
1434       (when spec
1435         (face-spec-set face spec frame))
1436       (internal-merge-in-global-face face frame)
1437       (when (memq window-system '(x w32))
1438         (make-face-x-resource-internal face frame))))
1439
1440   ;; Initialize attributes from frame parameters.
1441   (let ((params '((foreground-color default :foreground)
1442                   (background-color default :background)
1443                   (border-color border :background)
1444                   (cursor-color cursor :background)
1445                   (scroll-bar-foreground scroll-bar :foreground)
1446                   (scroll-bar-background scroll-bar :background)
1447                   (mouse-color mouse :background))))
1448     (while params
1449       (let ((param-name (nth 0 (car params)))
1450             (face (nth 1 (car params)))
1451             (attr (nth 2 (car params)))
1452             value)
1453         (when (setq value (frame-parameter frame param-name))
1454           (set-face-attribute face frame attr value)))
1455       (setq params (cdr params)))))
1456
1457
1458 (defun tty-create-frame-with-faces (&optional parameters)
1459   "Create a frame from optional frame parameters PARAMETERS.
1460 Parameters not specified by PARAMETERS are taken from
1461 `default-frame-alist'.  If either PARAMETERS or `default-frame-alist'
1462 contains a `reverse' parameter, handle that.  Value is the new frame
1463 created."
1464   (let ((frame (make-terminal-frame parameters))
1465         success)
1466     (unwind-protect
1467         (progn
1468           (frame-set-background-mode frame)
1469           (face-set-after-frame-default frame)
1470           (setq success t))
1471       (unless success
1472         (delete-frame frame)))
1473     frame))
1474
1475
1476 ;; Called from C function init_display to initialize faces of the
1477 ;; dumped terminal frame on startup.
1478
1479 (defun tty-set-up-initial-frame-faces ()
1480   (let ((frame (selected-frame)))
1481     (frame-set-background-mode frame)
1482     (face-set-after-frame-default frame)))
1483
1484
1485
1486 \f
1487 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1488 ;;; Compatiblity with 20.2
1489 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1490
1491 ;; Update a frame's faces when we change its default font.
1492
1493 (defalias 'frame-update-faces 'ignore)
1494 (make-obsolete 'frame-update-faces "No longer necessary" "21.1")
1495
1496 ;; Update the colors of FACE, after FRAME's own colors have been
1497 ;; changed.
1498
1499 (defalias 'frame-update-face-colors 'frame-set-background-mode)
1500 (make-obsolete 'frame-update-face-colors 'frame-set-background-mode "21.1")
1501
1502 \f
1503 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1504 ;;; Standard faces.
1505 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1506
1507 (defgroup basic-faces nil
1508   "The standard faces of Emacs."
1509   :group 'faces)
1510
1511
1512 (defface default
1513   '((t nil))
1514   "Basic default face."
1515   :group 'basic-faces)
1516
1517
1518 (defface mode-line
1519   '((((type x w32) (class color))
1520      (:box (:line-width 2 :style released-button)
1521            :background "grey75" :foreground "black"))
1522     (t
1523      (:inverse-video t)))
1524   "Basic mode line face."
1525   :version "21.1"
1526   :group 'modeline
1527   :group 'basic-faces)
1528
1529 ;; Make `modeline' an alias for `mode-line', for compatibility.
1530 (put 'modeline 'face-alias 'mode-line)
1531
1532 (defface header-line
1533   '((((type tty))
1534      (:inverse-video t))
1535     (((class color) (background light))
1536      (:box (:line-width 1 :style released-button)
1537            :background "grey90" :foreground "grey20"
1538            :inherit mode-line))
1539     (((class color) (background dark))
1540      (:box (:line-width 1 :style released-button)
1541            :background "grey20" :foreground "grey90"
1542            :inherit mode-line))
1543     (((class mono))
1544      (:box (:line-width 1 :style released-button)
1545            :background "grey"
1546            :inherit mode-line))
1547     (t
1548      (:inverse-video t)))
1549   "Basic header-line face."
1550   :version "21.1"
1551   :group 'basic-faces)
1552
1553
1554 (defface tool-bar
1555   '((((type x w32) (class color))
1556      (:box (:line-width 1 :style released-button)
1557            :background "grey75" :foreground "black"))
1558     (((type x) (class mono))
1559      (:box (:line-width 1 :style released-button)
1560            :background "grey" :foreground "black"))
1561     (t
1562      ()))
1563   "Basic tool-bar face."
1564   :version "21.1"
1565   :group 'basic-faces)
1566
1567
1568 (defface region
1569   '((((type tty) (class color))
1570      (:background "blue" :foreground "white"))
1571     (((type tty) (class mono))
1572      (:inverse-video t))
1573     (((class color) (background dark))
1574      (:background "blue"))
1575     (((class color) (background light))
1576      (:background "light goldenrod yellow"))
1577     (t (:background "gray")))
1578   "Basic face for highlighting the region."
1579   :version "21.1"
1580   :group 'basic-faces)
1581
1582
1583 (defface fringe
1584   '((((class color) (background light))
1585        (:background "grey95"))
1586       (((class color) (background dark))
1587        (:background "grey10"))
1588       (t
1589        (:background "gray")))
1590   "Basic face for the fringes to the left and right of windows under X."
1591   :version "21.1"
1592   :group 'frames
1593   :group 'basic-faces)
1594
1595
1596 (defface scroll-bar '()
1597   "Basic face for the scroll bar colors under X."
1598   :version "21.1"
1599   :group 'frames
1600   :group 'basic-faces)
1601
1602
1603 (defface menu
1604   '((((type x-toolkit)) ())
1605     (t (:inverse-video t)))
1606   "Basic menu face."
1607   :version "21.1"
1608   :group 'menu
1609   :group 'basic-faces)
1610
1611
1612 (defface border '()
1613   "Basic face for the frame border under X."
1614   :version "21.1"
1615   :group 'frames
1616   :group 'basic-faces)
1617
1618
1619 (defface cursor '()
1620   "Basic face for the cursor color under X."
1621   :version "21.1"
1622   :group 'cursor
1623   :group 'basic-faces)
1624
1625
1626 (defface mouse '()
1627   "Basic face for the mouse color under X."
1628   :version "21.1"
1629   :group 'mouse
1630   :group 'basic-faces)
1631
1632
1633 (defface bold '((t (:weight bold)))
1634   "Basic bold face."
1635   :group 'basic-faces)
1636
1637
1638 (defface italic '((t (:slant italic)))
1639   "Basic italic font."
1640   :group 'basic-faces)
1641
1642
1643 (defface bold-italic '((t (:weight bold :slant italic)))
1644   "Basic bold-italic face."
1645   :group 'basic-faces)
1646
1647
1648 (defface underline '((t (:underline t)))
1649   "Basic underlined face."
1650   :group 'basic-faces)
1651
1652
1653 (defface highlight
1654   '((((type tty) (class color))
1655      (:background "green"))
1656     (((class color) (background light))
1657      (:background "darkseagreen2"))
1658     (((class color) (background dark))
1659      (:background "darkolivegreen"))
1660     (t (:inverse-video t)))
1661   "Basic face for highlighting."
1662   :group 'basic-faces)
1663
1664
1665 (defface secondary-selection
1666   '((((type tty) (class color))
1667      (:background "cyan" :foreground "black"))
1668     (((class color) (background light))
1669      (:background "yellow"))
1670     (((class color) (background dark))
1671      (:background "SkyBlue4"))
1672     (t (:inverse-video t)))
1673   "Basic face for displaying the secondary selection."
1674   :group 'basic-faces)
1675
1676
1677 (defface fixed-pitch '((t (:family "courier")))
1678   "The basic fixed-pitch face."
1679   :group 'basic-faces)
1680
1681
1682 (defface variable-pitch '((t (:family "helv")))
1683   "The basic variable-pitch face."
1684   :group 'basic-faces)
1685
1686
1687 (defface trailing-whitespace
1688   '((((class color) (background light))
1689      (:background "red"))
1690     (((class color) (background dark))
1691      (:background "red"))
1692     (t (:inverse-video t)))
1693   "Basic face for highlighting trailing whitespace."
1694   :version "21.1"
1695   :group 'font-lock                     ; like `show-trailing-whitespace'
1696   :group 'basic-faces)
1697
1698
1699 \f
1700 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1701 ;;; Manipulating font names.
1702 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1703
1704 ;; This is here for compatibilty with Emacs 20.2.  For example,
1705 ;; international/fontset.el uses x-resolve-font-name.  The following
1706 ;; functions are not used in the face implementation itself.
1707
1708 (defvar x-font-regexp nil)
1709 (defvar x-font-regexp-head nil)
1710 (defvar x-font-regexp-weight nil)
1711 (defvar x-font-regexp-slant nil)
1712
1713 (defconst x-font-regexp-weight-subnum 1)
1714 (defconst x-font-regexp-slant-subnum 2)
1715 (defconst x-font-regexp-swidth-subnum 3)
1716 (defconst x-font-regexp-adstyle-subnum 4)
1717
1718 ;;; Regexps matching font names in "Host Portable Character Representation."
1719 ;;;
1720 (let ((-                "[-?]")
1721       (foundry          "[^-]+")
1722       (family           "[^-]+")
1723       (weight           "\\(bold\\|demibold\\|medium\\)")               ; 1
1724 ;     (weight\?         "\\(\\*\\|bold\\|demibold\\|medium\\|\\)")      ; 1
1725       (weight\?         "\\([^-]*\\)")                                  ; 1
1726       (slant            "\\([ior]\\)")                                  ; 2
1727 ;     (slant\?          "\\([ior?*]?\\)")                               ; 2
1728       (slant\?          "\\([^-]?\\)")                                  ; 2
1729 ;     (swidth           "\\(\\*\\|normal\\|semicondensed\\|\\)")        ; 3
1730       (swidth           "\\([^-]*\\)")                                  ; 3
1731 ;     (adstyle          "\\(\\*\\|sans\\|\\)")                          ; 4
1732       (adstyle          "\\([^-]*\\)")                                  ; 4
1733       (pixelsize        "[0-9]+")
1734       (pointsize        "[0-9][0-9]+")
1735       (resx             "[0-9][0-9]+")
1736       (resy             "[0-9][0-9]+")
1737       (spacing          "[cmp?*]")
1738       (avgwidth         "[0-9]+")
1739       (registry         "[^-]+")
1740       (encoding         "[^-]+")
1741       )
1742   (setq x-font-regexp
1743         (concat "\\`\\*?[-?*]"
1744                 foundry - family - weight\? - slant\? - swidth - adstyle -
1745                 pixelsize - pointsize - resx - resy - spacing - avgwidth -
1746                 registry - encoding "\\*?\\'"
1747                 ))
1748   (setq x-font-regexp-head
1749         (concat "\\`[-?*]" foundry - family - weight\? - slant\?
1750                 "\\([-*?]\\|\\'\\)"))
1751   (setq x-font-regexp-slant (concat - slant -))
1752   (setq x-font-regexp-weight (concat - weight -))
1753   nil)
1754
1755
1756 (defun x-resolve-font-name (pattern &optional face frame)
1757   "Return a font name matching PATTERN.
1758 All wildcards in PATTERN are instantiated.
1759 If PATTERN is nil, return the name of the frame's base font, which never
1760 contains wildcards.
1761 Given optional arguments FACE and FRAME, return a font which is
1762 also the same size as FACE on FRAME, or fail."
1763   (or (symbolp face)
1764       (setq face (face-name face)))
1765   (and (eq frame t)
1766        (setq frame nil))
1767   (if pattern
1768       ;; Note that x-list-fonts has code to handle a face with nil as its font.
1769       (let ((fonts (x-list-fonts pattern face frame 1)))
1770         (or fonts
1771             (if face
1772                 (if (string-match "\\*" pattern)
1773                     (if (null (face-font face))
1774                         (error "No matching fonts are the same height as the frame default font")
1775                       (error "No matching fonts are the same height as face `%s'" face))
1776                   (if (null (face-font face))
1777                       (error "Height of font `%s' doesn't match the frame default font"
1778                              pattern)
1779                     (error "Height of font `%s' doesn't match face `%s'"
1780                            pattern face)))
1781               (error "No fonts match `%s'" pattern)))
1782         (car fonts))
1783     (cdr (assq 'font (frame-parameters (selected-frame))))))
1784
1785
1786 (defun x-frob-font-weight (font which)
1787   (let ((case-fold-search t))
1788     (cond ((string-match x-font-regexp font)
1789            (concat (substring font 0
1790                               (match-beginning x-font-regexp-weight-subnum))
1791                    which
1792                    (substring font (match-end x-font-regexp-weight-subnum)
1793                               (match-beginning x-font-regexp-adstyle-subnum))
1794                    ;; Replace the ADD_STYLE_NAME field with *
1795                    ;; because the info in it may not be the same
1796                    ;; for related fonts.
1797                    "*"
1798                    (substring font (match-end x-font-regexp-adstyle-subnum))))
1799           ((string-match x-font-regexp-head font)
1800            (concat (substring font 0 (match-beginning 1)) which
1801                    (substring font (match-end 1))))
1802           ((string-match x-font-regexp-weight font)
1803            (concat (substring font 0 (match-beginning 1)) which
1804                    (substring font (match-end 1)))))))
1805 (make-obsolete 'x-frob-font-weight 'make-face-... "21.1")
1806
1807 (defun x-frob-font-slant (font which)
1808   (let ((case-fold-search t))
1809     (cond ((string-match x-font-regexp font)
1810            (concat (substring font 0
1811                               (match-beginning x-font-regexp-slant-subnum))
1812                    which
1813                    (substring font (match-end x-font-regexp-slant-subnum)
1814                               (match-beginning x-font-regexp-adstyle-subnum))
1815                    ;; Replace the ADD_STYLE_NAME field with *
1816                    ;; because the info in it may not be the same
1817                    ;; for related fonts.
1818                    "*"
1819                    (substring font (match-end x-font-regexp-adstyle-subnum))))
1820           ((string-match x-font-regexp-head font)
1821            (concat (substring font 0 (match-beginning 2)) which
1822                    (substring font (match-end 2))))
1823           ((string-match x-font-regexp-slant font)
1824            (concat (substring font 0 (match-beginning 1)) which
1825                    (substring font (match-end 1)))))))
1826 (make-obsolete 'x-frob-font-slant 'make-face-... "21.1")
1827
1828 (defun x-make-font-bold (font)
1829   "Given an X font specification, make a bold version of it.
1830 If that can't be done, return nil."
1831   (x-frob-font-weight font "bold"))
1832 (make-obsolete 'x-make-font-bold 'make-face-bold "21.1")
1833
1834 (defun x-make-font-demibold (font)
1835   "Given an X font specification, make a demibold version of it.
1836 If that can't be done, return nil."
1837   (x-frob-font-weight font "demibold"))
1838 (make-obsolete 'x-make-font-demibold 'make-face-bold "21.1")
1839
1840 (defun x-make-font-unbold (font)
1841   "Given an X font specification, make a non-bold version of it.
1842 If that can't be done, return nil."
1843   (x-frob-font-weight font "medium"))
1844 (make-obsolete 'x-make-font-unbold 'make-face-unbold "21.1")
1845
1846 (defun x-make-font-italic (font)
1847   "Given an X font specification, make an italic version of it.
1848 If that can't be done, return nil."
1849   (x-frob-font-slant font "i"))
1850 (make-obsolete 'x-make-font-italic 'make-face-italic "21.1")
1851
1852 (defun x-make-font-oblique (font) ; you say tomayto...
1853   "Given an X font specification, make an oblique version of it.
1854 If that can't be done, return nil."
1855   (x-frob-font-slant font "o"))
1856 (make-obsolete 'x-make-font-oblique 'make-face-italic "21.1")
1857
1858 (defun x-make-font-unitalic (font)
1859   "Given an X font specification, make a non-italic version of it.
1860 If that can't be done, return nil."
1861   (x-frob-font-slant font "r"))
1862 (make-obsolete 'x-make-font-unitalic 'make-face-unitalic "21.1")
1863
1864 (defun x-make-font-bold-italic (font)
1865   "Given an X font specification, make a bold and italic version of it.
1866 If that can't be done, return nil."
1867   (and (setq font (x-make-font-bold font))
1868        (x-make-font-italic font)))
1869 (make-obsolete 'x-make-font-bold-italic 'make-face-bold-italic "21.1")
1870
1871 (provide 'faces)
1872
1873 ;;; faces.el ends here