lisp/progmodes/which-func.el

   1 ;;; which-func.el --- print current function in mode line
   2
   3 ;; Copyright (C) 1994, 1997, 1998, 2001, 2002, 2003, 2004, 2005, 2006
   4 ;;   2007, 2008, 2009, 2010, 2011  Free Software Foundation, Inc.
   5
   6 ;; Author:   Alex Rezinsky <alexr@msil.sps.mot.com>
   7 ;;           (doesn't seem to be responsive any more)
   8 ;; Keywords: mode-line, imenu, tools
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This package prints name of function where your current point is
  28 ;; located in mode line. It assumes that you work with imenu package
  29 ;; and imenu--index-alist is up to date.
  30
  31 ;; KNOWN BUGS
  32 ;; ----------
  33 ;; Really this package shows not "function where the current point is
  34 ;; located now", but "nearest function which defined above the current
  35 ;; point". So if your current point is located after end of function
  36 ;; FOO but before begin of function BAR, FOO will be displayed in mode
  37 ;; line.
  38 ;; - if two windows display the same buffer, both windows
  39 ;;   show the same `which-func' information.
  40
  41 ;; TODO LIST
  42 ;; ---------
  43 ;;     1. Dependence on imenu package should be removed.  Separate
  44 ;; function determination mechanism should be used to determine the end
  45 ;; of a function as well as the beginning of a function.
  46 ;;     2. This package should be realized with the help of overlay
  47 ;; properties instead of imenu--index-alist variable.
  48
  49 ;;; History:
  50
  51 ;; THANKS TO
  52 ;; ---------
  53 ;; Per Abrahamsen   <abraham@iesd.auc.dk>
  54 ;;     Some ideas (inserting  in mode-line,  using of post-command  hook
  55 ;;     and toggling this  mode) have  been   borrowed from  his  package
  56 ;;     column.el
  57 ;; Peter Eisenhauer <pipe@fzi.de>
  58 ;;     Bug fixing in case nested indexes.
  59 ;; Terry Tateyama   <ttt@ursa0.cs.utah.edu>
  60 ;;     Suggestion to use find-file-hook for first imenu
  61 ;;     index building.
  62
  63 ;;; Code:
  64
  65 ;; Variables for customization
  66 ;; ---------------------------
  67 ;;
  68 (defvar which-func-unknown "???"
  69   "String to display in the mode line when current function is unknown.")
  70
  71 (defgroup which-func nil
  72   "Mode to display the current function name in the modeline."
  73   :group 'tools
  74   :version "20.3")
  75
  76 (defcustom which-func-modes
  77   '(emacs-lisp-mode c-mode c++-mode perl-mode cperl-mode python-mode
  78                     makefile-mode sh-mode fortran-mode f90-mode ada-mode
  79                     diff-mode)
  80   "List of major modes for which Which Function mode should be used.
  81 For other modes it is disabled.  If this is equal to t,
  82 then Which Function mode is enabled in any major mode that supports it."
  83   :group 'which-func
  84   :type '(choice (const :tag "All modes" t)
  85                  (repeat (symbol :tag "Major mode"))))
  86
  87 (defcustom which-func-non-auto-modes nil
  88   "List of major modes where Which Function mode is inactive till Imenu is used.
  89 This means that Which Function mode won't really do anything
  90 until you use Imenu, in these modes.  Note that files
  91 larger than `which-func-maxout' behave in this way too;
  92 Which Function mode doesn't do anything until you use Imenu."
  93   :group 'which-func
  94   :type '(repeat (symbol :tag "Major mode")))
  95
  96 (defcustom which-func-maxout 500000
  97   "Don't automatically compute the Imenu menu if buffer is this big or bigger.
  98 Zero means compute the Imenu menu regardless of size."
  99   :group 'which-func
 100   :type 'integer)
 101
 102 (defvar which-func-keymap
 103   (let ((map (make-sparse-keymap)))
 104     (define-key map [mode-line mouse-1] 'beginning-of-defun)
 105     (define-key map [mode-line mouse-2]
 106       (lambda ()
 107         (interactive)
 108         (if (eq (point-min) 1)
 109             (narrow-to-defun)
 110           (widen))))
 111     (define-key map [mode-line mouse-3] 'end-of-defun)
 112     map)
 113   "Keymap to display on mode line which-func.")
 114
 115 (defface which-func
 116   ;; Whether `font-lock-function-name-face' is an appropriate face to
 117   ;; inherit depends on the mode-line face; define several variants based
 118   ;; on the default mode-line face.
 119   '(;; The default mode-line face on a high-color display is a relatively
 120     ;; light color ("grey75"), and only the light-background variant of
 121     ;; `font-lock-function-name-face' is visible against it.
 122     (((class color) (min-colors 88) (background light))
 123      :inherit font-lock-function-name-face)
 124     ;; The default mode-line face on other display types is inverse-video;
 125     ;; it seems that only in the dark-background case is
 126     ;; `font-lock-function-name-face' visible against it.
 127     (((class grayscale mono) (background dark))
 128      :inherit font-lock-function-name-face)
 129     (((class color) (background light))
 130      :inherit font-lock-function-name-face)
 131     ;; If none of the above cases, use an explicit color chosen to contrast
 132     ;; well with the default mode-line face.
 133     (((class color) (min-colors 88) (background dark))
 134      :foreground "Blue1")
 135     (((background dark))
 136      :foreground "Blue1")
 137     (t
 138      :foreground "LightSkyBlue"))
 139   "Face used to highlight mode line function names."
 140   :group 'which-func)
 141
 142 (defcustom which-func-format
 143   `("["
 144     (:propertize which-func-current
 145                  local-map ,which-func-keymap
 146                  face which-func
 147                  ;;mouse-face highlight ; currently not evaluated :-(
 148                  help-echo "mouse-1: go to beginning\n\
 149 mouse-2: toggle rest visibility\n\
 150 mouse-3: go to end")
 151     "]")
 152   "Format for displaying the function in the mode line."
 153   :group 'which-func
 154   :type 'sexp)
 155 ;;;###autoload (put 'which-func-format 'risky-local-variable t)
 156
 157 (defvar which-func-imenu-joiner-function (lambda (x) (car (last x)))
 158   "Function to join together multiple levels of imenu nomenclature.
 159 Called with a single argument, a list of strings giving the names
 160 of the menus we had to traverse to get to the item.  Returns a
 161 single string, the new name of the item.")
 162
 163 (defvar which-func-cleanup-function nil
 164   "Function to transform a string before displaying it in the mode line.
 165 The function is called with one argument, the string to display.
 166 Its return value is displayed in the modeline.
 167 If nil, no function is called.  The default value is nil.
 168
 169 This feature can be useful if Imenu is set up to make more
 170 detailed entries (e.g., containing the argument list of a function),
 171 and you want to simplify them for the mode line
 172 \(e.g., removing the parameter list to just have the function name.)")
 173
 174 ;;; Code, nothing to customize below here
 175 ;;; -------------------------------------
 176 ;;;
 177 (require 'imenu)
 178
 179 (defvar which-func-table (make-hash-table :test 'eq :weakness 'key))
 180
 181 (defconst which-func-current
 182   '(:eval (gethash (selected-window) which-func-table which-func-unknown)))
 183 ;;;###autoload (put 'which-func-current 'risky-local-variable t)
 184
 185 (defvar which-func-mode nil
 186   "Non-nil means display current function name in mode line.
 187 This makes a difference only if `which-function-mode' is non-nil.")
 188 (make-variable-buffer-local 'which-func-mode)
 189 ;;(put 'which-func-mode 'permanent-local t)
 190
 191 (add-hook 'find-file-hook 'which-func-ff-hook t)
 192
 193 (defun which-func-ff-hook ()
 194   "File find hook for Which Function mode.
 195 It creates the Imenu index for the buffer, if necessary."
 196   (setq which-func-mode
 197         (and which-function-mode
 198              (or (eq which-func-modes t)
 199                  (member major-mode which-func-modes))))
 200
 201   (condition-case err
 202       (if (and which-func-mode
 203                (not (member major-mode which-func-non-auto-modes))
 204                (or (null which-func-maxout)
 205                    (< buffer-saved-size which-func-maxout)
 206                    (= which-func-maxout 0)))
 207           (setq imenu--index-alist
 208                 (save-excursion (funcall imenu-create-index-function))))
 209     (error
 210      (message "which-func-ff-hook error: %S" err)
 211      (setq which-func-mode nil))))
 212
 213 (defun which-func-update ()
 214   ;; "Update the Which-Function mode display for all windows."
 215   ;; (walk-windows 'which-func-update-1 nil 'visible))
 216   (which-func-update-1 (selected-window)))
 217
 218 (defun which-func-update-1 (window)
 219   "Update the Which Function mode display for window WINDOW."
 220   (with-selected-window window
 221     (when which-func-mode
 222       (condition-case info
 223           (let ((current (which-function)))
 224             (unless (equal current (gethash window which-func-table))
 225               (puthash window current which-func-table)
 226               (force-mode-line-update)))
 227         (error
 228          (setq which-func-mode nil)
 229          (error "Error in which-func-update: %S" info))))))
 230
 231 ;;;###autoload
 232 (defalias 'which-func-mode 'which-function-mode)
 233
 234 (defvar which-func-update-timer nil)
 235
 236 ;; This is the name people would normally expect.
 237 ;;;###autoload
 238 (define-minor-mode which-function-mode
 239   "Toggle Which Function mode, globally.
 240 When Which Function mode is enabled, the current function name is
 241 continuously displayed in the mode line, in certain major modes.
 242
 243 With prefix ARG, turn Which Function mode on if arg is positive,
 244 and off otherwise."
 245   :global t :group 'which-func
 246   (when (timerp which-func-update-timer)
 247     (cancel-timer which-func-update-timer))
 248   (setq which-func-update-timer nil)
 249   (if which-function-mode
 250       ;;Turn it on
 251       (progn
 252         (setq which-func-update-timer
 253               (run-with-idle-timer idle-update-delay t 'which-func-update))
 254         (dolist (buf (buffer-list))
 255           (with-current-buffer buf
 256             (setq which-func-mode
 257                   (or (eq which-func-modes t)
 258                       (member major-mode which-func-modes))))))
 259     ;; Turn it off
 260     (dolist (buf (buffer-list))
 261       (with-current-buffer buf (setq which-func-mode nil)))))
 262
 263 (defvar which-function-imenu-failed nil
 264   "Locally t in a buffer if `imenu--make-index-alist' found nothing there.")
 265
 266 (defvar which-func-functions nil
 267   "List of functions for `which-function' to call with no arguments.
 268 It calls them sequentially, and if any returns non-nil,
 269 `which-function' uses that name and stops looking for the name.")
 270
 271 (defun which-function ()
 272   "Return current function name based on point.
 273 Uses `which-func-functions', `imenu--index-alist'
 274 or `add-log-current-defun-function'.
 275 If no function name is found, return nil."
 276   (let ((name
 277          ;; Try the `which-func-functions' functions first.
 278          (run-hook-with-args-until-success 'which-func-functions)))
 279
 280     ;; If Imenu is loaded, try to make an index alist with it.
 281     (when (and (null name)
 282                (boundp 'imenu--index-alist) (null imenu--index-alist)
 283                (null which-function-imenu-failed))
 284       (imenu--make-index-alist t)
 285       (unless imenu--index-alist
 286         (set (make-local-variable 'which-function-imenu-failed) t)))
 287     ;; If we have an index alist, use it.
 288     (when (and (null name)
 289                (boundp 'imenu--index-alist) imenu--index-alist)
 290       (let ((alist imenu--index-alist)
 291             (minoffset (point-max))
 292             offset pair mark imstack namestack)
 293         ;; Elements of alist are either ("name" . marker), or
 294         ;; ("submenu" ("name" . marker) ... ). The list can be
 295         ;; arbitrarily nested.
 296         (while (or alist imstack)
 297           (if (null alist)
 298               (setq alist     (car imstack)
 299                     namestack (cdr namestack)
 300                     imstack   (cdr imstack))
 301
 302             (setq pair (car-safe alist)
 303                   alist (cdr-safe alist))
 304
 305             (cond
 306              ((atom pair))              ; Skip anything not a cons.
 307
 308              ((imenu--subalist-p pair)
 309               (setq imstack   (cons alist imstack)
 310                     namestack (cons (car pair) namestack)
 311                     alist     (cdr pair)))
 312
 313              ((number-or-marker-p (setq mark (cdr pair)))
 314               (when (and (>= (setq offset (- (point) mark)) 0)
 315                          (< offset minoffset)) ; Find the closest item.
 316                 (setq minoffset offset
 317                       name (if (null which-func-imenu-joiner-function)
 318                                (car pair)
 319                              (funcall
 320                               which-func-imenu-joiner-function
 321                               (reverse (cons (car pair) namestack))))))))))))
 322
 323     ;; Try using add-log support.
 324     (when (and (null name) (boundp 'add-log-current-defun-function)
 325                add-log-current-defun-function)
 326       (setq name (funcall add-log-current-defun-function)))
 327     ;; Filter the name if requested.
 328     (when name
 329       (if which-func-cleanup-function
 330           (funcall which-func-cleanup-function name)
 331         name))))
 332
 333 (provide 'which-func)
 334
 335 ;;; which-func.el ends here