lisp/apropos.el

   1 ;;; apropos.el --- apropos commands for users and programmers.
   2
   3 ;; Copyright (C) 1989, 1994, 1995 Free Software Foundation, Inc.
   4
   5 ;; Author: Joe Wells <jbw@bigbird.bu.edu>
   6 ;; Rewritten: Daniel Pfeiffer <occitan@esperanto.org>
   7 ;; Keywords: help
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; The ideas for this package were derived from the C code in
  29 ;; src/keymap.c and elsewhere.  The functions in this file should
  30 ;; always be byte-compiled for speed.  Someone should rewrite this in
  31 ;; C (as part of src/keymap.c) for speed.
  32
  33 ;; The idea for super-apropos is based on the original implementation
  34 ;; by Lynn Slater <lrs@esl.com>.
  35
  36 ;; History:
  37 ;; Fixed bug, current-local-map can return nil.
  38 ;; Change, doesn't calculate key-bindings unless needed.
  39 ;; Added super-apropos capability, changed print functions.
  40 ;;; Made fast-apropos and super-apropos share code.
  41 ;;; Sped up fast-apropos again.
  42 ;; Added apropos-do-all option.
  43 ;;; Added fast-command-apropos.
  44 ;; Changed doc strings to comments for helping functions.
  45 ;;; Made doc file buffer read-only, buried it.
  46 ;; Only call substitute-command-keys if do-all set.
  47
  48 ;; Optionally use configurable faces to make the output more legible.
  49 ;; Differentiate between command, function and macro.
  50 ;; Apropos-command (ex command-apropos) does cmd and optionally user var.
  51 ;; Apropos shows all 3 aspects of symbols (fn, var and plist)
  52 ;; Apropos-documentation (ex super-apropos) now finds all it should.
  53 ;; New apropos-value snoops through all values and optionally plists.
  54 ;; Reading DOC file doesn't load nroff.
  55 ;; Added hypertext following of documentation, mouse-2 on variable gives value
  56 ;;   from buffer in active window.
  57
  58 ;;; Code:
  59
  60 (defgroup apropos nil
  61   "Apropos commands for users and programmers"
  62   :group 'help
  63   :prefix "apropos")
  64
  65 ;; I see a degradation of maybe 10-20% only.
  66 (defcustom apropos-do-all nil
  67   "*Whether the apropos commands should do more.
  68
  69 Slows them down more or less.  Set this non-nil if you have a fast machine."
  70   :group 'apropos
  71   :type 'boolean)
  72
  73
  74 (defcustom apropos-symbol-face 'bold
  75   "*Face for symbol name in Apropos output, or nil for none."
  76   :group 'apropos
  77   :type 'face)
  78
  79 (defcustom apropos-keybinding-face 'underline
  80   "*Face for lists of keybinding in Apropos output, or nil for none."
  81   :group 'apropos
  82   :type 'face)
  83
  84 (defcustom apropos-label-face 'italic
  85   "*Face for label (`Command', `Variable' ...) in Apropos output.
  86 A value of nil means don't use any special font for them, and also
  87 turns off mouse highlighting."
  88   :group 'apropos
  89   :type 'face)
  90
  91 (defcustom apropos-property-face 'bold-italic
  92   "*Face for property name in apropos output, or nil for none."
  93   :group 'apropos
  94   :type 'face)
  95
  96 (defcustom apropos-match-face 'secondary-selection
  97   "*Face for matching text in Apropos documentation/value, or nil for none.
  98 This applies when you look for matches in the documentation or variable value
  99 for the regexp; the part that matches gets displayed in this font."
 100   :group 'apropos
 101   :type 'face)
 102
 103
 104 (defvar apropos-mode-map
 105   (let ((map (make-sparse-keymap)))
 106     (define-key map "\C-m" 'apropos-follow)
 107     (define-key map " "    'scroll-up)
 108     (define-key map "\177" 'scroll-down)
 109     (define-key map "q"    'quit-window)
 110     (define-key map [mouse-2] 'apropos-mouse-follow)
 111     (define-key map [down-mouse-2] nil)
 112     map)
 113   "Keymap used in Apropos mode.")
 114
 115 (defvar apropos-mode-hook nil
 116   "*Hook run when mode is turned on.")
 117
 118 (defvar apropos-regexp nil
 119   "Regexp used in current apropos run.")
 120
 121 (defvar apropos-files-scanned ()
 122   "List of elc files already scanned in current run of `apropos-documentation'.")
 123
 124 (defvar apropos-accumulator ()
 125   "Alist of symbols already found in current apropos run.")
 126
 127 (defvar apropos-item ()
 128   "Current item in or for `apropos-accumulator'.")
 129 \f
 130 ;;;###autoload
 131 (define-derived-mode apropos-mode fundamental-mode "Apropos"
 132   "Major mode for following hyperlinks in output of apropos commands.
 133
 134 \\{apropos-mode-map}")
 135
 136 ;;;###autoload
 137 (defun apropos-variable (regexp &optional do-all)
 138   "Show user variables that match REGEXP.
 139 With optional prefix DO-ALL or if `apropos-do-all' is non-nil, also show
 140 normal variables."
 141   (interactive (list (read-string
 142                       (concat "Apropos "
 143                               (if (or current-prefix-arg apropos-do-all)
 144                                   "variable"
 145                                 "user option")
 146                               " (regexp): "))
 147                      current-prefix-arg))
 148   (apropos-command regexp nil
 149                    (if (or do-all apropos-do-all)
 150                        #'(lambda (symbol)
 151                            (and (boundp symbol)
 152                                 (get symbol 'variable-documentation)))
 153                      'user-variable-p)))
 154
 155 ;; For auld lang syne:
 156 ;;;###autoload
 157 (fset 'command-apropos 'apropos-command)
 158 ;;;###autoload
 159 (defun apropos-command (apropos-regexp &optional do-all var-predicate)
 160   "Show commands (interactively callable functions) that match APROPOS-REGEXP.
 161 With optional prefix DO-ALL, or if `apropos-do-all' is non-nil, also show
 162 noninteractive functions.
 163
 164 If VAR-PREDICATE is non-nil, show only variables, and only those that
 165 satisfy the predicate VAR-PREDICATE."
 166   (interactive (list (read-string (concat
 167                                    "Apropos command "
 168                                    (if (or current-prefix-arg
 169                                            apropos-do-all)
 170                                        "or function ")
 171                                    "(regexp): "))
 172                      current-prefix-arg))
 173   (let ((message
 174          (let ((standard-output (get-buffer-create "*Apropos*")))
 175            (print-help-return-message 'identity))))
 176     (or do-all (setq do-all apropos-do-all))
 177     (setq apropos-accumulator
 178           (apropos-internal apropos-regexp
 179                             (or var-predicate
 180                                 (if do-all 'functionp 'commandp))))
 181     (let ((tem apropos-accumulator))
 182       (while tem
 183         (if (get (car tem) 'apropos-inhibit)
 184             (setq apropos-accumulator (delq (car tem) apropos-accumulator)))
 185         (setq tem (cdr tem))))
 186     (let ((p apropos-accumulator)
 187           doc symbol)
 188       (while p
 189         (setcar p (list
 190                    (setq symbol (car p))
 191                    (unless var-predicate
 192                      (if (functionp symbol)
 193                          (if (setq doc (documentation symbol t))
 194                              (substring doc 0 (string-match "\n" doc))
 195                            "(not documented)")))
 196                    (and var-predicate
 197                         (funcall var-predicate symbol)
 198                         (if (setq doc (documentation-property
 199                                        symbol 'variable-documentation t))
 200                             (substring doc 0
 201                                        (string-match "\n" doc))))))
 202         (setq p (cdr p))))
 203     (and (apropos-print t nil)
 204          message
 205          (message message))))
 206
 207
 208 ;;;###autoload
 209 (defun apropos (apropos-regexp &optional do-all)
 210   "Show all bound symbols whose names match APROPOS-REGEXP.
 211 With optional prefix DO-ALL or if `apropos-do-all' is non-nil, also
 212 show unbound symbols and key bindings, which is a little more
 213 time-consuming.  Returns list of symbols and documentation found."
 214   (interactive "sApropos symbol (regexp): \nP")
 215   (setq apropos-accumulator
 216         (apropos-internal apropos-regexp
 217                           (and (not do-all)
 218                                (not apropos-do-all)
 219                                (lambda (symbol)
 220                                  (or (fboundp symbol)
 221                                      (boundp symbol)
 222                                      (facep symbol)
 223                                      (symbol-plist symbol))))))
 224   (let ((tem apropos-accumulator))
 225     (while tem
 226       (if (get (car tem) 'apropos-inhibit)
 227           (setq apropos-accumulator (delq (car tem) apropos-accumulator)))
 228       (setq tem (cdr tem))))
 229   (let ((p apropos-accumulator)
 230         symbol doc properties)
 231     (while p
 232       (setcar p (list
 233                  (setq symbol (car p))
 234                  (when (fboundp symbol)
 235                    (if (setq doc (condition-case nil
 236                                      (documentation symbol t)
 237                                    (void-function
 238                                     "(alias for undefined function)")))
 239                        (substring doc 0 (string-match "\n" doc))
 240                      "(not documented)"))
 241                  (when (boundp symbol)
 242                    (if (setq doc (documentation-property
 243                                   symbol 'variable-documentation t))
 244                        (substring doc 0 (string-match "\n" doc))
 245                      "(not documented)"))
 246                  (when (setq properties (symbol-plist symbol))
 247                    (setq doc (list (car properties)))
 248                    (while (setq properties (cdr (cdr properties)))
 249                      (setq doc (cons (car properties) doc)))
 250                    (mapconcat #'symbol-name (nreverse doc) " "))
 251                  (when (get symbol 'widget-type)
 252                    (if (setq doc (documentation-property
 253                                   symbol 'widget-documentation t))
 254                        (substring doc 0
 255                                   (string-match "\n" doc))
 256                      "(not documented)"))
 257                  (when (facep symbol)
 258                    (if (setq doc (documentation-property
 259                                   symbol 'face-documentation t))
 260                        (substring doc 0
 261                                   (string-match "\n" doc))
 262                      "(not documented)"))
 263                  (when (get symbol 'custom-group)
 264                    (if (setq doc (documentation-property
 265                                   symbol 'group-documentation t))
 266                        (substring doc 0
 267                                   (string-match "\n" doc))
 268                      "(not documented)"))))
 269       (setq p (cdr p))))
 270   (apropos-print
 271    (or do-all apropos-do-all)
 272    nil))
 273
 274
 275 ;;;###autoload
 276 (defun apropos-value (apropos-regexp &optional do-all)
 277   "Show all symbols whose value's printed image matches APROPOS-REGEXP.
 278 With optional prefix DO-ALL or if `apropos-do-all' is non-nil, also looks
 279 at the function and at the names and values of properties.
 280 Returns list of symbols and values found."
 281   (interactive "sApropos value (regexp): \nP")
 282   (or do-all (setq do-all apropos-do-all))
 283   (setq apropos-accumulator ())
 284    (let (f v p)
 285      (mapatoms
 286       (lambda (symbol)
 287         (setq f nil v nil p nil)
 288         (or (memq symbol '(apropos-regexp do-all apropos-accumulator
 289                                           symbol f v p))
 290             (setq v (apropos-value-internal 'boundp symbol 'symbol-value)))
 291         (if do-all
 292             (setq f (apropos-value-internal 'fboundp symbol 'symbol-function)
 293                   p (apropos-format-plist symbol "\n    " t)))
 294         (if (or f v p)
 295             (setq apropos-accumulator (cons (list symbol f v p)
 296                                             apropos-accumulator))))))
 297   (apropos-print nil t))
 298
 299
 300 ;;;###autoload
 301 (defun apropos-documentation (apropos-regexp &optional do-all)
 302   "Show symbols whose documentation contain matches for APROPOS-REGEXP.
 303 With optional prefix DO-ALL or if `apropos-do-all' is non-nil, also use
 304 documentation that is not stored in the documentation file and show key
 305 bindings.
 306 Returns list of symbols and documentation found."
 307   (interactive "sApropos documentation (regexp): \nP")
 308   (or do-all (setq do-all apropos-do-all))
 309   (setq apropos-accumulator () apropos-files-scanned ())
 310   (let ((standard-input (get-buffer-create " apropos-temp"))
 311         f v)
 312     (unwind-protect
 313         (save-excursion
 314           (set-buffer standard-input)
 315           (apropos-documentation-check-doc-file)
 316           (if do-all
 317               (mapatoms
 318                (lambda (symbol)
 319                  (setq f (apropos-safe-documentation symbol)
 320                        v (get symbol 'variable-documentation))
 321                  (if (integerp v) (setq v))
 322                  (setq f (apropos-documentation-internal f)
 323                        v (apropos-documentation-internal v))
 324                  (if (or f v)
 325                      (if (setq apropos-item
 326                                (cdr (assq symbol apropos-accumulator)))
 327                          (progn
 328                            (if f
 329                                (setcar apropos-item f))
 330                            (if v
 331                                (setcar (cdr apropos-item) v)))
 332                        (setq apropos-accumulator
 333                              (cons (list symbol f v)
 334                                    apropos-accumulator)))))))
 335           (apropos-print nil t))
 336       (kill-buffer standard-input))))
 337
 338 \f
 339 (defun apropos-value-internal (predicate symbol function)
 340   (if (funcall predicate symbol)
 341       (progn
 342         (setq symbol (prin1-to-string (funcall function symbol)))
 343         (if (string-match apropos-regexp symbol)
 344             (progn
 345               (if apropos-match-face
 346                   (put-text-property (match-beginning 0) (match-end 0)
 347                                      'face apropos-match-face
 348                                      symbol))
 349               symbol)))))
 350
 351 (defun apropos-documentation-internal (doc)
 352   (if (consp doc)
 353       (apropos-documentation-check-elc-file (car doc))
 354     (and doc
 355          (string-match apropos-regexp doc)
 356          (progn
 357            (if apropos-match-face
 358                (put-text-property (match-beginning 0)
 359                                   (match-end 0)
 360                                   'face apropos-match-face
 361                                   (setq doc (copy-sequence doc))))
 362            doc))))
 363
 364 (defun apropos-format-plist (pl sep &optional compare)
 365   (setq pl (symbol-plist pl))
 366   (let (p p-out)
 367     (while pl
 368       (setq p (format "%s %S" (car pl) (nth 1 pl)))
 369       (if (or (not compare) (string-match apropos-regexp p))
 370           (if apropos-property-face
 371               (put-text-property 0 (length (symbol-name (car pl)))
 372                                  'face apropos-property-face p))
 373         (setq p nil))
 374       (if p
 375           (progn
 376             (and compare apropos-match-face
 377                  (put-text-property (match-beginning 0) (match-end 0)
 378                                     'face apropos-match-face
 379                                     p))
 380             (setq p-out (concat p-out (if p-out sep) p))))
 381       (setq pl (nthcdr 2 pl)))
 382     p-out))
 383
 384
 385 ;; Finds all documentation related to APROPOS-REGEXP in internal-doc-file-name.
 386
 387 (defun apropos-documentation-check-doc-file ()
 388   (let (type symbol (sepa 2) sepb beg end)
 389     (insert ?\^_)
 390     (backward-char)
 391     (insert-file-contents (concat doc-directory internal-doc-file-name))
 392     (forward-char)
 393     (while (save-excursion
 394              (setq sepb (search-forward "\^_"))
 395              (not (eobp)))
 396       (beginning-of-line 2)
 397       (if (save-restriction
 398             (narrow-to-region (point) (1- sepb))
 399             (re-search-forward apropos-regexp nil t))
 400           (progn
 401             (setq beg (match-beginning 0)
 402                   end (point))
 403             (goto-char (1+ sepa))
 404             (or (setq type (if (eq ?F (preceding-char))
 405                                1        ; function documentation
 406                              2)         ; variable documentation
 407                       symbol (read)
 408                       beg (- beg (point) 1)
 409                       end (- end (point) 1)
 410                       doc (buffer-substring (1+ (point)) (1- sepb))
 411                       apropos-item (assq symbol apropos-accumulator))
 412                 (setq apropos-item (list symbol nil nil)
 413                       apropos-accumulator (cons apropos-item
 414                                                 apropos-accumulator)))
 415             (if apropos-match-face
 416                 (put-text-property beg end 'face apropos-match-face doc))
 417             (setcar (nthcdr type apropos-item) doc)))
 418       (setq sepa (goto-char sepb)))))
 419
 420 (defun apropos-documentation-check-elc-file (file)
 421   (if (member file apropos-files-scanned)
 422       nil
 423     (let (symbol doc beg end this-is-a-variable)
 424       (setq apropos-files-scanned (cons file apropos-files-scanned))
 425       (erase-buffer)
 426       (insert-file-contents file)
 427       (while (search-forward "\n#@" nil t)
 428         ;; Read the comment length, and advance over it.
 429         (setq end (read)
 430               beg (1+ (point))
 431               end (+ (point) end -1))
 432         (forward-char)
 433         (if (save-restriction
 434               ;; match ^ and $ relative to doc string
 435               (narrow-to-region beg end)
 436               (re-search-forward apropos-regexp nil t))
 437             (progn
 438               (goto-char (+ end 2))
 439               (setq doc (buffer-substring beg end)
 440                     end (- (match-end 0) beg)
 441                     beg (- (match-beginning 0) beg)
 442                     this-is-a-variable (looking-at "(def\\(var\\|const\\) ")
 443                     symbol (progn
 444                              (skip-chars-forward "(a-z")
 445                              (forward-char)
 446                              (read))
 447                     symbol (if (consp symbol)
 448                                (nth 1 symbol)
 449                              symbol))
 450               (if (if this-is-a-variable
 451                       (get symbol 'variable-documentation)
 452                     (and (fboundp symbol) (apropos-safe-documentation symbol)))
 453                   (progn
 454                     (or (setq apropos-item (assq symbol apropos-accumulator))
 455                         (setq apropos-item (list symbol nil nil)
 456                               apropos-accumulator (cons apropos-item
 457                                                         apropos-accumulator)))
 458                     (if apropos-match-face
 459                         (put-text-property beg end 'face apropos-match-face
 460                                            doc))
 461                     (setcar (nthcdr (if this-is-a-variable 2 1)
 462                                     apropos-item)
 463                             doc)))))))))
 464
 465
 466
 467 (defun apropos-safe-documentation (function)
 468   "Like `documentation', except it avoids calling `get_doc_string'.
 469 Will return nil instead."
 470   (while (and function (symbolp function))
 471     (setq function (if (fboundp function)
 472                        (symbol-function function))))
 473   (if (eq (car-safe function) 'macro)
 474       (setq function (cdr function)))
 475   (setq function (if (byte-code-function-p function)
 476                      (if (> (length function) 4)
 477                          (aref function 4))
 478                    (if (eq (car-safe function) 'autoload)
 479                        (nth 2 function)
 480                      (if (eq (car-safe function) 'lambda)
 481                          (if (stringp (nth 2 function))
 482                              (nth 2 function)
 483                            (if (stringp (nth 3 function))
 484                                (nth 3 function)))))))
 485   (if (integerp function)
 486       nil
 487     function))
 488
 489
 490
 491 (defvar apropos-label-properties nil
 492   "List of face properties to use for a label.
 493 Bound by `apropos-print' for use by `apropos-print-doc'.")
 494
 495 (defun apropos-print (do-keys spacing)
 496   "Output result of apropos searching into buffer `*Apropos*'.
 497 The value of `apropos-accumulator' is the list of items to output.
 498 Each element should have the format (SYMBOL FN-DOC VAR-DOC [PLIST-DOC]).
 499 The return value is the list that was in `apropos-accumulator', sorted
 500 alphabetically by symbol name; but this function also sets
 501 `apropos-accumulator' to nil before returning."
 502   (if (null apropos-accumulator)
 503       (message "No apropos matches for `%s'" apropos-regexp)
 504     (setq apropos-accumulator
 505           (sort apropos-accumulator (lambda (a b)
 506                                       (string-lessp (car a) (car b)))))
 507     (setq apropos-label-properties
 508           (if (and apropos-label-face
 509                    (symbolp apropos-label-face))
 510               `(face ,apropos-label-face
 511                      mouse-face highlight)))
 512     (with-output-to-temp-buffer "*Apropos*"
 513       (let ((p apropos-accumulator)
 514             (old-buffer (current-buffer))
 515             symbol item point1 point2)
 516         (set-buffer standard-output)
 517         (apropos-mode)
 518         (if (display-mouse-p)
 519             (insert "If you move the mouse over text that changes color,\n"
 520                     (substitute-command-keys
 521                      "you can click \\[apropos-mouse-follow] to get more information.\n")))
 522         (insert (substitute-command-keys
 523                  "In this buffer, type \\[apropos-follow] to get full documentation.\n\n"))
 524         (while (consp p)
 525           (or (not spacing) (bobp) (terpri))
 526           (setq apropos-item (car p)
 527                 symbol (car apropos-item)
 528                 p (cdr p)
 529                 point1 (point))
 530           (princ symbol)                        ; print symbol name
 531           (setq point2 (point))
 532           ;; Calculate key-bindings if we want them.
 533           (and do-keys
 534                (commandp symbol)
 535                (indent-to 30 1)
 536                (if (let ((keys
 537                           (save-excursion
 538                             (set-buffer old-buffer)
 539                             (where-is-internal symbol)))
 540                          filtered)
 541                      ;; Copy over the list of key sequences,
 542                      ;; omitting any that contain a buffer or a frame.
 543                      (while keys
 544                        (let ((key (car keys))
 545                              (i 0)
 546                              loser)
 547                          (while (< i (length key))
 548                            (if (or (framep (aref key i))
 549                                    (bufferp (aref key i)))
 550                                (setq loser t))
 551                            (setq i (1+ i)))
 552                          (or loser
 553                              (setq filtered (cons key filtered))))
 554                        (setq keys (cdr keys)))
 555                      (setq item filtered))
 556                    ;; Convert the remaining keys to a string and insert.
 557                    (insert
 558                     (mapconcat
 559                      (lambda (key)
 560                        (setq key (condition-case ()
 561                                      (key-description key)
 562                                    (error)))
 563                        (if apropos-keybinding-face
 564                            (put-text-property 0 (length key)
 565                                               'face apropos-keybinding-face
 566                                               key))
 567                        key)
 568                      item ", "))
 569                  (insert "M-x")
 570                  (put-text-property (- (point) 3) (point)
 571                                     'face apropos-keybinding-face)
 572                  (insert " " (symbol-name symbol) " ")
 573                  (insert "RET")
 574                  (put-text-property (- (point) 3) (point)
 575                                     'face apropos-keybinding-face)))
 576           (terpri)
 577           ;; only now so we don't propagate text attributes all over
 578           (put-text-property point1 point2 'item
 579                              (if (eval `(or ,@(cdr apropos-item)))
 580                                  (car apropos-item)
 581                                apropos-item))
 582           (if apropos-symbol-face
 583               (put-text-property point1 point2 'face apropos-symbol-face))
 584           (apropos-print-doc 'describe-function 1
 585                              (if (commandp symbol)
 586                                  "Command"
 587                                (if (apropos-macrop symbol)
 588                                    "Macro"
 589                                  "Function"))
 590                              t)
 591           ;; We used to use `customize-variable-other-window' instead
 592           ;; for a customizable variable, but that is slow.
 593           ;; It is better to show an ordinary help buffer
 594           ;; and let the user click on the customization button
 595           ;; in that buffer, if he wants to.
 596           ;; Likewise for `customize-face-other-window'.
 597           (apropos-print-doc 'describe-variable 2 "Variable" t)
 598           (apropos-print-doc 'customize-group-other-window 6 "Group" t)
 599           (apropos-print-doc 'describe-face 5 "Face" t)
 600           (apropos-print-doc 'widget-browse-other-window 4 "Widget" t)
 601           (apropos-print-doc 'apropos-describe-plist 3
 602                              "Plist" nil))
 603         (setq buffer-read-only t))))
 604   (prog1 apropos-accumulator
 605     (setq apropos-accumulator ())))     ; permit gc
 606
 607
 608 (defun apropos-macrop (symbol)
 609   "T if SYMBOL is a Lisp macro."
 610   (and (fboundp symbol)
 611        (consp (setq symbol
 612                     (symbol-function symbol)))
 613        (or (eq (car symbol) 'macro)
 614            (if (eq (car symbol) 'autoload)
 615                (memq (nth 4 symbol)
 616                      '(macro t))))))
 617
 618
 619 (defun apropos-print-doc (action i str do-keys)
 620   (if (stringp (setq i (nth i apropos-item)))
 621       (progn
 622         (insert "  ")
 623         (put-text-property (- (point) 2) (1- (point))
 624                            'action action)
 625         (insert str ": ")
 626         (if apropos-label-properties
 627             (add-text-properties (- (point) (length str) 2)
 628                                  (1- (point))
 629                                  apropos-label-properties))
 630         (insert (if do-keys (substitute-command-keys i) i))
 631         (or (bolp) (terpri)))))
 632
 633
 634 (defun apropos-mouse-follow (event)
 635   (interactive "e")
 636   (let ((other (if (eq (current-buffer) (get-buffer "*Apropos*"))
 637                    ()
 638                  (current-buffer))))
 639     (save-excursion
 640       (set-buffer (window-buffer (posn-window (event-start event))))
 641       (goto-char (posn-point (event-start event)))
 642       (or (and (not (eobp)) (get-text-property (point) 'mouse-face))
 643           (and (not (bobp)) (get-text-property (1- (point)) 'mouse-face))
 644           (error "There is nothing to follow here"))
 645       (apropos-follow other))))
 646
 647
 648 (defun apropos-follow (&optional other)
 649   (interactive)
 650   (let* (;; Properties are always found at the beginning of the line.
 651          (bol (save-excursion (beginning-of-line) (point)))
 652          ;; If there is no `item' property here, look behind us.
 653          (item (get-text-property bol 'item))
 654          (item-at (if item nil (previous-single-property-change bol 'item)))
 655          ;; Likewise, if there is no `action' property here, look in front.
 656          (action (get-text-property bol 'action))
 657          (action-at (if action nil (next-single-property-change bol 'action))))
 658     (and (null item) item-at
 659          (setq item (get-text-property (1- item-at) 'item)))
 660     (and (null action) action-at
 661          (setq action (get-text-property action-at 'action)))
 662     (if (not (and item action))
 663         (error "There is nothing to follow here"))
 664     (if (consp item) (error "There is nothing to follow in `%s'" (car item)))
 665     (if other (set-buffer other))
 666     (funcall action item)))
 667
 668
 669
 670 (defun apropos-describe-plist (symbol)
 671   "Display a pretty listing of SYMBOL's plist."
 672   (with-output-to-temp-buffer "*Help*"
 673     (set-buffer standard-output)
 674     (princ "Symbol ")
 675     (prin1 symbol)
 676     (princ "'s plist is\n (")
 677     (if apropos-symbol-face
 678         (put-text-property 8 (- (point) 14) 'face apropos-symbol-face))
 679     (insert (apropos-format-plist symbol "\n  "))
 680     (princ ")")
 681     (print-help-return-message)))
 682
 683 (provide 'apropos)
 684
 685 ;;; apropos.el ends here