lisp/derived.el

   1 ;;; derived.el --- allow inheritance of major modes.
   2 ;;; (formerly mode-clone.el)
   3
   4 ;; Copyright (C) 1993, 1994, 1999 Free Software Foundation, Inc.
   5
   6 ;; Author: David Megginson (dmeggins@aix1.uottawa.ca)
   7 ;; Maintainer: FSF
   8 ;; Keywords: obsolete
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26 \f
  27 ;;; Commentary:
  28
  29 ;; Obsolete.
  30 ;; Use the `derived-major-mode' provided by easy-mmode.el instead.
  31 ;; It is only kept for backward compatibility with Emacs-20 byte-compiled
  32 ;; files that refer to `derived-mode-init-mode-variables' and other functions.
  33
  34
  35
  36 ;; GNU Emacs is already, in a sense, object oriented -- each object
  37 ;; (buffer) belongs to a class (major mode), and that class defines
  38 ;; the relationship between messages (input events) and methods
  39 ;; (commands) by means of a keymap.
  40 ;;
  41 ;; The only thing missing is a good scheme of inheritance.  It is
  42 ;; possible to simulate a single level of inheritance with generous
  43 ;; use of hooks and a bit of work -- sgml-mode, for example, also runs
  44 ;; the hooks for text-mode, and keymaps can inherit from other keymaps
  45 ;; -- but generally, each major mode ends up reinventing the wheel.
  46 ;; Ideally, someone should redesign all of Emacs's major modes to
  47 ;; follow a more conventional object-oriented system: when defining a
  48 ;; new major mode, the user should need only to name the existing mode
  49 ;; it is most similar to, then list the (few) differences.
  50 ;;
  51 ;; In the mean time, this package offers most of the advantages of
  52 ;; full inheritance with the existing major modes.  The macro
  53 ;; `define-derived-mode' allows the user to make a variant of an existing
  54 ;; major mode, with its own keymap.  The new mode will inherit the key
  55 ;; bindings of its parent, and will, in fact, run its parent first
  56 ;; every time it is called.  For example, the commands
  57 ;;
  58 ;;  (define-derived-mode hypertext-mode text-mode "Hypertext"
  59 ;;    "Major mode for hypertext.\n\n\\{hypertext-mode-map}"
  60 ;;    (setq case-fold-search nil))
  61 ;;
  62 ;;  (define-key hypertext-mode-map [down-mouse-3] 'do-hyper-link)
  63 ;;
  64 ;; will create a function `hypertext-mode' with its own (sparse)
  65 ;; keymap `hypertext-mode-map.'  The command M-x hypertext-mode will
  66 ;; perform the following actions:
  67 ;;
  68 ;; - run the command (text-mode) to get its default setup
  69 ;; - replace the current keymap with 'hypertext-mode-map,' which will
  70 ;;   inherit from 'text-mode-map'.
  71 ;; - replace the current syntax table with
  72 ;;   'hypertext-mode-syntax-table', which will borrow its defaults
  73 ;;   from the current text-mode-syntax-table.
  74 ;; - replace the current abbrev table with
  75 ;;   'hypertext-mode-abbrev-table', which will borrow its defaults
  76 ;;   from the current text-mode-abbrev table
  77 ;; - change the mode line to read "Hypertext"
  78 ;; - assign the value 'hypertext-mode' to the 'major-mode' variable
  79 ;; - run the body of commands provided in the macro -- in this case,
  80 ;;   set the local variable `case-fold-search' to nil.
  81 ;;
  82 ;; The advantages of this system are threefold.  First, text mode is
  83 ;; untouched -- if you had added the new keystroke to `text-mode-map,'
  84 ;; possibly using hooks, you would have added it to all text buffers
  85 ;; -- here, it appears only in hypertext buffers, where it makes
  86 ;; sense.  Second, it is possible to build even further, and make
  87 ;; a derived mode from a derived mode.  The commands
  88 ;;
  89 ;;   (define-derived-mode html-mode hypertext-mode "HTML")
  90 ;;   [various key definitions]
  91 ;;
  92 ;; will add a new major mode for HTML with very little fuss.
  93 ;;
  94 ;; Note also the function `derived-mode-class,' which returns the non-derived
  95 ;; major mode which a derived mode is based on (ie. NOT necessarily the
  96 ;; immediate parent).
  97 ;;
  98 ;; (derived-mode-class 'text-mode) ==> text-mode
  99 ;; (derived-mode-class 'hypertext-mode) ==> text-mode
 100 ;; (derived-mode-class 'html-mode) ==> text-mode
 101 \f
 102 ;;; Code:
 103
 104 ;; PUBLIC: define a new major mode which inherits from an existing one.
 105
 106 ;; ;;;###autoload
 107 ;; Don't override the definition provided by easy-mmode.el
 108 (unless (fboundp 'define-derived-mode)
 109 (defmacro define-derived-mode (child parent name &optional docstring &rest body)
 110   "Create a new mode as a variant of an existing mode.
 111
 112 The arguments to this command are as follow:
 113
 114 CHILD:     the name of the command for the derived mode.
 115 PARENT:    the name of the command for the parent mode (e.g. `text-mode').
 116 NAME:      a string which will appear in the status line (e.g. \"Hypertext\")
 117 DOCSTRING: an optional documentation string--if you do not supply one,
 118            the function will attempt to invent something useful.
 119 BODY:      forms to execute just before running the
 120            hooks for the new mode.
 121
 122 Here is how you could define LaTeX-Thesis mode as a variant of LaTeX mode:
 123
 124   (define-derived-mode LaTeX-thesis-mode LaTeX-mode \"LaTeX-Thesis\")
 125
 126 You could then make new key bindings for `LaTeX-thesis-mode-map'
 127 without changing regular LaTeX mode.  In this example, BODY is empty,
 128 and DOCSTRING is generated by default.
 129
 130 On a more complicated level, the following command uses `sgml-mode' as
 131 the parent, and then sets the variable `case-fold-search' to nil:
 132
 133   (define-derived-mode article-mode sgml-mode \"Article\"
 134     \"Major mode for editing technical articles.\"
 135     (setq case-fold-search nil))
 136
 137 Note that if the documentation string had been left out, it would have
 138 been generated automatically, with a reference to the keymap."
 139
 140                                         ; Some trickiness, since what
 141                                         ; appears to be the docstring
 142                                         ; may really be the first
 143                                         ; element of the body.
 144   (if (and docstring (not (stringp docstring)))
 145       (progn (setq body (cons docstring body))
 146              (setq docstring nil)))
 147   (setq docstring (or docstring (derived-mode-make-docstring parent child)))
 148
 149   `(progn
 150      (derived-mode-init-mode-variables (quote ,child))
 151      (defun ,child ()
 152        ,docstring
 153        (interactive)
 154                                         ; Run the parent.
 155        (,parent)
 156                                         ; Identify special modes.
 157        (if (get (quote ,parent) 'special)
 158            (put (quote ,child) 'special t))
 159                                         ; Identify the child mode.
 160        (setq major-mode (quote ,child))
 161        (setq mode-name ,name)
 162                                         ; Set up maps and tables.
 163        (derived-mode-set-keymap (quote ,child))
 164        (derived-mode-set-syntax-table (quote ,child))
 165        (derived-mode-set-abbrev-table (quote ,child))
 166                                         ; Splice in the body (if any).
 167        ,@body
 168 ;;;                                     ; Run the setup function, if
 169 ;;;                                     ; any -- this will soon be
 170 ;;;                                     ; obsolete.
 171 ;;;      (derived-mode-run-setup-function (quote ,child))
 172                                         ; Run the hooks, if any.
 173        (derived-mode-run-hooks (quote ,child))))))
 174
 175
 176 ;; PUBLIC: find the ultimate class of a derived mode.
 177
 178 (defun derived-mode-class (mode)
 179   "Find the class of a major MODE.
 180 A mode's class is the first ancestor which is NOT a derived mode.
 181 Use the `derived-mode-parent' property of the symbol to trace backwards."
 182   (while (get mode 'derived-mode-parent)
 183     (setq mode (get mode 'derived-mode-parent)))
 184   mode)
 185
 186 \f
 187 ;; Inline functions to construct various names from a mode name.
 188
 189 (defsubst derived-mode-setup-function-name (mode)
 190   "Construct a setup-function name based on a MODE name."
 191   (intern (concat (symbol-name mode) "-setup")))
 192
 193 (defsubst derived-mode-hook-name (mode)
 194   "Construct the mode hook name based on mode name MODE."
 195   (intern (concat (symbol-name mode) "-hook")))
 196
 197 (defsubst derived-mode-map-name (mode)
 198   "Construct a map name based on a MODE name."
 199   (intern (concat (symbol-name mode) "-map")))
 200
 201 (defsubst derived-mode-syntax-table-name (mode)
 202   "Construct a syntax-table name based on a MODE name."
 203   (intern (concat (symbol-name mode) "-syntax-table")))
 204
 205 (defsubst derived-mode-abbrev-table-name (mode)
 206   "Construct an abbrev-table name based on a MODE name."
 207   (intern (concat (symbol-name mode) "-abbrev-table")))
 208
 209 \f
 210 ;; Utility functions for defining a derived mode.
 211
 212 ;;;###autoload
 213 (defun derived-mode-init-mode-variables (mode)
 214   "Initialise variables for a new MODE.
 215 Right now, if they don't already exist, set up a blank keymap, an
 216 empty syntax table, and an empty abbrev table -- these will be merged
 217 the first time the mode is used."
 218
 219   (if (boundp (derived-mode-map-name mode))
 220       t
 221     (eval `(defvar ,(derived-mode-map-name mode)
 222                (make-sparse-keymap)
 223                ,(format "Keymap for %s." mode)))
 224     (put (derived-mode-map-name mode) 'derived-mode-unmerged t))
 225
 226   (if (boundp (derived-mode-syntax-table-name mode))
 227       t
 228     (eval `(defvar ,(derived-mode-syntax-table-name mode)
 229              ;; Make a syntax table which doesn't specify anything
 230              ;; for any char.  Valid data will be merged in by
 231              ;; derived-mode-merge-syntax-tables.
 232              (make-char-table 'syntax-table nil)
 233              ,(format "Syntax table for %s." mode)))
 234     (put (derived-mode-syntax-table-name mode) 'derived-mode-unmerged t))
 235
 236   (if (boundp (derived-mode-abbrev-table-name mode))
 237       t
 238     (eval `(defvar ,(derived-mode-abbrev-table-name mode)
 239              (progn
 240                (define-abbrev-table (derived-mode-abbrev-table-name mode) nil)
 241                (make-abbrev-table))
 242              ,(format "Abbrev table for %s." mode)))))
 243
 244 (defun derived-mode-make-docstring (parent child)
 245   "Construct a docstring for a new mode if none is provided."
 246
 247   (format "This major mode is a variant of `%s', created by `define-derived-mode'.
 248 It inherits all of the parent's attributes, but has its own keymap,
 249 abbrev table and syntax table:
 250
 251   `%s-map' and `%s-syntax-table'
 252
 253 which more-or-less shadow
 254
 255   `%s-map' and `%s-syntax-table'
 256
 257 \\{%s-map}" parent child child parent parent child))
 258
 259 \f
 260 ;; Utility functions for running a derived mode.
 261
 262 (defun derived-mode-set-keymap (mode)
 263   "Set the keymap of the new MODE, maybe merging with the parent."
 264   (let* ((map-name (derived-mode-map-name mode))
 265          (new-map (eval map-name))
 266          (old-map (current-local-map)))
 267     (and old-map
 268          (get map-name 'derived-mode-unmerged)
 269          (derived-mode-merge-keymaps old-map new-map))
 270     (put map-name 'derived-mode-unmerged nil)
 271     (use-local-map new-map)))
 272
 273 (defun derived-mode-set-syntax-table (mode)
 274   "Set the syntax table of the new MODE, maybe merging with the parent."
 275   (let* ((table-name (derived-mode-syntax-table-name mode))
 276          (old-table (syntax-table))
 277          (new-table (eval table-name)))
 278     (if (get table-name 'derived-mode-unmerged)
 279         (derived-mode-merge-syntax-tables old-table new-table))
 280     (put table-name 'derived-mode-unmerged nil)
 281     (set-syntax-table new-table)))
 282
 283 (defun derived-mode-set-abbrev-table (mode)
 284   "Set the abbrev table for MODE if it exists.
 285 Always merge its parent into it, since the merge is non-destructive."
 286   (let* ((table-name (derived-mode-abbrev-table-name mode))
 287          (old-table local-abbrev-table)
 288          (new-table (eval table-name)))
 289     (derived-mode-merge-abbrev-tables old-table new-table)
 290     (setq local-abbrev-table new-table)))
 291
 292 ;;;(defun derived-mode-run-setup-function (mode)
 293 ;;;  "Run the setup function if it exists."
 294
 295 ;;;  (let ((fname (derived-mode-setup-function-name mode)))
 296 ;;;    (if (fboundp fname)
 297 ;;;     (funcall fname))))
 298
 299 (defun derived-mode-run-hooks (mode)
 300   "Run the mode hook for MODE."
 301
 302   (let ((hooks-name (derived-mode-hook-name mode)))
 303     (if (boundp hooks-name)
 304         (run-hooks hooks-name))))
 305
 306 ;; Functions to merge maps and tables.
 307
 308 (defun derived-mode-merge-keymaps (old new)
 309   "Merge an OLD keymap into a NEW one.
 310 The old keymap is set to be the last cdr of the new one, so that there will
 311 be automatic inheritance."
 312   ;; ?? Can this just use `set-keymap-parent'?
 313   (let ((tail new))
 314     ;; Scan the NEW map for prefix keys.
 315     (while (consp tail)
 316       (and (consp (car tail))
 317            (let* ((key (vector (car (car tail))))
 318                   (subnew (lookup-key new key))
 319                   (subold (lookup-key old key)))
 320              ;; If KEY is a prefix key in both OLD and NEW, merge them.
 321              (and (keymapp subnew) (keymapp subold)
 322                   (derived-mode-merge-keymaps subold subnew))))
 323       (and (vectorp (car tail))
 324            ;; Search a vector of ASCII char bindings for prefix keys.
 325            (let ((i (1- (length (car tail)))))
 326              (while (>= i 0)
 327                (let* ((key (vector i))
 328                       (subnew (lookup-key new key))
 329                       (subold (lookup-key old key)))
 330                  ;; If KEY is a prefix key in both OLD and NEW, merge them.
 331                  (and (keymapp subnew) (keymapp subold)
 332                       (derived-mode-merge-keymaps subold subnew)))
 333                (setq i (1- i)))))
 334       (setq tail (cdr tail))))
 335   (setcdr (nthcdr (1- (length new)) new) old))
 336
 337 (defun derived-mode-merge-syntax-tables (old new)
 338   "Merge an OLD syntax table into a NEW one.
 339 Where the new table already has an entry, nothing is copied from the old one."
 340   (set-char-table-parent new old))
 341
 342 ;; Merge an old abbrev table into a new one.
 343 ;; This function requires internal knowledge of how abbrev tables work,
 344 ;; presuming that they are obarrays with the abbrev as the symbol, the expansion
 345 ;; as the value of the symbol, and the hook as the function definition.
 346 (defun derived-mode-merge-abbrev-tables (old new)
 347   (if old
 348       (mapatoms
 349        (lambda (symbol)
 350          (or (intern-soft (symbol-name symbol) new)
 351              (define-abbrev new (symbol-name symbol)
 352                (symbol-value symbol) (symbol-function symbol))))
 353        old)))
 354
 355 (provide 'derived)
 356
 357 ;;; derived.el ends here