configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl There are two types of comments in this file.
   4 dnl Comments that refer to Autoconf macros begin with "dnl", and m4
   5 dnl discards them.  Other comments begin with "#", and they get copied
   6 dnl to the configure script, hopefully making it easier to read.
   7
   8 dnl Autoconf 2.13 generates an incomplete config.h.in; see ELinks bug 936.
   9 dnl Autoconf 2.61 is installed in the computer that generates our nightly
  10 dnl snapshots, so we need to be compatible with that.  (Also, some files
  11 dnl in Autoconf 2.62 and 2.63 sources are not GPLv2 compatible.)
  12 AC_PREREQ(2.61)
  13 AC_INIT
  14 AC_CONFIG_SRCDIR([src/main/main.c])
  15 AC_CONFIG_AUX_DIR(config)
  16
  17 PACKAGE=elinks
  18 VERSION=0.13.GIT
  19 AC_SUBST(PACKAGE)
  20 AC_SUBST(VERSION)
  21 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Package version])
  22 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Package version])
  23 AC_CONFIG_HEADERS(config.h)
  24
  25 AC_CHECK_PROG(ACLOCAL,[aclocal],[aclocal],[config/missing aclocal])
  26 AC_CHECK_PROG(AUTOCONF,[autoconf],[autoconf],[config/missing autoconf])
  27 AC_CHECK_PROG(AUTOHEADER,[autoheader],[autoheader],[config/missing autoheader])
  28
  29 MAKE=
  30
  31 for make in gnumake gmake make false; do
  32         if test "x$MAKE" = x; then
  33                 AC_PATH_PROGS(MAKE, "$make")
  34         fi
  35 done
  36
  37 builddir="`pwd`"
  38
  39 # Cleanup if we are configuring with a previous build in the tree
  40 if test -e Makefile.config; then
  41         AC_MSG_CHECKING([for previous build to clean])
  42         "$MAKE" -C "$builddir/src" cleanall >/dev/null 2>/dev/null
  43         AC_MSG_RESULT(done)
  44 fi
  45
  46 # ===================================================================
  47 # Load feature configuration file and start logging features.
  48 # ===================================================================
  49
  50 features="features.conf"
  51 AC_CHECK_FILE("$srcdir/$features", [ . $srcdir/$features ])
  52 AC_CHECK_FILE("$builddir/$features", [ . $builddir/$features ])
  53 echo "Feature summary:" > features.log
  54
  55 # ===================================================================
  56 # Checks for programs.
  57 # ===================================================================
  58
  59 AC_PROG_CC
  60 AC_PROG_AWK
  61 AC_PATH_PROGS(AWK, "$AWK")
  62 AC_PROG_RANLIB
  63 AC_PROG_INSTALL
  64
  65 AC_PATH_PROGS(GIT, "git")
  66 AC_PATH_PROGS(SPARSE, "sparse")
  67
  68 CONFIG_ASCIIDOC="no"
  69 CONFIG_POD2HTML="no"
  70 CONFIG_XMLTO="no"
  71 CONFIG_JW="no"
  72
  73 if test "x$CONFIG_DOC" != xno; then
  74         AC_PATH_PROGS(PYTHON, "python")
  75         if test "x$PYTHON" != "x"; then
  76                 EL_CONFIG(CONFIG_ASCIIDOC, [AsciiDoc])
  77                 EL_CONFIG(MANUAL_ASCIIDOC, [HTML (one file)])
  78                 EL_CONFIG(MAN_ASCIIDOC, [HTML])
  79         fi
  80
  81         AC_PATH_PROGS(XMLTO, "xmlto")
  82         if test "x$XMLTO" != "x"; then
  83                 EL_CONFIG(CONFIG_XMLTO, [XmlTo])
  84                 EL_CONFIG(MANUAL_XMLTO, [HTML (multiple files)])
  85                 EL_CONFIG(MAN_XMLTO, [man (groff)])
  86         fi
  87
  88         AC_PATH_PROGS(JW, "jw")
  89         if test "x$JW" != "x"; then
  90                 EL_CONFIG(CONFIG_JW, [JadeWrapper])
  91                 EL_CONFIG(MANUAL_JW, [PDF])
  92         fi
  93
  94         AC_PATH_PROGS(POD2HTML, "pod2html")
  95         if test "x$POD2HTML" != "x"; then
  96                 EL_CONFIG(CONFIG_POD2HTML, [Pod2HTML])
  97         fi
  98
  99         AC_PATH_PROGS(DOXYGEN, "doxygen")
 100         if test "x$DOXYGEN" != "x"; then
 101                 EL_CONFIG(CONFIG_DOXYGEN, [Doxygen])
 102                 api_srcdir="$(cd "$srcdir" && pwd)/src"
 103                 AC_SUBST(api_srcdir)
 104         fi
 105 fi
 106
 107 AC_SUBST(CONFIG_ASCIIDOC)
 108 AC_SUBST(CONFIG_DOXYGEN)
 109 AC_SUBST(CONFIG_POD2HTML)
 110 AC_SUBST(CONFIG_XMLTO)
 111 AC_SUBST(CONFIG_JW)
 112
 113 EL_CONFIG_DEPENDS(CONFIG_DOC, [CONFIG_ASCIIDOC CONFIG_XMLTO CONFIG_JW CONFIG_POD2HTML], [Documentation Tools])
 114 EL_CONFIG_DEPENDS(CONFIG_MANUAL, [MANUAL_ASCIIDOC MANUAL_XMLTO MANUAL_JW], [Manual Formats])
 115 EL_CONFIG_DEPENDS(CONFIG_MANPAGE, [MAN_ASCIIDOC MAN_XMLTO], [Man Page Formats])
 116 EL_CONFIG_DEPENDS(CONFIG_APIDOCS, [CONFIG_DOXYGEN], [API Documentation])
 117
 118 # gcc specific options (to be continued at the bottom of configure)
 119 if test "x$ac_cv_c_compiler_gnu" = "xyes"; then
 120   # We want to see all warnings and live with none.
 121   # We can't set up -Werror here as there may be some warnings in test
 122   # suite of configure, and we don't want to fail them.
 123   CFLAGS="$CFLAGS -Wall"
 124 fi
 125
 126 # ===================================================================
 127 # Checks for special OSes.
 128 # ===================================================================
 129
 130 dnl EL_CHECK_COMPILER_MACRO(define, name, flagname)
 131 AC_DEFUN([EL_CHECK_COMPILER_MACROS],
 132 [
 133         AC_MSG_CHECKING([for $2])
 134
 135         for flag in $3; do
 136                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[#ifndef $flag
 137 kill me!
 138 #endif ]])],[$1=yes],[$1=no])
 139                 if test "[$]$1" = yes; then
 140                         EL_CONFIG([$1], [$2])
 141                         break
 142                 fi
 143         done
 144
 145         AC_MSG_RESULT([$]$1)
 146 ])
 147
 148 EL_CHECK_COMPILER_MACROS(CONFIG_OS_BEOS, [BEOS], [__BEOS__])
 149 AC_SUBST(CONFIG_OS_BEOS)
 150
 151 EL_CHECK_COMPILER_MACROS(CONFIG_OS_RISCOS, [RISCOS], [__riscos__])
 152 AC_SUBST(CONFIG_OS_RISCOS)
 153
 154 EL_CHECK_COMPILER_MACROS(CONFIG_OS_WIN32, [WIN32], [_WIN32 __WIN32__])
 155 AC_SUBST(CONFIG_OS_WIN32)
 156
 157 EL_CHECK_COMPILER_MACROS(CONFIG_OS_OS2, [EMX], [__EMX__])
 158 AC_SUBST(CONFIG_OS_OS2)
 159 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zexe//g"`
 160
 161 AC_MSG_CHECKING([for UNIX])
 162 dnl FIXME: some depend kind of mechanism
 163 if test "$CONFIG_OS_BEOS" = no && \
 164    test "$CONFIG_OS_RISCOS" = no && \
 165    test "$CONFIG_OS_WIN32" = no && \
 166    test "$CONFIG_OS_OS2" = no; then
 167         EL_CONFIG(CONFIG_OS_UNIX, [UNIX])
 168 else
 169         CONFIG_OS_UNIX=no
 170 fi
 171 AC_MSG_RESULT($CONFIG_OS_UNIX)
 172 AC_SUBST(CONFIG_OS_UNIX)
 173
 174 # ===================================================================
 175 # Checks for header files.
 176 # ===================================================================
 177
 178 AC_HEADER_DIRENT
 179 AC_HEADER_STDC
 180 AC_HEADER_SYS_WAIT
 181 AC_HEADER_TIME
 182
 183 AC_CHECK_HEADERS(wchar.h wctype.h)
 184 AC_CHECK_HEADERS(fcntl.h limits.h time.h unistd.h)
 185 AC_CHECK_HEADERS(sigaction.h)
 186 AC_CHECK_HEADERS(arpa/inet.h)
 187 AC_CHECK_HEADERS(netinet/in_systm.h netinet/in_system.h netinet/ip.h)
 188 AC_CHECK_HEADERS(netdb.h netinet/in.h netinet/in6_var.h)
 189 AC_CHECK_HEADERS(ifaddrs.h)
 190 AC_CHECK_HEADERS(sys/cygwin.h io.h)
 191 AC_CHECK_HEADERS(sys/fmutex.h)
 192 AC_CHECK_HEADERS(sys/ioctl.h sys/sockio.h)
 193 AC_CHECK_HEADERS(sys/resource.h)
 194 AC_CHECK_HEADERS(sys/select.h)
 195 AC_CHECK_HEADERS(sys/signal.h)
 196 AC_CHECK_HEADERS(sys/socket.h)
 197 AC_CHECK_HEADERS(sys/time.h)
 198 AC_CHECK_HEADERS(sys/utsname.h)
 199 AC_CHECK_HEADERS([net/if.h], [], [],
 200 [[#ifdef HAVE_SYS_SOCKET_H
 201 # include <sys/socket.h> /* <net/if.h> on Mac OS X 10.5.4 needs this */
 202 #endif
 203 ]])
 204 AC_CHECK_HEADERS(stdint.h inttypes.h)
 205 AC_CHECK_HEADERS(locale.h pwd.h)
 206 AC_CHECK_HEADERS(termios.h)
 207
 208
 209 AC_CHECK_HEADERS(sys/un.h,
 210         [CONFIG_INTERLINK=yes
 211          EL_CONFIG([CONFIG_INTERLINK], [interlinking])],
 212         [CONFIG_INTERLINK=no])
 213 AC_SUBST(CONFIG_INTERLINK)
 214
 215 # ===================================================================
 216 # Checks for typedefs, structures, and compiler characteristics.
 217 # ===================================================================
 218
 219 AC_STRUCT_TM
 220 AC_C_CONST
 221 AC_C_INLINE
 222 AC_MSG_CHECKING([[for C99-conforming inline]])
 223 AC_COMPILE_IFELSE([[
 224         int add(int change);
 225
 226         static int sum;
 227
 228         inline int
 229         add(int change)
 230         {
 231                 sum += change;
 232                 return sum;
 233         }
 234
 235         int
 236         sub(int change)
 237         {
 238                 return add(-change);
 239         }]],
 240         [AC_MSG_RESULT([[yes]])
 241          AC_DEFINE([NONSTATIC_INLINE], [inline],
 242                 [Define as inline if the compiler lets you declare a function without inline, then define it with inline, and have that definition refer to identifiers with internal linkage.  This is allowed by C99 6.7.4p6 and 6.7.4p3 together.  Otherwise define as nothing.])],
 243         [AC_MSG_RESULT([[no]])
 244          AC_DEFINE([NONSTATIC_INLINE], [])])
 245 EL_CHECK_CODE(typeof, HAVE_TYPEOF, [], [int a; typeof(a) b;])
 246
 247 AC_SYS_LARGEFILE
 248 AC_TYPE_SIZE_T
 249 AC_TYPE_OFF_T
 250 EL_CHECK_TYPE(ssize_t, int)
 251 EL_CHECK_SYS_TYPE(long long, HAVE_LONG_LONG, [])
 252 EL_CHECK_SYS_TYPE(off_t, HAVE_OFF_T, [])
 253 EL_CHECK_INT_TYPE(int32_t, HAVE_INT32_T)
 254 EL_CHECK_INT_TYPE(uint32_t, HAVE_UINT32_T)
 255 EL_CHECK_INT_TYPE(uint16_t, HAVE_UINT16_T)
 256
 257 AC_CHECK_SIZEOF(char, 1)
 258 AC_CHECK_SIZEOF(short, 2)
 259 AC_CHECK_SIZEOF(int, 4)
 260 AC_CHECK_SIZEOF(long, 4)
 261 test "x$HAVE_LONG_LONG" = xyes && AC_CHECK_SIZEOF(long long, 8)
 262 test "x$HAVE_OFF_T" = xyes && AC_CHECK_SIZEOF(off_t, 4)
 263
 264 # Check for variadic macros
 265 EL_CHECK_CODE([variadic macros], HAVE_VARIADIC_MACROS,
 266                 [#include <stdio.h>
 267                  #define a(b,c...) printf(b,##c)],
 268                 [a("foo");a("%s","bar");a("%s%s","baz","quux");])
 269
 270 # ===================================================================
 271 # Checks for library functions.
 272 # ===================================================================
 273
 274 AC_PROG_GCC_TRADITIONAL
 275 AC_FUNC_MEMCMP
 276 AC_FUNC_MMAP
 277 AC_FUNC_STRFTIME
 278 AC_CHECK_FUNCS(atoll gethostbyaddr herror strerror)
 279 AC_CHECK_FUNCS(popen uname access chmod alarm timegm mremap)
 280 AC_CHECK_FUNCS(strcasecmp strncasecmp strcasestr strstr strchr strrchr)
 281 AC_CHECK_FUNCS(memmove bcopy stpcpy strdup index isdigit mempcpy memrchr)
 282 AC_CHECK_FUNCS(snprintf vsnprintf asprintf vasprintf)
 283 AC_CHECK_FUNCS(getifaddrs getpwnam inet_pton inet_ntop)
 284 AC_CHECK_FUNCS(fflush fsync fseeko ftello sigaction)
 285 AC_CHECK_FUNCS(gettimeofday clock_gettime)
 286 AC_CHECK_FUNCS(setitimer, HAVE_SETITIMER=yes)
 287
 288 AC_CHECK_FUNCS([cygwin_conv_to_full_win32_path])
 289
 290 AC_CHECK_FUNCS(setenv putenv, HAVE_SETENV_OR_PUTENV=yes)
 291 AC_CHECK_FUNCS(unsetenv)
 292 AC_CHECK_FUNCS(getuid, HAVE_GETUID=yes)
 293 AC_CHECK_FUNCS(geteuid, HAVE_GETEUID=yes)
 294
 295 AC_CHECK_FUNCS(wcwidth, HAVE_WCWIDTH=yes)
 296
 297 # These aren't probably needed now, as they are commented in links.h.
 298 # I've no idea about their historical background, but I keep them here
 299 # just in the case they will help later. --pasky
 300 AC_CHECK_FUNCS(getpid, HAVE_GETPID=yes)
 301 AC_CHECK_FUNCS(setpgid getpgid setpgrp getpgrp)
 302 AC_CHECK_FUNCS(raise, HAVE_RAISE=yes)
 303 AC_CHECK_FUNCS(kill, HAVE_KILL=yes)
 304
 305 AC_CHECK_FUNCS(fpathconf, HAVE_FPATHCONF=yes)
 306
 307 if test x"$HAVE_RAISE" = x; then
 308         if test x"$HAVE_KILL" = x || test x"$HAVE_GETPID" = x; then
 309                 AC_MSG_ERROR([Unable to emulate raise()])
 310         fi
 311 fi
 312
 313 AC_CACHE_CHECK([for __va_copy],el_cv_HAVE_VA_COPY,[
 314 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>
 315 va_list ap1,ap2;]], [[__va_copy(ap1,ap2);]])],[el_cv_HAVE_VA_COPY=yes],[el_cv_HAVE_VA_COPY=no])])
 316 if test x"$el_cv_HAVE_VA_COPY" = x"yes"; then
 317         EL_DEFINE(HAVE_VA_COPY, __va_copy)
 318 fi
 319
 320 AC_CACHE_CHECK([for sysconf(_SC_PAGE_SIZE)],el_cv_HAVE_SC_PAGE_SIZE,[
 321 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <unistd.h>
 322 ]], [[int page_size = sysconf(_SC_PAGE_SIZE);]])],[el_cv_HAVE_SC_PAGE_SIZE=yes],[el_cv_HAVE_SC_PAGE_SIZE=no])])
 323 if test x"$el_cv_HAVE_SC_PAGE_SIZE" = x"yes"; then
 324         EL_DEFINE(HAVE_SC_PAGE_SIZE, _SC_PAGE_SIZE)
 325 fi
 326
 327 AC_CACHE_CHECK([for C99 vsnprintf],el_cv_HAVE_C99_VSNPRINTF,[
 328 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 329 #include <stdio.h>
 330 #include <stdarg.h>
 331 #include <stdlib.h>
 332 #include <string.h>
 333
 334 char buf[8];
 335
 336 int bar(char *buf, const char *format, va_list ap)
 337 {
 338        return vsnprintf(buf, 0, format, ap);
 339 }
 340
 341 void foo(const char *format, ...) {
 342        va_list ap;
 343        int len;
 344
 345        va_start(ap, format);
 346        len = bar(buf, format, ap);
 347        va_end(ap);
 348        if ((len != 6) && (len != 7)) exit(1); /* \n -> \r\n */
 349
 350        va_start(ap, format);
 351        len = bar(buf, format, ap);
 352        va_end(ap);
 353        if ((len != 6) && (len != 7)) exit(1);
 354
 355        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 356
 357        exit(0);
 358 }
 359 main() { foo("hello\n"); }
 360 ]])],[el_cv_HAVE_C99_VSNPRINTF=yes],[el_cv_HAVE_C99_VSNPRINTF=no],[el_cv_HAVE_C99_VSNPRINTF=cross])])
 361 if test x"$el_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 362         EL_DEFINE(HAVE_C99_VSNPRINTF, [C99 compliant vsnprintf()])
 363 fi
 364
 365 # OpenSSL and Lua frequently need dlopen
 366 AC_CHECK_LIB(dl, dlopen)
 367
 368 # ===================================================================
 369 # Checks for libraries.
 370 # ===================================================================
 371
 372 AC_CHECK_FUNC(socket, cf_result=yes, cf_result=no)
 373 if test "$cf_result" = no; then
 374         AC_CHECK_LIB(socket, socket)
 375 fi
 376
 377 AC_CHECK_FUNC(setsockopt, cf_result=yes, cf_result=no)
 378 if test "$cf_result" = no; then
 379         AC_CHECK_LIB(socket, setsockopt)
 380 fi
 381
 382 AC_CHECK_FUNC(gethostbyname, cf_result=yes, cf_result=no)
 383 if test "$cf_result" = no; then
 384         AC_CHECK_LIB(socket, gethostbyname, cf_result=yes, cf_result=no)
 385         if test "$cf_result" = no; then
 386                 AC_CHECK_LIB(nsl, gethostbyname)
 387         else
 388                 test -z "`echo $LIBS | grep -- -lsocket`" && LIBS="$LIBS -lsocket"
 389         fi
 390 fi
 391
 392 # ===================================================================
 393 # Checks for packaging specific options.
 394 # ===================================================================
 395
 396 AC_ARG_WITH(xterm, [  --with-xterm            how to invoke the X terminal emulator],
 397             [ if test "$withval" != no && test "$withval" != yes; then
 398                 AC_DEFINE_UNQUOTED(XTERM, "$withval", [How to invoke XTerm])
 399               fi ])
 400
 401 # ===================================================================
 402 # Checks for a libraries, optional even if installed.
 403 # ===================================================================
 404
 405 dnl EL_CHECK_OPTIONAL_LIBRARY(define, name, header, lib, function)
 406 AC_DEFUN([EL_CHECK_OPTIONAL_LIBRARY],
 407 [
 408         AC_MSG_CHECKING([for $2 support])
 409
 410         if test "[$]$1" != no; then
 411                 AC_MSG_RESULT(yes)
 412                 EL_SAVE_FLAGS
 413                 if test -n "$withval" && test -d "$withval"; then
 414                         # Be a little more careful when setting
 415                         # include and lib directories. This way
 416                         # $withval will work when includes are
 417                         # there but the library is in the common
 418                         # /usr/lib ... Does the right thing when
 419                         # looking for gc on Debian.
 420                         if test -d "$withval/include"; then
 421                                 CFLAGS="$CFLAGS -I$withval/include"
 422                                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 423                         else
 424                                 CFLAGS="$CFLAGS -I$withval"
 425                                 CPPFLAGS="$CPPFLAGS -I$withval"
 426                         fi
 427                         if test -d "$withval/lib"; then
 428                                 LDFLAGS="$LDFLAGS -L$withval/lib"
 429                         fi
 430                 fi
 431
 432                 AC_CHECK_HEADERS([$3], [$1=yes], [$1=no; break;])
 433                 if test "[$]$1" = yes; then
 434                         AC_CHECK_LIB([$4], [$5], [$1=yes], [$1=no])
 435                 fi
 436
 437                 if test "[$]$1" = yes; then
 438                         EL_CONFIG([$1], [$2])
 439                         LIBS="$LIBS -l$4"
 440                 else
 441                         if test -n "[$]WITHVAL_$1" &&
 442                            test "[$]WITHVAL_$1" != xno; then
 443                                 AC_MSG_ERROR([$2 not found])
 444                         fi
 445                         EL_RESTORE_FLAGS
 446                 fi
 447         else
 448                 AC_MSG_RESULT(disabled)
 449         fi
 450 ])
 451
 452 dnl EL_CONFIG_OPTIONAL_LIBRARY(define, name, header, lib, function, confhelp)
 453 AC_DEFUN([EL_CONFIG_OPTIONAL_LIBRARY],
 454 [
 455         if test "x[$]$1" != xno; then $1=yes; fi
 456         WITHVAL_$1=
 457
 458         AC_ARG_WITH([$2], [$6], [WITHVAL_$1="[$]withval"])
 459         if test "x[$]WITHVAL_$1" = xno; then $1=no; fi
 460         if test "x[$]WITHVAL_$1" = xyes; then $1=yes; fi
 461
 462         EL_CHECK_OPTIONAL_LIBRARY([$1], [$2], [$3], [$4], [$5])
 463
 464         EL_LOG_CONFIG([$1], [$2], [])
 465 ])
 466
 467 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GPM, gpm, gpm.h, gpm, Gpm_Open,
 468         [  --without-gpm           disable gpm (mouse) support])
 469
 470 # ELinks calls deflateInit2 with windowBits = MAX_WBITS | 32, to
 471 # enable automatic decoding of both zlib and gzip headers.  This
 472 # feature was added in zlib 1.2.0.2; earlier versions return an error.
 473 # The gzclearerr function was also added in zlib 1.2.0.2, so check for
 474 # that, even though ELinks does not actually call gzclearerr.
 475 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GZIP, zlib, zlib.h, z, gzclearerr,
 476         [  --without-zlib          disable zlib support])
 477
 478 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_BZIP2, bzlib, bzlib.h, bz2, BZ2_bzReadOpen,
 479         [  --without-bzlib         disable bzlib support])
 480
 481 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_IDN, idn, idna.h, idn, stringprep_check_version,
 482         [  --without-idn           disable international domain names support])
 483
 484 if test "x${with_gc}" != xno; then
 485         EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GC, gc, gc.h, gc, GC_init,
 486                 [  --with-gc               enable Boehm's garbage collector])
 487 fi
 488
 489 # LZMA disabled by default, because of little usability and compilation problems
 490 # with new xz
 491 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_LZMA, lzma, lzma.h, lzma, lzma_code,
 492         [  --with-lzma             enable lzma encoding support])
 493
 494 # ===================================================================
 495 # Check for GSSAPI, optional even if installed.
 496 # ===================================================================
 497
 498 enable_gssapi="no";
 499
 500 AC_ARG_WITH(gssapi, [  --with-gssapi           enable GSSAPI support],
 501             [ if test "x$withval" != xno; then enable_gssapi=yes; fi ])
 502
 503 AC_MSG_CHECKING([for GSSAPI])
 504
 505 if test "$enable_gssapi" = "yes"; then
 506         AC_MSG_RESULT(yes)
 507         GSSAPI_CFLAGS=`krb5-config --cflags gssapi`
 508         GSSAPI_LIBS=`krb5-config --libs gssapi`
 509         CFLAGS="$GSSAPI_CFLAGS $CFLAGS"
 510         LIBS="$GSSAPI_LIBS $LIBS"
 511         EL_CONFIG(CONFIG_GSSAPI, [GssApi])
 512 else
 513         AC_MSG_RESULT(no)
 514 fi
 515
 516 AC_SUBST(CONFIG_GSSAPI)
 517
 518 # ===================================================================
 519 # Bookmark and XBEL support
 520 # ===================================================================
 521
 522 EL_SAVE_FLAGS
 523
 524 EL_ARG_ENABLE(CONFIG_BOOKMARKS, bookmarks, [Bookmarks],
 525               [  --disable-bookmarks     disable bookmark support])
 526
 527 # Check whether --enable-xbel or --disable-xbel was given.
 528 if test "x${enable_xbel}" != xno; then
 529         AC_CHECK_HEADERS(expat.h, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 530
 531         if test "$HAVE_LIBEXPAT" = yes; then
 532                 AC_CHECK_LIB(expat, XML_ParserCreate, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 533                 if test "$HAVE_LIBEXPAT" = yes; then
 534                         LIBS="$LIBS -lexpat"
 535                 fi
 536         fi
 537 fi
 538
 539
 540 EL_ARG_DEPEND(CONFIG_XBEL_BOOKMARKS, xbel, [CONFIG_BOOKMARKS:yes HAVE_LIBEXPAT:yes],
 541               [XBEL bookmarks],
 542               [  --disable-xbel          disable XBEL bookmark support (requires expat)])
 543
 544 if test "$CONFIG_XBEL_BOOKMARKS" != yes; then
 545         EL_RESTORE_FLAGS
 546 fi
 547
 548 # ===================================================================
 549 # Checks for BSD sysmouse
 550 # ===================================================================
 551
 552 HAVE_SYSMOUSE_HEADER="no"
 553
 554 # Either of these header files provides the (same) sysmouse interface
 555 AC_CHECK_HEADERS(sys/consio.h machine/console.h, [HAVE_SYSMOUSE_HEADER="yes"])
 556
 557 # ===================================================================
 558 # Checks for OS/2
 559 # ===================================================================
 560
 561 if test "$CONFIG_OS_OS2" = yes; then
 562         EL_CONFIG_OS_OS2
 563 fi
 564
 565 # ===================================================================
 566 # Checks for Win32
 567 # ===================================================================
 568
 569 if test "$CONFIG_OS_WIN32" = yes; then
 570         EL_CONFIG_OS_WIN32
 571 fi
 572
 573 # ===================================================================
 574 # Check for SEE (Simple Ecmascript Engine)
 575 # ===================================================================
 576 AC_ARG_WITH(see, [  --with-see              enable Simple Ecmascript Engine (SEE) support],
 577             [ if test "x$withval" != xno; then enable_see=yes; fi ])
 578
 579 # The following is probably bad, ugly and so on. Stolen from Guile's (1.4)
 580 # GUILE_FLAGS but I really don't want to require people to have Guile in order
 581 # to compile CVS. Also, the macro seems to be really stupid regarding searching
 582 # for Guile in $PATH etc. --pasky
 583
 584 CONFIG_ECMASCRIPT_SEE=no
 585
 586 if test "$enable_see" = "yes"; then
 587         if test -d "$withval"; then
 588                 SEE_PATH="$withval:$PATH"
 589         else
 590                 SEE_PATH="$PATH"
 591         fi
 592
 593         AC_PATH_PROG(SEE_CONFIG, libsee-config, no, $SEE_PATH)
 594         AC_MSG_CHECKING([for SEE (2.0.1131 or later)])
 595         if test "$SEE_CONFIG" != no; then
 596                 EL_SAVE_FLAGS
 597                 SEE_LIBS="`$SEE_CONFIG --libs`"
 598                 SEE_CFLAGS="`$SEE_CONFIG --cppflags`"
 599                 CPPFLAGS="$SEE_CFLAGS $CPPFLAGS"
 600                 LIBS="$SEE_LIBS $LIBS_X"
 601                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <see/see.h>]], [[#if SEE_VERSION_API_MAJOR < 2
 602                         #error SEE too old
 603                         #endif
 604                 ]])],[cf_result=yes],[cf_result=no])
 605                 EL_RESTORE_FLAGS
 606                 if test "$cf_result" = yes; then
 607                         LIBS="$SEE_LIBS $LIBS"
 608                         EL_CONFIG(CONFIG_ECMASCRIPT_SEE, [SEE])
 609                         AC_SUBST(SEE_CFLAGS)
 610                 fi
 611                 AC_MSG_RESULT($cf_result)
 612         else
 613                 if test -n "$withval" && test "x$withval" != xno; then
 614                         AC_MSG_ERROR([SEE not found])
 615                 else
 616                         AC_MSG_WARN([SEE support disabled])
 617                 fi
 618         fi
 619 fi
 620
 621 # ===================================================================
 622 # Check for SpiderMonkey, optional even if installed.
 623 # ===================================================================
 624
 625 AC_ARG_WITH(spidermonkey, [  --without-spidermonkey  disable SpiderMonkey Mozilla JavaScript engine support],
 626             [if test "$withval" = no; then disable_spidermonkey=yes; fi])
 627 AC_MSG_CHECKING([for SpiderMonkey (1.5 RC3a or later)])
 628
 629 EL_SAVE_FLAGS
 630 cf_result=no
 631
 632 if test -z "$disable_spidermonkey"; then
 633         if test ! -d "$withval"; then
 634                 withval="";
 635         fi
 636         for spidermonkeydir in "$withval" "" /usr /usr/local /opt/spidermonkey /opt/js; do
 637                 for spidermonkeyinclude in "/include" "/include/js" "/include/smjs" "/include/mozjs"; do
 638                         for spidermonkeylib in js smjs mozjs; do
 639                                 if test "$cf_result" = no &&
 640                                    test -f "$spidermonkeydir$spidermonkeyinclude/jsapi.h"; then
 641                                         SPIDERMONKEY_LIBS="-L$spidermonkeydir/lib -l$spidermonkeylib"
 642                                         SPIDERMONKEY_CFLAGS="-I$spidermonkeydir$spidermonkeyinclude"
 643
 644                                         LIBS="$SPIDERMONKEY_LIBS $LIBS_X"
 645                                         CFLAGS="$CFLAGS_X $SPIDERMONKEY_CFLAGS"
 646                                         CPPFLAGS="$CPPFLAGS_X $SPIDERMONKEY_CFLAGS"
 647
 648                                         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define XP_UNIX
 649                                                      #include <jsapi.h>]], [[JS_GetReservedSlot(NULL, NULL, 0, NULL)]])],[cf_result=yes],[cf_result=no])
 650                                 fi
 651                         done
 652                 done
 653         done
 654 fi
 655
 656 AC_MSG_RESULT($cf_result)
 657 CONFIG_SPIDERMONKEY="$cf_result"
 658 if test "$cf_result" = "yes"; then
 659         AC_CHECK_FUNCS([[JS_ReportAllocationOverflow]])
 660         AC_CHECK_FUNCS(JS_SetBranchCallback)
 661         AC_CHECK_FUNCS(JS_TriggerOperationCallback, HAVE_JS_TRIGGEROPERATIONCALLBACK=yes)
 662 fi
 663 EL_RESTORE_FLAGS
 664
 665 if test "x$CONFIG_SPIDERMONKEY" = xyes &&
 666    test "x$CONFIG_ECMASCRIPT_SEE" != xyes; then
 667         EL_CONFIG(CONFIG_ECMASCRIPT_SMJS, [SpiderMonkey document scripting])
 668 else
 669         CONFIG_ECMASCRIPT_SMJS=no
 670 fi
 671
 672 EL_CONFIG_DEPENDS(CONFIG_ECMASCRIPT, [CONFIG_ECMASCRIPT_SEE CONFIG_ECMASCRIPT_SMJS], [ECMAScript (JavaScript)])
 673 AC_SUBST(CONFIG_ECMASCRIPT_SEE)
 674 AC_SUBST(CONFIG_ECMASCRIPT_SMJS)
 675
 676 if test "x$CONFIG_ECMASCRIPT_SMJS" = xyes &&
 677    test "x$HAVE_JS_TRIGGEROPERATIONCALLBACK" = xyes &&
 678    test "x$HAVE_SETITIMER" = xyes; then
 679         EL_CONFIG(CONFIG_ECMASCRIPT_SMJS_HEARTBEAT, [ECMAScript heartbeat support])
 680 else
 681         CONFIG_ECMASCRIPT_SMJS_HEARTBEAT=no
 682 fi
 683 AC_SUBST(CONFIG_ECMASCRIPT_SMJS_HEARTBEAT)
 684
 685
 686 # ===================================================================
 687 # Optional Spidermonkey-based ECMAScript browser scripting
 688 # ===================================================================
 689
 690 AC_ARG_ENABLE(sm-scripting,
 691               [  --disable-sm-scripting  ECMAScript browser scripting (requires Spidermonkey)],
 692               [if test "$enableval" != no; then enableval="yes"; fi
 693                CONFIG_SCRIPTING_SPIDERMONKEY="$enableval";])
 694
 695 if test "x$CONFIG_SPIDERMONKEY" = xyes &&
 696    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 697         EL_CONFIG(CONFIG_SCRIPTING_SPIDERMONKEY, [SpiderMonkey])
 698 else
 699         CONFIG_SCRIPTING_SPIDERMONKEY=no
 700 fi
 701
 702 if test "x$CONFIG_ECMASCRIPT_SMJS" = xyes ||
 703    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 704         LIBS="$LIBS $SPIDERMONKEY_LIBS"
 705         AC_SUBST(SPIDERMONKEY_LIBS)
 706         AC_SUBST(SPIDERMONKEY_CFLAGS)
 707         AC_SUBST(CONFIG_SPIDERMONKEY)
 708 fi
 709
 710 # ===================================================================
 711 # Check for Guile, optional even if installed.
 712 # ===================================================================
 713
 714 enable_guile="no";
 715
 716 AC_ARG_WITH(guile, [  --with-guile            enable Guile support],
 717             [ if test "x$withval" != xno; then enable_guile=yes; fi ])
 718
 719 # The following is probably bad, ugly and so on. Stolen from Guile's (1.4)
 720 # GUILE_FLAGS but I really don't want to require people to have Guile in order
 721 # to compile CVS. Also, the macro seems to be really stupid regarding searching
 722 # for Guile in $PATH etc. --pasky
 723
 724 AC_MSG_CHECKING([for Guile])
 725
 726 if test "$enable_guile" = "yes"; then
 727         AC_MSG_RESULT(yes);
 728         ## Based on the GUILE_FLAGS macro.
 729
 730         if test -d "$withval"; then
 731                 GUILE_PATH="$withval:$PATH"
 732         else
 733                 GUILE_PATH="$PATH"
 734         fi
 735
 736         AC_PATH_PROG(GUILE_CONFIG, guile-config, no, $GUILE_PATH)
 737
 738         ## First, let's just see if we can find Guile at all.
 739         if test "$GUILE_CONFIG" != no; then
 740                 cf_result="yes";
 741
 742                 GUILE_LIBS="`guile-config link`"
 743                 GUILE_CFLAGS="`guile-config compile`"
 744                 LIBS="$GUILE_LIBS $LIBS"
 745                 EL_CONFIG(CONFIG_SCRIPTING_GUILE, [Guile])
 746                 AC_SUBST(GUILE_CFLAGS)
 747                 cat <<EOF
 748 ***********************************************************************
 749 The Guile support is incomplete and not so well integrated to ELinks
 750 yet. That means, e.g., that you have no Guile console and there might
 751 not be all the necessary hooks. Also, the Guile interface is not too
 752 well tested (success stories heartily welcomed!).  See
 753 src/scripting/guile/README for further details and hints.
 754 ***********************************************************************
 755 EOF
 756         else
 757                 if test -n "$withval" && test "x$withval" != xno; then
 758                         AC_MSG_ERROR([Guile not found])
 759                 else
 760                         AC_MSG_WARN([Guile support disabled])
 761                 fi
 762         fi
 763 else
 764         AC_MSG_RESULT(no);
 765 fi
 766
 767 # ===================================================================
 768 # Check for Perl
 769 # ===================================================================
 770 enable_perl="no";
 771
 772 AC_ARG_WITH(perl, [  --with-perl             enable Perl support],
 773             [
 774 if test "$withval" = yes; then
 775         # FIXME: If withval is a valid directory append it to PATH
 776         # so that you can specify one of several perl installations.
 777         withval="";
 778         enable_perl=yes;
 779 fi
 780             ])
 781
 782 AC_MSG_CHECKING([for Perl])
 783
 784 cf_result=no
 785
 786 EL_SAVE_FLAGS
 787
 788 if test "$enable_perl" = "yes"; then
 789         PERL_LIBS="`perl -MExtUtils::Embed -e ldopts`"
 790         PERL_CFLAGS="`perl -MExtUtils::Embed -e ccopts`"
 791         LIBS="$PERL_LIBS $LIBS"
 792         CFLAGS="$PERL_CFLAGS $CFLAGS"
 793         CPPFLAGS="$CPPFLAGS $PERL_CFLAGS"
 794         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 795 #include <EXTERN.h>
 796 #include <perl.h>
 797 #include <perlapi.h>
 798 ]], [[PerlInterpreter *my_perl = perl_alloc();]])],[cf_result=yes],[cf_result=no])
 799 fi
 800
 801 if test "$cf_result"; then AC_MSG_RESULT($cf_result); fi
 802
 803 AC_MSG_CHECKING([whether POPpx works without an n_a variable])
 804 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 805 #include <EXTERN.h>
 806 #include <perl.h>
 807 extern PerlInterpreter *my_perl;
 808 ]], [[dSP; (void) POPpx;]])],[AC_MSG_RESULT([yes])
 809 AC_DEFINE([CONFIG_PERL_POPPX_WITHOUT_N_A], [1],
 810                 [Define if using Perl 5.8.8 or later, where the "POPpx" macro
 811 no longer needs an "n_a" variable like it did in 5.8.7])],[AC_MSG_RESULT([no])])
 812
 813 if test "$cf_result" != "yes"; then
 814         EL_RESTORE_FLAGS
 815 else
 816         EL_CONFIG(CONFIG_SCRIPTING_PERL, [Perl])
 817
 818         CFLAGS="$CFLAGS_X"
 819         CPPFLAGS="$CPPFLAGS_X"
 820         AC_SUBST(PERL_LIBS)
 821         AC_SUBST(PERL_CFLAGS)
 822 fi
 823
 824 # ===================================================================
 825 # Check for Python
 826 # ===================================================================
 827 enable_python="no";
 828
 829 AC_ARG_WITH(python, [[  --with-python[=DIR]     enable Python support]],
 830             [ if test "x$withval" != xno; then enable_python=yes; fi ])
 831
 832 EL_SAVE_FLAGS
 833 cf_result=no
 834
 835 AC_MSG_CHECKING([for Python])
 836
 837 if test "$enable_python" = "yes"; then
 838         AC_MSG_RESULT(yes);
 839
 840         if test -d "$withval"; then
 841                 PYTHON_PATH="$withval:$PATH"
 842         else
 843                 PYTHON_PATH="$PATH"
 844         fi
 845
 846         AC_PATH_PROG(PYTHON, python, no, $PYTHON_PATH)
 847
 848         if test "$PYTHON" != no; then
 849                 cf_result="yes";
 850
 851                 PYTHON_CFLAGS="`$PYTHON -c 'from distutils import sysconfig; print "-I%s -I%s" % (sysconfig.get_python_inc(), sysconfig.get_python_inc(plat_specific=True))'`"
 852                 PYTHON_LIBS="`$PYTHON -c 'from distutils import sysconfig; var = sysconfig.get_config_var; print "%s %s %s -L%s -lpython%s" % (var("LINKFORSHARED"), var("LIBS"), var("SYSLIBS"), var("LIBPL"), var("VERSION"))'`"
 853                 LIBS="$PYTHON_LIBS $LIBS"
 854                 CPPFLAGS="$CPPFLAGS $PYTHON_CFLAGS"
 855                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <Python.h>]], [[Py_Initialize();]])],[cf_result=yes],[cf_result=no])
 856
 857                 if test "$cf_result" != "yes"; then
 858                         EL_RESTORE_FLAGS
 859                 else
 860                         EL_CONFIG(CONFIG_SCRIPTING_PYTHON, [Python])
 861                         AC_SUBST(PYTHON_LIBS)
 862                         AC_SUBST(PYTHON_CFLAGS)
 863                         CPPFLAGS="$CPPFLAGS_X"
 864                         cat <<EOF
 865 ***********************************************************************
 866 The Python support is incomplete and not so well integrated to ELinks
 867 yet. That means, e.g., that you have no Python console and there might
 868 not be all the necessary hooks. Also, the Python interface is not too
 869 well tested (success stories heartily welcomed!).
 870 ***********************************************************************
 871 EOF
 872                 fi
 873         else
 874                 if test -n "$withval" && test "x$withval" != xno; then
 875                         AC_MSG_ERROR([Python not found])
 876                 else
 877                         AC_MSG_WARN([Python support disabled])
 878                 fi
 879         fi
 880 else
 881         AC_MSG_RESULT(no);
 882 fi
 883
 884
 885 # ===================================================================
 886 # Check for Lua, optional even if installed.
 887 # ===================================================================
 888
 889 # Do this the long way, as FreeBSD reportedly needs -L<dir> for
 890 # anything other than /usr/lib, and Lua is very often in /usr/local/lib.
 891
 892 AC_ARG_WITH(lua, [  --without-lua           disable Lua support],
 893             [if test "$withval" = no; then disable_lua=yes; fi])
 894 AC_MSG_CHECKING([for Lua])
 895
 896 EL_SAVE_FLAGS
 897 cf_result=no
 898
 899 if test -z "$disable_lua"; then
 900         if test ! -d "$withval"; then
 901                 withval="";
 902         fi
 903         for luadir in "$withval" "" /usr /usr/local; do
 904                 for suffix in "" 50; do
 905                         if test "$cf_result" = no && ( test -f "$luadir/include/lua.h" || \
 906                            test -f "$luadir/include/lua$suffix/lua.h" ) ; then
 907                                 LUA_LIBS="-L$luadir/lib -llua$suffix -llualib$suffix -lm"
 908                                 LUA_CFLAGS="-I$luadir/include -I$luadir/include/lua$suffix"
 909
 910                                 LIBS="$LUA_LIBS $LIBS_X"
 911                                 CFLAGS="$CFLAGS_X $LUA_CFLAGS"
 912                                 CPPFLAGS="$CPPFLAGS_X $LUA_CFLAGS"
 913
 914                                 # Check that it is a compatible Lua version
 915                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[      #include <lua.h>
 916                                                 #include <lualib.h>]], [[       lua_State *L = lua_open();
 917                                                 luaopen_base(L);
 918                                                 luaopen_table(L);
 919                                                 luaopen_io(L);
 920                                                 luaopen_string(L);
 921                                                 luaopen_math(L);
 922                                                 lua_pushboolean(L, 1);
 923                                                 lua_close(L);]])],[cf_result=yes],[cf_result=no])
 924                         fi
 925                 done
 926         done
 927 fi
 928
 929 AC_MSG_RESULT($cf_result)
 930
 931 if test "$cf_result" != yes; then
 932         EL_RESTORE_FLAGS
 933 else
 934         EL_CONFIG(CONFIG_SCRIPTING_LUA, [Lua])
 935         AC_CHECK_HEADERS(lauxlib.h)
 936
 937         CFLAGS="$CFLAGS_X"
 938         CPPFLAGS="$CPPFLAGS_X"
 939         AC_SUBST(LUA_LIBS)
 940         AC_SUBST(LUA_CFLAGS)
 941 fi
 942
 943 # ===================================================================
 944 # Check for TRE library
 945 # ===================================================================
 946 #
 947 # This section only checks that --without-tre is not given and the
 948 # library seems to work, and sets TRE_CFLAGS, TRE_LIBS, and
 949 # tre_log.  It does not define CONFIG_TRE, and always resets
 950 # LIBS and CFLAGS back to their original values.
 951 #
 952 # After any --enable-utf-8 and --disable-utf-8 options have been
 953 # handled, a separate section decides whether to actually use TRE.
 954 #
 955 # tre version 0.8.0 or higher is required which have the "tre_" prefix
 956 # for functions.
 957
 958 AC_ARG_WITH([[tre]], [[  --without-tre           disable TRE regex search support]])
 959 if test "$with_tre" = no; then
 960         AC_MSG_CHECKING([[for TRE]])
 961         AC_MSG_RESULT([[disabled]])
 962         tre_log="no (explicitly disabled)"
 963 else
 964         AC_MSG_CHECKING([[for TRE in pkg-config]])
 965         if pkg-config tre; then
 966                 TRE_CFLAGS=`pkg-config --cflags tre`
 967                 TRE_LIBS=`pkg-config --libs tre`
 968                 AC_MSG_RESULT([[yes]])
 969         else
 970                 # <http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=513055>
 971                 # "libtre-dev: /usr/lib/pkgconfig/tre.pc missing"
 972                 # so we look for the library even if pkg-config doesn't know about it.
 973                 TRE_CFLAGS=
 974                 TRE_LIBS=-ltre
 975                 AC_MSG_RESULT([[no, but let's try defaults]])
 976         fi
 977
 978         AC_MSG_CHECKING([[for TRE header and library]])
 979         EL_SAVE_FLAGS
 980         CFLAGS="$TRE_CFLAGS $CFLAGS"
 981         LIBS="$TRE_LIBS $LIBS" # must be first, because of regfree conflict
 982         AC_TRY_LINK([#include <tre/tre.h>],
 983                     [regex_t re;
 984                      regmatch_t match[1];
 985                      tre_regwcomp(&re, L"zap", REG_ICASE);
 986                      tre_regwexec(&re, L"ELIZAPROGRAM", 1, match, 0);],
 987                     [AC_MSG_RESULT([[yes]])
 988                      tre_log="available"],
 989                     [AC_MSG_RESULT([[no]])
 990                      tre_log="no (TRE not found)"])
 991         EL_RESTORE_FLAGS
 992 fi
 993
 994 # ===================================================================
 995 # Check for Ruby, optional even if installed.
 996 # ===================================================================
 997
 998 EL_CONFIG_SCRIPTING_RUBY
 999
1000 # ===================================================================
1001 # Setup global scripting
1002 # ===================================================================
1003
1004 EL_CONFIG_DEPENDS(CONFIG_SCRIPTING, [CONFIG_SCRIPTING_GUILE CONFIG_SCRIPTING_LUA CONFIG_SCRIPTING_PERL CONFIG_SCRIPTING_PYTHON CONFIG_SCRIPTING_RUBY CONFIG_SCRIPTING_SPIDERMONKEY], [Browser scripting])
1005 AC_SUBST(CONFIG_SCRIPTING_GUILE)
1006 AC_SUBST(CONFIG_SCRIPTING_LUA)
1007 AC_SUBST(CONFIG_SCRIPTING_PERL)
1008 AC_SUBST(CONFIG_SCRIPTING_PYTHON)
1009 AC_SUBST(CONFIG_SCRIPTING_RUBY)
1010 AC_SUBST(CONFIG_SCRIPTING_SPIDERMONKEY)
1011 AC_SUBST(CONFIG_SCRIPTING)
1012
1013
1014 # ===================================================================
1015 # Check for SSL support.
1016 # ===================================================================
1017
1018 # We by default use OpenSSL, and we always prefer it. However, when GNUTLS
1019 # is enabled, we won't try to use OpenSSL anymore.
1020
1021 # For wiping SSL hooks..
1022 #ifdef CONFIG_SSL
1023
1024 chosen_ssl_library=""
1025
1026 AC_ARG_WITH(gnutls, [[  --without-gnutls        disable GNUTLS SSL support]])
1027 AC_ARG_WITH(gnutls, [[  --with-gnutls           enable GNUTLS SSL support]],
1028             [case "$with_gnutls" in
1029                 "no")   : ;;
1030                 "yes")  chosen_ssl_library="GNUTLS" ;;
1031                 *)      chosen_ssl_library="GNUTLS"
1032                         AC_MSG_WARN([[Support for --with-gnutls=DIR has been removed.
1033 You may have to set the PKG_CONFIG_PATH environment variable instead.]]) ;;
1034              esac])
1035
1036 AC_ARG_WITH(openssl, [[  --without-openssl       disable OpenSSL support]])
1037 AC_ARG_WITH(openssl, [[  --with-openssl[=DIR]    enable OpenSSL support (default)]],
1038             [case "$with_openssl" in
1039                 "no")   : ;;
1040                 *)      chosen_ssl_library="OpenSSL" ;;
1041              esac])
1042
1043 AC_ARG_WITH(nss_compat_ossl, [[  --with-nss_compat_ossl[=DIR]
1044                           NSS compatibility SSL libraries/include files]],
1045             [case "$with_nss_compat_ossl" in
1046                 "no")   : ;;
1047                 *)      chosen_ssl_library="nss_compat_ossl" ;;
1048              esac])
1049
1050 # ---- nss_compat_ossl
1051
1052 if test "$with_nss_compat_ossl" = no; then
1053         # explicitly disabled
1054         :
1055 elif test -n "$chosen_ssl_library" && test "$chosen_ssl_library" != "nss_compat_ossl"; then
1056         # not used, because $chosen_ssl_library was chosen
1057         :
1058 elif test -z "${with_nss_compat_ossl+set}"; then
1059         # SSL_library_init() in nss_compat_ossl 0.9.2 calls exit(1)
1060         # with no error message if there is no certificate database.
1061         # https://bugzilla.redhat.com/show_bug.cgi?id=463437
1062         # So ELinks uses nss_compat_ossl only if explicitly requested.
1063         :
1064 else
1065         EL_SAVE_FLAGS
1066         if test "$with_nss_compat_ossl" = yes; then
1067                 if pkg-config nss; then
1068                         CFLAGS="$CFLAGS_X `pkg-config --cflags nss`"
1069                         LIBS="$LIBS_X `pkg-config --libs nss`"
1070                 else
1071                         with_nss_compat_ossl=no
1072                 fi
1073         else
1074                 # Without pkg-config, we'll kludge in some defaults
1075                 CFLAGS="$CFLAGS_X -I$with_nss_compat_ossl/include -I/usr/include/nss3 -I/usr/include/nspr4"
1076                 LIBS="$LIBS_X -L$with_nss_compat_ossl/lib -lssl3 -lsmime3 -lnss3 -lplds4 -lplc4 -lnspr4 -lpthread -ldl"
1077         fi
1078         AC_CHECK_HEADERS(nss_compat_ossl/nss_compat_ossl.h,, [with_nss_compat_ossl=no], [#define NSS_COMPAT_OSSL_H])
1079         AC_CHECK_LIB(nss_compat_ossl, X509_free,, [with_nss_compat_ossl=no])
1080
1081         if test "$with_nss_compat_ossl" = "no"; then
1082                 EL_RESTORE_FLAGS
1083         else
1084                 LIBS="$LIBS -lnss_compat_ossl"
1085                 EL_CONFIG(CONFIG_NSS_COMPAT_OSSL, [nss_compat_ossl])
1086                 chosen_ssl_library="nss_compat_ossl"
1087         fi
1088 fi
1089
1090 # ---- OpenSSL
1091
1092 AC_MSG_CHECKING([for OpenSSL])
1093
1094 EL_SAVE_FLAGS
1095
1096 if test "$with_openssl" = no; then
1097         cf_result="explicitly disabled"
1098
1099 elif test -n "$chosen_ssl_library" && test "$chosen_ssl_library" != "OpenSSL"; then
1100         cf_result="not used, because $chosen_ssl_library was chosen"
1101
1102 else
1103         cf_result=no
1104         for ssldir in "$with_openssl" "" /usr /usr/local/openssl \
1105                          /usr/lib/openssl /usr/local/ssl \
1106                          /usr/local/www /usr/lib/ssl /usr/local \
1107                          /usr/pkg /opt /opt/openssl; do
1108                 if test "$cf_result" = no; then
1109                         if test -d "$ssldir"; then
1110                                 OPENSSL_CFLAGS="-I$ssldir/include"
1111                                 LIBS="-L$ssldir/lib -lssl -lcrypto $LIBS_X"
1112                                 CFLAGS="$CFLAGS_X $OPENSSL_CFLAGS"
1113                                 CPPFLAGS="$CPPFLAGS_X $OPENSSL_CFLAGS"
1114 #                               # FIXME: This created serious portability problems. --pasky
1115 #                               if test "$CC" == "gcc"; then
1116 #                                       # I'm not sure about compatibility here. --pasky
1117 #                                       LIBS="$LIBS -R$ssldir/lib"
1118 #                               fi
1119                         else
1120                                 LIBS="-lssl -lcrypto $LIBS_X"
1121                         fi
1122                         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <openssl/ssl.h>]], [[OpenSSL_add_all_algorithms()]])],[cf_result=yes],[cf_result=no])
1123                         if test "$cf_result" != yes; then
1124                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <openssl/ssl.h>]], [[SSLeay_add_ssl_algorithms()]])],[cf_result=yes],[cf_result=no])
1125                         fi
1126                 fi
1127         done
1128
1129         if test "$cf_result" != yes; then
1130                 if test "${with_openssl-no}" != "no"; then
1131                         AC_MSG_ERROR([OpenSSL not found])
1132                 fi
1133                 EL_RESTORE_FLAGS
1134         else
1135                 EL_CONFIG(CONFIG_OPENSSL, [OpenSSL])
1136                 chosen_ssl_library="OpenSSL"
1137
1138                 CFLAGS="$CFLAGS_X"
1139                 AC_SUBST(OPENSSL_CFLAGS)
1140         fi
1141 fi
1142
1143 AC_MSG_RESULT($cf_result)
1144
1145 # ---- GNU TLS
1146
1147 # GnuTLS 2.2.0 changed libgnutls-openssl from GPLv2+
1148 # to GPLv3+.  Don't link that with the GPLv2 ELinks.
1149 # ELinks will use its internal MD5 code instead.
1150 CONFIG_GNUTLS_OPENSSL_COMPAT=no
1151
1152 if test "$with_gnutls" = no; then
1153         AC_MSG_CHECKING([[for GNUTLS]])
1154         AC_MSG_RESULT([[explicitly disabled]])
1155
1156 elif test -n "$chosen_ssl_library" && test "$chosen_ssl_library" != "GNUTLS"; then
1157         AC_MSG_CHECKING([[for GNUTLS]])
1158         AC_MSG_RESULT([[not used, because $chosen_ssl_library was chosen]])
1159
1160 else
1161         cf_result=no
1162         AC_MSG_CHECKING([[for GNUTLS (1.2 or later) in pkg-config]])
1163         if pkg-config --atleast-version=1.2 gnutls; then
1164                 GNUTLS_CFLAGS=`pkg-config --cflags gnutls`
1165                 GNUTLS_LIBS=`pkg-config --libs gnutls`
1166                 AC_MSG_RESULT([[yes: $GNUTLS_CFLAGS $GNUTLS_LIBS]])
1167
1168                 EL_SAVE_FLAGS
1169                 LIBS="$GNUTLS_LIBS $LIBS"
1170                 CFLAGS="$CFLAGS $GNUTLS_CFLAGS"
1171                 CPPFLAGS="$CPPFLAGS $GNUTLS_CFLAGS"
1172
1173                 # Verify if it's really usable.  gnutls_session was
1174                 # renamed to gnutls_session_t before GNU TLS 1.2.0
1175                 # (on 2004-06-13); ELinks now requires this.
1176                 AC_MSG_CHECKING([[whether GNUTLS can be linked with]])
1177                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <gnutls/gnutls.h>]],
1178                                                 [[gnutls_session_t dummy;
1179                                                   gnutls_check_version(NULL)]])],
1180                                [cf_result=yes],
1181                                [cf_result=no])
1182                 AC_MSG_RESULT([[$cf_result]])
1183
1184                 if test "$cf_result" = yes; then
1185                         # According to gnutls/NEWS, the function was originally
1186                         # added as gnutls_set_default_priority2 in GNUTLS 2.1.4
1187                         # (released 2007-10-27) and then renamed to
1188                         # gnutls_priority_set_direct in GNUTLS 2.1.7 (released
1189                         # 2007-11-29).
1190                         AC_CHECK_FUNCS([gnutls_priority_set_direct])
1191                 fi
1192
1193                 EL_RESTORE_FLAGS
1194         else
1195                 AC_MSG_RESULT([[$cf_result]])
1196         fi
1197
1198         if test "$cf_result" = yes; then
1199                 EL_CONFIG(CONFIG_GNUTLS, [GNUTLS])
1200                 chosen_ssl_library="GNUTLS"
1201
1202                 LIBS="$GNUTLS_LIBS $LIBS"
1203                 AC_SUBST(GNUTLS_CFLAGS)
1204
1205         elif test "${with_gnutls-no}" != "no"; then
1206                 AC_MSG_ERROR([[GNUTLS (1.2 or later) not found.  ELinks no longer supports GNUTLS 1.1.]])
1207         fi
1208 fi
1209
1210 # Final SSL setup
1211
1212 EL_CONFIG_DEPENDS(CONFIG_SSL, [CONFIG_OPENSSL CONFIG_GNUTLS CONFIG_NSS_COMPAT_OSSL], [SSL])
1213 AC_SUBST(CONFIG_GNUTLS_OPENSSL_COMPAT)
1214 AC_SUBST(CONFIG_OPENSSL)
1215 AC_SUBST(CONFIG_GNUTLS)
1216 AC_SUBST(CONFIG_NSS_COMPAT_OSSL)
1217
1218 #endif
1219
1220 AC_MSG_CHECKING([whether to be or not to be])
1221 AC_MSG_RESULT([needs to be determined experimentally])
1222
1223 # ===================================================================
1224 # Check for IPv6 support and related functions.
1225 # ===================================================================
1226
1227 EL_CHECK_NET_TYPE(struct sockaddr_storage, HAVE_SA_STORAGE, [])
1228 EL_CHECK_NET_TYPE(struct sockaddr_in6, HAVE_SA_IN6, [#include <netinet/in.h>])
1229 EL_CHECK_NET_TYPE(struct addrinfo, HAVE_ADDRINFO, [#include <netdb.h>])
1230
1231 AC_CHECK_FUNC(getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1232 if test "$HAVE_GETADDRINFO" != yes; then
1233         AC_CHECK_LIB(inet6, getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1234         if test "$HAVE_GETADDRINFO" = yes; then
1235                 LIBS="$LIBS -linet6"
1236         fi
1237 fi
1238
1239
1240 # ===================================================================
1241 # Checking for X11 (window title restoring).
1242 # ===================================================================
1243
1244 AC_PATH_X
1245 if test x"$no_x" != xyes; then
1246         EL_SAVE_FLAGS
1247         if test -n "$x_includes"; then
1248                 X_CFLAGS="-I$x_includes"
1249                 CPPFLAGS="$CPPLAGS $X_CFLAGS"
1250                 CFLAGS="$CFLAGS $X_CFLAGS"
1251         fi
1252         if test -n "$x_libraries"; then
1253                 LDFLAGS="$LDFLAGS -L$x_libraries"
1254         fi
1255         LIBS="-lX11 $LIBS"
1256         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]], [[XrmInitialize()]])],[cf_result=yes],[cf_result=no])
1257         EL_RESTORE_FLAGS
1258         if test "$cf_result" = yes; then
1259                 if test -n "$x_libraries"; then
1260                         LDFLAGS="$LDFLAGS -L$x_libraries"
1261                 fi
1262                 LIBS="-lX11 $LIBS"
1263                 EL_DEFINE(HAVE_X11, [X11 for restoring window titles])
1264                 AC_SUBST(X_CFLAGS)
1265         fi
1266 fi
1267
1268
1269 # ===================================================================
1270 # Backtraces displaying support.
1271 # ===================================================================
1272
1273 AC_CHECK_HEADERS(execinfo.h, HAVE_EXECINFO=yes, HAVE_EXECINFO=no)
1274 # possible checks for other system-specific means go here
1275
1276
1277 # ===================================================================
1278 # Gettext grey zone. Beware.
1279 # ===================================================================
1280
1281 ALL_LINGUAS="af be bg ca cs da de el es et fi fr gl hr hu id is it lt nl nb pl pt pt_BR ro ru sk sr sv tr uk"
1282
1283 AM_GNU_GETTEXT
1284
1285 dnl AC_MSG_CHECKING([how many characters your English alphabet has])
1286 dnl # f33r d4 l33t... I hope it's portable. :)
1287 dnl cf_result=$((48#z - 48#a + 1));
1288 dnl AC_MSG_RESULT($cf_result)
1289
1290
1291 # ===================================================================
1292 # Compile-time features control
1293 # ===================================================================
1294
1295 EL_ARG_ENABLE(CONFIG_COOKIES, cookies, [Cookies],
1296               [  --disable-cookies       disable cookie support])
1297
1298 EL_ARG_ENABLE(CONFIG_FORMHIST, formhist, [Form history],
1299               [  --disable-formhist      disable form history support])
1300
1301 EL_ARG_ENABLE(CONFIG_GLOBHIST, globhist, [Global history],
1302               [  --disable-globhist      disable global history support])
1303
1304
1305 EL_ARG_ENABLE(CONFIG_MAILCAP, mailcap, [Mailcap],
1306               [  --disable-mailcap       disable mailcap support])
1307
1308 EL_ARG_ENABLE(CONFIG_MIMETYPES, mimetypes, [Mimetypes files],
1309               [  --disable-mimetypes     disable mimetypes files support])
1310
1311
1312 EL_ARG_DEPEND(CONFIG_IPV6, ipv6,
1313               [HAVE_SA_STORAGE:yes HAVE_SA_IN6:yes HAVE_ADDRINFO:yes HAVE_GETADDRINFO:yes],
1314               [IPv6],
1315               [  --disable-ipv6          disable IPv6 support])
1316
1317 EL_ARG_ENABLE(CONFIG_BITTORRENT, bittorrent, [BitTorrent protocol],
1318               [  --enable-bittorrent     enable BitTorrent protocol support])
1319
1320 EL_ARG_ENABLE(CONFIG_DATA, data, [Data protocol],
1321               [  --disable-data          disable data protocol support])
1322
1323 EL_ARG_ENABLE(CONFIG_URI_REWRITE, uri-rewrite, [URI rewriting],
1324               [  --disable-uri-rewrite   disable URI rewrite support])
1325
1326 EL_ARG_DEPEND(CONFIG_CGI, cgi, [HAVE_SETENV_OR_PUTENV:yes], [Local CGI],
1327               [  --enable-cgi            enable local CGI support])
1328
1329 EL_ARG_ENABLE(CONFIG_FINGER, finger, [Finger protocol],
1330               [  --enable-finger         enable finger protocol support])
1331
1332 # ===================================================================
1333 # FSP protocol
1334 # ===================================================================
1335 EL_SAVE_FLAGS
1336
1337 if test "x${enable_fsp}" != xno; then
1338         AC_CHECK_HEADERS(fsplib.h, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1339
1340         if test "$HAVE_FSPLIB" = yes; then
1341                 AC_CHECK_LIB(fsplib, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1342                 if test "$HAVE_FSPLIB" = yes; then
1343                         LIBS="$LIBS -lfsplib"
1344                 else
1345                         AC_CHECK_LIB(fsp, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1346                         if test "$HAVE_FSPLIB" = yes; then
1347                                 LIBS="$LIBS -lfsp"
1348                         fi
1349                 fi
1350         fi
1351 fi
1352
1353 EL_ARG_DEPEND(CONFIG_FSP, fsp, [HAVE_FSPLIB:yes], [FSP protocol],
1354               [  --enable-fsp            enable FSP protocol support])
1355
1356 if test "x$CONFIG_FSP" = xno; then
1357         EL_RESTORE_FLAGS
1358 fi
1359
1360 EL_ARG_ENABLE(CONFIG_FTP, ftp, [FTP protocol],
1361               [  --disable-ftp           disable ftp protocol support])
1362
1363 EL_ARG_ENABLE(CONFIG_GOPHER, gopher, [Gopher protocol],
1364               [  --enable-gopher         enable gopher protocol support])
1365
1366 EL_ARG_ENABLE(CONFIG_NNTP, nntp, [NNTP protocol],
1367               [  --enable-nntp           enable nntp protocol support])
1368
1369 # ===================================================================
1370 # SMB protocol support.
1371 # ===================================================================
1372 EL_SAVE_FLAGS
1373
1374 if test "x${enable_smb}" != xno; then
1375         AC_CHECK_HEADERS(libsmbclient.h, HAVE_SMBCLIENT=yes, HAVE_SMBCLIENT=no)
1376
1377         if test "$HAVE_SMBCLIENT" = yes; then
1378                 AC_CHECK_LIB(smbclient, smbc_init, HAVE_SMBCLIENT=yes, HAVE_SMBCLIENT=no)
1379                 if test "$HAVE_SMBCLIENT" = yes; then
1380                         LIBS="$LIBS -lsmbclient"
1381                 fi
1382         fi
1383 fi
1384
1385 EL_ARG_DEPEND(CONFIG_SMB, smb, [HAVE_SMBCLIENT:yes], [Samba protocol],
1386               [  --enable-smb            enable Samba protocol support])
1387
1388 if test "x$CONFIG_SMB" = xno; then
1389         EL_RESTORE_FLAGS
1390 fi
1391
1392
1393 EL_ARG_ENABLE(CONFIG_MOUSE, mouse, [Mouse handling],
1394               [  --disable-mouse         disable mouse support])
1395
1396 # GPM mouse is Linux specific, so ...
1397 CONFIG_SYSMOUSE=yes
1398 EL_ARG_DEPEND(CONFIG_SYSMOUSE, sysmouse,
1399               [CONFIG_MOUSE:yes CONFIG_GPM:no HAVE_SYSMOUSE_HEADER:yes],
1400               [BSD sysmouse],
1401               [  --disable-sysmouse      disable BSD sysmouse support])
1402
1403 EL_ARG_ENABLE(CONFIG_88_COLORS, 88-colors, [88 colors],
1404               [  --enable-88-colors      enable 88 color support])
1405
1406 EL_ARG_ENABLE(CONFIG_256_COLORS, 256-colors, [256 colors],
1407               [  --enable-256-colors     enable 256 color support])
1408
1409 EL_ARG_ENABLE(CONFIG_TRUE_COLOR, true-color, [true color],
1410               [  --enable-true-color     enable true color support])
1411
1412 EL_ARG_ENABLE(CONFIG_EXMODE, exmode, [Exmode interface],
1413               [  --enable-exmode         enable exmode (CLI) interface])
1414
1415 EL_ARG_ENABLE(CONFIG_LEDS, leds, [LEDs],
1416               [  --disable-leds          disable LEDs support])
1417
1418 EL_ARG_ENABLE(CONFIG_MARKS, marks, [Marks],
1419               [  --disable-marks         disable document marks support])
1420
1421
1422 EL_ARG_ENABLE(CONFIG_CSS, css, [Cascading Style Sheets],
1423               [  --disable-css           disable Cascading Style Sheet support])
1424
1425 EL_ARG_DEPEND(CONFIG_HTML_HIGHLIGHT, html-highlight, [CONFIG_CSS:yes], [HTML highlighting],
1426               [  --enable-html-highlight HTML highlighting using DOM engine])
1427
1428 # Everything in the tree already uses CONFIG_DOM
1429 # so resolve CONFIG_HTML_HIGHLIGHT to CONFIG_DOM
1430 EL_CONFIG_DEPENDS(CONFIG_DOM, [CONFIG_HTML_HIGHLIGHT], [DOM engine])
1431
1432 EL_ARG_DEPEND(CONFIG_BACKTRACE, backtrace, [HAVE_EXECINFO:yes], [Backtrace],
1433               [  --disable-backtrace     disable backtrace support])
1434
1435 EL_ARG_DEPEND(CONFIG_NO_ROOT_EXEC, no-root, [HAVE_GETUID:yes HAVE_GETEUID:yes], [No root exec],
1436               [  --enable-no-root        enable prevention of usage by root])
1437
1438
1439 EL_ARG_ENABLE(CONFIG_DEBUG, debug, [Debug mode],
1440               [  --enable-debug          enable leak debug and internal error checking])
1441
1442 EL_ARG_DEPEND(CONFIG_FASTMEM, fastmem, [CONFIG_DEBUG:no], [Fast mode],
1443               [  --enable-fastmem        enable direct use of system allocation functions, not usable with --enable-debug])
1444
1445 EL_ARG_ENABLE(CONFIG_OWN_LIBC, own-libc, [Own libc stubs],
1446               [  --enable-own-libc       force use of internal functions instead of those of system libc])
1447
1448 EL_ARG_ENABLE(CONFIG_SMALL, small, [Small binary],
1449               [  --enable-small          reduce binary size as far as possible (but see the bottom of doc/small.txt!)])
1450
1451 EL_ARG_ENABLE(CONFIG_UTF8, utf-8, [UTF-8],
1452               [  --disable-utf-8         disable UTF-8 support])
1453
1454 EL_ARG_DEPEND(CONFIG_COMBINE, combining, [CONFIG_UTF8:yes HAVE_WCWIDTH:yes], [Combining characters],
1455               [  --enable-combining      support Unicode combining characters (experimental)])
1456
1457
1458 AC_ARG_ENABLE(weehoofooboomookerchoo,
1459               [
1460     Also check out the features.conf file for more information about features!
1461               ],
1462               [AC_MSG_ERROR(Are you strange, or what?)])
1463
1464
1465 # ===================================================================
1466 # Decide whether to use TRE
1467 # ===================================================================
1468 #
1469 # This must be done after the CONFIG_UTF8 check above.
1470 # The first part of the TRE check is separate, to get
1471 # the configure --help output in a sensible order.
1472 #
1473 # After this section, nothing else must be added to the
1474 # beginning of $LIBS.
1475
1476 if test "$tre_log" = "available"; then
1477         if test "$CONFIG_UTF8" = "yes"; then
1478                 # When CONFIG_UTF8 and CONFIG_TRE are both defined,
1479                 # src/viewer/text/search.c makes a string of
1480                 # unicode_val_T and gives it to regwexec(), which
1481                 # expects a string of wchar_t.  If the unicode_val_T
1482                 # and wchar_t types are too different, this won't
1483                 # work, so try to detect that and disable regexp
1484                 # operations entirely in that case.
1485                 #
1486                 # Currently, this code only compares the sizes of the
1487                 # types.  src/intl/charsets.h defines unicode_val_T as
1488                 # uint32_t, so we check whether wchar_t has exactly 32
1489                 # bits.  But don't use AC_CHECK_SIZEOF for this, because
1490                 # there doesn't seem to be a documented way to get the
1491                 # result of that for use in the configure script.
1492                 #
1493                 # C99 says the implementation can define
1494                 # __STDC_ISO_10646__ if wchar_t values match ISO 10646
1495                 # (or Unicode) numbers in all locales.  Do not check
1496                 # that macro here, because it is too restrictive: it
1497                 # should be enough for ELinks if the values match in
1498                 # the locales where ELinks is actually run.
1499                 AC_MSG_CHECKING([[whether wchar_t is exactly 32-bit]])
1500                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1501 #include <limits.h>
1502 #include <stddef.h>
1503 int dummy[(sizeof(wchar_t) * CHAR_BIT == 32) ? 1 : -1];]], [])],
1504                         [AC_MSG_RESULT([[yes]])
1505                          tre_log="TRE"],
1506                         [AC_MSG_RESULT([[no]])
1507                          tre_log="no (unsuitable wchar_t)"])
1508         else
1509                 # If UTF-8 is not used, then wchar_t doesn't matter.
1510                 tre_log="TRE"
1511         fi
1512 fi
1513
1514 if test "$tre_log" = "TRE"; then
1515         AC_DEFINE([CONFIG_TRE], [1],
1516                 [Define as 1 to use the TRE library for regular expression searching.  This requires the <tre/regex.h> header file.  If you define CONFIG_UTF8 too, then wchar_t must be exactly 32-bit so that it matches unicode_val_T.])
1517         # TRE_CFLAGS will be used only where needed.
1518         #
1519         # Bug 1081: If both TRE and libc define the regfree function,
1520         # ELinks needs to use the version defined by TRE because
1521         # that's the one compatible with regex_t initialized by the
1522         # regwcomp function of TRE.  Therefore put $TRE_LIBS at the
1523         # very beginning of $LIBS so that the linker hopefully finds
1524         # regfree there before it examines libc.  In particular,
1525         # $PERL_LIBS appears to often include "-lc".
1526         #
1527         # This scheme still risks a crash if ELinks is linked with
1528         # some static library that uses GNU <regex.h> extensions that
1529         # TRE does not implement.  For example, the library might call
1530         # re_compile_pattern, which is found in GNU libc, and then
1531         # regfree, which is found in TRE and probably crashes with the
1532         # GNU-initialized regex_t.  Ways to avoid such crashes:
1533         #
1534         # - Change TRE so it defines only tre_... functions and does
1535         #   not attempt to override the POSIX names by default.
1536         #
1537         # - Change ELinks to access TRE only via dlopen and dlsym.
1538         #   The problem then is how to find the correct file name.
1539         #   There might be libtre.so.4 and libtre.so.5 with different
1540         #   ABI.  How can this configure script detect which of them
1541         #   matches the <tre/regex.h> in the include path?
1542         #
1543         # - Replace the static library with a shared library.  At
1544         #   least on GNU/Linux, when the shared library is built, the
1545         #   linker should note that e.g. regfree is defined in libc
1546         #   and has the GLIBC_2.0 version there, and write that
1547         #   version string to the shared library as well; because TRE
1548         #   does not provide regfree with that version, any regfree
1549         #   calls at run time should then get resolved to libc.
1550         LIBS="$TRE_LIBS $LIBS"
1551 else
1552         TRE_LIBS=
1553         TRE_CFLAGS=
1554 fi
1555 AC_SUBST(TRE_CFLAGS)
1556 AC_SUBST(TRE_LIBS)
1557 EL_LOG_CONFIG([CONFIG_TRE], [[Regexp searching]], [[$tre_log]])
1558
1559
1560 # ===================================================================
1561 # Further LDFLAGS tweaks
1562 # ===================================================================
1563
1564 # == EMX hack
1565
1566 test "$CONFIG_OS_OS2" = yes && LDFLAGS="$LDFLAGS -Zexe"
1567 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zbin-files//g"`
1568
1569
1570 # Check for -rdynamic
1571 #
1572 # gcc -rdynamic calls ld -export-dynamic, which adds all symbols of
1573 # the executable to its dynamic symbol table.  ELinks uses this for
1574 # two purposes:
1575 #
1576 # 1. If ELinks detects a bug, it can try to display a backtrace by
1577 #    calling backtrace_symbols_fd() in the GNU libc.  The glibc-2.3.6
1578 #    manual states users of GNU ld must pass -rdynamic to make the
1579 #    symbols available to the program.
1580 #
1581 # 2. It would eventually be nice to dynamically load shared
1582 #    libraries as plugins (bug 73).  The plugins must be able to
1583 #    call ELinks functions.  This can be implemented either by
1584 #    registering all callable functions in ELinks-specific data
1585 #    structures, or by letting the dynamic linker handle them.
1586 #    The latter way requires something equivalent to -rdynamic.
1587 #
1588 # Because backtraces are not needed for correct operation, and bug
1589 # 73 is not yet being fixed, the configure script and makefiles
1590 # should not complain to the user if they find that -rdynamic does
1591 # not work.  Besides, it was reported at elinks-users on 2006-09-12
1592 # that gcc-3.4.2 with "ld: Software Generation Utilities - Solaris
1593 # Link Editors: 5.8-1.284" on Sun Solaris 8 Sparc does not support
1594 # -rdynamic but does something equivalent automatically.  (This was
1595 # tested with "nm -D elinks | grep redraw_from_window".)
1596 #
1597 # With Sun Studio 11 on Solaris 9, we get "cc: Warning: illegal option
1598 # -dynamic"; then, cc proceeds anyway, but the option can prevent the
1599 # linker from finding the libraries listed in -l operands.  So this
1600 # -rdynamic check needs to happen after the libraries have already
1601 # been added to $LDFLAGS.
1602 AC_MSG_CHECKING([for -rdynamic])
1603 LDFLAGS_X="$LDFLAGS"
1604 LDFLAGS="-rdynamic $LDFLAGS"
1605 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[]])],[have_rdynamic=yes],[have_rdynamic=no])
1606 test "$have_rdynamic" = no && LDFLAGS="$LDFLAGS_X"
1607 AC_MSG_RESULT($have_rdynamic)
1608
1609 # ===================================================================
1610 # Export directory paths
1611 # ===================================================================
1612
1613 # Set up the ``entry points'' if they were not supplied by builder
1614 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1615 test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1616
1617 # Create CONFDIR #define for config.h
1618
1619 # XXX: This may be dependent on a particular version of autoconf. Whatever,
1620 # it's autoconf fault to force us to do such hacks ;p.
1621 if test x"$sysconfdir" = x"\${prefix}/etc"; then
1622   # sysconfdir is set to its default value... fine, let's append /elinks/
1623   # XXX: We can't modify listing of the default in ./configure --help :-(
1624   sysconfdir_n=`eval echo "$sysconfdir"`
1625   sysconfdir=$sysconfdir_n
1626   (echo "$sysconfdir" | grep elinks >/dev/null 2>/dev/null) || \
1627         sysconfdir="$sysconfdir/elinks"
1628 fi
1629
1630 CONFDIR=$sysconfdir
1631 AC_DEFINE_UNQUOTED(CONFDIR, "$CONFDIR", [Directory containing default config])
1632 AC_SUBST(CONFDIR)
1633
1634 # Create LOCALEDIR #define for config.h
1635 LOCALEDIR=`eval echo "$datadir/locale"`
1636 while echo "$LOCALEDIR" | grep "\\$"
1637 do
1638         LOCALEDIR=`eval echo "$LOCALEDIR"`
1639 done > /dev/null 2> /dev/null
1640 AC_DEFINE_UNQUOTED(LOCALEDIR, "$LOCALEDIR", [Directory containing locales])
1641 AC_SUBST(LOCALEDIR)
1642
1643 # Create LIBDIR #define for config.h
1644 LIBDIR=`eval echo "$libdir"`
1645 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [Directory containing libraries])
1646 AC_SUBST(LIBDIR)
1647
1648 EL_LOG_CONFIG(CONFDIR, [System configuration directory], [])
1649 EL_LOG_CONFIG(LOCALEDIR, [Locale catalogs directory], [])
1650
1651
1652 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stddef.h>
1653 ]], [[#if !defined(__TINYC__) || !defined(alloca)
1654         #error not tcc
1655         #endif ]])],[cf_result=yes],[cf_result=no])
1656
1657 if test "$cf_result" = "yes"; then
1658         AC_DEFINE([HAVE_ALLOCA])
1659         AC_DEFINE([_ALLOCA_H], [1], [Define as 1 if you are using Tiny C Compiler
1660                 with the GNU C Library, and <alloca.h> of glibc would otherwise
1661                 override the alloca macro defined in <stddef.h> of TCC.
1662                 If <alloca.h> of glibc sees the _ALLOCA_H macro, it assumes
1663                 it has already been included, and does not redefine alloca.
1664                 This might not work in future glibc versions though, because
1665                 the names of the #include guard macros are not documented.
1666                 The incompatibility has been reported to the tinycc-devel
1667                 mailing list on 2008-07-14.  If a future version of TCC provides
1668                 an <alloca.h> of its own, this hack won't be needed.])
1669 fi
1670 # ===================================================================
1671 # A little fine tuning of gcc specific options (continued)
1672 # ===================================================================
1673
1674 if test "x$ac_cv_c_compiler_gnu" = "xyes"; then
1675   if test "$CONFIG_DEBUG" = "yes"; then
1676     # We want to see all warnings and live with none (in debug mode).
1677     CFLAGS="$CFLAGS -Werror"
1678   fi
1679
1680   case "`$CC -dumpversion`" in
1681     3.0|3.1|3.2)
1682       # These should be ok using -Werror
1683       ;;
1684     3.*)
1685       # If gcc is version 3.3 (or higher?) it emits lots of false positive
1686       # "dereferencing type-punned pointer will break strict-aliasing rules"
1687       # warnings. Disable them by not doing any strict-aliasing. The
1688       # alternative is just too ugly. Thanks gcc guys!! ;)
1689       CFLAGS="$CFLAGS -fno-strict-aliasing"
1690       ;;
1691     4.*)
1692       # Do not show warnings related to (char * | unsigned char *) type
1693       # difference.
1694       CFLAGS="$CFLAGS -fno-strict-aliasing -Wno-pointer-sign"
1695       ;;
1696     *)
1697       # These should be ok using -Werror
1698       ;;
1699   esac
1700
1701   # GCC 4.2.1 warns if we use the address of an object in Boolean context:
1702   # warning: the address of `builtin_modules' will always evaluate as `true'
1703   # This hits the object_lock and foreach_module macros in particular.
1704   # It would be okay to put something in the macros to avoid the warning,
1705   # but currently this seems to require defining parallel macros that skip
1706   # the NULL check, and that's too ugly.  So we instead disable the warning.
1707   # GCC 4.2.1 needs -Wno-address, but GCC 4.2 snapshots need -Wno-always-true.
1708   # GCC 4.1.3 recognizes neither and exits with code 1 if they are given.
1709   for warning_flag in -Wno-address -Wno-always-true; do
1710     AC_MSG_CHECKING([whether $CC accepts $warning_flag])
1711     EL_SAVE_FLAGS
1712     CFLAGS="$CFLAGS $warning_flag"
1713     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1714       [AC_MSG_RESULT([yes])
1715        break],
1716       [AC_MSG_RESULT([no])])
1717     EL_RESTORE_FLAGS
1718   done
1719
1720   # Bug 1012: Some parts of ELinks do arithmetic with signed integers
1721   # in such a way that an overflow is possible.  GCC 4.2.1 warns
1722   # "warning: assuming signed overflow does not occur when assuming
1723   # that (X + c) > X is always true", which may be an incorrect
1724   # optimization (although allowed by the standard), and breaks the
1725   # build with -Werror.
1726   #
1727   # All of the following tests included -S -Wall -Wextra:
1728   #
1729   # GCC: (GNU) 4.0.4 20060507 (prerelease) (Debian 4.0.3-3)
1730   # * gcc-4.0 -O0: OK, compares the values
1731   # * gcc-4.0 -O2: assumes no overflow, does not warn
1732   # * gcc-4.0 -O0 -fno-strict-overflow: unrecognized command line option
1733   # * gcc-4.0 -O0 -fwrapv: OK, compares the values
1734   # * gcc-4.0 -O2 -fwrapv: OK, compares the values
1735   # * gcc-4.0 -O0 -ftrapv: OK, calls __addvsi3
1736   # * gcc-4.0 -O2 -ftrapv: assumes no overflow, does not warn
1737   # * gcc-4.0 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1738   # * gcc-4.0 -O2 -fwrapv -ftrapv: compares the values
1739   #
1740   # GCC: (GNU) 4.1.3 20070812 (prerelease) (Debian 4.1.2-15)
1741   # * gcc-4.1 -O0: assumes no overflow, does not warn
1742   # * gcc-4.1 -O2: assumes no overflow, does not warn
1743   # * gcc-4.1 -O0 -fno-strict-overflow: unrecognized command line option
1744   # * gcc-4.1 -O0 -fwrapv: OK, compares the values
1745   # * gcc-4.1 -O2 -fwrapv: OK, compares the values
1746   # * gcc-4.1 -O0 -ftrapv: OK, calls __addvsi3
1747   # * gcc-4.1 -O2 -ftrapv: compares the values
1748   # * gcc-4.1 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1749   # * gcc-4.1 -O2 -fwrapv -ftrapv: compares the values
1750   #
1751   # GCC: (GNU) 4.2.1 (Debian 4.2.1-5)
1752   # * gcc-4.2 -O0: OK, compares the values
1753   # * gcc-4.2 -O2: assumes no overflow, warns about it
1754   # * gcc-4.2 -O0 -fno-strict-overflow: OK, compares the values
1755   # * gcc-4.2 -O2 -fno-strict-overflow: OK, compares the values
1756   # * gcc-4.2 -O0 -fwrapv: OK, compares the values
1757   # * gcc-4.2 -O2 -fwrapv: OK, compares the values
1758   # * gcc-4.2 -O0 -ftrapv: OK, calls __addvsi3
1759   # * gcc-4.2 -O2 -ftrapv: compares the values
1760   # * gcc-4.2 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1761   # * gcc-4.2 -O2 -fwrapv -ftrapv: compares the values
1762   #
1763   # Apparently, -ftrapv does not work reliably at all.
1764   for overflow_flag in -fno-strict-overflow -fwrapv; do
1765     AC_MSG_CHECKING([whether $CC accepts $overflow_flag])
1766     EL_SAVE_FLAGS
1767     CFLAGS="$CFLAGS $overflow_flag"
1768     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1769       [AC_MSG_RESULT([yes])
1770        break],
1771       [AC_MSG_RESULT([no])])
1772     EL_RESTORE_FLAGS
1773   done
1774 fi
1775
1776 EL_LOG_CONFIG(CFLAGS, [Compiler flags (CFLAGS)], [])
1777 EL_LOG_CONFIG(CPPFLAGS, [Preprocessor flags (CPPFLAGS)], [])
1778 EL_LOG_CONFIG(LDFLAGS, [Linker flags (LDFLAGS)], [])
1779 EL_LOG_CONFIG(LIBS, [Library flags (LIBS)], [])
1780
1781 # ===================================================================
1782 # Colored make output
1783 # ===================================================================
1784
1785 if test $(`which tput` colors) -ge 4; then
1786         MAKE_COLOR=1
1787         AC_SUBST(MAKE_COLOR)
1788 fi
1789
1790 # ===================================================================
1791 # Generated files
1792 # ===================================================================
1793
1794 AC_CONFIG_FILES([ \
1795  Makefile.config \
1796  contrib/elinks.spec \
1797  contrib/lua/hooks.lua \
1798  contrib/conv/w3m2links.awk \
1799  doc/Doxyfile \
1800  doc/man/man1/elinks.1 \
1801  src/intl/gettext/ref-add.sed \
1802  src/intl/gettext/ref-del.sed
1803 ])
1804 AC_OUTPUT
1805
1806 abs_srcdir="$(cd "$srcdir" && pwd)"
1807 # builddir is always absolute!
1808 if test "$abs_srcdir" != "$builddir"; then
1809         # Bootstrap the Makefile creation
1810         echo "include $abs_srcdir/Makefile" > "$builddir/Makefile"
1811         "$MAKE" "SRC=$abs_srcdir" init
1812
1813         # Make cg-status ignore this build directory
1814         echo "*" > "$builddir/.gitignore"
1815 fi
1816
1817 # ===================================================================
1818 # Configuration summary
1819 # ===================================================================
1820
1821 AC_MSG_RESULT(The following feature summary has been saved to features.log)
1822 cat features.log