configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.13)
   4 AC_INIT(src/main/main.c)
   5 AC_CONFIG_AUX_DIR(config)
   6
   7 PACKAGE=elinks
   8 VERSION=0.12.GIT
   9 AC_SUBST(PACKAGE)
  10 AC_SUBST(VERSION)
  11 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Package version])
  12 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Package version])
  13 AC_CONFIG_HEADERS(config.h)
  14
  15 AC_CHECK_PROG(ACLOCAL,[aclocal],[aclocal],[config/missing aclocal])
  16 AC_CHECK_PROG(AUTOCONF,[autoconf],[autoconf],[config/missing autoconf])
  17 AC_CHECK_PROG(AUTOHEADER,[autoheader],[autoheader],[config/missing autoheader])
  18
  19 MAKE=
  20
  21 for make in gnumake gmake make false; do
  22         if test "x$MAKE" = x; then
  23                 AC_PATH_PROGS(MAKE, "$make")
  24         fi
  25 done
  26
  27 builddir="`pwd`"
  28
  29 # Cleanup if we are configuring with a previous build in the tree
  30 if test -e Makefile.config; then
  31         AC_MSG_CHECKING([for previous build to clean])
  32         "$MAKE" -C "$builddir/src" cleanall >/dev/null 2>/dev/null
  33         AC_MSG_RESULT(done)
  34 fi
  35
  36 dnl ===================================================================
  37 dnl Load feature configuration file and start logging features.
  38 dnl ===================================================================
  39
  40 features="features.conf"
  41 AC_CHECK_FILE("$srcdir/$features", [ . $srcdir/$features ])
  42 AC_CHECK_FILE("$builddir/$features", [ . $builddir/$features ])
  43 echo "Feature summary:" > features.log
  44
  45 dnl ===================================================================
  46 dnl Checks for programs.
  47 dnl ===================================================================
  48
  49 AC_PROG_CC
  50 AC_PROG_AWK
  51 AC_PATH_PROGS(AWK, "$AWK")
  52 AC_PROG_RANLIB
  53 AC_PROG_INSTALL
  54
  55 AC_PATH_PROGS(CG_COMMIT_ID, "cg-commit-id")
  56 AC_PATH_PROGS(SPARSE, "sparse")
  57
  58 CONFIG_ASCIIDOC="no"
  59 CONFIG_POD2HTML="no"
  60 CONFIG_XMLTO="no"
  61 CONFIG_JW="no"
  62
  63 if test "x$CONFIG_DOC" != xno; then
  64         AC_PATH_PROGS(ASCIIDOC, "asciidoc")
  65         if test "x$ASCIIDOC" != "x"; then
  66                 EL_CONFIG(CONFIG_ASCIIDOC, [AsciiDoc])
  67                 EL_CONFIG(MANUAL_ASCIIDOC, [HTML (one file)])
  68                 EL_CONFIG(MAN_ASCIIDOC, [HTML])
  69
  70                 echo > config.asciidoc-unsafe.txt
  71                 if "$ASCIIDOC" --unsafe config.asciidoc-unsafe.txt >/dev/null 2>/dev/null; then
  72                         ASCIIDOC_FLAGS=--unsafe
  73                 fi
  74                 rm config.asciidoc-unsafe.*
  75         fi
  76
  77         AC_PATH_PROGS(XMLTO, "xmlto")
  78         if test "x$XMLTO" != "x"; then
  79                 EL_CONFIG(CONFIG_XMLTO, [XmlTo])
  80                 EL_CONFIG(MANUAL_XMLTO, [HTML (multiple files)])
  81                 EL_CONFIG(MAN_XMLTO, [man (groff)])
  82         fi
  83
  84         AC_PATH_PROGS(JW, "jw")
  85         if test "x$JW" != "x"; then
  86                 EL_CONFIG(CONFIG_JW, [JadeWrapper])
  87                 EL_CONFIG(MANUAL_JW, [PDF])
  88         fi
  89
  90         AC_PATH_PROGS(POD2HTML, "pod2html")
  91         if test "x$POD2HTML" != "x"; then
  92                 EL_CONFIG(CONFIG_POD2HTML, [Pod2HTML])
  93         fi
  94 fi
  95
  96 AC_SUBST(ASCIIDOC_FLAGS)
  97 AC_SUBST(CONFIG_ASCIIDOC)
  98 AC_SUBST(CONFIG_POD2HTML)
  99 AC_SUBST(CONFIG_XMLTO)
 100 AC_SUBST(CONFIG_JW)
 101
 102 EL_CONFIG_DEPENDS(CONFIG_DOC, [CONFIG_ASCIIDOC CONFIG_XMLTO CONFIG_JW CONFIG_POD2HTML], [Documentation Tools])
 103 EL_CONFIG_DEPENDS(CONFIG_MANUAL, [MANUAL_ASCIIDOC MANUAL_XMLTO MANUAL_JW], [Manual Formats])
 104 EL_CONFIG_DEPENDS(CONFIG_MANPAGE, [MAN_ASCIIDOC MAN_XMLTO], [Man Page Formats])
 105
 106 dnl gcc specific options (to be continued at the bottom of configure)
 107 if test "x$ac_cv_prog_gcc" = "xyes"; then
 108   dnl We want to see all warnings and live with none.
 109   dnl We can't set up -Werror here as there may be some warnings in test
 110   dnl suite of configure, and we don't want to fail them.
 111   CFLAGS="$CFLAGS -Wall"
 112 fi
 113
 114 dnl ===================================================================
 115 dnl Checks for special OSes.
 116 dnl ===================================================================
 117
 118 dnl EL_CHECK_COMPILER_MACRO(define, name, flagname)
 119 AC_DEFUN([EL_CHECK_COMPILER_MACROS],
 120 [
 121         AC_MSG_CHECKING([for $2])
 122
 123         for flag in $3; do
 124                 AC_TRY_COMPILE(, [#ifndef $flag
 125 kill me!
 126 #endif ], $1=yes, $1=no)
 127                 if test "[$]$1" = yes; then
 128                         EL_CONFIG([$1], [$2])
 129                         break
 130                 fi
 131         done
 132
 133         AC_MSG_RESULT([$]$1)
 134 ])
 135
 136 EL_CHECK_COMPILER_MACROS(CONFIG_OS_BEOS, [BEOS], [__BEOS__])
 137 AC_SUBST(CONFIG_OS_BEOS)
 138
 139 EL_CHECK_COMPILER_MACROS(CONFIG_OS_RISCOS, [RISCOS], [__riscos__])
 140 AC_SUBST(CONFIG_OS_RISCOS)
 141
 142 EL_CHECK_COMPILER_MACROS(CONFIG_OS_WIN32, [WIN32], [_WIN32 __WIN32__])
 143 AC_SUBST(CONFIG_OS_WIN32)
 144
 145 EL_CHECK_COMPILER_MACROS(CONFIG_OS_OS2, [EMX], [__EMX__])
 146 AC_SUBST(CONFIG_OS_OS2)
 147 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zexe//g"`
 148
 149 AC_MSG_CHECKING([for UNIX])
 150 dnl FIXME: some depend kind of mechanism
 151 if test "$CONFIG_OS_BEOS" = no && \
 152    test "$CONFIG_OS_RISCOS" = no && \
 153    test "$CONFIG_OS_WIN32" = no && \
 154    test "$CONFIG_OS_OS2" = no; then
 155         EL_CONFIG(CONFIG_OS_UNIX, [UNIX])
 156 else
 157         CONFIG_OS_UNIX=no
 158 fi
 159 AC_MSG_RESULT($CONFIG_OS_UNIX)
 160 AC_SUBST(CONFIG_OS_UNIX)
 161
 162 dnl ===================================================================
 163 dnl Checks for header files.
 164 dnl ===================================================================
 165
 166 AC_HEADER_DIRENT
 167 AC_HEADER_STDC
 168 AC_HEADER_SYS_WAIT
 169 AC_HEADER_TIME
 170
 171 AC_CHECK_HEADERS(wctype.h)
 172 AC_CHECK_HEADERS(fcntl.h limits.h time.h unistd.h)
 173 AC_CHECK_HEADERS(sigaction.h)
 174 AC_CHECK_HEADERS(arpa/inet.h)
 175 AC_CHECK_HEADERS(netinet/in_systm.h netinet/in_system.h netinet/ip.h)
 176 AC_CHECK_HEADERS(net/if.h netdb.h netinet/in.h netinet/in6_var.h)
 177 AC_CHECK_HEADERS(ifaddrs.h)
 178 AC_CHECK_HEADERS(sys/cygwin.h io.h)
 179 AC_CHECK_HEADERS(sys/fmutex.h)
 180 AC_CHECK_HEADERS(sys/ioctl.h sys/sockio.h)
 181 AC_CHECK_HEADERS(sys/resource.h)
 182 AC_CHECK_HEADERS(sys/select.h)
 183 AC_CHECK_HEADERS(sys/signal.h)
 184 AC_CHECK_HEADERS(sys/socket.h)
 185 AC_CHECK_HEADERS(sys/time.h)
 186 AC_CHECK_HEADERS(sys/utsname.h)
 187 AC_CHECK_HEADERS(stdint.h inttypes.h)
 188 AC_CHECK_HEADERS(locale.h pwd.h)
 189 AC_CHECK_HEADERS(termios.h)
 190
 191
 192 AC_CHECK_HEADERS(sys/un.h,
 193         [CONFIG_INTERLINK=yes
 194          EL_CONFIG([CONFIG_INTERLINK], [interlinking])],
 195         [CONFIG_INTERLINK=no])
 196 AC_SUBST(CONFIG_INTERLINK)
 197
 198 dnl ===================================================================
 199 dnl Checks for typedefs, structures, and compiler characteristics.
 200 dnl ===================================================================
 201
 202 AC_STRUCT_TM
 203 AC_C_CONST
 204 AC_C_INLINE
 205 EL_CHECK_CODE(typeof, HAVE_TYPEOF, [], [int a; typeof(a) b;])
 206
 207 AC_SYS_LARGEFILE
 208 AC_TYPE_SIZE_T
 209 AC_TYPE_OFF_T
 210 EL_CHECK_TYPE(ssize_t, int)
 211 EL_CHECK_SYS_TYPE(long long, HAVE_LONG_LONG, [])
 212 EL_CHECK_SYS_TYPE(off_t, HAVE_OFF_T, [])
 213 EL_CHECK_INT_TYPE(int32_t, HAVE_INT32_T)
 214 EL_CHECK_INT_TYPE(uint32_t, HAVE_UINT32_T)
 215 EL_CHECK_INT_TYPE(uint16_t, HAVE_UINT16_T)
 216
 217 AC_CHECK_SIZEOF(char, 1)
 218 AC_CHECK_SIZEOF(short, 2)
 219 AC_CHECK_SIZEOF(int, 4)
 220 AC_CHECK_SIZEOF(long, 4)
 221 test "x$HAVE_LONG_LONG" = xyes && AC_CHECK_SIZEOF(long long, 8)
 222 test "x$HAVE_OFF_T" = xyes && AC_CHECK_SIZEOF(off_t, 4)
 223
 224 dnl Check for variadic macros
 225 EL_CHECK_CODE([variadic macros], HAVE_VARIADIC_MACROS,
 226                 [#include <stdio.h>
 227                  #define a(b,c...) printf(b,##c)],
 228                 [a("foo");a("%s","bar");a("%s%s","baz","quux");])
 229
 230 dnl Check for -rdynamic
 231 dnl
 232 dnl gcc -rdynamic calls ld -export-dynamic, which adds all symbols of
 233 dnl the executable to its dynamic symbol table.  ELinks uses this for
 234 dnl two purposes:
 235 dnl
 236 dnl 1. If ELinks detects a bug, it can try to display a backtrace by
 237 dnl    calling backtrace_symbols_fd() in the GNU libc.  The glibc-2.3.6
 238 dnl    manual states users of GNU ld must pass -rdynamic to make the
 239 dnl    symbols available to the program.
 240 dnl
 241 dnl 2. It would eventually be nice to dynamically load shared
 242 dnl    libraries as plugins (bug 73).  The plugins must be able to
 243 dnl    call ELinks functions.  This can be implemented either by
 244 dnl    registering all callable functions in ELinks-specific data
 245 dnl    structures, or by letting the dynamic linker handle them.
 246 dnl    The latter way requires something equivalent to -rdynamic.
 247 dnl
 248 dnl Because backtraces are not needed for correct operation, and bug
 249 dnl 73 is not yet being fixed, the configure script and makefiles
 250 dnl should not complain to the user if they find that -rdynamic does
 251 dnl not work.  Besides, it was reported at elinks-users on 2006-09-12
 252 dnl that gcc-3.4.2 with "ld: Software Generation Utilities - Solaris
 253 dnl Link Editors: 5.8-1.284" on Sun Solaris 8 Sparc does not support
 254 dnl -rdynamic but does something equivalent automatically.  (This was
 255 dnl tested with "nm -D elinks | grep redraw_from_window".)
 256 dnl
 257 dnl FIXME: This check doesn't work. Something to do with the compiler
 258 dnl happily ignoring it and stderr not being checked for error messages.
 259 AC_MSG_CHECKING([for -rdynamic])
 260 LDFLAGS_X="$LDFLAGS"
 261 LDFLAGS="$LDFLAGS -rdynamic"
 262 AC_TRY_LINK([], [], have_rdynamic=yes, have_rdynamic=no)
 263 test "$have_rdynamic" = no && LDFLAGS="$LDFLAGS_X"
 264 AC_MSG_RESULT($have_rdynamic)
 265
 266 dnl ===================================================================
 267 dnl Check for POSIX <regex.h>
 268 dnl ===================================================================
 269
 270 EL_CHECK_SYS_TYPE(regex_t, HAVE_REGEX_H, [#include <regex.h>])
 271
 272 dnl ===================================================================
 273 dnl Checks for library functions.
 274 dnl ===================================================================
 275
 276 AC_PROG_GCC_TRADITIONAL
 277 AC_FUNC_MEMCMP
 278 AC_FUNC_MMAP
 279 AC_FUNC_STRFTIME
 280 AC_CHECK_FUNCS(cfmakeraw gethostbyaddr herror strerror)
 281 AC_CHECK_FUNCS(popen uname access chmod alarm timegm mremap)
 282 AC_CHECK_FUNCS(strcasecmp strncasecmp strcasestr strstr strchr strrchr)
 283 AC_CHECK_FUNCS(memmove bcopy stpcpy strdup index isdigit mempcpy memrchr)
 284 AC_CHECK_FUNCS(snprintf vsnprintf asprintf vasprintf)
 285 AC_CHECK_FUNCS(getifaddrs getpwnam inet_pton inet_ntop)
 286 AC_CHECK_FUNCS(fflush fsync fseeko ftello sigaction)
 287 AC_CHECK_FUNCS(gettimeofday clock_gettime)
 288
 289 AC_HAVE_FUNCS(cygwin_conv_to_full_win32_path)
 290
 291 AC_CHECK_FUNCS(setenv putenv, HAVE_SETENV_OR_PUTENV=yes)
 292 AC_CHECK_FUNCS(getuid, HAVE_GETUID=yes)
 293 AC_CHECK_FUNCS(geteuid, HAVE_GETEUID=yes)
 294
 295 dnl These aren't probably needed now, as they are commented in links.h.
 296 dnl I've no idea about their historical background, but I keep them here
 297 dnl just in the case they will help later. --pasky
 298 AC_CHECK_FUNCS(getpid, HAVE_GETPID=yes)
 299 AC_CHECK_FUNCS(setpgid getpgid setpgrp getpgrp)
 300 AC_CHECK_FUNCS(raise, HAVE_RAISE=yes)
 301 AC_CHECK_FUNCS(kill, HAVE_KILL=yes)
 302
 303 if test x"$HAVE_RAISE" = x; then
 304         if test x"$HAVE_KILL" = x || test x"$HAVE_GETPID" = x; then
 305                 AC_ERROR([Unable to emulate raise()])
 306         fi
 307 fi
 308
 309 AC_CACHE_CHECK([for __va_copy],el_cv_HAVE_VA_COPY,[
 310 AC_TRY_LINK([#include <stdarg.h>
 311 va_list ap1,ap2;], [__va_copy(ap1,ap2);],
 312 el_cv_HAVE_VA_COPY=yes,el_cv_HAVE_VA_COPY=no)])
 313 if test x"$el_cv_HAVE_VA_COPY" = x"yes"; then
 314         EL_DEFINE(HAVE_VA_COPY, __va_copy)
 315 fi
 316
 317 AC_CACHE_CHECK([for sysconf(_SC_PAGE_SIZE)],el_cv_HAVE_SC_PAGE_SIZE,[
 318 AC_TRY_LINK([#include <unistd.h>
 319 ], [int page_size = sysconf(_SC_PAGE_SIZE);],
 320 el_cv_HAVE_SC_PAGE_SIZE=yes,el_cv_HAVE_SC_PAGE_SIZE=no)])
 321 if test x"$el_cv_HAVE_SC_PAGE_SIZE" = x"yes"; then
 322         EL_DEFINE(HAVE_SC_PAGE_SIZE, _SC_PAGE_SIZE)
 323 fi
 324
 325 AC_CACHE_CHECK([for C99 vsnprintf],el_cv_HAVE_C99_VSNPRINTF,[
 326 AC_TRY_RUN([
 327 #include <stdio.h>
 328 #include <stdarg.h>
 329 #include <stdlib.h>
 330 #include <string.h>
 331
 332 char buf[8];
 333
 334 int bar(char *buf, const char *format, va_list ap)
 335 {
 336        return vsnprintf(buf, 0, format, ap);
 337 }
 338
 339 void foo(const char *format, ...) {
 340        va_list ap;
 341        int len;
 342
 343        va_start(ap, format);
 344        len = bar(buf, format, ap);
 345        va_end(ap);
 346        if ((len != 6) && (len != 7)) exit(1); /* \n -> \r\n */
 347
 348        va_start(ap, format);
 349        len = bar(buf, format, ap);
 350        va_end(ap);
 351        if ((len != 6) && (len != 7)) exit(1);
 352
 353        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 354
 355        exit(0);
 356 }
 357 main() { foo("hello\n"); }
 358 ],
 359 el_cv_HAVE_C99_VSNPRINTF=yes,el_cv_HAVE_C99_VSNPRINTF=no,el_cv_HAVE_C99_VSNPRINTF=cross)])
 360 if test x"$el_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 361         EL_DEFINE(HAVE_C99_VSNPRINTF, [C99 compliant vsnprintf()])
 362 fi
 363
 364 AC_CHECK_LIB(dl, dlopen) # OpenSSL and Lua frequently needs it
 365
 366 dnl ===================================================================
 367 dnl Checks for libraries.
 368 dnl ===================================================================
 369
 370 dnl Replace `main' with a function in -lsocket:
 371 AC_CHECK_FUNC(socket, cf_result=yes, cf_result=no)
 372 if test "$cf_result" = no; then
 373         AC_CHECK_LIB(socket, socket)
 374 fi
 375
 376 AC_CHECK_FUNC(setsockopt, cf_result=yes, cf_result=no)
 377 if test "$cf_result" = no; then
 378         AC_CHECK_LIB(socket, setsockopt)
 379 fi
 380
 381 AC_CHECK_FUNC(gethostbyname, cf_result=yes, cf_result=no)
 382 if test "$cf_result" = no; then
 383         AC_CHECK_LIB(socket, gethostbyname, cf_result=yes, cf_result=no)
 384         if test "$cf_result" = no; then
 385                 AC_CHECK_LIB(nsl, gethostbyname)
 386         else
 387                 test -z "`echo $LIBS | grep -- -lsocket`" && LIBS="$LIBS -lsocket"
 388         fi
 389 fi
 390
 391 dnl ===================================================================
 392 dnl Checks for packaging specific options.
 393 dnl ===================================================================
 394
 395 AC_ARG_WITH(xterm, [  --with-xterm            how to invoke the X terminal emulator],
 396             [ if test "$withval" != no && test "$withval" != yes; then
 397                 AC_DEFINE_UNQUOTED(XTERM, "$withval", [How to invoke XTerm])
 398               fi ])
 399
 400 dnl ===================================================================
 401 dnl Checks for a libraries, optional even if installed.
 402 dnl ===================================================================
 403
 404 dnl EL_CHECK_OPTIONAL_LIBRARY(define, name, header, lib, function)
 405 AC_DEFUN([EL_CHECK_OPTIONAL_LIBRARY],
 406 [
 407         AC_MSG_CHECKING([for $2 support])
 408
 409         if test "[$]$1" != no; then
 410                 AC_MSG_RESULT(yes)
 411                 EL_SAVE_FLAGS
 412                 if test -n "$withval" && test -d "$withval"; then
 413                         # Be a little more careful when setting
 414                         # include and lib directories. This way
 415                         # $withval will work when includes are
 416                         # there but the library is in the common
 417                         # /usr/lib ... Does the right thing when
 418                         # looking for gc on Debian.
 419                         if test -d "$withval/include"; then
 420                                 CFLAGS="$CFLAGS -I$withval/include"
 421                                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 422                         else
 423                                 CFLAGS="$CFLAGS -I$withval"
 424                                 CPPFLAGS="$CPPFLAGS -I$withval"
 425                         fi
 426                         if test -d "$withval/lib"; then
 427                                 LDFLAGS="$LDFLAGS -L$withval/lib"
 428                         fi
 429                 fi
 430
 431                 AC_CHECK_HEADERS([$3], [$1=yes], [$1=no; break;])
 432                 if test "[$]$1" = yes; then
 433                         AC_CHECK_LIB([$4], [$5], [$1=yes], [$1=no])
 434                 fi
 435
 436                 if test "[$]$1" = yes; then
 437                         EL_CONFIG([$1], [$2])
 438                         LIBS="$LIBS -l$4"
 439                 else
 440                         if test -n "[$]WITHVAL_$1" &&
 441                            test "[$]WITHVAL_$1" != xno; then
 442                                 AC_MSG_ERROR([$2 not found])
 443                         fi
 444                         EL_RESTORE_FLAGS
 445                 fi
 446         else
 447                 AC_MSG_RESULT(disabled)
 448         fi
 449 ])
 450
 451 dnl EL_CONFIG_OPTIONAL_LIBRARY(define, name, header, lib, function, confhelp)
 452 AC_DEFUN([EL_CONFIG_OPTIONAL_LIBRARY],
 453 [
 454         $1=yes
 455         WITHVAL_$1=
 456
 457         AC_ARG_WITH([$2], [$6], [WITHVAL_$1="[$]withval"])
 458         if test "x[$]WITHVAL_$1" = xno; then $1=no; fi
 459
 460         EL_CHECK_OPTIONAL_LIBRARY([$1], [$2], [$3], [$4], [$5])
 461
 462         EL_LOG_CONFIG([$1], [$2], [])
 463 ])
 464
 465 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GPM, gpm, gpm.h, gpm, Gpm_Open,
 466         [  --without-gpm           disable gpm (mouse) support])
 467
 468 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GZIP, zlib, zlib.h, z, gzdopen,
 469         [  --without-zlib          disable zlib support])
 470
 471 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_BZIP2, bzlib, bzlib.h, bz2, BZ2_bzReadOpen,
 472         [  --without-bzlib         disable bzlib support])
 473
 474 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_IDN, idn, idna.h, idn, stringprep_check_version,
 475         [  --without-idn           disable international domain names support])
 476
 477 if test "x{with_gc}" != xno; then
 478         EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GC, gc, gc.h, gc, GC_init,
 479                 [  --with-gc               enable Boehm's garbage collector])
 480 fi
 481
 482 EL_ARG_ENABLE(CONFIG_LZMA, lzma, [lzma],
 483               [  --enable-lzma           enable lzma encoding support])
 484 dnl ===================================================================
 485 dnl Check for GSSAPI, optional even if installed.
 486 dnl ===================================================================
 487
 488 enable_gssapi="no";
 489
 490 AC_ARG_WITH(gssapi, [  --with-gssapi           enable GSSAPI support],
 491             [ if test "x$withval" != xno; then enable_gssapi=yes; fi ])
 492
 493 AC_MSG_CHECKING([for GSSAPI])
 494
 495 if test "$enable_gssapi" = "yes"; then
 496         AC_MSG_RESULT(yes)
 497         GSSAPI_CFLAGS=`krb5-config --cflags gssapi`
 498         GSSAPI_LIBS=`krb5-config --libs gssapi`
 499         CFLAGS="$GSSAPI_CFLAGS $CFLAGS"
 500         LIBS="$GSSAPI_LIBS $LIBS"
 501         EL_CONFIG(CONFIG_GSSAPI, [GssApi])
 502 else
 503         AC_MSG_RESULT(no)
 504 fi
 505
 506 AC_SUBST(CONFIG_GSSAPI)
 507
 508 dnl ===================================================================
 509 dnl Bookmark and XBEL support
 510 dnl ===================================================================
 511
 512 EL_SAVE_FLAGS
 513
 514 EL_ARG_ENABLE(CONFIG_BOOKMARKS, bookmarks, [Bookmarks],
 515               [  --disable-bookmarks     disable bookmark support])
 516
 517 # Check whether --enable-xbel or --disable-xbel was given.
 518 if test "x${enable_xbel}" != xno; then
 519         AC_CHECK_HEADERS(expat.h, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 520
 521         if test "$HAVE_LIBEXPAT" = yes; then
 522                 AC_CHECK_LIB(expat, XML_ParserCreate, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 523                 if test "$HAVE_LIBEXPAT" = yes; then
 524                         LIBS="$LIBS -lexpat"
 525                 fi
 526         fi
 527 fi
 528
 529
 530 EL_ARG_DEPEND(CONFIG_XBEL_BOOKMARKS, xbel, [CONFIG_BOOKMARKS:yes HAVE_LIBEXPAT:yes],
 531               [XBEL bookmarks],
 532               [  --disable-xbel          disable XBEL bookmark support (requires expat)])
 533
 534 if test "$CONFIG_XBEL_BOOKMARKS" != yes; then
 535         EL_RESTORE_FLAGS
 536 fi
 537
 538 dnl ===================================================================
 539 dnl Checks for BSD sysmouse
 540 dnl ===================================================================
 541
 542 HAVE_SYSMOUSE_HEADER="no"
 543
 544 # Either of these header files provides the (same) sysmouse interface
 545 AC_CHECK_HEADERS(sys/consio.h machine/console.h, [HAVE_SYSMOUSE_HEADER="yes"])
 546
 547 dnl ===================================================================
 548 dnl Checks for OS/2
 549 dnl ===================================================================
 550
 551 if test "$CONFIG_OS_OS2" = yes; then
 552         EL_CONFIG_OS_OS2
 553 fi
 554
 555 dnl ===================================================================
 556 dnl Checks for Win32
 557 dnl ===================================================================
 558
 559 if test "$CONFIG_OS_WIN32" = yes; then
 560         EL_CONFIG_OS_WIN32
 561 fi
 562
 563 dnl ===================================================================
 564 dnl Check for SEE (Simple Ecmascript Engine)
 565 dnl ===================================================================
 566 AC_ARG_WITH(see, [  --with-see              enable Simple Ecmascript Engine (SEE) support],
 567             [ if test "x$withval" != xno; then enable_see=yes; fi ])
 568
 569 # The following is probably bad, ugly and so on. Stolen from Guile's (1.4)
 570 # SEE_FLAGS but I really don't want to require people to have Guile in order
 571 # to compile CVS. Also, the macro seems to be really stupid regarding searching
 572 # for Guile in $PATH etc. --pasky
 573
 574 AC_MSG_CHECKING([for SEE])
 575
 576 CONFIG_ECMASCRIPT_SEE=no
 577
 578 if test "$enable_see" = "yes"; then
 579         AC_MSG_RESULT(yes);
 580         ## Based on the SEE_FLAGS macro.
 581
 582         if test -d "$withval"; then
 583                 SEE_PATH="$withval:$PATH"
 584         else
 585                 SEE_PATH="$PATH"
 586         fi
 587
 588         AC_PATH_PROG(SEE_CONFIG, libsee-config, no, $SEE_PATH)
 589
 590         ## First, let's just see if we can find Guile at all.
 591         if test "$SEE_CONFIG" != no; then
 592                 cf_result="yes";
 593
 594                 SEE_LIBS="`$SEE_CONFIG --libs`"
 595                 SEE_CFLAGS="`$SEE_CONFIG --cppflags`"
 596                 LIBS="$SEE_LIBS $LIBS"
 597                 CPPFLAGS="$CPPFLAGS $SEE_CFLAGS"
 598                 EL_CONFIG(CONFIG_ECMASCRIPT_SEE, [SEE])
 599                 AC_SUBST(SEE_CFLAGS)
 600         else
 601                 if test -n "$withval" && test "x$withval" != xno; then
 602                         AC_MSG_ERROR([SEE not found])
 603                 else
 604                         AC_MSG_WARN([SEE support disabled])
 605                 fi
 606         fi
 607 else
 608         AC_MSG_RESULT(no);
 609 fi
 610
 611
 612 dnl ===================================================================
 613 dnl Check for SpiderMonkey, optional even if installed.
 614 dnl ===================================================================
 615
 616 AC_ARG_WITH(spidermonkey, [  --without-spidermonkey  disable SpiderMonkey Mozilla JavaScript engine support],
 617             [if test "$withval" = no; then disable_spidermonkey=yes; fi])
 618 AC_MSG_CHECKING([for SpiderMonkey])
 619
 620 EL_SAVE_FLAGS
 621 cf_result=no
 622
 623 if test -z "$disable_spidermonkey"; then
 624         if test ! -d "$withval"; then
 625                 withval="";
 626         fi
 627         for spidermonkeydir in "$withval" "" /usr /usr/local /opt/spidermonkey /opt/js; do
 628                 for spidermonkeyinclude in "/include" "/include/js" "/include/smjs" "/include/mozjs"; do
 629                         for spidermonkeylib in js smjs mozjs; do
 630                                 if test "$cf_result" = no; then
 631                                         SPIDERMONKEY_LIBS="-l$spidermonkeylib"
 632
 633                                         if test ! -z "$spidermonkeydir"; then
 634                                                 SPIDERMONKEY_LIBS="-L$spidermonkeydir/lib $SPIDERMONKEY_LIBS"
 635                                                 SPIDERMONKEY_CFLAGS="-I$spidermonkeydir$spidermonkeyinclude"
 636                                         fi
 637
 638                                         LIBS="$SPIDERMONKEY_LIBS $LIBS_X"
 639                                         CFLAGS="$CFLAGS_X $SPIDERMONKEY_CFLAGS"
 640                                         CPPFLAGS="$CPPFLAGS_X $SPIDERMONKEY_CFLAGS"
 641
 642                                         AC_TRY_LINK([#define XP_UNIX
 643                                                      #include <jsapi.h>],
 644                                                      [JS_GetImplementationVersion()],
 645                                                      cf_result=yes, cf_result=no)
 646                                 fi
 647                         done
 648                 done
 649         done
 650 fi
 651
 652 AC_MSG_RESULT($cf_result)
 653 CONFIG_SPIDERMONKEY="$cf_result"
 654 EL_RESTORE_FLAGS
 655
 656 if test "x$CONFIG_SPIDERMONKEY" = xyes &&
 657    test "x$CONFIG_ECMASCRIPT_SEE" != xyes; then
 658         EL_CONFIG(CONFIG_ECMASCRIPT_SMJS, [SpiderMonkey document scripting])
 659 else
 660         CONFIG_ECMASCRIPT_SMJS=no
 661 fi
 662
 663 EL_CONFIG_DEPENDS(CONFIG_ECMASCRIPT, [CONFIG_ECMASCRIPT_SEE CONFIG_ECMASCRIPT_SMJS], [ECMAScript (JavaScript)])
 664 AC_SUBST(CONFIG_ECMASCRIPT_SEE)
 665 AC_SUBST(CONFIG_ECMASCRIPT_SMJS)
 666
 667
 668 dnl ===================================================================
 669 dnl Optional Spidermonkey-based ECMAScript browser scripting
 670 dnl ===================================================================
 671
 672 AC_ARG_ENABLE(sm-scripting,
 673               [  --disable-sm-scripting  ECMAScript browser scripting (requires Spidermonkey)],
 674               [if test "$enableval" != no; then enableval="yes"; fi
 675                CONFIG_SCRIPTING_SPIDERMONKEY="$enableval";])
 676
 677 if test "x$CONFIG_SPIDERMONKEY" = xyes &&
 678    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 679         EL_CONFIG(CONFIG_SCRIPTING_SPIDERMONKEY, [SpiderMonkey])
 680 else
 681         CONFIG_SCRIPTING_SPIDERMONKEY=no
 682 fi
 683
 684 if test "x$CONFIG_ECMASCRIPT_SMJS" = xyes ||
 685    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 686         LIBS="$LIBS $SPIDERMONKEY_LIBS"
 687         AC_SUBST(SPIDERMONKEY_LIBS)
 688         AC_SUBST(SPIDERMONKEY_CFLAGS)
 689         AC_SUBST(CONFIG_SPIDERMONKEY)
 690 fi
 691
 692 dnl ===================================================================
 693 dnl Check for Guile, optional even if installed.
 694 dnl ===================================================================
 695
 696 enable_guile="no";
 697
 698 AC_ARG_WITH(guile, [  --with-guile            enable Guile support],
 699             [ if test "x$withval" != xno; then enable_guile=yes; fi ])
 700
 701 # The following is probably bad, ugly and so on. Stolen from Guile's (1.4)
 702 # GUILE_FLAGS but I really don't want to require people to have Guile in order
 703 # to compile CVS. Also, the macro seems to be really stupid regarding searching
 704 # for Guile in $PATH etc. --pasky
 705
 706 AC_MSG_CHECKING([for Guile])
 707
 708 if test "$enable_guile" = "yes"; then
 709         AC_MSG_RESULT(yes);
 710         ## Based on the GUILE_FLAGS macro.
 711
 712         if test -d "$withval"; then
 713                 GUILE_PATH="$withval:$PATH"
 714         else
 715                 GUILE_PATH="$PATH"
 716         fi
 717
 718         AC_PATH_PROG(GUILE_CONFIG, guile-config, no, $GUILE_PATH)
 719
 720         ## First, let's just see if we can find Guile at all.
 721         if test "$GUILE_CONFIG" != no; then
 722                 cf_result="yes";
 723
 724                 GUILE_LIBS="`guile-config link`"
 725                 GUILE_CFLAGS="`guile-config compile`"
 726                 LIBS="$GUILE_LIBS $LIBS"
 727                 CPPFLAGS="$CPPFLAGS $GUILE_CFLAGS"
 728                 EL_CONFIG(CONFIG_SCRIPTING_GUILE, [Guile])
 729                 AC_SUBST(GUILE_CFLAGS)
 730                 cat <<EOF
 731 ***********************************************************************
 732 The Guile support is incomplete and not so well integrated to ELinks
 733 yet. That means, e.g., that you have no Guile console and there might
 734 not be all the necessary hooks. Also, the Guile interface is not too
 735 well tested (success stories heartily welcomed!).  See
 736 src/scripting/guile/README for further details and hints.
 737 ***********************************************************************
 738 EOF
 739         else
 740                 if test -n "$withval" && test "x$withval" != xno; then
 741                         AC_MSG_ERROR([Guile not found])
 742                 else
 743                         AC_MSG_WARN([Guile support disabled])
 744                 fi
 745         fi
 746 else
 747         AC_MSG_RESULT(no);
 748 fi
 749
 750 dnl ===================================================================
 751 dnl Check for Perl
 752 dnl ===================================================================
 753 enable_perl="no";
 754
 755 AC_ARG_WITH(perl, [  --with-perl             enable Perl support],
 756             [
 757 if test "$withval" = yes; then
 758         # FIXME: If withval is a valid directory append it to PATH
 759         # so that you can specify one of several perl installations.
 760         withval="";
 761         enable_perl=yes;
 762 fi
 763             ])
 764
 765 AC_MSG_CHECKING([for Perl])
 766
 767 cf_result=no
 768
 769 EL_SAVE_FLAGS
 770
 771 if test "$enable_perl" = "yes"; then
 772         PERL_LIBS="`perl -MExtUtils::Embed -e ldopts`"
 773         PERL_CFLAGS="`perl -MExtUtils::Embed -e ccopts`"
 774         LIBS="$PERL_LIBS $LIBS"
 775         CFLAGS="$PERL_CFLAGS $CFLAGS"
 776         CPPFLAGS="$CPPFLAGS $PERL_CFLAGS"
 777         AC_TRY_LINK([
 778 #include <EXTERN.h>
 779 #include <perl.h>
 780 #include <perlapi.h>
 781 ],
 782                     [PerlInterpreter *my_perl = perl_alloc();],
 783                     cf_result=yes, cf_result=no)
 784 fi
 785
 786 if test "$cf_result" != "yes"; then
 787         EL_RESTORE_FLAGS
 788 else
 789         EL_CONFIG(CONFIG_SCRIPTING_PERL, [Perl])
 790
 791         CFLAGS="$CFLAGS_X"
 792         AC_SUBST(PERL_LIBS)
 793         AC_SUBST(PERL_CFLAGS)
 794 fi
 795
 796 if test "$cf_result"; then AC_MSG_RESULT($cf_result); fi
 797 dnl ===================================================================
 798 dnl Check for Python
 799 dnl ===================================================================
 800 enable_python="no";
 801
 802 AC_ARG_WITH(python, [  --with-python=[DIR]     enable Python support],
 803             [ if test "x$withval" != xno; then enable_python=yes; fi ])
 804
 805 EL_SAVE_FLAGS
 806 cf_result=no
 807
 808 AC_MSG_CHECKING([for Python])
 809
 810 if test "$enable_python" = "yes"; then
 811         AC_MSG_RESULT(yes);
 812
 813         if test -d "$withval"; then
 814                 PYTHON_PATH="$withval:$PATH"
 815         else
 816                 PYTHON_PATH="$PATH"
 817         fi
 818
 819         AC_PATH_PROG(PYTHON, python, no, $PYTHON_PATH)
 820
 821         if test "$PYTHON" != no; then
 822                 cf_result="yes";
 823
 824                 PYTHON_CFLAGS="`$PYTHON -c 'from distutils import sysconfig; print "-I%s -I%s" % (sysconfig.get_python_inc(), sysconfig.get_python_inc(plat_specific=True))'`"
 825                 PYTHON_LIBS="`$PYTHON -c 'from distutils import sysconfig; var = sysconfig.get_config_var; print "%s %s %s -L%s -lpython%s" % (var("LINKFORSHARED"), var("LIBS"), var("SYSLIBS"), var("LIBPL"), var("VERSION"))'`"
 826                 LIBS="$PYTHON_LIBS $LIBS"
 827                 CPPFLAGS="$CPPFLAGS $PYTHON_CFLAGS"
 828                 AC_TRY_LINK([#include <Python.h>],
 829                     [Py_Initialize();],
 830                     cf_result=yes, cf_result=no)
 831
 832                 if test "$cf_result" != "yes"; then
 833                         EL_RESTORE_FLAGS
 834                 else
 835                         EL_CONFIG(CONFIG_SCRIPTING_PYTHON, [Python])
 836                         AC_SUBST(PYTHON_LIBS)
 837                         AC_SUBST(PYTHON_CFLAGS)
 838                         cat <<EOF
 839 ***********************************************************************
 840 The Python support is incomplete and not so well integrated to ELinks
 841 yet. That means, e.g., that you have no Python console and there might
 842 not be all the necessary hooks. Also, the Python interface is not too
 843 well tested (success stories heartily welcomed!).
 844 ***********************************************************************
 845 EOF
 846                 fi
 847         else
 848                 if test -n "$withval" && test "x$withval" != xno; then
 849                         AC_MSG_ERROR([Python not found])
 850                 else
 851                         AC_MSG_WARN([Python support disabled])
 852                 fi
 853         fi
 854 else
 855         AC_MSG_RESULT(no);
 856 fi
 857
 858
 859 dnl ===================================================================
 860 dnl Check for Lua, optional even if installed.
 861 dnl ===================================================================
 862
 863 dnl Do this the long way, as FreeBSD reportedly needs -L<dir> for
 864 dnl anything other than /usr/lib, and Lua is very often in /usr/local/lib.
 865
 866 AC_ARG_WITH(lua, [  --without-lua           disable Lua support],
 867             [if test "$withval" = no; then disable_lua=yes; fi])
 868 AC_MSG_CHECKING([for Lua])
 869
 870 EL_SAVE_FLAGS
 871 cf_result=no
 872
 873 if test -z "$disable_lua"; then
 874         if test ! -d "$withval"; then
 875                 withval="";
 876         fi
 877         for luadir in "$withval" "" /usr /usr/local; do
 878                 for suffix in "" 50 51; do
 879                         if test "$cf_result" = no; then
 880                                 LUA_LIBS="-llua$suffix -llualib$suffix -lm"
 881
 882                                 if test ! -z "$luadir"; then
 883                                         LUA_LIBS="-L$luadir/lib $LUA_LIBS"
 884                                         LUA_CFLAGS="-I$luadir/include -I$luadir/include/lua$suffix"
 885                                 fi
 886
 887                                 LIBS="$LUA_LIBS $LIBS_X"
 888                                 CFLAGS="$CFLAGS_X $LUA_CFLAGS"
 889                                 CPPFLAGS="$CPPFLAGS_X $LUA_CFLAGS"
 890
 891                                 # Check that it is a compatible Lua version
 892                                 AC_TRY_LINK([   #include <lua.h>
 893                                                 #include <lualib.h>],
 894                                             [   lua_State *L = lua_open();
 895                                                 luaopen_base(L);
 896                                                 luaopen_table(L);
 897                                                 luaopen_io(L);
 898                                                 luaopen_string(L);
 899                                                 luaopen_math(L);
 900                                                 lua_pushboolean(L, 1);
 901                                                 lua_close(L);],
 902                                             cf_result=yes, cf_result=no)
 903                         fi
 904                 done
 905         done
 906 fi
 907
 908 AC_MSG_RESULT($cf_result)
 909
 910 if test "$cf_result" != yes; then
 911         EL_RESTORE_FLAGS
 912 else
 913         EL_CONFIG(CONFIG_SCRIPTING_LUA, [Lua])
 914         AC_CHECK_HEADERS(lauxlib.h)
 915
 916         CFLAGS="$CFLAGS_X"
 917         AC_SUBST(LUA_LIBS)
 918         AC_SUBST(LUA_CFLAGS)
 919 fi
 920
 921
 922 dnl ===================================================================
 923 dnl Check for Ruby, optional even if installed.
 924 dnl ===================================================================
 925
 926 EL_CONFIG_SCRIPTING_RUBY
 927
 928 dnl ===================================================================
 929 dnl Setup global scripting
 930 dnl ===================================================================
 931
 932 EL_CONFIG_DEPENDS(CONFIG_SCRIPTING, [CONFIG_SCRIPTING_GUILE CONFIG_SCRIPTING_LUA CONFIG_SCRIPTING_PERL CONFIG_SCRIPTING_PYTHON CONFIG_SCRIPTING_RUBY CONFIG_SCRIPTING_SPIDERMONKEY], [Browser scripting])
 933 AC_SUBST(CONFIG_SCRIPTING_GUILE)
 934 AC_SUBST(CONFIG_SCRIPTING_LUA)
 935 AC_SUBST(CONFIG_SCRIPTING_PERL)
 936 AC_SUBST(CONFIG_SCRIPTING_PYTHON)
 937 AC_SUBST(CONFIG_SCRIPTING_RUBY)
 938 AC_SUBST(CONFIG_SCRIPTING_SPIDERMONKEY)
 939 AC_SUBST(CONFIG_SCRIPTING)
 940
 941
 942 dnl ===================================================================
 943 dnl Check for SSL support.
 944 dnl ===================================================================
 945
 946 dnl We by default use OpenSSL, and we always prefer it. However, when GNUTLS
 947 dnl is enabled, we won't try to use OpenSSL anymore.
 948
 949 dnl For wiping SSL hooks..
 950 #ifdef CONFIG_SSL
 951
 952 disable_openssl=""
 953 disable_gnutls=""
 954 enable_gnutls=""
 955
 956 AC_ARG_WITH(gnutls, [  --without-gnutls        disable GNUTLS SSL support],
 957             [if test "$with_gnutls" = no;  then disable_gnutls=yes; fi])
 958 AC_ARG_WITH(gnutls, [  --with-gnutls[=DIR]     enable GNUTLS SSL support],
 959             [if test "$with_gnutls" != no;  then enable_gnutls=yes; fi])
 960 gnutls_withval="$withval"
 961
 962 if test "$enable_gnutls" = yes; then
 963         disable_openssl=yes;
 964 fi
 965
 966 AC_ARG_WITH(openssl, [  --without-openssl       disable OpenSSL support],
 967             [if test "$with_openssl" = no;  then disable_openssl=yes; fi])
 968 AC_ARG_WITH(openssl, [  --with-openssl[=DIR]    enable OpenSSL support (default)])
 969 openssl_withval="$withval"
 970
 971 dnl ---- OpenSSL
 972
 973 AC_MSG_CHECKING([for OpenSSL])
 974
 975 EL_SAVE_FLAGS
 976 cf_result="no"
 977
 978 if test "$disable_openssl" = yes; then
 979         cf_result="not used"
 980 else
 981         for ssldir in "$openssl_withval" "" /usr /usr/local/openssl \
 982                          /usr/lib/openssl /usr/local/ssl \
 983                          /usr/local/www /usr/lib/ssl /usr/local \
 984                          /usr/pkg /opt /opt/openssl; do
 985                 if test "$cf_result" = no; then
 986                         if test -d "$ssldir"; then
 987                                 OPENSSL_CFLAGS="-I$ssldir/include"
 988                                 LIBS="-L$ssldir/lib -lssl -lcrypto $LIBS_X"
 989                                 CFLAGS="$CFLAGS_X $OPENSSL_CFLAGS"
 990                                 CPPFLAGS="$CPPFLAGS_X $OPENSSL_CFLAGS"
 991 #                               # FIXME: This created serious portability problems. --pasky
 992 #                               if test "$CC" == "gcc"; then
 993 #                                       # I'm not sure about compatibility here. --pasky
 994 #                                       LIBS="$LIBS -R$ssldir/lib"
 995 #                               fi
 996                         else
 997                                 LIBS="-lssl -lcrypto $LIBS_X"
 998                         fi
 999                         AC_TRY_LINK([#include <openssl/ssl.h>],
1000                                     [OpenSSL_add_all_algorithms()],
1001                                     cf_result=yes, cf_result=no)
1002                         if test "$cf_result" != yes; then
1003                                 AC_TRY_LINK([#include <openssl/ssl.h>],
1004                                             [SSLeay_add_ssl_algorithms()],
1005                                             cf_result=yes, cf_result=no)
1006                         fi
1007                 fi
1008         done
1009
1010         if test "$cf_result" != yes; then
1011                 if test -n "$openssl_withval" && test "x$openssl_withval" != xno; then
1012                         AC_MSG_ERROR([OpenSSL not found])
1013                 fi
1014                 EL_RESTORE_FLAGS
1015         else
1016                 EL_CONFIG(CONFIG_OPENSSL, [OpenSSL])
1017
1018                 CFLAGS="$CFLAGS_X"
1019                 AC_SUBST(OPENSSL_CFLAGS)
1020         fi
1021 fi
1022
1023 AC_MSG_RESULT($cf_result)
1024
1025 CONFIG_GNUTLS_OPENSSL_COMPAT=no
1026 dnl ---- GNU TLS
1027 dnl We can't have AC_MSG_CHECKING here, because AC_PATH_PROG prints its own and
1028 dnl it looks ugly then.
1029
1030 if test "$cf_result" = yes; then
1031         cf_result="not used"
1032
1033 else
1034         EL_SAVE_FLAGS
1035         cf_result="no"
1036
1037         if test -z "$disable_gnutls"; then
1038                 # Sure, we maybe _could_ use their macro, but how to ensure
1039                 # that the ./configure script won't fail if the macro won't be
1040                 # found..? :( --pasky
1041
1042                 GNUTLS_PATH="$PATH:/usr/local/gnutls:/opt:/opt/gnutls"
1043
1044                 if test -d "$gnutls_withval"; then
1045                         GNUTLS_PATH="$gnutls_withval:$GNUTLS_PATH"
1046                 fi
1047
1048                 AC_PATH_PROG(LIBGNUTLS_CONFIG, libgnutls-config, no, $GNUTLS_PATH)
1049
1050                 if test "$LIBGNUTLS_CONFIG" = "no" ; then
1051                         cf_result=no
1052                 else
1053                         GNUTLS_CFLAGS=`$LIBGNUTLS_CONFIG --cflags`
1054                         GNUTLS_LIBS=`$LIBGNUTLS_CONFIG --libs`
1055
1056                         LIBS="$GNUTLS_LIBS $LIBS_X"
1057                         CFLAGS="$CFLAGS_X $GNUTLS_CFLAGS"
1058                         CPPFLAGS="$CPPFLAGS_X $GNUTLS_CFLAGS"
1059
1060                         # Verify if it's really usable.  gnutls_session was
1061                         # renamed to gnutls_session_t before GNU TLS 1.2.0
1062                         # (on 2004-06-13); ELinks now requires this.
1063                         AC_TRY_LINK([#include <gnutls/gnutls.h>],
1064                                     [gnutls_session_t dummy;
1065                                      gnutls_check_version(NULL)],
1066                                     cf_result=yes, cf_result=no)
1067                 fi
1068
1069                 if test "$cf_result" = yes; then
1070                         EL_CONFIG(CONFIG_GNUTLS, [GNUTLS])
1071
1072                         CFLAGS="$CFLAGS_X"
1073                         AC_SUBST(GNUTLS_CFLAGS)
1074
1075                         # Verify if the MD5 compatibility layer is usable.
1076                         CONFIG_GNUTLS_OPENSSL_COMPAT=yes
1077                         EL_CHECK_OPTIONAL_LIBRARY(CONFIG_GNUTLS_OPENSSL_COMPAT,
1078                                                   [GNU TLS OpenSSL compatibility],
1079                                                   gnutls/openssl.h, gnutls-openssl,
1080                                                   MD5_Init)
1081                 else
1082                         if test -n "$gnutls_withval" && test "x$gnutls_withval" != xno; then
1083                                 AC_MSG_ERROR([GNUTLS (1.2 or later) not found.  ELinks no longer supports GNUTLS 1.1.])
1084                         fi
1085                         EL_RESTORE_FLAGS
1086                 fi
1087         fi
1088 fi
1089
1090 AC_MSG_CHECKING([for GNU TLS (1.2 or later)])
1091 AC_MSG_RESULT($cf_result)
1092
1093 dnl Final SSL setup
1094
1095 EL_CONFIG_DEPENDS(CONFIG_SSL, [CONFIG_OPENSSL CONFIG_GNUTLS], [SSL])
1096 AC_SUBST(CONFIG_GNUTLS_OPENSSL_COMPAT)
1097 AC_SUBST(CONFIG_OPENSSL)
1098 AC_SUBST(CONFIG_GNUTLS)
1099
1100 #endif
1101
1102 AC_MSG_CHECKING([whether to be or not to be])
1103 AC_MSG_RESULT([needs to be determined experimentally])
1104
1105 dnl ===================================================================
1106 dnl Check for IPv6 support and related functions.
1107 dnl ===================================================================
1108
1109 EL_CHECK_NET_TYPE(struct sockaddr_storage, HAVE_SA_STORAGE, [])
1110 EL_CHECK_NET_TYPE(struct sockaddr_in6, HAVE_SA_IN6, [#include <netinet/in.h>])
1111 EL_CHECK_NET_TYPE(struct addrinfo, HAVE_ADDRINFO, [#include <netdb.h>])
1112
1113 AC_CHECK_FUNC(getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1114 if test "$HAVE_GETADDRINFO" != yes; then
1115         AC_CHECK_LIB(inet6, getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1116         if test "$HAVE_GETADDRINFO" = yes; then
1117                 LIBS="$LIBS -linet6"
1118         fi
1119 fi
1120
1121
1122 dnl ===================================================================
1123 dnl Checking for X11 (window title restoring).
1124 dnl ===================================================================
1125
1126 AC_PATH_X
1127 if test x"$no_x" != xyes; then
1128         if test -n "$x_includes"; then
1129                 X_CFLAGS="-I$x_includes"
1130                 CPPFLAGS="$CPPFLAGS -I$x_includes"
1131         fi
1132         if test -n "$x_libraries"; then
1133                 LDFLAGS="$LDFLAGS -L$x_libraries"
1134         fi
1135         LIBS="-lX11 $LIBS"
1136         EL_DEFINE(HAVE_X11, [X11 for restoring window titles])
1137         AC_SUBST(X_CFLAGS)
1138 fi
1139
1140
1141 dnl ===================================================================
1142 dnl Backtraces displaying support.
1143 dnl ===================================================================
1144
1145 AC_CHECK_HEADERS(execinfo.h, HAVE_EXECINFO=yes, HAVE_EXECINFO=no)
1146 # possible checks for other system-specific means go here
1147
1148
1149 dnl ===================================================================
1150 dnl SMB protocol support.
1151 dnl ===================================================================
1152
1153 AC_CHECK_PROG(HAVE_SMBCLIENT, smbclient, yes, no)
1154
1155
1156 dnl ===================================================================
1157 dnl Gettext grey zone. Beware.
1158 dnl ===================================================================
1159
1160 ALL_LINGUAS="af be bg ca cs da de el es et fi fr gl hr hu id is it lt nl nb pl pt pt_BR ro ru sk sr sv tr uk"
1161
1162 AM_GNU_GETTEXT
1163
1164 dnl AC_MSG_CHECKING([how many characters your English alphabet has])
1165 dnl # f33r d4 l33t... I hope it's portable. :)
1166 dnl cf_result=$((48#z - 48#a + 1));
1167 dnl AC_MSG_RESULT($cf_result)
1168
1169
1170 dnl ===================================================================
1171 dnl Compile-time features control
1172 dnl ===================================================================
1173
1174 EL_ARG_ENABLE(CONFIG_COOKIES, cookies, [Cookies],
1175               [  --disable-cookies       disable cookie support])
1176
1177 EL_ARG_ENABLE(CONFIG_FORMHIST, formhist, [Form history],
1178               [  --disable-formhist      disable form history support])
1179
1180 EL_ARG_ENABLE(CONFIG_GLOBHIST, globhist, [Global history],
1181               [  --disable-globhist      disable global history support])
1182
1183
1184 EL_ARG_ENABLE(CONFIG_MAILCAP, mailcap, [Mailcap],
1185               [  --disable-mailcap       disable mailcap support])
1186
1187 EL_ARG_ENABLE(CONFIG_MIMETYPES, mimetypes, [Mimetypes files],
1188               [  --disable-mimetypes     disable mimetypes files support])
1189
1190
1191 EL_ARG_DEPEND(CONFIG_IPV6, ipv6,
1192               [HAVE_SA_STORAGE:yes HAVE_SA_IN6:yes HAVE_ADDRINFO:yes HAVE_GETADDRINFO:yes],
1193               [IPv6],
1194               [  --disable-ipv6          disable IPv6 support])
1195
1196 EL_ARG_ENABLE(CONFIG_BITTORRENT, bittorrent, [BitTorrent protocol],
1197               [  --enable-bittorrent     enable BitTorrent protocol support])
1198
1199 EL_ARG_ENABLE(CONFIG_DATA, data, [Data protocol],
1200               [  --disable-data          disable data protocol support])
1201
1202 EL_ARG_ENABLE(CONFIG_URI_REWRITE, uri-rewrite, [URI rewriting],
1203               [  --disable-uri-rewrite   disable URI rewrite support])
1204
1205 EL_ARG_DEPEND(CONFIG_CGI, cgi, [HAVE_SETENV_OR_PUTENV:yes], [Local CGI],
1206               [  --enable-cgi            enable local CGI support])
1207
1208 EL_ARG_ENABLE(CONFIG_FINGER, finger, [Finger protocol],
1209               [  --enable-finger         enable finger protocol support])
1210
1211 dnl ===================================================================
1212 dnl FSP protocol
1213 dnl ===================================================================
1214 EL_SAVE_FLAGS
1215
1216 if test "x${enable_fsp}" != xno; then
1217         AC_CHECK_HEADERS(fsplib.h, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1218
1219         if test "$HAVE_FSPLIB" = yes; then
1220                 AC_CHECK_LIB(fsplib, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1221                 if test "$HAVE_FSPLIB" = yes; then
1222                         LIBS="$LIBS -lfsplib"
1223                 else
1224                         AC_CHECK_LIB(fsp, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1225                         if test "$HAVE_FSPLIB" = yes; then
1226                                 LIBS="$LIBS -lfsp"
1227                         fi
1228                 fi
1229         fi
1230 fi
1231
1232 EL_ARG_DEPEND(CONFIG_FSP, fsp, [HAVE_FSPLIB:yes], [FSP protocol],
1233               [  --enable-fsp            enable FSP protocol support])
1234
1235 if test "x$CONFIG_FSP" = xno; then
1236         EL_RESTORE_FLAGS
1237 fi
1238
1239 EL_ARG_ENABLE(CONFIG_FTP, ftp, [FTP protocol],
1240               [  --disable-ftp           disable ftp protocol support])
1241
1242 EL_ARG_ENABLE(CONFIG_GOPHER, gopher, [Gopher protocol],
1243               [  --enable-gopher         enable gopher protocol support])
1244
1245 EL_ARG_ENABLE(CONFIG_NNTP, nntp, [NNTP protocol],
1246               [  --enable-nntp           enable nntp protocol support])
1247
1248 EL_ARG_DEPEND(CONFIG_SMB, smb, [HAVE_SMBCLIENT:yes], [SMB protocol],
1249               [  --enable-smb            not currently allowed])
1250 dnl           [  --disable-smb           disable SMB protocol support (requires smbclient)])
1251 if test "$CONFIG_SMB" != no; then
1252   AC_MSG_WARN([Ignoring --enable-smb because of vulnerability CVE-2006-5925.
1253 If you want to use SMB, please vote for bug 844 or post a patch.])
1254   CONFIG_SMB=no
1255 fi
1256
1257
1258 EL_ARG_ENABLE(CONFIG_MOUSE, mouse, [Mouse handling],
1259               [  --disable-mouse         disable mouse support])
1260
1261 # GPM mouse is Linux specific, so ...
1262 CONFIG_SYSMOUSE=yes
1263 EL_ARG_DEPEND(CONFIG_SYSMOUSE, sysmouse,
1264               [CONFIG_MOUSE:yes CONFIG_GPM:no HAVE_SYSMOUSE_HEADER:yes],
1265               [BSD sysmouse],
1266               [  --disable-sysmouse      disable BSD sysmouse support])
1267
1268 EL_ARG_ENABLE(CONFIG_88_COLORS, 88-colors, [88 colors],
1269               [  --enable-88-colors      enable 88 color support])
1270
1271 EL_ARG_ENABLE(CONFIG_256_COLORS, 256-colors, [256 colors],
1272               [  --enable-256-colors     enable 256 color support])
1273
1274 EL_ARG_ENABLE(CONFIG_TRUE_COLOR, true-color, [true color],
1275               [  --enable-true-color     enable true color support])
1276
1277 EL_ARG_ENABLE(CONFIG_EXMODE, exmode, [Exmode interface],
1278               [  --enable-exmode         enable exmode (CLI) interface])
1279
1280 EL_ARG_ENABLE(CONFIG_LEDS, leds, [LEDs],
1281               [  --disable-leds          disable LEDs support])
1282
1283 EL_ARG_ENABLE(CONFIG_MARKS, marks, [Marks],
1284               [  --disable-marks         disable document marks support])
1285
1286
1287 EL_ARG_ENABLE(CONFIG_CSS, css, [Cascading Style Sheets],
1288               [  --disable-css           disable Cascading Style Sheet support])
1289
1290 EL_ARG_DEPEND(CONFIG_HTML_HIGHLIGHT, html-highlight, [CONFIG_CSS:yes], [HTML highlighting],
1291               [  --enable-html-highlight HTML highlighting using DOM engine])
1292
1293 dnl Everything in the tree already uses CONFIG_DOM
1294 dnl so resolve CONFIG_HTML_HIGHLIGHT to CONFIG_DOM
1295 EL_CONFIG_DEPENDS(CONFIG_DOM, [CONFIG_HTML_HIGHLIGHT], [DOM engine])
1296
1297 EL_ARG_DEPEND(CONFIG_BACKTRACE, backtrace, [HAVE_EXECINFO:yes], [Backtrace],
1298               [  --disable-backtrace     disable backtrace support])
1299
1300 EL_ARG_DEPEND(CONFIG_NO_ROOT_EXEC, no-root, [HAVE_GETUID:yes HAVE_GETEUID:yes], [No root exec],
1301               [  --enable-no-root        enable prevention of usage by root])
1302
1303
1304 EL_ARG_ENABLE(CONFIG_DEBUG, debug, [Debug mode],
1305               [  --enable-debug          enable leak debug and internal error checking])
1306
1307 EL_ARG_DEPEND(CONFIG_FASTMEM, fastmem, [CONFIG_DEBUG:no], [Fast mode],
1308               [  --enable-fastmem        enable direct use of system allocation functions, not usable with --enable-debug])
1309
1310 EL_ARG_ENABLE(CONFIG_OWN_LIBC, own-libc, [Own libc stubs],
1311               [  --enable-own-libc       force use of internal functions instead of those of system libc])
1312
1313 EL_ARG_ENABLE(CONFIG_SMALL, small, [Small binary],
1314               [  --enable-small          reduce binary size as far as possible (but see the bottom of doc/small.txt!)])
1315
1316 EL_ARG_ENABLE(CONFIG_UTF8, utf-8, [UTF-8],
1317               [  --enable-utf-8          enable UTF-8 support])
1318
1319
1320 AC_ARG_ENABLE(weehoofooboomookerchoo,
1321               [
1322     Also check out the features.conf file for more information about features!
1323               ],
1324               [AC_MSG_ERROR(Are you strange, or what?)])
1325
1326
1327 dnl == EMX hack
1328
1329 test "$CONFIG_OS_OS2" = yes && LDFLAGS="$LDFLAGS -Zexe"
1330 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zbin-files//g"`
1331
1332
1333 dnl ===================================================================
1334 dnl Export directory paths
1335 dnl ===================================================================
1336
1337 # Set up the ``entry points'' if they were not supplied by builder
1338 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1339 test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1340
1341 # Create CONFDIR #define for config.h
1342
1343 # XXX: This may be dependent on a particular version of autoconf. Whatever,
1344 # it's autoconf fault to force us to do such hacks ;p.
1345 if test x"$sysconfdir" = x"\${prefix}/etc"; then
1346   # sysconfdir is set to its default value... fine, let's append /elinks/
1347   # XXX: We can't modify listing of the default in ./configure --help :-(
1348   sysconfdir_n=`eval echo "$sysconfdir"`
1349   sysconfdir=$sysconfdir_n
1350   (echo "$sysconfdir" | grep elinks >/dev/null 2>/dev/null) || \
1351         sysconfdir="$sysconfdir/elinks"
1352 fi
1353
1354 CONFDIR=$sysconfdir
1355 AC_DEFINE_UNQUOTED(CONFDIR, "$CONFDIR", [Directory containing default config])
1356 AC_SUBST(CONFDIR)
1357
1358 # Create LOCALEDIR #define for config.h
1359 LOCALEDIR=`eval echo "$datadir/locale"`
1360 while echo "$LOCALEDIR" | grep "\\$"
1361 do
1362         LOCALEDIR=`eval echo "$LOCALEDIR"`
1363 done > /dev/null 2> /dev/null
1364 AC_DEFINE_UNQUOTED(LOCALEDIR, "$LOCALEDIR", [Directory containing locales])
1365 AC_SUBST(LOCALEDIR)
1366
1367 # Create LIBDIR #define for config.h
1368 LIBDIR=`eval echo "$libdir"`
1369 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [Directory containing libraries])
1370 AC_SUBST(LIBDIR)
1371
1372 EL_LOG_CONFIG(CONFDIR, [System configuration directory], [])
1373 EL_LOG_CONFIG(LOCALEDIR, [Locale catalogs directory], [])
1374
1375 dnl ===================================================================
1376 dnl A little fine tuning of gcc specific options (continued)
1377 dnl ===================================================================
1378
1379 if test "x$ac_cv_prog_gcc" = "xyes"; then
1380   if test "$CONFIG_DEBUG" = "yes"; then
1381     dnl We want to see all warnings and live with none (in debug mode).
1382     CFLAGS="$CFLAGS -Werror"
1383   fi
1384
1385   case "`$CC -dumpversion`" in
1386     3.0|3.1|3.2)
1387       # These should be ok using -Werror
1388       ;;
1389     3.*)
1390       # If gcc is version 3.3 (or higher?) it emits lots of false positive
1391       # "dereferencing type-punned pointer will break strict-aliasing rules"
1392       # warnings. Disable them by not doing any strict-aliasing. The
1393       # alternative is just too ugly. Thanks gcc guys!! ;)
1394       CFLAGS="$CFLAGS -fno-strict-aliasing"
1395       ;;
1396     4.*)
1397       # Do not show warnings related to (char * | unsigned char *) type
1398       # difference.
1399       CFLAGS="$CFLAGS -fno-strict-aliasing -Wno-pointer-sign"
1400       ;;
1401     *)
1402       # These should be ok using -Werror
1403       ;;
1404   esac
1405 fi
1406
1407 # CFLAGS doesn't contain all compile flags. Some will be added only when
1408 # needed in the respective source directory. To get all compile flags
1409 # easily just add CPPFLAGS.
1410 ALL_CFLAGS="$CFLAGS $CPPFLAGS"
1411
1412 EL_LOG_CONFIG(ALL_CFLAGS, [Compiler options (CFLAGS)], [])
1413 EL_LOG_CONFIG(LIBS, [Linker options (LIBS)], [])
1414
1415 dnl ===================================================================
1416 dnl Colored make output
1417 dnl ===================================================================
1418
1419 if test $(`which tput` colors) -ge 4; then
1420         MAKE_COLOR=1
1421         AC_SUBST(MAKE_COLOR)
1422 fi
1423
1424 dnl ===================================================================
1425 dnl Generated files
1426 dnl ===================================================================
1427
1428 AC_OUTPUT([ \
1429  Makefile.config \
1430  contrib/elinks.spec \
1431  contrib/lua/hooks.lua \
1432  contrib/conv/w3m2links.awk \
1433  doc/man/man1/elinks.1 \
1434  src/intl/gettext/ref-add.sed \
1435  src/intl/gettext/ref-del.sed
1436 ])
1437
1438 abs_srcdir="$(cd "$srcdir" && pwd)"
1439 # builddir is always absolute!
1440 if test "$abs_srcdir" != "$builddir"; then
1441         # Bootstrap the Makefile creation
1442         echo "include $abs_srcdir/Makefile" > "$builddir/Makefile"
1443         "$MAKE" "SRC=$abs_srcdir" init
1444
1445         # Make cg-status ignore this build directory
1446         echo "*" > "$builddir/.gitignore"
1447 fi
1448
1449 dnl ===================================================================
1450 dnl Configuration summary
1451 dnl ===================================================================
1452
1453 AC_MSG_RESULT(The following feature summary has been saved to features.log)
1454 cat features.log