lisp/mail/mailalias.el

   1 ;;; mailalias.el --- expand and complete mailing address aliases
   2
   3 ;; Copyright (C) 1985, 1987, 1995, 1996, 1997 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Basic functions for defining and expanding mail aliases.
  28 ;; These seal off the interface to the alias-definition parts of a
  29 ;; .mailrc file formatted for BSD's Mail or USL's mailx.
  30
  31 ;;; Code:
  32
  33 (require 'sendmail)
  34
  35 (defgroup mailalias nil
  36   "Expanding mail aliases"
  37   :group 'mail)
  38
  39 (defcustom mail-passwd-files '("/etc/passwd")
  40   "*List of files from which to determine valid user names."
  41   :type '(repeat string)
  42   :group 'mailalias)
  43
  44 (defcustom mail-passwd-command nil
  45   "*Shell command to retrieve text to add to `/etc/passwd', or nil."
  46   :type '(choice string (const nil))
  47   :group 'mailalias)
  48
  49 (defvar mail-directory-names t
  50   "Alist of mail address directory entries.
  51 When t this still needs to be initialized.")
  52
  53 (defvar mail-address-field-regexp
  54   "^\\(Resent-\\)?\\(To\\|From\\|CC\\|BCC\\|Reply-to\\):")
  55
  56 (defcustom mail-complete-alist
  57   ;; Don't use backquote here; we don't want backquote to get loaded
  58   ;; just because of loading this file.
  59   ;; Don't refer to mail-address-field-regexp here;
  60   ;; that confuses some things such as cus-dep.el.
  61   (cons '("^\\(Resent-\\)?\\(To\\|From\\|CC\\|BCC\\|Reply-to\\):"
  62           . (mail-get-names pattern))
  63         '(("Newsgroups:" . (if (boundp 'gnus-active-hashtb)
  64                                gnus-active-hashtb
  65                              (if (boundp news-group-article-assoc)
  66                                  news-group-article-assoc)))
  67           ("Followup-To:" . (mail-sentto-newsgroups))
  68           ;;("Distribution:" ???)
  69           ))
  70   "*Alist of header field and expression to return alist for completion.
  71 The expression may reference the variable `pattern'
  72 which will hold the string being completed.
  73 If not on matching header, `mail-complete-function' gets called instead."
  74   :type 'alist
  75   :group 'mailalias)
  76 (put 'mail-complete-alist 'risky-local-variable t)
  77
  78 ;;;###autoload
  79 (defcustom mail-complete-style 'angles
  80   "*Specifies how \\[mail-complete] formats the full name when it completes.
  81 If `nil', they contain just the return address like:
  82         king@grassland.com
  83 If `parens', they look like:
  84         king@grassland.com (Elvis Parsley)
  85 If `angles', they look like:
  86         Elvis Parsley <king@grassland.com>"
  87   :type '(choice (const angles) (const parens) (const nil))
  88   :group 'mailalias)
  89
  90 (defcustom mail-complete-function 'ispell-complete-word
  91   "*Function to call when completing outside `mail-complete-alist'-header."
  92   :type '(choice function (const nil))
  93   :group 'mailalias)
  94
  95 (defcustom mail-directory-function nil
  96   "*Function to get completions from directory service or nil for none.
  97 See `mail-directory-requery'."
  98   :type '(choice function (const nil))
  99   :group 'mailalias)
 100
 101 ;; This is for when the directory is huge, or changes frequently.
 102 (defcustom mail-directory-requery nil
 103   "*When non-nil call `mail-directory-function' for each completion.
 104 In that case, one argument gets passed to the function, the partial string
 105 entered so far."
 106   :type 'boolean
 107   :group 'mailalias)
 108
 109 (defcustom mail-directory-process nil
 110   "*Shell command to get the list of names from a mail directory.
 111 This value is used when the value of `mail-directory-function'
 112 is `mail-directory-process'.  The value should be a list
 113 of the form (COMMAND ARG ...), where each of the list elements
 114 is evaluated.  COMMAND should evaluate to a string.  When
 115 `mail-directory-requery' is non-nil, during evaluation of these
 116 elements, the variable `pattern' contains the partial input being
 117 completed.  `pattern' is nil when `mail-directory-requery' is nil.
 118
 119 The value might look like this:
 120
 121   '(remote-shell-program \"HOST\" \"-nl\" \"USER\" \"COMMAND\")
 122
 123 or like this:
 124
 125   '(remote-shell-program \"HOST\" \"-n\" \"COMMAND '^\" pattern \"'\")"
 126   :type 'sexp
 127   :group 'mailalias)
 128 (put 'mail-directory-process 'risky-local-variable t)
 129
 130 (defcustom mail-directory-stream nil
 131   "*List of (HOST SERVICE) for stream connection to mail directory."
 132   :type 'sexp
 133   :group 'mailalias)
 134 (put 'mail-directory-stream 'risky-local-variable t)
 135
 136 (defcustom mail-directory-parser nil
 137   "*How to interpret the output of `mail-directory-function'.
 138 Three types of values are possible:
 139
 140   - nil means to gather each line as one name
 141   - regexp means first \\(grouping\\) in successive matches is name
 142   - function called at beginning of buffer that returns an alist of names"
 143   :type '(choice (const nil) regexp function)
 144   :group 'mailalias)
 145 (put 'mail-directory-parser 'risky-local-variable t)
 146
 147 ;; Internal variables.
 148
 149 (defvar mail-names t
 150   "Alist of local users, aliases and directory entries as available.
 151 Elements have the form (MAILNAME) or (MAILNAME . FULLNAME).
 152 If the value means t, it means the real value should be calculated
 153 for the next use.  This is used in `mail-complete'.")
 154
 155 (defvar mail-local-names t
 156   "Alist of local users.
 157 When t this still needs to be initialized.")
 158 \f
 159
 160 ;; Called from sendmail-send-it, or similar functions,
 161 ;; only if some mail aliases are defined.
 162 ;;;###autoload
 163 (defun expand-mail-aliases (beg end &optional exclude)
 164   "Expand all mail aliases in suitable header fields found between BEG and END.
 165 If interactive, expand in header fields.
 166 Suitable header fields are `To', `From', `CC' and `BCC', `Reply-to', and
 167 their `Resent-' variants.
 168
 169 Optional second arg EXCLUDE may be a regular expression defining text to be
 170 removed from alias expansions."
 171   (interactive
 172    (save-excursion
 173      (list (goto-char (point-min))
 174            (mail-header-end))))
 175   (sendmail-sync-aliases)
 176   (when (eq mail-aliases t)
 177     (setq mail-aliases nil)
 178     (build-mail-aliases))
 179   (save-excursion
 180     (goto-char beg)
 181     (setq end (set-marker (make-marker) end))
 182     (let ((case-fold-search nil))
 183       (while (let ((case-fold-search t))
 184                (re-search-forward mail-address-field-regexp end t))
 185         (skip-chars-forward " \t")
 186         (let ((beg1 (point))
 187               end1 pos epos seplen
 188               ;; DISABLED-ALIASES records aliases temporarily disabled
 189               ;; while we scan text that resulted from expanding those aliases.
 190               ;; Each element is (ALIAS . TILL-WHEN), where TILL-WHEN
 191               ;; is where to reenable the alias (expressed as number of chars
 192               ;; counting from END1).
 193               (disabled-aliases nil))
 194           (re-search-forward "^[^ \t]" end 'move)
 195           (beginning-of-line)
 196           (skip-chars-backward " \t\n")
 197           (setq end1 (point-marker))
 198           (goto-char beg1)
 199           (while (< (point) end1)
 200             (setq pos (point))
 201             ;; Reenable any aliases which were disabled for ranges
 202             ;; that we have passed out of.
 203             (while (and disabled-aliases
 204                         (> pos (- end1 (cdr (car disabled-aliases)))))
 205               (setq disabled-aliases (cdr disabled-aliases)))
 206             ;; EPOS gets position of end of next name;
 207             ;; SEPLEN gets length of whitespace&separator that follows it.
 208             (if (re-search-forward "[ \t]*[\n,][ \t]*" end1 t)
 209                 (setq epos (match-beginning 0)
 210                       seplen (- (point) epos))
 211               (setq epos (marker-position end1) seplen 0))
 212             (let ((string (buffer-substring-no-properties pos epos))
 213                   translation)
 214               (if (and (not (assoc string disabled-aliases))
 215                        (setq translation (cdr (assoc string mail-aliases))))
 216                   (progn
 217                     ;; This name is an alias.  Disable it.
 218                     (setq disabled-aliases (cons (cons string (- end1 epos))
 219                                                  disabled-aliases))
 220                     ;; Replace the alias with its expansion
 221                     ;; then rescan the expansion for more aliases.
 222                     (goto-char pos)
 223                     (insert translation)
 224                     (when exclude
 225                       (let ((regexp (concat "\\b\\(" exclude "\\)\\b"))
 226                             (end (point-marker)))
 227                         (goto-char pos)
 228                         (while (re-search-forward regexp end t)
 229                           (replace-match ""))
 230                         (goto-char end)))
 231                     (delete-region (point) (+ (point) (- epos pos)))
 232                     (goto-char pos))
 233                 ;; Name is not an alias.  Skip to start of next name.
 234                 (goto-char epos)
 235                 (forward-char seplen))))
 236           (set-marker end1 nil)))
 237       (set-marker end nil))))
 238
 239 ;; Called by mail-setup, or similar functions, only if the file specified
 240 ;; by mail-personal-alias-file (usually `~/.mailrc') exists.
 241 (defun build-mail-aliases (&optional file)
 242   "Read mail aliases from personal aliases file and set `mail-aliases'.
 243 By default, this is the file specified by `mail-personal-alias-file'."
 244   (setq file (expand-file-name (or file mail-personal-alias-file)))
 245   ;; In case mail-aliases is t, make sure define-mail-alias
 246   ;; does not recursively call build-mail-aliases.
 247   (setq mail-aliases nil)
 248   (let ((buffer nil)
 249         (obuf (current-buffer)))
 250     (unwind-protect
 251         (progn
 252           (setq buffer (generate-new-buffer " mailrc"))
 253           (set-buffer buffer)
 254           (while file
 255             (cond ((get-file-buffer file)
 256                    (insert (save-excursion
 257                              (set-buffer (get-file-buffer file))
 258                              (buffer-substring-no-properties
 259                               (point-min) (point-max)))))
 260                   ((file-exists-p file) (insert-file-contents file))
 261                   ((file-exists-p (setq file (concat "~/" file)))
 262                    (insert-file-contents file))
 263                   (t (setq file nil)))
 264             ;; Don't lose if no final newline.
 265             (goto-char (point-max))
 266             (or (eq (preceding-char) ?\n) (newline))
 267             (goto-char (point-min))
 268             ;; handle "\\\n" continuation lines
 269             (while (not (eobp))
 270               (end-of-line)
 271               (if (= (preceding-char) ?\\)
 272                   (progn (delete-char -1) (delete-char 1) (insert ?\ ))
 273                 (forward-char 1)))
 274             (goto-char (point-min))
 275             ;; handle `source' directives -- Eddy/1994/May/25
 276             (cond ((re-search-forward "^source[ \t]+" nil t)
 277                    (re-search-forward "\\S-+")
 278                    (setq file (buffer-substring-no-properties
 279                                (match-beginning 0) (match-end 0)))
 280                    (beginning-of-line)
 281                    (insert "# ") ; to ensure we don't re-process this file
 282                    (beginning-of-line))
 283                   (t (setq file nil))))
 284           (goto-char (point-min))
 285           (while (re-search-forward
 286                   "^\\(a\\|alias\\|g\\|group\\)[ \t]+\\([^ \t\n]+\\)" nil t)
 287             (let* ((name (match-string 2))
 288                    (start (progn (skip-chars-forward " \t") (point)))
 289                    value)
 290               (end-of-line)
 291               (setq value (buffer-substring-no-properties start (point)))
 292               (unless (equal value "")
 293                 (define-mail-alias name value t))))
 294           mail-aliases)
 295       (if buffer (kill-buffer buffer))
 296       (set-buffer obuf))))
 297
 298 ;; Always autoloadable in case the user wants to define aliases
 299 ;; interactively or in .emacs.
 300 ;;;###autoload
 301 (defun define-mail-alias (name definition &optional from-mailrc-file)
 302   "Define NAME as a mail alias that translates to DEFINITION.
 303 This means that sending a message to NAME will actually send to DEFINITION.
 304
 305 Normally, the addresses in DEFINITION must be separated by commas.
 306 If FROM-MAILRC-FILE is non-nil, then addresses in DEFINITION
 307 can be separated by spaces; an address can contain spaces
 308 if it is quoted with double-quotes."
 309
 310   (interactive "sDefine mail alias: \nsDefine %s as mail alias for: ")
 311   ;; Read the defaults first, if we have not done so.
 312   ;; But not if we are doing that already right now.
 313   (unless from-mailrc-file
 314     (sendmail-sync-aliases))
 315   (if (eq mail-aliases t)
 316       (progn
 317         (setq mail-aliases nil)
 318         (if (file-exists-p mail-personal-alias-file)
 319             (build-mail-aliases))))
 320   ;; strip garbage from front and end
 321   (if (string-match "\\`[ \t\n,]+" definition)
 322       (setq definition (substring definition (match-end 0))))
 323   (if (string-match "[ \t\n,]+\\'" definition)
 324       (setq definition (substring definition 0 (match-beginning 0))))
 325   (let ((result '())
 326         ;; If DEFINITION is null string, avoid looping even once.
 327         (start (and (not (equal definition "")) 0))
 328         (L (length definition))
 329         convert-backslash
 330         end tem)
 331     (while start
 332       (setq convert-backslash nil)
 333       ;; If we're reading from the mailrc file, then addresses are delimited
 334       ;; by spaces, and addresses with embedded spaces must be surrounded by
 335       ;; double-quotes.  Otherwise, addresses are separated by commas.
 336       (if from-mailrc-file
 337           (if (eq ?\" (aref definition start))
 338               ;; The following test on `found' compensates for a bug
 339               ;; in match-end, which does not return nil when match
 340               ;; failed.
 341               (let ((found (string-match "[^\\]\\(\\([\\][\\]\\)*\\)\"[ \t,]*"
 342                                          definition start)))
 343                 (setq start (1+ start)
 344                       end (and found (match-end 1))
 345                       convert-backslash t))
 346             (setq end (string-match "[ \t,]+" definition start)))
 347         (setq end (string-match "[ \t\n,]*,[ \t\n,]*" definition start)))
 348       (let ((temp (substring definition start end))
 349             (pos 0))
 350         (setq start (and end
 351                          (/= (match-end 0) L)
 352                          (match-end 0)))
 353         (if convert-backslash
 354             (while (string-match "[\\]" temp pos)
 355               (setq temp (replace-match "" t t temp))
 356               (if start
 357                   (setq start (1- start)))
 358               (setq pos (match-end 0))))
 359         (setq result (cons temp result))))
 360     (setq definition (mapconcat (function identity)
 361                                 (nreverse result)
 362                                 ", "))
 363     (setq tem (assoc name mail-aliases))
 364     (if tem
 365         (rplacd tem definition)
 366       (setq mail-aliases (cons (cons name definition) mail-aliases)
 367             mail-names t))))
 368
 369 ;;;###autoload
 370 (defun mail-complete (arg)
 371   "Perform completion on header field or word preceding point.
 372 Completable headers are according to `mail-complete-alist'.  If none matches
 373 current header, calls `mail-complete-function' and passes prefix arg if any."
 374   (interactive "P")
 375   ;; Read the defaults first, if we have not done so.
 376   (sendmail-sync-aliases)
 377   (if (eq mail-aliases t)
 378       (progn
 379         (setq mail-aliases nil)
 380         (if (file-exists-p mail-personal-alias-file)
 381             (build-mail-aliases))))
 382   (let ((list mail-complete-alist))
 383     (if (and (< 0 (mail-header-end))
 384              (save-excursion
 385                (if (re-search-backward "^[^\t]" nil t)
 386                    (while list
 387                      (if (looking-at (car (car list)))
 388                          (setq arg (cdr (car list))
 389                                list ())
 390                        (setq list (cdr list)))))
 391                arg))
 392         (let* ((end (point))
 393                (beg (save-excursion
 394                       (skip-chars-backward "^ \t<,:")
 395                       (point)))
 396                (pattern (buffer-substring beg end))
 397                completion)
 398           (setq list (eval arg)
 399                 completion (try-completion pattern list))
 400           (cond ((eq completion t))
 401                 ((null completion)
 402                  (message "Can't find completion for \"%s\"" pattern)
 403                  (ding))
 404                 ((not (string= pattern completion))
 405                  (delete-region beg end)
 406                  (let ((alist-elt (assoc completion mail-names)))
 407                    (if (cdr alist-elt)
 408                        (cond ((eq mail-complete-style 'parens)
 409                               (insert completion " (" (cdr alist-elt) ")"))
 410                              ((eq mail-complete-style 'angles)
 411                               (insert (cdr alist-elt) " <" completion ">"))
 412                              (t
 413                               (insert completion)))
 414                      (insert completion))))
 415                 (t
 416                  (message "Making completion list...")
 417                  (with-output-to-temp-buffer "*Completions*"
 418                    (display-completion-list
 419                     (all-completions pattern list)))
 420                  (message "Making completion list...%s" "done"))))
 421       (funcall mail-complete-function arg))))
 422
 423 (defun mail-get-names (pattern)
 424   "Fetch local users and global mail addresses for completion.
 425 Consults `/etc/passwd' and a directory service if one is set up via
 426 `mail-directory-function'.
 427 PATTERN is the string we want to complete."
 428   (if (eq mail-local-names t)
 429       (save-excursion
 430         (set-buffer (generate-new-buffer " passwd"))
 431         (let ((files mail-passwd-files))
 432           (while files
 433             (insert-file-contents (car files) nil nil nil t)
 434             (setq files (cdr files))))
 435         (if mail-passwd-command
 436             (call-process shell-file-name nil t nil
 437                           shell-command-switch mail-passwd-command))
 438         (beginning-of-buffer)
 439         (setq mail-local-names nil)
 440         (while (not (eobp))
 441           ;;Recognize lines like
 442           ;;  nobody:*:65534:65534::/:
 443           ;;  +demo::::::/bin/csh
 444           ;;  +ethanb
 445           ;;while skipping
 446           ;;  +@SOFTWARE
 447           ;; The second \(...\) matches the user id.
 448           (if (looking-at "\\+?\\([^:@\n+]+\\):[^:\n]*:\\([^\n:]*\\):")
 449               (add-to-list 'mail-local-names
 450                            (cons (match-string 1)
 451                                  (user-full-name
 452                                   (string-to-number (match-string 2))))))
 453           (beginning-of-line 2))
 454         (kill-buffer (current-buffer))))
 455   (if (or (eq mail-names t)
 456           (eq mail-directory-names t))
 457       (let (directory)
 458         (and mail-directory-function
 459              (eq mail-directory-names t)
 460              (setq directory
 461                    (mail-directory (if mail-directory-requery pattern))))
 462         (or mail-directory-requery
 463             (setq mail-directory-names directory))
 464         (if (or directory
 465                 (eq mail-names t))
 466             (setq mail-names
 467                   (sort (append (if (consp mail-aliases)
 468                                     (mapcar
 469                                      (function (lambda (a) (list (car a))))
 470                                      mail-aliases))
 471                                 (if (consp mail-local-names)
 472                                     mail-local-names)
 473                                 (or directory
 474                                     (when (consp mail-directory-names)
 475                                       mail-directory-names)))
 476                         (lambda (a b)
 477                           ;; should cache downcased strings
 478                           (string< (downcase (car a))
 479                                    (downcase (car b)))))))))
 480   mail-names)
 481
 482
 483 (defun mail-directory (pattern)
 484   "Use mail-directory facility to get user names matching PATTERN.
 485 If PATTERN is nil, get all the defined user names.
 486 This function calls `mail-directory-function' to query the directory,
 487 then uses `mail-directory-parser' to parse the output it returns."
 488   (save-excursion
 489     (message "Querying directory...")
 490     (set-buffer (generate-new-buffer " *mail-directory*"))
 491     (funcall mail-directory-function pattern)
 492     (goto-char 1)
 493     (let (directory)
 494       (if (stringp mail-directory-parser)
 495           (while (re-search-forward mail-directory-parser nil t)
 496             (setq directory
 497                   (cons (match-string 1) directory)))
 498         (if mail-directory-parser
 499             (setq directory (funcall mail-directory-parser))
 500           (while (not (eobp))
 501             (setq directory
 502                   (cons (buffer-substring (point)
 503                                           (progn
 504                                             (forward-line)
 505                                             (if (bolp)
 506                                                 (1- (point))
 507                                               (point))))
 508                         directory)))))
 509       (kill-buffer (current-buffer))
 510       (message "Querying directory...done")
 511       directory)))
 512
 513
 514 (defun mail-directory-process (pattern)
 515   "Run a shell command to output names in directory.
 516 See `mail-directory-process'."
 517   (when (consp mail-directory-process)
 518     (apply 'call-process (eval (car mail-directory-process)) nil t nil
 519            (mapcar 'eval (cdr mail-directory-process)))))
 520
 521 ;; This should handle a dialog.  Currently expects port to spit out names.
 522 (defun mail-directory-stream (pattern)
 523   "Open a stream to retrieve names in directory.
 524 See `mail-directory-stream'."
 525   (let (mailalias-done)
 526     (set-process-sentinel
 527      (apply 'open-network-stream "mailalias" (current-buffer)
 528             mail-directory-stream)
 529      (lambda (x y)
 530        (setq mailalias-done t)))
 531     (while (not mailalias-done)
 532       (sit-for .1))))
 533
 534 (defun mail-sentto-newsgroups ()
 535   "Return all entries from Newsgroups: header as completion alist."
 536   (save-excursion
 537     (if (mail-position-on-field "newsgroups" t)
 538         (let ((point (point))
 539               list)
 540           (while (< (skip-chars-backward "^:, \t\n") 0)
 541             (setq list `((,(buffer-substring (point) point))
 542                          ,@list))
 543             (skip-chars-backward ", \t\n")
 544             (setq point (point)))
 545           list))))
 546
 547 (provide 'mailalias)
 548
 549 ;;; arch-tag: 1d6a0f87-eb34-4d45-8816-60c1b952cf46
 550 ;;; mailalias.el ends here