lisp/vc/vc-sccs.el

   1 ;;; vc-sccs.el --- support for SCCS version-control
   2
   3 ;; Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   4 ;;   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   5 ;;   Free Software Foundation, Inc.
   6
   7 ;; Author:     FSF (see vc.el for full credits)
   8 ;; Maintainer: Andre Spiegel <spiegel@gnu.org>
   9 ;; Package: vc
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; Proper function of the SCCS diff commands requires the shellscript vcdiff
  29 ;; to be installed somewhere on Emacs's path for executables.
  30 ;;
  31
  32 ;;; Code:
  33
  34 (eval-when-compile
  35   (require 'vc))
  36
  37 ;;;
  38 ;;; Customization options
  39 ;;;
  40
  41 ;; ;; Maybe a better solution is to not use "get" but "sccs get".
  42 ;; (defcustom vc-sccs-path
  43 ;;   (let ((path ()))
  44 ;;     (dolist (dir '("/usr/sccs" "/usr/lib/sccs" "/usr/libexec/sccs"))
  45 ;;       (if (file-directory-p dir)
  46 ;;           (push dir path)))
  47 ;;     path)
  48 ;;   "List of extra directories to search for SCCS commands."
  49 ;;   :type '(repeat directory)
  50 ;;   :group 'vc)
  51
  52 (defcustom vc-sccs-register-switches nil
  53   "Switches for registering a file in SCCS.
  54 A string or list of strings passed to the checkin program by
  55 \\[vc-register].  If nil, use the value of `vc-register-switches'.
  56 If t, use no switches."
  57   :type '(choice (const :tag "Unspecified" nil)
  58                  (const :tag "None" t)
  59                  (string :tag "Argument String")
  60                  (repeat :tag "Argument List" :value ("") string))
  61   :version "21.1"
  62   :group 'vc)
  63
  64 (defcustom vc-sccs-diff-switches nil
  65   "String or list of strings specifying switches for SCCS diff under VC.
  66 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
  67   :type '(choice (const :tag "Unspecified" nil)
  68                  (const :tag "None" t)
  69                  (string :tag "Argument String")
  70                  (repeat :tag "Argument List" :value ("") string))
  71   :version "21.1"
  72   :group 'vc)
  73
  74 (defcustom vc-sccs-header '("%W%")
  75   "Header keywords to be inserted by `vc-insert-headers'."
  76   :type '(repeat string)
  77   :version "24.1"     ; no longer consult the obsolete vc-header-alist
  78   :group 'vc)
  79
  80 ;;;###autoload
  81 (defcustom vc-sccs-master-templates
  82   (purecopy '("%sSCCS/s.%s" "%ss.%s" vc-sccs-search-project-dir))
  83   "Where to look for SCCS master files.
  84 For a description of possible values, see `vc-check-master-templates'."
  85   :type '(choice (const :tag "Use standard SCCS file names"
  86                         ("%sSCCS/s.%s" "%ss.%s" vc-sccs-search-project-dir))
  87                  (repeat :tag "User-specified"
  88                          (choice string
  89                                  function)))
  90   :version "21.1"
  91   :group 'vc)
  92
  93 \f
  94 ;;;
  95 ;;; Internal variables
  96 ;;;
  97
  98 (defconst vc-sccs-name-assoc-file "VC-names")
  99
 100 \f
 101 ;;; Properties of the backend
 102
 103 (defun vc-sccs-revision-granularity () 'file)
 104 (defun vc-sccs-checkout-model (files) 'locking)
 105
 106 ;;;
 107 ;;; State-querying functions
 108 ;;;
 109
 110 ;; The autoload cookie below places vc-sccs-registered directly into
 111 ;; loaddefs.el, so that vc-sccs.el does not need to be loaded for
 112 ;; every file that is visited.  The definition is repeated below
 113 ;; so that Help and etags can find it.
 114
 115 ;;;###autoload (defun vc-sccs-registered(f) (vc-default-registered 'SCCS f))
 116 (defun vc-sccs-registered (f) (vc-default-registered 'SCCS f))
 117
 118 (defun vc-sccs-state (file)
 119   "SCCS-specific function to compute the version control state."
 120   (if (not (vc-sccs-registered file))
 121       'unregistered
 122     (with-temp-buffer
 123       (if (vc-insert-file (vc-sccs-lock-file file))
 124           (let* ((locks (vc-sccs-parse-locks))
 125                  (working-revision (vc-working-revision file))
 126                  (locking-user (cdr (assoc working-revision locks))))
 127             (if (not locking-user)
 128                 (if (vc-workfile-unchanged-p file)
 129                     'up-to-date
 130                   'unlocked-changes)
 131               (if (string= locking-user (vc-user-login-name file))
 132                   'edited
 133                 locking-user)))
 134         'up-to-date))))
 135
 136 (defun vc-sccs-state-heuristic (file)
 137   "SCCS-specific state heuristic."
 138   (if (not (vc-mistrust-permissions file))
 139       ;;   This implementation assumes that any file which is under version
 140       ;; control and has -rw-r--r-- is locked by its owner.  This is true
 141       ;; for both RCS and SCCS, which keep unlocked files at -r--r--r--.
 142       ;; We have to be careful not to exclude files with execute bits on;
 143       ;; scripts can be under version control too.  Also, we must ignore the
 144       ;; group-read and other-read bits, since paranoid users turn them off.
 145       (let* ((attributes  (file-attributes file 'string))
 146              (owner-name  (nth 2 attributes))
 147              (permissions (nth 8 attributes)))
 148         (if (string-match ".r-..-..-." permissions)
 149             'up-to-date
 150           (if (string-match ".rw..-..-." permissions)
 151               (if (file-ownership-preserved-p file)
 152                   'edited
 153                 owner-name)
 154             ;; Strange permissions.
 155             ;; Fall through to real state computation.
 156             (vc-sccs-state file))))
 157     (vc-sccs-state file)))
 158
 159 (defun vc-sccs-dir-status (dir update-function)
 160   ;; FIXME: this function should be rewritten, using `vc-expand-dirs'
 161   ;; is not TRTD because it returns files from multiple backends.
 162   ;; It should also return 'unregistered files.
 163
 164   ;; Doing lots of individual VC-state calls is painful, but
 165   ;; there is no better option in SCCS-land.
 166   (let ((flist (vc-expand-dirs (list dir)))
 167         (result nil))
 168     (dolist (file flist)
 169       (let ((state (vc-state file))
 170             (frel (file-relative-name file)))
 171         (when (and (eq (vc-backend file) 'SCCS)
 172                    (not (eq state 'up-to-date)))
 173           (push (list frel state) result))))
 174     (funcall update-function result)))
 175
 176 (defun vc-sccs-working-revision (file)
 177   "SCCS-specific version of `vc-working-revision'."
 178   (with-temp-buffer
 179     ;; The working revision is always the latest revision number.
 180     ;; To find this number, search the entire delta table,
 181     ;; rather than just the first entry, because the
 182     ;; first entry might be a deleted ("R") revision.
 183     (vc-insert-file (vc-name file) "^\001e\n\001[^s]")
 184     (vc-parse-buffer "^\001d D \\([^ ]+\\)" 1)))
 185
 186 (defun vc-sccs-workfile-unchanged-p (file)
 187   "SCCS-specific implementation of `vc-workfile-unchanged-p'."
 188   (zerop (apply 'vc-do-command "*vc*" 1 "vcdiff" (vc-name file)
 189                 (list "--brief" "-q"
 190                       (concat "-r" (vc-working-revision file))))))
 191
 192 \f
 193 ;;;
 194 ;;; State-changing functions
 195 ;;;
 196
 197 (defun vc-sccs-do-command (buffer okstatus command file-or-list &rest flags)
 198   ;; (let ((load-path (append vc-sccs-path load-path)))
 199   ;;   (apply 'vc-do-command buffer okstatus command file-or-list flags))
 200   (apply 'vc-do-command (or buffer "*vc*") okstatus "sccs" file-or-list command flags))
 201
 202 (defun vc-sccs-create-repo ()
 203   "Create a new SCCS repository."
 204   ;; SCCS is totally file-oriented, so all we have to do is make the directory
 205   (make-directory "SCCS"))
 206
 207 (defun vc-sccs-register (files &optional rev comment)
 208   "Register FILES into the SCCS version-control system.
 209 REV is the optional revision number for the file.  COMMENT can be used
 210 to provide an initial description of FILES.
 211 Passes either `vc-sccs-register-switches' or `vc-register-switches'
 212 to the SCCS command.
 213
 214 Automatically retrieve a read-only version of the files with keywords
 215 expanded if `vc-keep-workfiles' is non-nil, otherwise, delete the workfile."
 216   (dolist (file files)
 217     (let* ((dirname (or (file-name-directory file) ""))
 218            (basename (file-name-nondirectory file))
 219            (project-file (vc-sccs-search-project-dir dirname basename)))
 220       (let ((vc-name
 221              (or project-file
 222                  (format (car vc-sccs-master-templates) dirname basename))))
 223         (apply 'vc-sccs-do-command nil 0 "admin" vc-name
 224                (and rev (not (string= rev "")) (concat "-r" rev))
 225                "-fb"
 226                (concat "-i" (file-relative-name file))
 227                (and comment (concat "-y" comment))
 228                (vc-switches 'SCCS 'register)))
 229       (delete-file file)
 230       (if vc-keep-workfiles
 231           (vc-sccs-do-command nil 0 "get" (vc-name file))))))
 232
 233 (defun vc-sccs-responsible-p (file)
 234   "Return non-nil if SCCS thinks it would be responsible for registering FILE."
 235   ;; TODO: check for all the patterns in vc-sccs-master-templates
 236   (or (file-directory-p (expand-file-name "SCCS" (file-name-directory file)))
 237       (stringp (vc-sccs-search-project-dir (or (file-name-directory file) "")
 238                                            (file-name-nondirectory file)))))
 239
 240 (defun vc-sccs-checkin (files rev comment)
 241   "SCCS-specific version of `vc-backend-checkin'."
 242   (dolist (file (vc-expand-dirs files))
 243     (apply 'vc-sccs-do-command nil 0 "delta" (vc-name file)
 244            (if rev (concat "-r" rev))
 245            (concat "-y" comment)
 246            (vc-switches 'SCCS 'checkin))
 247     (if vc-keep-workfiles
 248         (vc-sccs-do-command nil 0 "get" (vc-name file)))))
 249
 250 (defun vc-sccs-find-revision (file rev buffer)
 251   (apply 'vc-sccs-do-command
 252          buffer 0 "get" (vc-name file)
 253          "-s" ;; suppress diagnostic output
 254          "-p"
 255          (and rev
 256               (concat "-r"
 257                       (vc-sccs-lookup-triple file rev)))
 258          (vc-switches 'SCCS 'checkout)))
 259
 260 (defun vc-sccs-checkout (file &optional editable rev)
 261   "Retrieve a copy of a saved revision of SCCS controlled FILE.
 262 If FILE is a directory, all version-controlled files beneath are checked out.
 263 EDITABLE non-nil means that the file should be writable and
 264 locked.  REV is the revision to check out."
 265   (if (file-directory-p file)
 266       (mapc 'vc-sccs-checkout (vc-expand-dirs (list file)))
 267     (let ((file-buffer (get-file-buffer file))
 268           switches)
 269       (message "Checking out %s..." file)
 270       (save-excursion
 271         ;; Change buffers to get local value of vc-checkout-switches.
 272         (if file-buffer (set-buffer file-buffer))
 273         (setq switches (vc-switches 'SCCS 'checkout))
 274         ;; Save this buffer's default-directory
 275         ;; and use save-excursion to make sure it is restored
 276         ;; in the same buffer it was saved in.
 277         (let ((default-directory default-directory))
 278           (save-excursion
 279             ;; Adjust the default-directory so that the check-out creates
 280             ;; the file in the right place.
 281             (setq default-directory (file-name-directory file))
 282
 283             (and rev (or (string= rev "")
 284                          (not (stringp rev)))
 285                  (setq rev nil))
 286             (apply 'vc-sccs-do-command nil 0 "get" (vc-name file)
 287                    (if editable "-e")
 288                    (and rev (concat "-r" (vc-sccs-lookup-triple file rev)))
 289                    switches))))
 290       (message "Checking out %s...done" file))))
 291
 292 (defun vc-sccs-rollback (files)
 293   "Roll back, undoing the most recent checkins of FILES.  Directories
 294 are expanded to all version-controlled subfiles."
 295   (setq files (vc-expand-dirs files))
 296   (if (not files)
 297       (error "SCCS backend doesn't support directory-level rollback"))
 298   (dolist (file files)
 299           (let ((discard (vc-working-revision file)))
 300             (if (null (yes-or-no-p (format "Remove version %s from %s history? "
 301                                            discard file)))
 302                 (error "Aborted"))
 303             (message "Removing revision %s from %s..." discard file)
 304             (vc-sccs-do-command nil 0 "rmdel"
 305                                 (vc-name file) (concat "-r" discard))
 306             (vc-sccs-do-command nil 0 "get" (vc-name file) nil))))
 307
 308 (defun vc-sccs-revert (file &optional contents-done)
 309   "Revert FILE to the version it was based on. If FILE is a directory,
 310 revert all subfiles."
 311   (if (file-directory-p file)
 312       (mapc 'vc-sccs-revert (vc-expand-dirs (list file)))
 313     (vc-sccs-do-command nil 0 "unget" (vc-name file))
 314     (vc-sccs-do-command nil 0 "get" (vc-name file))
 315     ;; Checking out explicit revisions is not supported under SCCS, yet.
 316     ;; We always "revert" to the latest revision; therefore
 317     ;; vc-working-revision is cleared here so that it gets recomputed.
 318     (vc-file-setprop file 'vc-working-revision nil)))
 319
 320 (defun vc-sccs-steal-lock (file &optional rev)
 321   "Steal the lock on the current workfile for FILE and revision REV."
 322   (if (file-directory-p file)
 323       (mapc 'vc-sccs-steal-lock (vc-expand-dirs (list file)))
 324     (vc-sccs-do-command nil 0 "unget"
 325                         (vc-name file) "-n" (if rev (concat "-r" rev)))
 326     (vc-sccs-do-command nil 0 "get"
 327                         (vc-name file) "-g" (if rev (concat "-r" rev)))))
 328
 329 (defun vc-sccs-modify-change-comment (files rev comment)
 330   "Modify (actually, append to) the change comments for FILES on a specified REV."
 331   (dolist (file (vc-expand-dirs files))
 332     (vc-sccs-do-command nil 0 "cdc" (vc-name file)
 333                         (concat "-y" comment) (concat "-r" rev))))
 334
 335 \f
 336 ;;;
 337 ;;; History functions
 338 ;;;
 339
 340 (defun vc-sccs-print-log (files buffer &optional shortlog start-revision-ignored limit)
 341   "Get change log associated with FILES."
 342   (setq files (vc-expand-dirs files))
 343   (vc-sccs-do-command buffer 0 "prs" (mapcar 'vc-name files))
 344   (when limit 'limit-unsupported))
 345
 346 (defun vc-sccs-diff (files &optional oldvers newvers buffer)
 347   "Get a difference report using SCCS between two filesets."
 348   (setq files (vc-expand-dirs files))
 349   (setq oldvers (vc-sccs-lookup-triple (car files) oldvers))
 350   (setq newvers (vc-sccs-lookup-triple (car files) newvers))
 351   (apply 'vc-do-command (or buffer "*vc-diff*")
 352          1 "vcdiff" (mapcar 'vc-name (vc-expand-dirs files))
 353          (append (list "-q"
 354                        (and oldvers (concat "-r" oldvers))
 355                        (and newvers (concat "-r" newvers)))
 356                  (vc-switches 'SCCS 'diff))))
 357
 358 \f
 359 ;;;
 360 ;;; Tag system.  SCCS doesn't have tags, so we simulate them by maintaining
 361 ;;; our own set of name-to-revision mappings.
 362 ;;;
 363
 364 (defun vc-sccs-create-tag (backend dir name branchp)
 365   (when branchp
 366     (error "SCCS backend %s does not support module branches" backend))
 367   (let ((result (vc-tag-precondition dir)))
 368     (if (stringp result)
 369         (error "File %s is not up-to-date" result)
 370       (vc-file-tree-walk
 371        dir
 372        (lambda (f)
 373          (vc-sccs-add-triple name f (vc-working-revision f)))))))
 374
 375 \f
 376 ;;;
 377 ;;; Miscellaneous
 378 ;;;
 379
 380 (defun vc-sccs-previous-revision (file rev)
 381   (vc-call-backend 'RCS 'previous-revision file rev))
 382
 383 (defun vc-sccs-next-revision (file rev)
 384   (vc-call-backend 'RCS 'next-revision file rev))
 385
 386 (defun vc-sccs-check-headers ()
 387   "Check if the current file has any headers in it."
 388   (save-excursion
 389     (goto-char (point-min))
 390     (re-search-forward  "%[A-Z]%" nil t)))
 391
 392 (defun vc-sccs-rename-file (old new)
 393   ;; Move the master file (using vc-rcs-master-templates).
 394   (vc-rename-master (vc-name old) new vc-sccs-master-templates)
 395   ;; Update the tag file.
 396   (with-current-buffer
 397       (find-file-noselect
 398        (expand-file-name vc-sccs-name-assoc-file
 399                          (file-name-directory (vc-name old))))
 400     (goto-char (point-min))
 401     ;; (replace-regexp (concat ":" (regexp-quote old) "$") (concat ":" new))
 402     (while (re-search-forward (concat ":" (regexp-quote old) "$") nil t)
 403       (replace-match (concat ":" new) nil nil))
 404     (basic-save-buffer)
 405     (kill-buffer (current-buffer))))
 406
 407 (defun vc-sccs-find-file-hook ()
 408   ;; If the file is locked by some other user, make
 409   ;; the buffer read-only.  Like this, even root
 410   ;; cannot modify a file that someone else has locked.
 411   (and (stringp (vc-state buffer-file-name 'SCCS))
 412        (setq buffer-read-only t)))
 413
 414 \f
 415 ;;;
 416 ;;; Internal functions
 417 ;;;
 418
 419 ;; This function is wrapped with `progn' so that the autoload cookie
 420 ;; copies the whole function itself into loaddefs.el rather than just placing
 421 ;; a (autoload 'vc-sccs-search-project-dir "vc-sccs") which would not
 422 ;; help us avoid loading vc-sccs.
 423 ;;;###autoload
 424 (progn (defun vc-sccs-search-project-dir (dirname basename)
 425   "Return the name of a master file in the SCCS project directory.
 426 Does not check whether the file exists but returns nil if it does not
 427 find any project directory."
 428   (let ((project-dir (getenv "PROJECTDIR")) dirs dir)
 429     (when project-dir
 430       (if (file-name-absolute-p project-dir)
 431           (setq dirs '("SCCS" ""))
 432         (setq dirs '("src/SCCS" "src" "source/SCCS" "source"))
 433         (setq project-dir (expand-file-name (concat "~" project-dir))))
 434       (while (and (not dir) dirs)
 435         (setq dir (expand-file-name (car dirs) project-dir))
 436         (unless (file-directory-p dir)
 437           (setq dir nil)
 438           (setq dirs (cdr dirs))))
 439       (and dir (expand-file-name (concat "s." basename) dir))))))
 440
 441 (defun vc-sccs-lock-file (file)
 442   "Generate lock file name corresponding to FILE."
 443   (let ((master (vc-name file)))
 444     (and
 445      master
 446      (string-match "\\(.*/\\)\\(s\\.\\)\\(.*\\)" master)
 447      (replace-match "p." t t master 2))))
 448
 449 (defun vc-sccs-parse-locks ()
 450   "Parse SCCS locks in current buffer.
 451 The result is a list of the form ((REVISION . USER) (REVISION . USER) ...)."
 452   (let (master-locks)
 453     (goto-char (point-min))
 454     (while (re-search-forward "^\\([0-9.]+\\) [0-9.]+ \\([^ ]+\\) .*\n?"
 455                               nil t)
 456       (setq master-locks
 457             (cons (cons (match-string 1) (match-string 2)) master-locks)))
 458     ;; FIXME: is it really necessary to reverse ?
 459     (nreverse master-locks)))
 460
 461 (defun vc-sccs-add-triple (name file rev)
 462   (with-current-buffer
 463       (find-file-noselect
 464        (expand-file-name vc-sccs-name-assoc-file
 465                          (file-name-directory (vc-name file))))
 466     (goto-char (point-max))
 467     (insert name "\t:\t" file "\t" rev "\n")
 468     (basic-save-buffer)
 469     (kill-buffer (current-buffer))))
 470
 471 (defun vc-sccs-lookup-triple (file name)
 472   "Return the numeric revision corresponding to a named tag of FILE.
 473 If NAME is nil or a revision number string it's just passed through."
 474   (if (or (null name)
 475           (let ((firstchar (aref name 0)))
 476             (and (>= firstchar ?0) (<= firstchar ?9))))
 477       name
 478     (with-temp-buffer
 479       (vc-insert-file
 480        (expand-file-name vc-sccs-name-assoc-file
 481                          (file-name-directory (vc-name file))))
 482       (vc-parse-buffer (concat name "\t:\t" file "\t\\(.+\\)") 1))))
 483
 484 (provide 'vc-sccs)
 485
 486 ;;; vc-sccs.el ends here