lisp/obsolete/resume.el

   1 ;;; resume.el --- process command line args from within a suspended Emacs job
   2
   3 ;; Copyright (C) 1992, 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007, 2008, 2009, 2010, 2011 Free Software Foundation, Inc.
   5
   6 ;; Author: Joe Wells <jbw@bucsf.bu.edu>
   7 ;; Adapted-By: ESR
   8 ;; Keywords: processes
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This file has been obsolete since Emacs 23.1.
  28
  29 ;; The purpose of this library is to handle command line arguments
  30 ;; when you resume an existing Emacs job.
  31
  32 ;; In order to use it, you must put this code in your .emacs file.
  33
  34 ;; (add-hook 'suspend-hook 'resume-suspend-hook)
  35 ;; (add-hook 'suspend-resume-hook 'resume-process-args)
  36
  37 ;; You can't get the benefit of this library by using the `emacs' command,
  38 ;; since that always starts a new Emacs job.  Instead you must use a
  39 ;; command called `edit' which knows how to resume an existing Emacs job
  40 ;; if you have one, or start a new Emacs job if you don't have one.
  41
  42 ;; To define the `edit' command, run the script etc/emacs.csh (if you use CSH),
  43 ;; or etc/emacs.bash if you use BASH.  You would normally do this in your
  44 ;; login script.
  45
  46 ;; Stephan Gildea suggested bug fix (gildea@bbn.com).
  47 ;; Ideas from Michael DeCorte and other people.
  48
  49 ;;; Code:
  50
  51 (defvar resume-emacs-args-file (expand-file-name "~/.emacs_args")
  52   "*This file is where arguments are placed for a suspended Emacs job.")
  53
  54 (defvar resume-emacs-args-buffer " *Command Line Args*"
  55   "Buffer that is used by `resume-process-args'.")
  56
  57 (defun resume-process-args ()
  58   "Handler for command line args given when Emacs is resumed."
  59   (let ((start-buffer (current-buffer))
  60         (args-buffer (get-buffer-create resume-emacs-args-buffer))
  61         length args
  62         (command-line-default-directory default-directory))
  63     (unwind-protect
  64         (progn
  65           (set-buffer args-buffer)
  66           (erase-buffer)
  67           ;; get the contents of resume-emacs-args-file
  68           (condition-case ()
  69               (let ((result (insert-file-contents resume-emacs-args-file)))
  70                 (setq length (car (cdr result))))
  71             ;; the file doesn't exist, ergo no arguments
  72             (file-error
  73               (erase-buffer)
  74               (setq length 0)))
  75           (if (<= length 0)
  76               (setq args nil)
  77             ;; get the arguments from the buffer
  78             (goto-char (point-min))
  79             (while (not (eobp))
  80               (skip-chars-forward " \t\n")
  81               (let ((begin (point)))
  82                 (skip-chars-forward "^ \t\n")
  83                 (setq args (cons (buffer-substring begin (point)) args)))
  84               (skip-chars-forward " \t\n"))
  85             ;; arguments are now in reverse order
  86             (setq args (nreverse args))
  87             ;; make sure they're not read again
  88             (erase-buffer))
  89           (resume-write-buffer-to-file (current-buffer) resume-emacs-args-file)
  90           ;; if nothing was in buffer, args will be null
  91           (or (null args)
  92               (setq command-line-default-directory
  93                     (file-name-as-directory (car args))
  94                     args (cdr args)))
  95           ;; actually process the arguments
  96           (command-line-1 args))
  97       ;; If the command line args don't result in a find-file, the
  98       ;; buffer will be left in args-buffer.  So we change back to the
  99       ;; original buffer.  The reason I don't just use
 100       ;; (let ((default-directory foo))
 101       ;;    (command-line-1 args))
 102       ;; in the context of the original buffer is because let does not
 103       ;; work properly with buffer-local variables.
 104       (if (eq (current-buffer) args-buffer)
 105           (set-buffer start-buffer)))))
 106
 107 ;;;###autoload
 108 (defun resume-suspend-hook ()
 109   "Clear out the file used for transmitting args when Emacs resumes."
 110   (with-current-buffer (get-buffer-create resume-emacs-args-buffer)
 111     (erase-buffer)
 112     (resume-write-buffer-to-file (current-buffer) resume-emacs-args-file)))
 113
 114 (defun resume-write-buffer-to-file (buffer file)
 115   "Writes the contents of BUFFER into FILE, if permissions allow."
 116   (if (not (file-writable-p file))
 117       (error "No permission to write file %s" file))
 118   (with-current-buffer buffer
 119     (clear-visited-file-modtime)
 120     (save-restriction
 121       (widen)
 122       (write-region (point-min) (point-max) file nil 'quiet))
 123     (set-buffer-modified-p nil)))
 124
 125 (provide 'resume)
 126
 127 ;;; resume.el ends here