lisp/cedet/ede/locate.el

   1 ;;; ede/locate.el --- Locate support
   2
   3 ;; Copyright (C) 2008, 2009, 2010, 2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric M. Ludlam <eric@siege-engine.com>
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23 ;;
  24 ;; Support for various LOCATE type functions.
  25 ;;
  26 ;; A key feature of EDE is `ede-expand-filename', which allows a
  27 ;; project to expand a filename reference in one file to some actual
  28 ;; filename.
  29 ;;
  30 ;; In that way, you may #include <foo.h>, and without knowing how to
  31 ;; read a Makefile, find it in <root>/include/foo.h.
  32 ;;
  33 ;; Some projects are regular, such as the Emacs project.  Some
  34 ;; projects are completely controlled by EDE, such sh the Project.ede
  35 ;; based projects.
  36 ;;
  37 ;; For other projects, having a "quick hack" to support these location
  38 ;; routines is handy.
  39 ;;
  40 ;; The baseclass `ede-locate-base' provides the abstract interface to
  41 ;; finding files in a project.
  42 ;;
  43 ;; New location routines will subclass `ede-locate-base'.
  44 ;;
  45 ;; How to use:
  46 ;;
  47 ;; Configure `ede-locate-setup-options' to add the types of locate
  48 ;; features you have available.  EDE will then enable the correct one
  49 ;; when it is available.
  50
  51 (require 'ede)
  52 (eval-when-compile (require 'data-debug)
  53                    (require 'eieio-datadebug)
  54                    (require 'cedet-global)
  55                    (require 'cedet-idutils)
  56                    (require 'cedet-cscope))
  57
  58 (require 'locate)
  59
  60 ;;; Code:
  61 (defcustom ede-locate-setup-options
  62   '(ede-locate-base)
  63   "List of locate objects to try out by default.
  64 Listed in order of preference.  If the first item cannot be used in
  65 a particular project, then the next one is tried.
  66 It is always assumed that `ede-locate-base' is at end of the list."
  67   :group 'ede
  68   :type '(repeat
  69           (choice (const :tag "None" ede-locate-base)
  70                   (const :tag "locate" ede-locate-locate)
  71                   (const :tag "GNU Global" ede-locate-global)
  72                   (const :tag "ID Utils" ede-locate-idutils)
  73                   (const :tag "CScope" ede-locate-cscope)))
  74   )
  75
  76 ;;;###autoload
  77 (defun ede-enable-locate-on-project (&optional project)
  78   "Enable an EDE locate feature on PROJECT.
  79 Attempt to guess which project locate style to use
  80 based on `ede-locate-setup-options'."
  81   (interactive)
  82   (let* ((proj (or project (ede-toplevel)))
  83          (root (ede-project-root-directory proj))
  84          (opts ede-locate-setup-options)
  85          (ans nil))
  86     (while (and opts (not ans))
  87       (when (ede-locate-ok-in-project (car opts) root)
  88         ;; If interactive, check with the user.
  89         (when (or (not (called-interactively-p 'any))
  90                   (y-or-n-p (format "Set project locator to %s? " (car opts))))
  91           (setq ans (car opts))))
  92       (setq opts (cdr opts)))
  93     ;; No match?  Always create the baseclass for the hashing tool.
  94     (when (not ans)
  95       (when (called-interactively-p 'interactive)
  96         (message "Setting locator to ede-locate-base"))
  97       (setq ans 'ede-locate-base))
  98     (oset proj locate-obj (make-instance ans "Loc" :root root))
  99     (when (called-interactively-p 'interactive)
 100       (message "Setting locator to %s" ans))
 101     ))
 102
 103 ;;; LOCATE BASECLASS
 104 ;;
 105 ;; The baseclass for all location style queries.
 106 (defclass ede-locate-base ()
 107   ((root :initarg :root
 108          :documentation
 109          "The root of these locat searches.")
 110    (file :documentation
 111          "The last file search for with EDE locate.")
 112    (lastanswer :documentation
 113               "The last answer provided by the locator.")
 114    (hash :documentation
 115          "Hash table of previously found files.")
 116    )
 117   "Baseclass for LOCATE feature in EDE.")
 118
 119 (defmethod initialize-instance ((loc ede-locate-base) &rest fields)
 120   "Make sure we have a hash table."
 121   ;; Basic setup.
 122   (call-next-method)
 123   ;; Make sure we have a hash table.
 124   (ede-locate-flush-hash loc)
 125   )
 126
 127 (defmethod ede-locate-ok-in-project :static ((loc ede-locate-base)
 128                                              root)
 129   "Is it ok to use this project type under ROOT."
 130   t)
 131
 132 (defmethod ede-locate-flush-hash ((loc ede-locate-base))
 133   "For LOC, flush hashtable and start from scratch."
 134   (oset loc hash (make-hash-table :test 'equal)))
 135
 136 (defmethod ede-locate-file-in-hash ((loc ede-locate-base)
 137                                     filestring)
 138   "For LOC, is the file FILESTRING in our hashtable?"
 139   (gethash filestring (oref loc hash)))
 140
 141 (defmethod ede-locate-add-file-to-hash ((loc ede-locate-base)
 142                                         filestring fullfilename)
 143   "For LOC, add FILESTR to the hash with FULLFILENAME."
 144   (puthash filestring fullfilename (oref loc hash)))
 145
 146 (defmethod ede-locate-file-in-project ((loc ede-locate-base)
 147                                        filesubstring
 148                                        )
 149   "Locate with LOC occurrences of FILESUBSTRING.
 150 Searches are done under the current root of the EDE project
 151 that created this EDE locate object."
 152   (let ((ans (ede-locate-file-in-project-impl loc filesubstring))
 153         )
 154     (oset loc file filesubstring)
 155     (oset loc lastanswer ans)
 156     ans))
 157
 158 (defmethod ede-locate-file-in-project-impl ((loc ede-locate-base)
 159                                             filesubstring
 160                                             )
 161   "Locate with LOC occurrences of FILESUBSTRING.
 162 Searches are done under the current root of the EDE project
 163 that created this EDE locate object."
 164   nil
 165   )
 166
 167 (defmethod ede-locate-create/update-root-database :STATIC
 168   ((loc ede-locate-base) root)
 169   "Create or update the database for the current project.
 170 You cannot create projects for the baseclass."
 171   (error "Cannot create/update a database of type %S"
 172          (object-name loc)))
 173
 174 ;;; LOCATE
 175 ;;
 176 ;; Using the standard unix "locate" command.
 177 ;; Since locate is system wide, we need to hack the search
 178 ;; to restrict it to within just this project.
 179
 180 (defclass ede-locate-locate (ede-locate-base)
 181   ()
 182   "EDE Locator using the locate command.
 183 Configure the Emacs `locate-program' variable to also
 184 configure the use of EDE locate.")
 185
 186 (defmethod ede-locate-ok-in-project :static ((loc ede-locate-locate)
 187                                              root)
 188   "Is it ok to use this project type under ROOT."
 189   (or (featurep 'locate) (locate-library "locate"))
 190   )
 191
 192 (defmethod ede-locate-file-in-project-impl ((loc ede-locate-locate)
 193                                             filesubstring)
 194   "Locate with LOC occurrences of FILESUBSTRING under PROJECTROOT.
 195 Searches are done under the current root of the EDE project
 196 that created this EDE locate object."
 197   ;; We want something like:
 198   ;;  /my/project/root*/filesubstring.c
 199   (let* ((searchstr (concat (directory-file-name (oref loc root))
 200                             "*/" filesubstring))
 201          (b (get-buffer-create "*LOCATE*"))
 202          (cd default-directory)
 203          )
 204     (with-current-buffer b
 205       (setq default-directory cd)
 206       (erase-buffer))
 207     (apply 'call-process locate-command
 208            nil b nil
 209            searchstr nil)
 210     (with-current-buffer b
 211       (split-string (buffer-string) "\n" t))
 212     )
 213   )
 214
 215 ;;; GLOBAL
 216 ;;
 217 (defclass ede-locate-global (ede-locate-base)
 218   ()
 219   "EDE Locator using GNU Global.
 220 Configure EDE's use of GNU Global through the cedet-global.el
 221 variable `cedet-global-command'.")
 222
 223 (defmethod initialize-instance ((loc ede-locate-global)
 224                                 &rest slots)
 225   "Make sure that we can use GNU Global."
 226   (require 'cedet-global)
 227   ;; Get ourselves initialized.
 228   (call-next-method)
 229   ;; Do the checks.
 230   (cedet-gnu-global-version-check)
 231   (let* ((default-directory (oref loc root))
 232          (root (cedet-gnu-global-root)))
 233     (when (not root)
 234       (error "Cannot use GNU Global in %s"
 235              (oref loc root))))
 236   )
 237
 238 (defmethod ede-locate-ok-in-project :static ((loc ede-locate-global)
 239                                              root)
 240   "Is it ok to use this project type under ROOT."
 241   (require 'cedet-global)
 242   (cedet-gnu-global-version-check)
 243   (let* ((default-directory root)
 244          (newroot (cedet-gnu-global-root)))
 245     newroot))
 246
 247 (defmethod ede-locate-file-in-project-impl ((loc ede-locate-global)
 248                                             filesubstring)
 249   "Locate with LOC occurrences of FILESUBSTRING under PROJECTROOT.
 250 Searches are done under the current root of the EDE project
 251 that created this EDE locate object."
 252   (require 'cedet-global)
 253   (let ((default-directory (oref loc root)))
 254     (cedet-gnu-global-expand-filename filesubstring)))
 255
 256 (defmethod ede-locate-create/update-root-database :STATIC
 257   ((loc ede-locate-global) root)
 258   "Create or update the GNU Global database for the current project."
 259   (cedet-gnu-global-create/update-database root))
 260
 261 ;;; IDUTILS
 262 ;;
 263 (defclass ede-locate-idutils (ede-locate-base)
 264   ()
 265   "EDE Locator using IDUtils.
 266 Configure EDE's use of IDUtils through the cedet-idutils.el
 267 file name searching variable `cedet-idutils-file-command'.")
 268
 269 (defmethod initialize-instance ((loc ede-locate-idutils)
 270                                 &rest slots)
 271   "Make sure that we can use IDUtils."
 272   ;; Get ourselves initialized.
 273   (call-next-method)
 274   ;; Do the checks.
 275   (require 'cedet-idutils)
 276   (cedet-idutils-version-check)
 277   (when (not (cedet-idutils-support-for-directory (oref loc root)))
 278     (error "Cannot use IDUtils in %s"
 279            (oref loc root)))
 280   )
 281
 282 (defmethod ede-locate-ok-in-project :static ((loc ede-locate-idutils)
 283                                              root)
 284   "Is it ok to use this project type under ROOT."
 285   (require 'cedet-idutils)
 286   (cedet-idutils-version-check)
 287   (when (cedet-idutils-support-for-directory root)
 288     root))
 289
 290 (defmethod ede-locate-file-in-project-impl ((loc ede-locate-idutils)
 291                                             filesubstring)
 292   "Locate with LOC occurrences of FILESUBSTRING under PROJECTROOT.
 293 Searches are done under the current root of the EDE project
 294 that created this EDE locate object."
 295   (require 'cedet-idutils)
 296   (let ((default-directory (oref loc root)))
 297     (cedet-idutils-expand-filename filesubstring)))
 298
 299 (defmethod ede-locate-create/update-root-database :STATIC
 300   ((loc ede-locate-idutils) root)
 301   "Create or update the GNU Global database for the current project."
 302   (cedet-idutils-create/update-database root))
 303
 304 ;;; CSCOPE
 305 ;;
 306 (defclass ede-locate-cscope (ede-locate-base)
 307   ()
 308   "EDE Locator using Cscope.
 309 Configure EDE's use of Cscope through the cedet-cscope.el
 310 file name searching variable `cedet-cscope-file-command'.")
 311
 312 (defmethod initialize-instance ((loc ede-locate-cscope)
 313                                 &rest slots)
 314   "Make sure that we can use Cscope."
 315   ;; Get ourselves initialized.
 316   (call-next-method)
 317   ;; Do the checks.
 318   (cedet-cscope-version-check)
 319   (when (not (cedet-cscope-support-for-directory (oref loc root)))
 320     (error "Cannot use Cscope in %s"
 321            (oref loc root)))
 322   )
 323
 324 (defmethod ede-locate-ok-in-project :static ((loc ede-locate-cscope)
 325                                              root)
 326   "Is it ok to use this project type under ROOT."
 327   (cedet-cscope-version-check)
 328   (when (cedet-cscope-support-for-directory root)
 329     root))
 330
 331 (defmethod ede-locate-file-in-project-impl ((loc ede-locate-cscope)
 332                                             filesubstring)
 333   "Locate with LOC occurrences of FILESUBSTRING under PROJECTROOT.
 334 Searches are done under the current root of the EDE project
 335 that created this EDE locate object."
 336   (let ((default-directory (oref loc root)))
 337     (cedet-cscope-expand-filename filesubstring)))
 338
 339 (defmethod ede-locate-create/update-root-database :STATIC
 340   ((loc ede-locate-cscope) root)
 341   "Create or update the GNU Global database for the current project."
 342   (cedet-cscope-create/update-database root))
 343
 344 (provide 'ede/locate)
 345
 346 ;; Local variables:
 347 ;; generated-autoload-file: "loaddefs.el"
 348 ;; generated-autoload-load-name: "ede/locate"
 349 ;; End:
 350
 351 ;;; ede/locate.el ends here