lisp/scroll-all.el

   1 ;;; scroll-all.el --- scroll all buffers together minor mode
   2
   3 ;; Copyright (C) 1997, 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007, 2008, 2009, 2010, 2011 Free Software Foundation, Inc.
   5
   6 ;; Author: Gary D. Foster <Gary.Foster@corp.sun.com>
   7 ;; Keywords: scroll crisp brief lock
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25 ;;    This mode allows multiple buffers to be 'locked' so that scrolling
  26 ;;    up or down lines in any buffer causes all the buffers to mirror
  27 ;;    the scrolling.  It hooks into the post-command-hook to check for
  28 ;;    potential scrolling commands and if we're locked, mirrors them in all
  29 ;;    windows.  This allows us to grab line-at-a-time scrolling as well as
  30 ;;    screen-at-a-time scrolling, and doesn't remap any of the keyboard
  31 ;;    commands to do it.
  32
  33 ;; You can enable and disable this mode with the 'scroll-all-mode' command.
  34
  35 ;; Suggestions/ideas from:
  36 ;;    Rick Macdonald <rickm@vsl.com>
  37 ;;    Anders Lindgren <andersl@csd.uu.se>
  38
  39 ;;; Code:
  40
  41 (defun scroll-all-function-all (func arg)
  42   "Apply function FUNC with argument ARG to all visible windows."
  43   (let ((num-windows (count-windows))
  44         (count 1))
  45     (when (> num-windows 1)
  46       (other-window 1)
  47       (while (< count num-windows)
  48         (condition-case nil
  49             (funcall func arg)
  50           ;; Ignore beginning- or end-of-buffer error in other windows.
  51           (error nil)
  52           )
  53         (other-window 1)
  54         (setq count (1+ count))))))
  55
  56 (defun scroll-all-scroll-down-all (arg)
  57   "Scroll down in all visible windows."
  58   (interactive "p")
  59   (scroll-all-function-all 'next-line arg))
  60
  61 (defun scroll-all-scroll-up-all (arg)
  62   "Scroll up in all visible windows."
  63   (interactive "p")
  64   (scroll-all-function-all 'previous-line arg))
  65
  66 (defun scroll-all-page-down-all (arg)
  67   "Page down in all visible windows."
  68   (interactive "P")
  69   (scroll-all-function-all 'scroll-up arg))
  70
  71 (defun scroll-all-page-up-all (arg)
  72   "Page up in all visible windows."
  73   (interactive "P")
  74   (scroll-all-function-all 'scroll-down arg))
  75
  76 (defun scroll-all-beginning-of-buffer-all (arg)
  77   "Go to the beginning of the buffer in all visible windows."
  78   (interactive "P")
  79   (scroll-all-function-all 'beginning-of-buffer arg))
  80
  81 (defun scroll-all-end-of-buffer-all (arg)
  82   "Go to the end of the buffer in all visible windows."
  83   (interactive "P")
  84   (scroll-all-function-all 'end-of-buffer arg))
  85
  86
  87 (defun scroll-all-check-to-scroll ()
  88   "Check `this-command' to see if a scroll is to be done."
  89   (cond ((eq this-command 'next-line)
  90          (call-interactively 'scroll-all-scroll-down-all))
  91         ((eq this-command 'previous-line)
  92          (call-interactively 'scroll-all-scroll-up-all))
  93         ((memq this-command '(scroll-up scroll-up-command))
  94          (call-interactively 'scroll-all-page-down-all))
  95         ((memq this-command '(scroll-down scroll-down-command))
  96          (call-interactively 'scroll-all-page-up-all))
  97         ((eq this-command 'beginning-of-buffer)
  98          (call-interactively 'scroll-all-beginning-of-buffer-all))
  99         ((eq this-command 'end-of-buffer)
 100          (call-interactively 'scroll-all-end-of-buffer-all))))
 101
 102
 103 ;;;###autoload
 104 (define-minor-mode scroll-all-mode
 105   "Toggle Scroll-All minor mode.
 106 With ARG, turn Scroll-All minor mode on if ARG is positive, off otherwise.
 107 When Scroll-All mode is on, scrolling commands entered in one window
 108 apply to all visible windows in the same frame."
 109   nil " *SL*" nil
 110   :global t
 111   :group 'windows
 112   :group 'scrolling
 113   (if scroll-all-mode
 114       (add-hook 'post-command-hook 'scroll-all-check-to-scroll)
 115     (remove-hook 'post-command-hook 'scroll-all-check-to-scroll)))
 116
 117 (provide 'scroll-all)
 118
 119 ;;; scroll-all.el ends here