lisp/time.el

   1 ;;; time.el --- display time, load and mail indicator in mode line of Emacs -*-coding: utf-8 -*-
   2
   3 ;; Copyright (C) 1985, 86, 87, 93, 94, 96, 2000, 2001, 2002, 2003
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Facilities to display current time/date and a new-mail indicator
  28 ;; in the Emacs mode line.  The single entry point is `display-time'.
  29
  30 ;;; Code:
  31
  32 (defgroup display-time nil
  33   "Display time and load in mode line of Emacs."
  34   :group 'modeline
  35   :group 'mail)
  36
  37
  38 (defcustom display-time-mail-file nil
  39   "*File name of mail inbox file, for indicating existence of new mail.
  40 Non-nil and not a string means don't check for mail.  nil means use
  41 default, which is system-dependent, and is the same as used by Rmail."
  42   :type '(choice (const :tag "None" none)
  43                  (const :tag "Default" nil)
  44                  (file :format "%v"))
  45   :group 'display-time)
  46
  47 (defcustom display-time-mail-directory nil
  48   "*Name of mail inbox directory, for indicating existence of new mail.
  49 Any nonempty regular file in the directory is regarded as newly arrived mail.
  50 If nil, do not check a directory for arriving mail."
  51   :type '(choice (const :tag "None" nil)
  52                  (directory :format "%v"))
  53   :group 'display-time)
  54
  55 (defcustom display-time-mail-function nil
  56   "*Function to call, for indicating existence of new mail.
  57 If nil, that means use the default method: check that the file
  58 specified by `display-time-mail-file' is nonempty or that the
  59 directory `display-time-mail-directory' contains nonempty files."
  60   :type '(choice (const :tag "Default" nil)
  61                  (function))
  62   :group 'display-time)
  63
  64 (defcustom display-time-default-load-average 0
  65   "*Which load average value will be shown in the mode line.
  66 Almost every system can provide values of load for past 1 minute, past 5 or
  67 past 15 minutes.  The default is to display 1 minute load average."
  68   :type '(choice (const :tag "1 minute load" 0)
  69                  (const :tag "5 minutes load" 1)
  70                  (const :tag "15 minutes load" 2)
  71                  (const :tag "None" nil))
  72   :group 'display-time)
  73
  74 (defvar display-time-load-average nil
  75   "Load average currently being shown in mode line.")
  76
  77 (defcustom display-time-load-average-threshold 0.1
  78   "*Load-average values below this value won't be shown in the mode line."
  79   :type 'number
  80   :group 'display-time)
  81
  82 ;;;###autoload
  83 (defcustom display-time-day-and-date nil "\
  84 *Non-nil means \\[display-time] should display day and date as well as time."
  85   :type 'boolean
  86   :group 'display-time)
  87
  88 (defvar display-time-timer nil)
  89
  90 (defcustom display-time-interval 60
  91   "*Seconds between updates of time in the mode line."
  92   :type 'integer
  93   :group 'display-time)
  94
  95 (defcustom display-time-24hr-format nil
  96   "*Non-nil indicates time should be displayed as hh:mm, 0 <= hh <= 23.
  97 nil means 1 <= hh <= 12, and an AM/PM suffix is used."
  98   :type 'boolean
  99   :group 'display-time)
 100
 101 (defvar display-time-string nil)
 102
 103 (defcustom display-time-hook nil
 104   "*List of functions to be called when the time is updated on the mode line."
 105   :type 'hook
 106   :group 'display-time)
 107
 108 (defvar display-time-server-down-time nil
 109    "Time when mail file's file system was recorded to be down.
 110 If that file system seems to be up, the value is nil.")
 111
 112 ;;;###autoload
 113 (defun display-time ()
 114   "Enable display of time, load level, and mail flag in mode lines.
 115 This display updates automatically every minute.
 116 If `display-time-day-and-date' is non-nil, the current day and date
 117 are displayed as well.
 118 This runs the normal hook `display-time-hook' after each update."
 119   (interactive)
 120   (display-time-mode 1))
 121
 122 ;; This business used to be simpler when all mode lines had the same
 123 ;; face and the image could just be pbm.  Now we try to rely on an xpm
 124 ;; image with a transparent background.  Otherwise, set the background
 125 ;; for pbm.
 126
 127 (defcustom display-time-mail-face nil
 128   "Face to use for `display-time-mail-string'.
 129 If `display-time-use-mail-icon' is non-nil, the image's
 130 background colour is the background of this face.  Set this to
 131 make the mail indicator stand out on a colour display."
 132   :group 'faces
 133   :group 'display-time
 134   :version "22.1"
 135   :type '(choice (const :tag "None" nil) face))
 136
 137 (defvar display-time-mail-icon
 138   (find-image '((:type xpm :file "letter.xpm" :ascent center)
 139                 (:type pbm :file "letter.pbm" :ascent center)))
 140   "Image specification to offer as the mail indicator on a graphic display.
 141 See `display-time-use-mail-icon' and `display-time-mail-face'.")
 142
 143 ;; Fixme: Default to icon on graphical display?
 144 (defcustom display-time-use-mail-icon nil
 145   "Non-nil means use an icon as the mail indicator on a graphic display.
 146 Otherwise use `display-time-mail-string'.  The icon may consume less
 147 of the mode line.  It is specified by `display-time-mail-icon'."
 148   :group 'display-time
 149   :type 'boolean)
 150
 151 ;; Fixme: maybe default to the character if we can display Unicode.
 152 (defcustom display-time-mail-string "Mail"
 153   "String to use as the mail indicator in `display-time-string-forms'.
 154 This can use the Unicode letter character if you can display it."
 155   :group 'display-time
 156   :version "22.1"
 157   :type '(choice (const "Mail")
 158                  ;; Use :tag here because the Lucid menu won't display
 159                  ;; multibyte text.
 160                  (const :tag "Unicode letter character" "✉")
 161                  string))
 162
 163 (defcustom display-time-format nil
 164   "*A string specifying the format for displaying the time in the mode line.
 165 See the function `format-time-string' for an explanation of
 166 how to write this string.  If this is nil, the defaults
 167 depend on `display-time-day-and-date' and `display-time-24hr-format'."
 168   :type '(choice (const :tag "Default" nil)
 169                  string)
 170   :group 'display-time)
 171
 172 (defcustom display-time-string-forms
 173   '((if (and (not display-time-format) display-time-day-and-date)
 174         (format-time-string "%a %b %e " now)
 175       "")
 176     (propertize
 177      (format-time-string (or display-time-format
 178                              (if display-time-24hr-format "%H:%M" "%-I:%M%p"))
 179                          now)
 180      'help-echo (format-time-string "%a %b %e, %Y" now))
 181     load
 182     (if mail
 183         ;; Build the string every time to act on customization.
 184         ;; :set-after doesn't help for `customize-option'.  I think it
 185         ;; should.
 186         (concat
 187          " "
 188          (propertize
 189           display-time-mail-string
 190           'display `(when (and display-time-use-mail-icon
 191                                (display-graphic-p))
 192                       ,@display-time-mail-icon
 193                       ,@(if (and display-time-mail-face
 194                                  (memq (plist-get (cdr display-time-mail-icon)
 195                                                   :type)
 196                                        '(pbm xbm)))
 197                             (let ((bg (face-attribute display-time-mail-face
 198                                                       :background)))
 199                               (if (stringp bg)
 200                                   (list :background bg)))))
 201           'face display-time-mail-face
 202           'help-echo "You have new mail; mouse-2: Read mail"
 203           'local-map (make-mode-line-mouse-map 'mouse-2
 204                                                read-mail-command)))
 205       ""))
 206   "*A list of expressions governing display of the time in the mode line.
 207 For most purposes, you can control the time format using `display-time-format'
 208 which is a more standard interface.
 209
 210 This expression is a list of expressions that can involve the keywords
 211 `load', `day', `month', and `year', `12-hours', `24-hours', `minutes',
 212 `seconds', all numbers in string form, and `monthname', `dayname', `am-pm',
 213 and `time-zone' all alphabetic strings, and `mail' a true/nil value.
 214
 215 For example, the form
 216
 217   '((substring year -2) \"/\" month \"/\" day
 218     \" \" 24-hours \":\" minutes \":\" seconds
 219     (if time-zone \" (\") time-zone (if time-zone \")\")
 220     (if mail \" Mail\" \"\"))
 221
 222 would give mode line times like `94/12/30 21:07:48 (UTC)'."
 223   :type 'sexp
 224   :group 'display-time)
 225
 226 (defun display-time-event-handler ()
 227   (display-time-update)
 228   ;; Do redisplay right now, if no input pending.
 229   (sit-for 0)
 230   (let* ((current (current-time))
 231          (timer display-time-timer)
 232          ;; Compute the time when this timer will run again, next.
 233          (next-time (timer-relative-time
 234                      (list (aref timer 1) (aref timer 2) (aref timer 3))
 235                      (* 5 (aref timer 4)) 0)))
 236     ;; If the activation time is far in the past,
 237     ;; skip executions until we reach a time in the future.
 238     ;; This avoids a long pause if Emacs has been suspended for hours.
 239     (or (> (nth 0 next-time) (nth 0 current))
 240         (and (= (nth 0 next-time) (nth 0 current))
 241              (> (nth 1 next-time) (nth 1 current)))
 242         (and (= (nth 0 next-time) (nth 0 current))
 243              (= (nth 1 next-time) (nth 1 current))
 244              (> (nth 2 next-time) (nth 2 current)))
 245         (progn
 246           (timer-set-time timer (timer-next-integral-multiple-of-time
 247                                  current display-time-interval)
 248                           display-time-interval)
 249           (timer-activate timer)))))
 250
 251 (defun display-time-next-load-average ()
 252   (interactive)
 253   (if (= 3 (setq display-time-load-average (1+ display-time-load-average)))
 254       (setq display-time-load-average 0))
 255   (display-time-update)
 256   (sit-for 0))
 257
 258 (defun display-time-mail-check-directory ()
 259   (let ((mail-files (directory-files display-time-mail-directory t))
 260         (size 0))
 261     (while (and mail-files (= size 0))
 262       ;; Count size of regular files only.
 263       (setq size (+ size (or (and (file-regular-p (car mail-files))
 264                                   (nth 7 (file-attributes (car mail-files))))
 265                              0)))
 266       (setq mail-files (cdr mail-files)))
 267     (if (> size 0)
 268         size
 269       nil)))
 270
 271 (defun display-time-update ()
 272   "Update the display-time info for the mode line.
 273 However, don't redisplay right now.
 274
 275 This is used for things like Rmail `g' that want to force an
 276 update which can wait for the next redisplay."
 277   (let* ((now (current-time))
 278          (time (current-time-string now))
 279          (load (if (null display-time-load-average)
 280                    ""
 281                  (condition-case ()
 282                      ;; Do not show values less than
 283                      ;; `display-time-load-average-threshold'.
 284                      (if (> (* display-time-load-average-threshold 100)
 285                             (nth display-time-load-average (load-average)))
 286                          ""
 287                        ;; The load average number is mysterious, so
 288                        ;; provide some help.
 289                        (let ((str (format " %03d"
 290                                           (nth display-time-load-average
 291                                                (load-average)))))
 292                          (propertize
 293                           (concat (substring str 0 -2) "." (substring str -2))
 294                           'local-map (make-mode-line-mouse-map
 295                                       'mouse-2 'display-time-next-load-average)
 296                           'help-echo (concat
 297                                       "System load average for past "
 298                                       (if (= 0 display-time-load-average)
 299                                           "1 minute"
 300                                         (if (= 1 display-time-load-average)
 301                                             "5 minutes"
 302                                           "15 minutes"))
 303                                       "; mouse-2: next"))))
 304                    (error ""))))
 305          (mail-spool-file (or display-time-mail-file
 306                               (getenv "MAIL")
 307                               (concat rmail-spool-directory
 308                                       (user-login-name))))
 309          (mail (or (and display-time-mail-function
 310                         (funcall display-time-mail-function))
 311                    (and display-time-mail-directory
 312                         (display-time-mail-check-directory))
 313                    (and (stringp mail-spool-file)
 314                         (or (null display-time-server-down-time)
 315                             ;; If have been down for 20 min, try again.
 316                             (> (- (nth 1 now) display-time-server-down-time)
 317                                1200)
 318                             (and (< (nth 1 now) display-time-server-down-time)
 319                                  (> (- (nth 1 now)
 320                                        display-time-server-down-time)
 321                                     -64336)))
 322                         (let ((start-time (current-time)))
 323                           (prog1
 324                               (display-time-file-nonempty-p mail-spool-file)
 325                             (if (> (- (nth 1 (current-time))
 326                                       (nth 1 start-time))
 327                                    20)
 328                                 ;; Record that mail file is not accessible.
 329                                 (setq display-time-server-down-time
 330                                       (nth 1 (current-time)))
 331                               ;; Record that mail file is accessible.
 332                               (setq display-time-server-down-time nil)))))))
 333          (24-hours (substring time 11 13))
 334          (hour (string-to-number 24-hours))
 335          (12-hours (int-to-string (1+ (% (+ hour 11) 12))))
 336          (am-pm (if (>= hour 12) "pm" "am"))
 337          (minutes (substring time 14 16))
 338          (seconds (substring time 17 19))
 339          (time-zone (car (cdr (current-time-zone now))))
 340          (day (substring time 8 10))
 341          (year (substring time 20 24))
 342          (monthname (substring time 4 7))
 343          (month
 344           (cdr
 345            (assoc
 346             monthname
 347             '(("Jan" . "1") ("Feb" . "2") ("Mar" . "3") ("Apr" . "4")
 348               ("May" . "5") ("Jun" . "6") ("Jul" . "7") ("Aug" . "8")
 349               ("Sep" . "9") ("Oct" . "10") ("Nov" . "11") ("Dec" . "12")))))
 350          (dayname (substring time 0 3)))
 351     (setq display-time-string
 352           (mapconcat 'eval display-time-string-forms ""))
 353     ;; This is inside the let binding, but we are not going to document
 354     ;; what variables are available.
 355     (run-hooks 'display-time-hook))
 356   (force-mode-line-update))
 357
 358 (defun display-time-file-nonempty-p (file)
 359   (and (file-exists-p file)
 360        (< 0 (nth 7 (file-attributes (file-chase-links file))))))
 361
 362 ;;;###autoload
 363 (define-minor-mode display-time-mode
 364   "Toggle display of time, load level, and mail flag in mode lines.
 365 With a numeric arg, enable this display if arg is positive.
 366
 367 When this display is enabled, it updates automatically every minute.
 368 If `display-time-day-and-date' is non-nil, the current day and date
 369 are displayed as well.
 370 This runs the normal hook `display-time-hook' after each update."
 371   :global t :group 'display-time
 372   (and display-time-timer (cancel-timer display-time-timer))
 373   (setq display-time-timer nil)
 374   (setq display-time-string "")
 375   (or global-mode-string (setq global-mode-string '("")))
 376   (setq display-time-load-average display-time-default-load-average)
 377   (if display-time-mode
 378       (progn
 379         (or (memq 'display-time-string global-mode-string)
 380             (setq global-mode-string
 381                   (append global-mode-string '(display-time-string))))
 382         ;; Set up the time timer.
 383         (setq display-time-timer
 384               (run-at-time t display-time-interval
 385                            'display-time-event-handler))
 386         ;; Make the time appear right away.
 387         (display-time-update)
 388         ;; When you get new mail, clear "Mail" from the mode line.
 389         (add-hook 'rmail-after-get-new-mail-hook
 390                   'display-time-event-handler))
 391     (remove-hook 'rmail-after-get-new-mail-hook
 392                  'display-time-event-handler)))
 393
 394 (provide 'time)
 395
 396 ;;; arch-tag: b9c1623f-b5cb-48e4-b650-482a4d23c5a6
 397 ;;; time.el ends here