configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl There are two types of comments in this file.
   4 dnl Comments that refer to Autoconf macros begin with "dnl", and m4
   5 dnl discards them.  Other comments begin with "#", and they get copied
   6 dnl to the configure script, hopefully making it easier to read.
   7
   8 dnl Autoconf 2.13 generates an incomplete config.h.in; see ELinks bug 936.
   9 dnl Autoconf 2.59 is installed in the computer that generates our nightly
  10 dnl snapshots, so we need to be compatible with that.
  11 AC_PREREQ(2.59)
  12 AC_INIT
  13 AC_CONFIG_SRCDIR([src/main/main.c])
  14 AC_CONFIG_AUX_DIR(config)
  15
  16 PACKAGE=elinks
  17 VERSION=0.12pre2.GIT
  18 AC_SUBST(PACKAGE)
  19 AC_SUBST(VERSION)
  20 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Package version])
  21 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Package version])
  22 AC_CONFIG_HEADERS(config.h)
  23
  24 AC_CHECK_PROG(ACLOCAL,[aclocal],[aclocal],[config/missing aclocal])
  25 AC_CHECK_PROG(AUTOCONF,[autoconf],[autoconf],[config/missing autoconf])
  26 AC_CHECK_PROG(AUTOHEADER,[autoheader],[autoheader],[config/missing autoheader])
  27
  28 MAKE=
  29
  30 for make in gnumake gmake make false; do
  31         if test "x$MAKE" = x; then
  32                 AC_PATH_PROGS(MAKE, "$make")
  33         fi
  34 done
  35
  36 builddir="`pwd`"
  37
  38 # Cleanup if we are configuring with a previous build in the tree
  39 if test -e Makefile.config; then
  40         AC_MSG_CHECKING([for previous build to clean])
  41         "$MAKE" -C "$builddir/src" cleanall >/dev/null 2>/dev/null
  42         AC_MSG_RESULT(done)
  43 fi
  44
  45 # ===================================================================
  46 # Load feature configuration file and start logging features.
  47 # ===================================================================
  48
  49 features="features.conf"
  50 AC_CHECK_FILE("$srcdir/$features", [ . $srcdir/$features ])
  51 AC_CHECK_FILE("$builddir/$features", [ . $builddir/$features ])
  52 echo "Feature summary:" > features.log
  53
  54 # ===================================================================
  55 # Checks for programs.
  56 # ===================================================================
  57
  58 AC_PROG_CC
  59 AC_PROG_AWK
  60 AC_PATH_PROGS(AWK, "$AWK")
  61 AC_PROG_RANLIB
  62 AC_PROG_INSTALL
  63
  64 AC_PATH_PROGS(GIT, "git")
  65 AC_PATH_PROGS(SPARSE, "sparse")
  66
  67 CONFIG_ASCIIDOC="no"
  68 CONFIG_POD2HTML="no"
  69 CONFIG_XMLTO="no"
  70 CONFIG_JW="no"
  71
  72 if test "x$CONFIG_DOC" != xno; then
  73         AC_PATH_PROGS(ASCIIDOC, "asciidoc")
  74         if test "x$ASCIIDOC" != "x"; then
  75                 EL_CONFIG(CONFIG_ASCIIDOC, [AsciiDoc])
  76                 EL_CONFIG(MANUAL_ASCIIDOC, [HTML (one file)])
  77                 EL_CONFIG(MAN_ASCIIDOC, [HTML])
  78
  79                 echo > config.asciidoc-unsafe.txt
  80                 if "$ASCIIDOC" --unsafe config.asciidoc-unsafe.txt >/dev/null 2>/dev/null; then
  81                         ASCIIDOC_FLAGS=--unsafe
  82                 fi
  83                 rm config.asciidoc-unsafe.*
  84         fi
  85
  86         AC_PATH_PROGS(XMLTO, "xmlto")
  87         if test "x$XMLTO" != "x"; then
  88                 EL_CONFIG(CONFIG_XMLTO, [XmlTo])
  89                 EL_CONFIG(MANUAL_XMLTO, [HTML (multiple files)])
  90                 EL_CONFIG(MAN_XMLTO, [man (groff)])
  91         fi
  92
  93         AC_PATH_PROGS(JW, "jw")
  94         if test "x$JW" != "x"; then
  95                 EL_CONFIG(CONFIG_JW, [JadeWrapper])
  96                 EL_CONFIG(MANUAL_JW, [PDF])
  97         fi
  98
  99         AC_PATH_PROGS(POD2HTML, "pod2html")
 100         if test "x$POD2HTML" != "x"; then
 101                 EL_CONFIG(CONFIG_POD2HTML, [Pod2HTML])
 102         fi
 103
 104         AC_PATH_PROGS(DOXYGEN, "doxygen")
 105         if test "x$DOXYGEN" != "x"; then
 106                 EL_CONFIG(CONFIG_DOXYGEN, [Doxygen])
 107                 api_srcdir="$(cd "$srcdir" && pwd)/src"
 108                 AC_SUBST(api_srcdir)
 109         fi
 110 fi
 111
 112 AC_SUBST(ASCIIDOC_FLAGS)
 113 AC_SUBST(CONFIG_ASCIIDOC)
 114 AC_SUBST(CONFIG_DOXYGEN)
 115 AC_SUBST(CONFIG_POD2HTML)
 116 AC_SUBST(CONFIG_XMLTO)
 117 AC_SUBST(CONFIG_JW)
 118
 119 EL_CONFIG_DEPENDS(CONFIG_DOC, [CONFIG_ASCIIDOC CONFIG_XMLTO CONFIG_JW CONFIG_POD2HTML], [Documentation Tools])
 120 EL_CONFIG_DEPENDS(CONFIG_MANUAL, [MANUAL_ASCIIDOC MANUAL_XMLTO MANUAL_JW], [Manual Formats])
 121 EL_CONFIG_DEPENDS(CONFIG_MANPAGE, [MAN_ASCIIDOC MAN_XMLTO], [Man Page Formats])
 122 EL_CONFIG_DEPENDS(CONFIG_APIDOCS, [CONFIG_DOXYGEN], [API Documentation])
 123
 124 # gcc specific options (to be continued at the bottom of configure)
 125 if test "x$ac_cv_c_compiler_gnu" = "xyes"; then
 126   # We want to see all warnings and live with none.
 127   # We can't set up -Werror here as there may be some warnings in test
 128   # suite of configure, and we don't want to fail them.
 129   CFLAGS="$CFLAGS -Wall"
 130 fi
 131
 132 # ===================================================================
 133 # Checks for special OSes.
 134 # ===================================================================
 135
 136 dnl EL_CHECK_COMPILER_MACRO(define, name, flagname)
 137 AC_DEFUN([EL_CHECK_COMPILER_MACROS],
 138 [
 139         AC_MSG_CHECKING([for $2])
 140
 141         for flag in $3; do
 142                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[#ifndef $flag
 143 kill me!
 144 #endif ]])],[$1=yes],[$1=no])
 145                 if test "[$]$1" = yes; then
 146                         EL_CONFIG([$1], [$2])
 147                         break
 148                 fi
 149         done
 150
 151         AC_MSG_RESULT([$]$1)
 152 ])
 153
 154 EL_CHECK_COMPILER_MACROS(CONFIG_OS_BEOS, [BEOS], [__BEOS__])
 155 AC_SUBST(CONFIG_OS_BEOS)
 156
 157 EL_CHECK_COMPILER_MACROS(CONFIG_OS_RISCOS, [RISCOS], [__riscos__])
 158 AC_SUBST(CONFIG_OS_RISCOS)
 159
 160 EL_CHECK_COMPILER_MACROS(CONFIG_OS_WIN32, [WIN32], [_WIN32 __WIN32__])
 161 AC_SUBST(CONFIG_OS_WIN32)
 162
 163 EL_CHECK_COMPILER_MACROS(CONFIG_OS_OS2, [EMX], [__EMX__])
 164 AC_SUBST(CONFIG_OS_OS2)
 165 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zexe//g"`
 166
 167 AC_MSG_CHECKING([for UNIX])
 168 dnl FIXME: some depend kind of mechanism
 169 if test "$CONFIG_OS_BEOS" = no && \
 170    test "$CONFIG_OS_RISCOS" = no && \
 171    test "$CONFIG_OS_WIN32" = no && \
 172    test "$CONFIG_OS_OS2" = no; then
 173         EL_CONFIG(CONFIG_OS_UNIX, [UNIX])
 174 else
 175         CONFIG_OS_UNIX=no
 176 fi
 177 AC_MSG_RESULT($CONFIG_OS_UNIX)
 178 AC_SUBST(CONFIG_OS_UNIX)
 179
 180 # ===================================================================
 181 # Checks for header files.
 182 # ===================================================================
 183
 184 AC_HEADER_DIRENT
 185 AC_HEADER_STDC
 186 AC_HEADER_SYS_WAIT
 187 AC_HEADER_TIME
 188
 189 AC_CHECK_HEADERS(wctype.h)
 190 AC_CHECK_HEADERS(fcntl.h limits.h time.h unistd.h)
 191 AC_CHECK_HEADERS(sigaction.h)
 192 AC_CHECK_HEADERS(arpa/inet.h)
 193 AC_CHECK_HEADERS(netinet/in_systm.h netinet/in_system.h netinet/ip.h)
 194 AC_CHECK_HEADERS(netdb.h netinet/in.h netinet/in6_var.h)
 195 AC_CHECK_HEADERS(ifaddrs.h)
 196 AC_CHECK_HEADERS(sys/cygwin.h io.h)
 197 AC_CHECK_HEADERS(sys/fmutex.h)
 198 AC_CHECK_HEADERS(sys/ioctl.h sys/sockio.h)
 199 AC_CHECK_HEADERS(sys/resource.h)
 200 AC_CHECK_HEADERS(sys/select.h)
 201 AC_CHECK_HEADERS(sys/signal.h)
 202 AC_CHECK_HEADERS(sys/socket.h)
 203 AC_CHECK_HEADERS(sys/time.h)
 204 AC_CHECK_HEADERS(sys/utsname.h)
 205 AC_CHECK_HEADERS([net/if.h], [], [],
 206 [[#ifdef HAVE_SYS_SOCKET_H
 207 # include <sys/socket.h> /* <net/if.h> on Mac OS X 10.5.4 needs this */
 208 #endif
 209 ]])
 210 AC_CHECK_HEADERS(stdint.h inttypes.h)
 211 AC_CHECK_HEADERS(locale.h pwd.h)
 212 AC_CHECK_HEADERS(termios.h)
 213
 214
 215 AC_CHECK_HEADERS(sys/un.h,
 216         [CONFIG_INTERLINK=yes
 217          EL_CONFIG([CONFIG_INTERLINK], [interlinking])],
 218         [CONFIG_INTERLINK=no])
 219 AC_SUBST(CONFIG_INTERLINK)
 220
 221 # ===================================================================
 222 # Checks for typedefs, structures, and compiler characteristics.
 223 # ===================================================================
 224
 225 AC_STRUCT_TM
 226 AC_C_CONST
 227 AC_C_INLINE
 228 EL_CHECK_CODE(typeof, HAVE_TYPEOF, [], [int a; typeof(a) b;])
 229
 230 AC_SYS_LARGEFILE
 231 AC_TYPE_SIZE_T
 232 AC_TYPE_OFF_T
 233 EL_CHECK_TYPE(ssize_t, int)
 234 EL_CHECK_SYS_TYPE(long long, HAVE_LONG_LONG, [])
 235 EL_CHECK_SYS_TYPE(off_t, HAVE_OFF_T, [])
 236 EL_CHECK_INT_TYPE(int32_t, HAVE_INT32_T)
 237 EL_CHECK_INT_TYPE(uint32_t, HAVE_UINT32_T)
 238 EL_CHECK_INT_TYPE(uint16_t, HAVE_UINT16_T)
 239
 240 AC_CHECK_SIZEOF(char, 1)
 241 AC_CHECK_SIZEOF(short, 2)
 242 AC_CHECK_SIZEOF(int, 4)
 243 AC_CHECK_SIZEOF(long, 4)
 244 test "x$HAVE_LONG_LONG" = xyes && AC_CHECK_SIZEOF(long long, 8)
 245 test "x$HAVE_OFF_T" = xyes && AC_CHECK_SIZEOF(off_t, 4)
 246
 247 # Check for variadic macros
 248 EL_CHECK_CODE([variadic macros], HAVE_VARIADIC_MACROS,
 249                 [#include <stdio.h>
 250                  #define a(b,c...) printf(b,##c)],
 251                 [a("foo");a("%s","bar");a("%s%s","baz","quux");])
 252
 253 # ===================================================================
 254 # Checks for library functions.
 255 # ===================================================================
 256
 257 AC_PROG_GCC_TRADITIONAL
 258 AC_FUNC_MEMCMP
 259 AC_FUNC_MMAP
 260 AC_FUNC_STRFTIME
 261 AC_CHECK_FUNCS(atoll gethostbyaddr herror strerror)
 262 AC_CHECK_FUNCS(popen uname access chmod alarm timegm mremap)
 263 AC_CHECK_FUNCS(strcasecmp strncasecmp strcasestr strstr strchr strrchr)
 264 AC_CHECK_FUNCS(memmove bcopy stpcpy strdup index isdigit mempcpy memrchr)
 265 AC_CHECK_FUNCS(snprintf vsnprintf asprintf vasprintf)
 266 AC_CHECK_FUNCS(getifaddrs getpwnam inet_pton inet_ntop)
 267 AC_CHECK_FUNCS(fflush fsync fseeko ftello sigaction)
 268 AC_CHECK_FUNCS(gettimeofday clock_gettime)
 269
 270 AC_CHECK_FUNCS([cygwin_conv_to_full_win32_path])
 271
 272 AC_CHECK_FUNCS(setenv putenv, HAVE_SETENV_OR_PUTENV=yes)
 273 AC_CHECK_FUNCS(getuid, HAVE_GETUID=yes)
 274 AC_CHECK_FUNCS(geteuid, HAVE_GETEUID=yes)
 275
 276 # These aren't probably needed now, as they are commented in links.h.
 277 # I've no idea about their historical background, but I keep them here
 278 # just in the case they will help later. --pasky
 279 AC_CHECK_FUNCS(getpid, HAVE_GETPID=yes)
 280 AC_CHECK_FUNCS(setpgid getpgid setpgrp getpgrp)
 281 AC_CHECK_FUNCS(raise, HAVE_RAISE=yes)
 282 AC_CHECK_FUNCS(kill, HAVE_KILL=yes)
 283
 284 if test x"$HAVE_RAISE" = x; then
 285         if test x"$HAVE_KILL" = x || test x"$HAVE_GETPID" = x; then
 286                 AC_MSG_ERROR([Unable to emulate raise()])
 287         fi
 288 fi
 289
 290 AC_CACHE_CHECK([for __va_copy],el_cv_HAVE_VA_COPY,[
 291 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>
 292 va_list ap1,ap2;]], [[__va_copy(ap1,ap2);]])],[el_cv_HAVE_VA_COPY=yes],[el_cv_HAVE_VA_COPY=no])])
 293 if test x"$el_cv_HAVE_VA_COPY" = x"yes"; then
 294         EL_DEFINE(HAVE_VA_COPY, __va_copy)
 295 fi
 296
 297 AC_CACHE_CHECK([for sysconf(_SC_PAGE_SIZE)],el_cv_HAVE_SC_PAGE_SIZE,[
 298 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <unistd.h>
 299 ]], [[int page_size = sysconf(_SC_PAGE_SIZE);]])],[el_cv_HAVE_SC_PAGE_SIZE=yes],[el_cv_HAVE_SC_PAGE_SIZE=no])])
 300 if test x"$el_cv_HAVE_SC_PAGE_SIZE" = x"yes"; then
 301         EL_DEFINE(HAVE_SC_PAGE_SIZE, _SC_PAGE_SIZE)
 302 fi
 303
 304 AC_CACHE_CHECK([for C99 vsnprintf],el_cv_HAVE_C99_VSNPRINTF,[
 305 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 306 #include <stdio.h>
 307 #include <stdarg.h>
 308 #include <stdlib.h>
 309 #include <string.h>
 310
 311 char buf[8];
 312
 313 int bar(char *buf, const char *format, va_list ap)
 314 {
 315        return vsnprintf(buf, 0, format, ap);
 316 }
 317
 318 void foo(const char *format, ...) {
 319        va_list ap;
 320        int len;
 321
 322        va_start(ap, format);
 323        len = bar(buf, format, ap);
 324        va_end(ap);
 325        if ((len != 6) && (len != 7)) exit(1); /* \n -> \r\n */
 326
 327        va_start(ap, format);
 328        len = bar(buf, format, ap);
 329        va_end(ap);
 330        if ((len != 6) && (len != 7)) exit(1);
 331
 332        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 333
 334        exit(0);
 335 }
 336 main() { foo("hello\n"); }
 337 ]])],[el_cv_HAVE_C99_VSNPRINTF=yes],[el_cv_HAVE_C99_VSNPRINTF=no],[el_cv_HAVE_C99_VSNPRINTF=cross])])
 338 if test x"$el_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 339         EL_DEFINE(HAVE_C99_VSNPRINTF, [C99 compliant vsnprintf()])
 340 fi
 341
 342 # OpenSSL and Lua frequently need dlopen
 343 AC_CHECK_LIB(dl, dlopen)
 344
 345 # ===================================================================
 346 # Checks for libraries.
 347 # ===================================================================
 348
 349 AC_CHECK_FUNC(socket, cf_result=yes, cf_result=no)
 350 if test "$cf_result" = no; then
 351         AC_CHECK_LIB(socket, socket)
 352 fi
 353
 354 AC_CHECK_FUNC(setsockopt, cf_result=yes, cf_result=no)
 355 if test "$cf_result" = no; then
 356         AC_CHECK_LIB(socket, setsockopt)
 357 fi
 358
 359 AC_CHECK_FUNC(gethostbyname, cf_result=yes, cf_result=no)
 360 if test "$cf_result" = no; then
 361         AC_CHECK_LIB(socket, gethostbyname, cf_result=yes, cf_result=no)
 362         if test "$cf_result" = no; then
 363                 AC_CHECK_LIB(nsl, gethostbyname)
 364         else
 365                 test -z "`echo $LIBS | grep -- -lsocket`" && LIBS="$LIBS -lsocket"
 366         fi
 367 fi
 368
 369 # ===================================================================
 370 # Checks for packaging specific options.
 371 # ===================================================================
 372
 373 AC_ARG_WITH(xterm, [  --with-xterm            how to invoke the X terminal emulator],
 374             [ if test "$withval" != no && test "$withval" != yes; then
 375                 AC_DEFINE_UNQUOTED(XTERM, "$withval", [How to invoke XTerm])
 376               fi ])
 377
 378 # ===================================================================
 379 # Checks for a libraries, optional even if installed.
 380 # ===================================================================
 381
 382 dnl EL_CHECK_OPTIONAL_LIBRARY(define, name, header, lib, function)
 383 AC_DEFUN([EL_CHECK_OPTIONAL_LIBRARY],
 384 [
 385         AC_MSG_CHECKING([for $2 support])
 386
 387         if test "[$]$1" != no; then
 388                 AC_MSG_RESULT(yes)
 389                 EL_SAVE_FLAGS
 390                 if test -n "$withval" && test -d "$withval"; then
 391                         # Be a little more careful when setting
 392                         # include and lib directories. This way
 393                         # $withval will work when includes are
 394                         # there but the library is in the common
 395                         # /usr/lib ... Does the right thing when
 396                         # looking for gc on Debian.
 397                         if test -d "$withval/include"; then
 398                                 CFLAGS="$CFLAGS -I$withval/include"
 399                                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 400                         else
 401                                 CFLAGS="$CFLAGS -I$withval"
 402                                 CPPFLAGS="$CPPFLAGS -I$withval"
 403                         fi
 404                         if test -d "$withval/lib"; then
 405                                 LDFLAGS="$LDFLAGS -L$withval/lib"
 406                         fi
 407                 fi
 408
 409                 AC_CHECK_HEADERS([$3], [$1=yes], [$1=no; break;])
 410                 if test "[$]$1" = yes; then
 411                         AC_CHECK_LIB([$4], [$5], [$1=yes], [$1=no])
 412                 fi
 413
 414                 if test "[$]$1" = yes; then
 415                         EL_CONFIG([$1], [$2])
 416                         LIBS="$LIBS -l$4"
 417                 else
 418                         if test -n "[$]WITHVAL_$1" &&
 419                            test "[$]WITHVAL_$1" != xno; then
 420                                 AC_MSG_ERROR([$2 not found])
 421                         fi
 422                         EL_RESTORE_FLAGS
 423                 fi
 424         else
 425                 AC_MSG_RESULT(disabled)
 426         fi
 427 ])
 428
 429 dnl EL_CONFIG_OPTIONAL_LIBRARY(define, name, header, lib, function, confhelp)
 430 AC_DEFUN([EL_CONFIG_OPTIONAL_LIBRARY],
 431 [
 432         $1=yes
 433         WITHVAL_$1=
 434
 435         AC_ARG_WITH([$2], [$6], [WITHVAL_$1="[$]withval"])
 436         if test "x[$]WITHVAL_$1" = xno; then $1=no; fi
 437
 438         EL_CHECK_OPTIONAL_LIBRARY([$1], [$2], [$3], [$4], [$5])
 439
 440         EL_LOG_CONFIG([$1], [$2], [])
 441 ])
 442
 443 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GPM, gpm, gpm.h, gpm, Gpm_Open,
 444         [  --without-gpm           disable gpm (mouse) support])
 445
 446 # ELinks calls deflateInit2 with windowBits = MAX_WBITS | 32, to
 447 # enable automatic decoding of both zlib and gzip headers.  This
 448 # feature was added in zlib 1.2.0.2; earlier versions return an error.
 449 # The gzclearerr function was also added in zlib 1.2.0.2, so check for
 450 # that, even though ELinks does not actually call gzclearerr.
 451 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GZIP, zlib, zlib.h, z, gzclearerr,
 452         [  --without-zlib          disable zlib support])
 453
 454 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_BZIP2, bzlib, bzlib.h, bz2, BZ2_bzReadOpen,
 455         [  --without-bzlib         disable bzlib support])
 456
 457 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_IDN, idn, idna.h, idn, stringprep_check_version,
 458         [  --without-idn           disable international domain names support])
 459
 460 if test "x{with_gc}" != xno; then
 461         EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GC, gc, gc.h, gc, GC_init,
 462                 [  --with-gc               enable Boehm's garbage collector])
 463 fi
 464
 465 # LZMA disabled by default, because of little usability and compilation problems
 466 # with new xz
 467 AC_ARG_WITH(lzma, [  --with-lzma           enable lzma encoding support],
 468             [ if test "x$withval" != xno; then
 469             EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_LZMA, lzma, lzma.h, lzma, lzma_code, [])
 470             fi ])
 471
 472 # ===================================================================
 473 # Check for GSSAPI, optional even if installed.
 474 # ===================================================================
 475
 476 enable_gssapi="no";
 477
 478 AC_ARG_WITH(gssapi, [  --with-gssapi           enable GSSAPI support],
 479             [ if test "x$withval" != xno; then enable_gssapi=yes; fi ])
 480
 481 AC_MSG_CHECKING([for GSSAPI])
 482
 483 if test "$enable_gssapi" = "yes"; then
 484         AC_MSG_RESULT(yes)
 485         GSSAPI_CFLAGS=`krb5-config --cflags gssapi`
 486         GSSAPI_LIBS=`krb5-config --libs gssapi`
 487         CFLAGS="$GSSAPI_CFLAGS $CFLAGS"
 488         LIBS="$GSSAPI_LIBS $LIBS"
 489         EL_CONFIG(CONFIG_GSSAPI, [GssApi])
 490 else
 491         AC_MSG_RESULT(no)
 492 fi
 493
 494 AC_SUBST(CONFIG_GSSAPI)
 495
 496 # ===================================================================
 497 # Bookmark and XBEL support
 498 # ===================================================================
 499
 500 EL_SAVE_FLAGS
 501
 502 EL_ARG_ENABLE(CONFIG_BOOKMARKS, bookmarks, [Bookmarks],
 503               [  --disable-bookmarks     disable bookmark support])
 504
 505 # Check whether --enable-xbel or --disable-xbel was given.
 506 if test "x${enable_xbel}" != xno; then
 507         AC_CHECK_HEADERS(expat.h, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 508
 509         if test "$HAVE_LIBEXPAT" = yes; then
 510                 AC_CHECK_LIB(expat, XML_ParserCreate, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 511                 if test "$HAVE_LIBEXPAT" = yes; then
 512                         LIBS="$LIBS -lexpat"
 513                 fi
 514         fi
 515 fi
 516
 517
 518 EL_ARG_DEPEND(CONFIG_XBEL_BOOKMARKS, xbel, [CONFIG_BOOKMARKS:yes HAVE_LIBEXPAT:yes],
 519               [XBEL bookmarks],
 520               [  --disable-xbel          disable XBEL bookmark support (requires expat)])
 521
 522 if test "$CONFIG_XBEL_BOOKMARKS" != yes; then
 523         EL_RESTORE_FLAGS
 524 fi
 525
 526 # ===================================================================
 527 # Checks for BSD sysmouse
 528 # ===================================================================
 529
 530 HAVE_SYSMOUSE_HEADER="no"
 531
 532 # Either of these header files provides the (same) sysmouse interface
 533 AC_CHECK_HEADERS(sys/consio.h machine/console.h, [HAVE_SYSMOUSE_HEADER="yes"])
 534
 535 # ===================================================================
 536 # Checks for OS/2
 537 # ===================================================================
 538
 539 if test "$CONFIG_OS_OS2" = yes; then
 540         EL_CONFIG_OS_OS2
 541 fi
 542
 543 # ===================================================================
 544 # Checks for Win32
 545 # ===================================================================
 546
 547 if test "$CONFIG_OS_WIN32" = yes; then
 548         EL_CONFIG_OS_WIN32
 549 fi
 550
 551 # ===================================================================
 552 # Check for SEE (Simple Ecmascript Engine)
 553 # ===================================================================
 554 AC_ARG_WITH(see, [  --with-see              enable Simple Ecmascript Engine (SEE) support],
 555             [ if test "x$withval" != xno; then enable_see=yes; fi ])
 556
 557 # The following is probably bad, ugly and so on. Stolen from Guile's (1.4)
 558 # SEE_FLAGS but I really don't want to require people to have Guile in order
 559 # to compile CVS. Also, the macro seems to be really stupid regarding searching
 560 # for Guile in $PATH etc. --pasky
 561
 562 CONFIG_ECMASCRIPT_SEE=no
 563
 564 if test "$enable_see" = "yes"; then
 565         if test -d "$withval"; then
 566                 SEE_PATH="$withval:$PATH"
 567         else
 568                 SEE_PATH="$PATH"
 569         fi
 570
 571         AC_PATH_PROG(SEE_CONFIG, libsee-config, no, $SEE_PATH)
 572         AC_MSG_CHECKING([for SEE (2.0.1131 or later)])
 573         if test "$SEE_CONFIG" != no; then
 574                 EL_SAVE_FLAGS
 575                 SEE_LIBS="`$SEE_CONFIG --libs`"
 576                 SEE_CFLAGS="`$SEE_CONFIG --cppflags`"
 577                 CPPFLAGS="$SEE_CFLAGS $CPPFLAGS"
 578                 LIBS="$SEE_LIBS $LIBS_X"
 579                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <see/see.h>]], [[#if SEE_VERSION_API_MAJOR < 2
 580                         #error SEE too old
 581                         #endif
 582                 ]])],[cf_result=yes],[cf_result=no])
 583                 EL_RESTORE_FLAGS
 584                 if test "$cf_result" = yes; then
 585                         LIBS="$SEE_LIBS $LIBS"
 586                         EL_CONFIG(CONFIG_ECMASCRIPT_SEE, [SEE])
 587                         AC_SUBST(SEE_CFLAGS)
 588                 fi
 589                 AC_MSG_RESULT($cf_result)
 590         else
 591                 if test -n "$withval" && test "x$withval" != xno; then
 592                         AC_MSG_ERROR([SEE not found])
 593                 else
 594                         AC_MSG_WARN([SEE support disabled])
 595                 fi
 596         fi
 597 fi
 598
 599 # ===================================================================
 600 # Check for SpiderMonkey, optional even if installed.
 601 # ===================================================================
 602
 603 AC_ARG_WITH(spidermonkey, [  --without-spidermonkey  disable SpiderMonkey Mozilla JavaScript engine support],
 604             [if test "$withval" = no; then disable_spidermonkey=yes; fi])
 605 AC_MSG_CHECKING([for SpiderMonkey (1.5 RC3a or later)])
 606
 607 EL_SAVE_FLAGS
 608 cf_result=no
 609
 610 if test -z "$disable_spidermonkey"; then
 611         if test ! -d "$withval"; then
 612                 withval="";
 613         fi
 614         for spidermonkeydir in "$withval" "" /usr /usr/local /opt/spidermonkey /opt/js; do
 615                 for spidermonkeyinclude in "/include" "/include/js" "/include/smjs" "/include/mozjs"; do
 616                         for spidermonkeylib in js smjs mozjs; do
 617                                 if test "$cf_result" = no &&
 618                                    test -f "$spidermonkeydir$spidermonkeyinclude/jsapi.h"; then
 619                                         SPIDERMONKEY_LIBS="-L$spidermonkeydir/lib -l$spidermonkeylib"
 620                                         SPIDERMONKEY_CFLAGS="-I$spidermonkeydir$spidermonkeyinclude"
 621
 622                                         LIBS="$SPIDERMONKEY_LIBS $LIBS_X"
 623                                         CFLAGS="$CFLAGS_X $SPIDERMONKEY_CFLAGS"
 624                                         CPPFLAGS="$CPPFLAGS_X $SPIDERMONKEY_CFLAGS"
 625
 626                                         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define XP_UNIX
 627                                                      #include <jsapi.h>]], [[JS_GetReservedSlot(NULL, NULL, 0, NULL)]])],[cf_result=yes],[cf_result=no])
 628                                 fi
 629                         done
 630                 done
 631         done
 632 fi
 633
 634 AC_MSG_RESULT($cf_result)
 635 CONFIG_SPIDERMONKEY="$cf_result"
 636 if test "$cf_result" = "yes"; then
 637         AC_CHECK_FUNCS([[JS_ReportAllocationOverflow]])
 638 fi
 639 EL_RESTORE_FLAGS
 640
 641 if test "x$CONFIG_SPIDERMONKEY" = xyes &&
 642    test "x$CONFIG_ECMASCRIPT_SEE" != xyes; then
 643         EL_CONFIG(CONFIG_ECMASCRIPT_SMJS, [SpiderMonkey document scripting])
 644 else
 645         CONFIG_ECMASCRIPT_SMJS=no
 646 fi
 647
 648 EL_CONFIG_DEPENDS(CONFIG_ECMASCRIPT, [CONFIG_ECMASCRIPT_SEE CONFIG_ECMASCRIPT_SMJS], [ECMAScript (JavaScript)])
 649 AC_SUBST(CONFIG_ECMASCRIPT_SEE)
 650 AC_SUBST(CONFIG_ECMASCRIPT_SMJS)
 651
 652
 653 # ===================================================================
 654 # Optional Spidermonkey-based ECMAScript browser scripting
 655 # ===================================================================
 656
 657 AC_ARG_ENABLE(sm-scripting,
 658               [  --disable-sm-scripting  ECMAScript browser scripting (requires Spidermonkey)],
 659               [if test "$enableval" != no; then enableval="yes"; fi
 660                CONFIG_SCRIPTING_SPIDERMONKEY="$enableval";])
 661
 662 if test "x$CONFIG_SPIDERMONKEY" = xyes &&
 663    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 664         EL_CONFIG(CONFIG_SCRIPTING_SPIDERMONKEY, [SpiderMonkey])
 665 else
 666         CONFIG_SCRIPTING_SPIDERMONKEY=no
 667 fi
 668
 669 if test "x$CONFIG_ECMASCRIPT_SMJS" = xyes ||
 670    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 671         LIBS="$LIBS $SPIDERMONKEY_LIBS"
 672         AC_SUBST(SPIDERMONKEY_LIBS)
 673         AC_SUBST(SPIDERMONKEY_CFLAGS)
 674         AC_SUBST(CONFIG_SPIDERMONKEY)
 675 fi
 676
 677 # ===================================================================
 678 # Check for Guile, optional even if installed.
 679 # ===================================================================
 680
 681 enable_guile="no";
 682
 683 AC_ARG_WITH(guile, [  --with-guile            enable Guile support],
 684             [ if test "x$withval" != xno; then enable_guile=yes; fi ])
 685
 686 # The following is probably bad, ugly and so on. Stolen from Guile's (1.4)
 687 # GUILE_FLAGS but I really don't want to require people to have Guile in order
 688 # to compile CVS. Also, the macro seems to be really stupid regarding searching
 689 # for Guile in $PATH etc. --pasky
 690
 691 AC_MSG_CHECKING([for Guile])
 692
 693 if test "$enable_guile" = "yes"; then
 694         AC_MSG_RESULT(yes);
 695         ## Based on the GUILE_FLAGS macro.
 696
 697         if test -d "$withval"; then
 698                 GUILE_PATH="$withval:$PATH"
 699         else
 700                 GUILE_PATH="$PATH"
 701         fi
 702
 703         AC_PATH_PROG(GUILE_CONFIG, guile-config, no, $GUILE_PATH)
 704
 705         ## First, let's just see if we can find Guile at all.
 706         if test "$GUILE_CONFIG" != no; then
 707                 cf_result="yes";
 708
 709                 GUILE_LIBS="`guile-config link`"
 710                 GUILE_CFLAGS="`guile-config compile`"
 711                 LIBS="$GUILE_LIBS $LIBS"
 712                 EL_CONFIG(CONFIG_SCRIPTING_GUILE, [Guile])
 713                 AC_SUBST(GUILE_CFLAGS)
 714                 cat <<EOF
 715 ***********************************************************************
 716 The Guile support is incomplete and not so well integrated to ELinks
 717 yet. That means, e.g., that you have no Guile console and there might
 718 not be all the necessary hooks. Also, the Guile interface is not too
 719 well tested (success stories heartily welcomed!).  See
 720 src/scripting/guile/README for further details and hints.
 721 ***********************************************************************
 722 EOF
 723         else
 724                 if test -n "$withval" && test "x$withval" != xno; then
 725                         AC_MSG_ERROR([Guile not found])
 726                 else
 727                         AC_MSG_WARN([Guile support disabled])
 728                 fi
 729         fi
 730 else
 731         AC_MSG_RESULT(no);
 732 fi
 733
 734 # ===================================================================
 735 # Check for Perl
 736 # ===================================================================
 737 enable_perl="no";
 738
 739 AC_ARG_WITH(perl, [  --with-perl             enable Perl support],
 740             [
 741 if test "$withval" = yes; then
 742         # FIXME: If withval is a valid directory append it to PATH
 743         # so that you can specify one of several perl installations.
 744         withval="";
 745         enable_perl=yes;
 746 fi
 747             ])
 748
 749 AC_MSG_CHECKING([for Perl])
 750
 751 cf_result=no
 752
 753 EL_SAVE_FLAGS
 754
 755 if test "$enable_perl" = "yes"; then
 756         PERL_LIBS="`perl -MExtUtils::Embed -e ldopts`"
 757         PERL_CFLAGS="`perl -MExtUtils::Embed -e ccopts`"
 758         LIBS="$PERL_LIBS $LIBS"
 759         CFLAGS="$PERL_CFLAGS $CFLAGS"
 760         CPPFLAGS="$CPPFLAGS $PERL_CFLAGS"
 761         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 762 #include <EXTERN.h>
 763 #include <perl.h>
 764 #include <perlapi.h>
 765 ]], [[PerlInterpreter *my_perl = perl_alloc();]])],[cf_result=yes],[cf_result=no])
 766 fi
 767
 768 if test "$cf_result"; then AC_MSG_RESULT($cf_result); fi
 769
 770 AC_MSG_CHECKING([whether POPpx works without an n_a variable])
 771 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 772 #include <EXTERN.h>
 773 #include <perl.h>
 774 extern PerlInterpreter *my_perl;
 775 ]], [[dSP; (void) POPpx;]])],[AC_MSG_RESULT([yes])
 776 AC_DEFINE([CONFIG_PERL_POPPX_WITHOUT_N_A], [1],
 777                 [Define if using Perl 5.8.8 or later, where the "POPpx" macro
 778 no longer needs an "n_a" variable like it did in 5.8.7])],[AC_MSG_RESULT([no])])
 779
 780 if test "$cf_result" != "yes"; then
 781         EL_RESTORE_FLAGS
 782 else
 783         EL_CONFIG(CONFIG_SCRIPTING_PERL, [Perl])
 784
 785         CFLAGS="$CFLAGS_X"
 786         CPPFLAGS="$CPPFLAGS_X"
 787         AC_SUBST(PERL_LIBS)
 788         AC_SUBST(PERL_CFLAGS)
 789 fi
 790
 791 # ===================================================================
 792 # Check for Python
 793 # ===================================================================
 794 enable_python="no";
 795
 796 AC_ARG_WITH(python, [[  --with-python[=DIR]     enable Python support]],
 797             [ if test "x$withval" != xno; then enable_python=yes; fi ])
 798
 799 EL_SAVE_FLAGS
 800 cf_result=no
 801
 802 AC_MSG_CHECKING([for Python])
 803
 804 if test "$enable_python" = "yes"; then
 805         AC_MSG_RESULT(yes);
 806
 807         if test -d "$withval"; then
 808                 PYTHON_PATH="$withval:$PATH"
 809         else
 810                 PYTHON_PATH="$PATH"
 811         fi
 812
 813         AC_PATH_PROG(PYTHON, python, no, $PYTHON_PATH)
 814
 815         if test "$PYTHON" != no; then
 816                 cf_result="yes";
 817
 818                 PYTHON_CFLAGS="`$PYTHON -c 'from distutils import sysconfig; print "-I%s -I%s" % (sysconfig.get_python_inc(), sysconfig.get_python_inc(plat_specific=True))'`"
 819                 PYTHON_LIBS="`$PYTHON -c 'from distutils import sysconfig; var = sysconfig.get_config_var; print "%s %s %s -L%s -lpython%s" % (var("LINKFORSHARED"), var("LIBS"), var("SYSLIBS"), var("LIBPL"), var("VERSION"))'`"
 820                 LIBS="$PYTHON_LIBS $LIBS"
 821                 CPPFLAGS="$CPPFLAGS $PYTHON_CFLAGS"
 822                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <Python.h>]], [[Py_Initialize();]])],[cf_result=yes],[cf_result=no])
 823
 824                 if test "$cf_result" != "yes"; then
 825                         EL_RESTORE_FLAGS
 826                 else
 827                         EL_CONFIG(CONFIG_SCRIPTING_PYTHON, [Python])
 828                         AC_SUBST(PYTHON_LIBS)
 829                         AC_SUBST(PYTHON_CFLAGS)
 830                         CPPFLAGS="$CPPFLAGS_X"
 831                         cat <<EOF
 832 ***********************************************************************
 833 The Python support is incomplete and not so well integrated to ELinks
 834 yet. That means, e.g., that you have no Python console and there might
 835 not be all the necessary hooks. Also, the Python interface is not too
 836 well tested (success stories heartily welcomed!).
 837 ***********************************************************************
 838 EOF
 839                 fi
 840         else
 841                 if test -n "$withval" && test "x$withval" != xno; then
 842                         AC_MSG_ERROR([Python not found])
 843                 else
 844                         AC_MSG_WARN([Python support disabled])
 845                 fi
 846         fi
 847 else
 848         AC_MSG_RESULT(no);
 849 fi
 850
 851
 852 # ===================================================================
 853 # Check for Lua, optional even if installed.
 854 # ===================================================================
 855
 856 # Do this the long way, as FreeBSD reportedly needs -L<dir> for
 857 # anything other than /usr/lib, and Lua is very often in /usr/local/lib.
 858
 859 AC_ARG_WITH(lua, [  --without-lua           disable Lua support],
 860             [if test "$withval" = no; then disable_lua=yes; fi])
 861 AC_MSG_CHECKING([for Lua])
 862
 863 EL_SAVE_FLAGS
 864 cf_result=no
 865
 866 if test -z "$disable_lua"; then
 867         if test ! -d "$withval"; then
 868                 withval="";
 869         fi
 870         for luadir in "$withval" "" /usr /usr/local; do
 871                 for suffix in "" 50; do
 872                         if test "$cf_result" = no && ( test -f "$luadir/include/lua.h" || \
 873                            test -f "$luadir/include/lua$suffix/lua.h" ) ; then
 874                                 LUA_LIBS="-L$luadir/lib -llua$suffix -llualib$suffix -lm"
 875                                 LUA_CFLAGS="-I$luadir/include -I$luadir/include/lua$suffix"
 876
 877                                 LIBS="$LUA_LIBS $LIBS_X"
 878                                 CFLAGS="$CFLAGS_X $LUA_CFLAGS"
 879                                 CPPFLAGS="$CPPFLAGS_X $LUA_CFLAGS"
 880
 881                                 # Check that it is a compatible Lua version
 882                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[      #include <lua.h>
 883                                                 #include <lualib.h>]], [[       lua_State *L = lua_open();
 884                                                 luaopen_base(L);
 885                                                 luaopen_table(L);
 886                                                 luaopen_io(L);
 887                                                 luaopen_string(L);
 888                                                 luaopen_math(L);
 889                                                 lua_pushboolean(L, 1);
 890                                                 lua_close(L);]])],[cf_result=yes],[cf_result=no])
 891                         fi
 892                 done
 893         done
 894 fi
 895
 896 AC_MSG_RESULT($cf_result)
 897
 898 if test "$cf_result" != yes; then
 899         EL_RESTORE_FLAGS
 900 else
 901         EL_CONFIG(CONFIG_SCRIPTING_LUA, [Lua])
 902         AC_CHECK_HEADERS(lauxlib.h)
 903
 904         CFLAGS="$CFLAGS_X"
 905         CPPFLAGS="$CPPFLAGS_X"
 906         AC_SUBST(LUA_LIBS)
 907         AC_SUBST(LUA_CFLAGS)
 908 fi
 909
 910 # ===================================================================
 911 # Check for TRE library
 912 # ===================================================================
 913
 914 AC_MSG_CHECKING([[for TRE in pkg-config]])
 915 if pkg-config tre; then
 916         TRE_CFLAGS=`pkg-config --cflags tre`
 917         TRE_LIBS=`pkg-config --libs tre`
 918         AC_MSG_RESULT([[yes]])
 919 else
 920         # <http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=513055>
 921         # "libtre-dev: /usr/lib/pkgconfig/tre.pc missing"
 922         # so we look for the library even if pkg-config doesn't know about it.
 923         TRE_CFLAGS=
 924         TRE_LIBS=-ltre
 925         AC_MSG_RESULT([[no, but let's try defaults]])
 926 fi
 927
 928 AC_MSG_CHECKING([[for TRE header and library]])
 929 EL_SAVE_FLAGS
 930 CFLAGS="$TRE_CFLAGS $CFLAGS"
 931 LIBS="$TRE_LIBS $LIBS"
 932 AC_TRY_LINK([#include <tre/regex.h>],
 933             [regex_t re;
 934              regmatch_t match[1];
 935              regwcomp(&re, L"zap", REG_ICASE);
 936              regwexec(&re, L"ELIZAPROGRAM", 1, match, 0);],
 937             [AC_MSG_RESULT([[yes]])
 938              AC_DEFINE([HAVE_TRE_REGEX_H], [1],
 939                        [Define to 1 if you have the <tre/regex.h> header file.])
 940              # TRE_CFLAGS will be used only where needed.
 941              # TRE_LIBS will be kept in LIBS and used everywhere.
 942              EL_RESTORE_FLAGS
 943              LIBS="$TRE_LIBS $LIBS"],
 944             [AC_MSG_RESULT([[no]])
 945              TRE_CFLAGS=
 946              TRE_LIBS=
 947              EL_RESTORE_FLAGS])
 948 AC_SUBST(TRE_CFLAGS)
 949 AC_SUBST(TRE_LIBS)
 950
 951 AC_CHECK_SIZEOF([wchar_t], [4], [[#include <wchar.h>]])
 952
 953 # ===================================================================
 954 # Check for Ruby, optional even if installed.
 955 # ===================================================================
 956
 957 EL_CONFIG_SCRIPTING_RUBY
 958
 959 # ===================================================================
 960 # Setup global scripting
 961 # ===================================================================
 962
 963 EL_CONFIG_DEPENDS(CONFIG_SCRIPTING, [CONFIG_SCRIPTING_GUILE CONFIG_SCRIPTING_LUA CONFIG_SCRIPTING_PERL CONFIG_SCRIPTING_PYTHON CONFIG_SCRIPTING_RUBY CONFIG_SCRIPTING_SPIDERMONKEY], [Browser scripting])
 964 AC_SUBST(CONFIG_SCRIPTING_GUILE)
 965 AC_SUBST(CONFIG_SCRIPTING_LUA)
 966 AC_SUBST(CONFIG_SCRIPTING_PERL)
 967 AC_SUBST(CONFIG_SCRIPTING_PYTHON)
 968 AC_SUBST(CONFIG_SCRIPTING_RUBY)
 969 AC_SUBST(CONFIG_SCRIPTING_SPIDERMONKEY)
 970 AC_SUBST(CONFIG_SCRIPTING)
 971
 972
 973 # ===================================================================
 974 # Check for SSL support.
 975 # ===================================================================
 976
 977 # We by default use OpenSSL, and we always prefer it. However, when GNUTLS
 978 # is enabled, we won't try to use OpenSSL anymore.
 979
 980 # For wiping SSL hooks..
 981 #ifdef CONFIG_SSL
 982
 983 disable_openssl=""
 984 disable_gnutls=""
 985 enable_gnutls=""
 986
 987 AC_ARG_WITH(gnutls, [  --without-gnutls        disable GNUTLS SSL support],
 988             [if test "$with_gnutls" = no;  then disable_gnutls=yes; fi])
 989 AC_ARG_WITH(gnutls, [[  --with-gnutls[=DIR]     enable GNUTLS SSL support]],
 990             [if test "$with_gnutls" != no;  then enable_gnutls=yes; fi])
 991 gnutls_withval="$withval"
 992
 993 if test "$enable_gnutls" = yes; then
 994         disable_openssl=yes;
 995 fi
 996
 997 AC_ARG_WITH(openssl, [  --without-openssl       disable OpenSSL support],
 998             [if test "$with_openssl" = no;  then disable_openssl=yes; fi])
 999 AC_ARG_WITH(openssl, [[  --with-openssl[=DIR]    enable OpenSSL support (default)]])
1000 openssl_withval="$withval"
1001
1002 # ---- OpenSSL
1003
1004 AC_MSG_CHECKING([for OpenSSL])
1005
1006 EL_SAVE_FLAGS
1007 cf_result="no"
1008
1009 if test "$disable_openssl" = yes; then
1010         cf_result="not used"
1011 else
1012         for ssldir in "$openssl_withval" "" /usr /usr/local/openssl \
1013                          /usr/lib/openssl /usr/local/ssl \
1014                          /usr/local/www /usr/lib/ssl /usr/local \
1015                          /usr/pkg /opt /opt/openssl; do
1016                 if test "$cf_result" = no; then
1017                         if test -d "$ssldir"; then
1018                                 OPENSSL_CFLAGS="-I$ssldir/include"
1019                                 LIBS="-L$ssldir/lib -lssl -lcrypto $LIBS_X"
1020                                 CFLAGS="$CFLAGS_X $OPENSSL_CFLAGS"
1021                                 CPPFLAGS="$CPPFLAGS_X $OPENSSL_CFLAGS"
1022 #                               # FIXME: This created serious portability problems. --pasky
1023 #                               if test "$CC" == "gcc"; then
1024 #                                       # I'm not sure about compatibility here. --pasky
1025 #                                       LIBS="$LIBS -R$ssldir/lib"
1026 #                               fi
1027                         else
1028                                 LIBS="-lssl -lcrypto $LIBS_X"
1029                         fi
1030                         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <openssl/ssl.h>]], [[OpenSSL_add_all_algorithms()]])],[cf_result=yes],[cf_result=no])
1031                         if test "$cf_result" != yes; then
1032                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <openssl/ssl.h>]], [[SSLeay_add_ssl_algorithms()]])],[cf_result=yes],[cf_result=no])
1033                         fi
1034                 fi
1035         done
1036
1037         if test "$cf_result" != yes; then
1038                 if test -n "$openssl_withval" && test "x$openssl_withval" != xno; then
1039                         AC_MSG_ERROR([OpenSSL not found])
1040                 fi
1041                 EL_RESTORE_FLAGS
1042         else
1043                 EL_CONFIG(CONFIG_OPENSSL, [OpenSSL])
1044
1045                 CFLAGS="$CFLAGS_X"
1046                 AC_SUBST(OPENSSL_CFLAGS)
1047         fi
1048 fi
1049
1050 AC_MSG_RESULT($cf_result)
1051
1052 CONFIG_GNUTLS_OPENSSL_COMPAT=no
1053 # ---- GNU TLS
1054 dnl We can't have AC_MSG_CHECKING here, because AC_PATH_PROG prints its own and
1055 dnl it looks ugly then.
1056
1057 if test "$cf_result" = yes; then
1058         cf_result="not used"
1059
1060 else
1061         EL_SAVE_FLAGS
1062         cf_result="no"
1063
1064         if test -z "$disable_gnutls"; then
1065                 # Sure, we maybe _could_ use their macro, but how to ensure
1066                 # that the ./configure script won't fail if the macro won't be
1067                 # found..? :( --pasky
1068
1069                 GNUTLS_PATH="$PATH:/usr/local/gnutls:/opt:/opt/gnutls"
1070
1071                 if test -d "$gnutls_withval"; then
1072                         GNUTLS_PATH="$gnutls_withval:$GNUTLS_PATH"
1073                 fi
1074
1075                 AC_PATH_PROG(LIBGNUTLS_CONFIG, libgnutls-config, no, $GNUTLS_PATH)
1076
1077                 if test "$LIBGNUTLS_CONFIG" = "no" ; then
1078                         cf_result=no
1079                 else
1080                         GNUTLS_CFLAGS=`$LIBGNUTLS_CONFIG --cflags`
1081                         GNUTLS_LIBS=`$LIBGNUTLS_CONFIG --libs`
1082
1083                         LIBS="$GNUTLS_LIBS $LIBS_X"
1084                         CFLAGS="$CFLAGS_X $GNUTLS_CFLAGS"
1085                         CPPFLAGS="$CPPFLAGS_X $GNUTLS_CFLAGS"
1086
1087                         # Verify if it's really usable.  gnutls_session was
1088                         # renamed to gnutls_session_t before GNU TLS 1.2.0
1089                         # (on 2004-06-13); ELinks now requires this.
1090                         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <gnutls/gnutls.h>]], [[gnutls_session_t dummy;
1091                                      gnutls_check_version(NULL)]])],[cf_result=yes],[cf_result=no])
1092                 fi
1093
1094                 if test "$cf_result" = yes; then
1095                         EL_CONFIG(CONFIG_GNUTLS, [GNUTLS])
1096
1097                         CFLAGS="$CFLAGS_X"
1098                         AC_SUBST(GNUTLS_CFLAGS)
1099
1100                         # GnuTLS 2.2.0 changed libgnutls-openssl from GPLv2+
1101                         # to GPLv3+.  Don't link that with the GPLv2 ELinks.
1102                         # ELinks will use its internal MD5 code instead.
1103                         CONFIG_GNUTLS_OPENSSL_COMPAT=no
1104                 else
1105                         if test -n "$gnutls_withval" && test "x$gnutls_withval" != xno; then
1106                                 AC_MSG_ERROR([GNUTLS (1.2 or later) not found.  ELinks no longer supports GNUTLS 1.1.])
1107                         fi
1108                         EL_RESTORE_FLAGS
1109                 fi
1110         fi
1111 fi
1112
1113 AC_MSG_CHECKING([for GNU TLS (1.2 or later)])
1114 AC_MSG_RESULT($cf_result)
1115
1116 # Final SSL setup
1117
1118 EL_CONFIG_DEPENDS(CONFIG_SSL, [CONFIG_OPENSSL CONFIG_GNUTLS], [SSL])
1119 AC_SUBST(CONFIG_GNUTLS_OPENSSL_COMPAT)
1120 AC_SUBST(CONFIG_OPENSSL)
1121 AC_SUBST(CONFIG_GNUTLS)
1122
1123 #endif
1124
1125 AC_MSG_CHECKING([whether to be or not to be])
1126 AC_MSG_RESULT([needs to be determined experimentally])
1127
1128 # ===================================================================
1129 # Check for IPv6 support and related functions.
1130 # ===================================================================
1131
1132 EL_CHECK_NET_TYPE(struct sockaddr_storage, HAVE_SA_STORAGE, [])
1133 EL_CHECK_NET_TYPE(struct sockaddr_in6, HAVE_SA_IN6, [#include <netinet/in.h>])
1134 EL_CHECK_NET_TYPE(struct addrinfo, HAVE_ADDRINFO, [#include <netdb.h>])
1135
1136 AC_CHECK_FUNC(getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1137 if test "$HAVE_GETADDRINFO" != yes; then
1138         AC_CHECK_LIB(inet6, getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1139         if test "$HAVE_GETADDRINFO" = yes; then
1140                 LIBS="$LIBS -linet6"
1141         fi
1142 fi
1143
1144
1145 # ===================================================================
1146 # Checking for X11 (window title restoring).
1147 # ===================================================================
1148
1149 AC_PATH_X
1150 if test x"$no_x" != xyes; then
1151         EL_SAVE_FLAGS
1152         if test -n "$x_includes"; then
1153                 X_CFLAGS="-I$x_includes"
1154                 CPPFLAGS="$CPPLAGS $X_CFLAGS"
1155                 CFLAGS="$CFLAGS $X_CFLAGS"
1156         fi
1157         if test -n "$x_libraries"; then
1158                 LDFLAGS="$LDFLAGS -L$x_libraries"
1159         fi
1160         LIBS="-lX11 $LIBS"
1161         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]], [[XrmInitialize()]])],[cf_result=yes],[cf_result=no])
1162         EL_RESTORE_FLAGS
1163         if test "$cf_result" = yes; then
1164                 if test -n "$x_libraries"; then
1165                         LDFLAGS="$LDFLAGS -L$x_libraries"
1166                 fi
1167                 LIBS="-lX11 $LIBS"
1168                 EL_DEFINE(HAVE_X11, [X11 for restoring window titles])
1169                 AC_SUBST(X_CFLAGS)
1170         fi
1171 fi
1172
1173
1174 # ===================================================================
1175 # Backtraces displaying support.
1176 # ===================================================================
1177
1178 AC_CHECK_HEADERS(execinfo.h, HAVE_EXECINFO=yes, HAVE_EXECINFO=no)
1179 # possible checks for other system-specific means go here
1180
1181
1182 # ===================================================================
1183 # Gettext grey zone. Beware.
1184 # ===================================================================
1185
1186 ALL_LINGUAS="af be bg ca cs da de el es et fi fr gl hr hu id is it lt nl nb pl pt pt_BR ro ru sk sr sv tr uk"
1187
1188 AM_GNU_GETTEXT
1189
1190 dnl AC_MSG_CHECKING([how many characters your English alphabet has])
1191 dnl # f33r d4 l33t... I hope it's portable. :)
1192 dnl cf_result=$((48#z - 48#a + 1));
1193 dnl AC_MSG_RESULT($cf_result)
1194
1195
1196 # ===================================================================
1197 # Compile-time features control
1198 # ===================================================================
1199
1200 EL_ARG_ENABLE(CONFIG_COOKIES, cookies, [Cookies],
1201               [  --disable-cookies       disable cookie support])
1202
1203 EL_ARG_ENABLE(CONFIG_FORMHIST, formhist, [Form history],
1204               [  --disable-formhist      disable form history support])
1205
1206 EL_ARG_ENABLE(CONFIG_GLOBHIST, globhist, [Global history],
1207               [  --disable-globhist      disable global history support])
1208
1209
1210 EL_ARG_ENABLE(CONFIG_MAILCAP, mailcap, [Mailcap],
1211               [  --disable-mailcap       disable mailcap support])
1212
1213 EL_ARG_ENABLE(CONFIG_MIMETYPES, mimetypes, [Mimetypes files],
1214               [  --disable-mimetypes     disable mimetypes files support])
1215
1216
1217 EL_ARG_DEPEND(CONFIG_IPV6, ipv6,
1218               [HAVE_SA_STORAGE:yes HAVE_SA_IN6:yes HAVE_ADDRINFO:yes HAVE_GETADDRINFO:yes],
1219               [IPv6],
1220               [  --disable-ipv6          disable IPv6 support])
1221
1222 EL_ARG_ENABLE(CONFIG_BITTORRENT, bittorrent, [BitTorrent protocol],
1223               [  --enable-bittorrent     enable BitTorrent protocol support])
1224
1225 EL_ARG_ENABLE(CONFIG_DATA, data, [Data protocol],
1226               [  --disable-data          disable data protocol support])
1227
1228 EL_ARG_ENABLE(CONFIG_URI_REWRITE, uri-rewrite, [URI rewriting],
1229               [  --disable-uri-rewrite   disable URI rewrite support])
1230
1231 EL_ARG_DEPEND(CONFIG_CGI, cgi, [HAVE_SETENV_OR_PUTENV:yes], [Local CGI],
1232               [  --enable-cgi            enable local CGI support])
1233
1234 EL_ARG_ENABLE(CONFIG_FINGER, finger, [Finger protocol],
1235               [  --enable-finger         enable finger protocol support])
1236
1237 # ===================================================================
1238 # FSP protocol
1239 # ===================================================================
1240 EL_SAVE_FLAGS
1241
1242 if test "x${enable_fsp}" != xno; then
1243         AC_CHECK_HEADERS(fsplib.h, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1244
1245         if test "$HAVE_FSPLIB" = yes; then
1246                 AC_CHECK_LIB(fsplib, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1247                 if test "$HAVE_FSPLIB" = yes; then
1248                         LIBS="$LIBS -lfsplib"
1249                 else
1250                         AC_CHECK_LIB(fsp, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1251                         if test "$HAVE_FSPLIB" = yes; then
1252                                 LIBS="$LIBS -lfsp"
1253                         fi
1254                 fi
1255         fi
1256 fi
1257
1258 EL_ARG_DEPEND(CONFIG_FSP, fsp, [HAVE_FSPLIB:yes], [FSP protocol],
1259               [  --enable-fsp            enable FSP protocol support])
1260
1261 if test "x$CONFIG_FSP" = xno; then
1262         EL_RESTORE_FLAGS
1263 fi
1264
1265 EL_ARG_ENABLE(CONFIG_FTP, ftp, [FTP protocol],
1266               [  --disable-ftp           disable ftp protocol support])
1267
1268 EL_ARG_ENABLE(CONFIG_GOPHER, gopher, [Gopher protocol],
1269               [  --enable-gopher         enable gopher protocol support])
1270
1271 EL_ARG_ENABLE(CONFIG_NNTP, nntp, [NNTP protocol],
1272               [  --enable-nntp           enable nntp protocol support])
1273
1274 # ===================================================================
1275 # SMB protocol support.
1276 # ===================================================================
1277 EL_SAVE_FLAGS
1278
1279 if test "x${enable_smb}" != xno; then
1280         AC_CHECK_HEADERS(libsmbclient.h, HAVE_SMBCLIENT=yes, HAVE_SMBCLIENT=no)
1281
1282         if test "$HAVE_SMBCLIENT" = yes; then
1283                 AC_CHECK_LIB(smbclient, smbc_init, HAVE_SMBCLIENT=yes, HAVE_SMBCLIENT=no)
1284                 if test "$HAVE_SMBCLIENT" = yes; then
1285                         LIBS="$LIBS -lsmbclient"
1286                 fi
1287         fi
1288 fi
1289
1290 EL_ARG_DEPEND(CONFIG_SMB, smb, [HAVE_SMBCLIENT:yes], [Samba protocol],
1291               [  --enable-smb            enable Samba protocol support])
1292
1293 if test "x$CONFIG_SMB" = xno; then
1294         EL_RESTORE_FLAGS
1295 fi
1296
1297
1298 EL_ARG_ENABLE(CONFIG_MOUSE, mouse, [Mouse handling],
1299               [  --disable-mouse         disable mouse support])
1300
1301 # GPM mouse is Linux specific, so ...
1302 CONFIG_SYSMOUSE=yes
1303 EL_ARG_DEPEND(CONFIG_SYSMOUSE, sysmouse,
1304               [CONFIG_MOUSE:yes CONFIG_GPM:no HAVE_SYSMOUSE_HEADER:yes],
1305               [BSD sysmouse],
1306               [  --disable-sysmouse      disable BSD sysmouse support])
1307
1308 EL_ARG_ENABLE(CONFIG_88_COLORS, 88-colors, [88 colors],
1309               [  --enable-88-colors      enable 88 color support])
1310
1311 EL_ARG_ENABLE(CONFIG_256_COLORS, 256-colors, [256 colors],
1312               [  --enable-256-colors     enable 256 color support])
1313
1314 EL_ARG_ENABLE(CONFIG_TRUE_COLOR, true-color, [true color],
1315               [  --enable-true-color     enable true color support])
1316
1317 EL_ARG_ENABLE(CONFIG_EXMODE, exmode, [Exmode interface],
1318               [  --enable-exmode         enable exmode (CLI) interface])
1319
1320 EL_ARG_ENABLE(CONFIG_LEDS, leds, [LEDs],
1321               [  --disable-leds          disable LEDs support])
1322
1323 EL_ARG_ENABLE(CONFIG_MARKS, marks, [Marks],
1324               [  --disable-marks         disable document marks support])
1325
1326
1327 EL_ARG_ENABLE(CONFIG_CSS, css, [Cascading Style Sheets],
1328               [  --disable-css           disable Cascading Style Sheet support])
1329
1330 EL_ARG_DEPEND(CONFIG_HTML_HIGHLIGHT, html-highlight, [CONFIG_CSS:yes], [HTML highlighting],
1331               [  --enable-html-highlight HTML highlighting using DOM engine])
1332
1333 # Everything in the tree already uses CONFIG_DOM
1334 # so resolve CONFIG_HTML_HIGHLIGHT to CONFIG_DOM
1335 EL_CONFIG_DEPENDS(CONFIG_DOM, [CONFIG_HTML_HIGHLIGHT], [DOM engine])
1336
1337 EL_ARG_DEPEND(CONFIG_BACKTRACE, backtrace, [HAVE_EXECINFO:yes], [Backtrace],
1338               [  --disable-backtrace     disable backtrace support])
1339
1340 EL_ARG_DEPEND(CONFIG_NO_ROOT_EXEC, no-root, [HAVE_GETUID:yes HAVE_GETEUID:yes], [No root exec],
1341               [  --enable-no-root        enable prevention of usage by root])
1342
1343
1344 EL_ARG_ENABLE(CONFIG_DEBUG, debug, [Debug mode],
1345               [  --enable-debug          enable leak debug and internal error checking])
1346
1347 EL_ARG_DEPEND(CONFIG_FASTMEM, fastmem, [CONFIG_DEBUG:no], [Fast mode],
1348               [  --enable-fastmem        enable direct use of system allocation functions, not usable with --enable-debug])
1349
1350 EL_ARG_ENABLE(CONFIG_OWN_LIBC, own-libc, [Own libc stubs],
1351               [  --enable-own-libc       force use of internal functions instead of those of system libc])
1352
1353 EL_ARG_ENABLE(CONFIG_SMALL, small, [Small binary],
1354               [  --enable-small          reduce binary size as far as possible (but see the bottom of doc/small.txt!)])
1355
1356 EL_ARG_ENABLE(CONFIG_UTF8, utf-8, [UTF-8],
1357               [  --disable-utf-8         disable UTF-8 support])
1358
1359
1360 AC_ARG_ENABLE(weehoofooboomookerchoo,
1361               [
1362     Also check out the features.conf file for more information about features!
1363               ],
1364               [AC_MSG_ERROR(Are you strange, or what?)])
1365
1366
1367 # ===================================================================
1368 # Further LDFLAGS tweaks
1369 # ===================================================================
1370
1371 # == EMX hack
1372
1373 test "$CONFIG_OS_OS2" = yes && LDFLAGS="$LDFLAGS -Zexe"
1374 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zbin-files//g"`
1375
1376
1377 # Check for -rdynamic
1378 #
1379 # gcc -rdynamic calls ld -export-dynamic, which adds all symbols of
1380 # the executable to its dynamic symbol table.  ELinks uses this for
1381 # two purposes:
1382 #
1383 # 1. If ELinks detects a bug, it can try to display a backtrace by
1384 #    calling backtrace_symbols_fd() in the GNU libc.  The glibc-2.3.6
1385 #    manual states users of GNU ld must pass -rdynamic to make the
1386 #    symbols available to the program.
1387 #
1388 # 2. It would eventually be nice to dynamically load shared
1389 #    libraries as plugins (bug 73).  The plugins must be able to
1390 #    call ELinks functions.  This can be implemented either by
1391 #    registering all callable functions in ELinks-specific data
1392 #    structures, or by letting the dynamic linker handle them.
1393 #    The latter way requires something equivalent to -rdynamic.
1394 #
1395 # Because backtraces are not needed for correct operation, and bug
1396 # 73 is not yet being fixed, the configure script and makefiles
1397 # should not complain to the user if they find that -rdynamic does
1398 # not work.  Besides, it was reported at elinks-users on 2006-09-12
1399 # that gcc-3.4.2 with "ld: Software Generation Utilities - Solaris
1400 # Link Editors: 5.8-1.284" on Sun Solaris 8 Sparc does not support
1401 # -rdynamic but does something equivalent automatically.  (This was
1402 # tested with "nm -D elinks | grep redraw_from_window".)
1403 #
1404 # With Sun Studio 11 on Solaris 9, we get "cc: Warning: illegal option
1405 # -dynamic"; then, cc proceeds anyway, but the option can prevent the
1406 # linker from finding the libraries listed in -l operands.  So this
1407 # -rdynamic check needs to happen after the libraries have already
1408 # been added to $LDFLAGS.
1409 AC_MSG_CHECKING([for -rdynamic])
1410 LDFLAGS_X="$LDFLAGS"
1411 LDFLAGS="-rdynamic $LDFLAGS"
1412 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[]])],[have_rdynamic=yes],[have_rdynamic=no])
1413 test "$have_rdynamic" = no && LDFLAGS="$LDFLAGS_X"
1414 AC_MSG_RESULT($have_rdynamic)
1415
1416 # ===================================================================
1417 # Export directory paths
1418 # ===================================================================
1419
1420 # Set up the ``entry points'' if they were not supplied by builder
1421 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1422 test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1423
1424 # Create CONFDIR #define for config.h
1425
1426 # XXX: This may be dependent on a particular version of autoconf. Whatever,
1427 # it's autoconf fault to force us to do such hacks ;p.
1428 if test x"$sysconfdir" = x"\${prefix}/etc"; then
1429   # sysconfdir is set to its default value... fine, let's append /elinks/
1430   # XXX: We can't modify listing of the default in ./configure --help :-(
1431   sysconfdir_n=`eval echo "$sysconfdir"`
1432   sysconfdir=$sysconfdir_n
1433   (echo "$sysconfdir" | grep elinks >/dev/null 2>/dev/null) || \
1434         sysconfdir="$sysconfdir/elinks"
1435 fi
1436
1437 CONFDIR=$sysconfdir
1438 AC_DEFINE_UNQUOTED(CONFDIR, "$CONFDIR", [Directory containing default config])
1439 AC_SUBST(CONFDIR)
1440
1441 # Create LOCALEDIR #define for config.h
1442 LOCALEDIR=`eval echo "$datadir/locale"`
1443 while echo "$LOCALEDIR" | grep "\\$"
1444 do
1445         LOCALEDIR=`eval echo "$LOCALEDIR"`
1446 done > /dev/null 2> /dev/null
1447 AC_DEFINE_UNQUOTED(LOCALEDIR, "$LOCALEDIR", [Directory containing locales])
1448 AC_SUBST(LOCALEDIR)
1449
1450 # Create LIBDIR #define for config.h
1451 LIBDIR=`eval echo "$libdir"`
1452 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [Directory containing libraries])
1453 AC_SUBST(LIBDIR)
1454
1455 EL_LOG_CONFIG(CONFDIR, [System configuration directory], [])
1456 EL_LOG_CONFIG(LOCALEDIR, [Locale catalogs directory], [])
1457
1458
1459 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stddef.h>
1460 ]], [[#if !defined(__TINYC__) || !defined(alloca)
1461         #error not tcc
1462         #endif ]])],[cf_result=yes],[cf_result=no])
1463
1464 if test "$cf_result" = "yes"; then
1465         AC_DEFINE([HAVE_ALLOCA])
1466         AC_DEFINE([_ALLOCA_H], [1], [Define as 1 if you are using Tiny C Compiler
1467                 with the GNU C Library, and <alloca.h> of glibc would otherwise
1468                 override the alloca macro defined in <stddef.h> of TCC.
1469                 If <alloca.h> of glibc sees the _ALLOCA_H macro, it assumes
1470                 it has already been included, and does not redefine alloca.
1471                 This might not work in future glibc versions though, because
1472                 the names of the #include guard macros are not documented.
1473                 The incompatibility has been reported to the tinycc-devel
1474                 mailing list on 2008-07-14.  If a future version of TCC provides
1475                 an <alloca.h> of its own, this hack won't be needed.])
1476 fi
1477 # ===================================================================
1478 # A little fine tuning of gcc specific options (continued)
1479 # ===================================================================
1480
1481 if test "x$ac_cv_c_compiler_gnu" = "xyes"; then
1482   if test "$CONFIG_DEBUG" = "yes"; then
1483     # We want to see all warnings and live with none (in debug mode).
1484     CFLAGS="$CFLAGS -Werror"
1485   fi
1486
1487   case "`$CC -dumpversion`" in
1488     3.0|3.1|3.2)
1489       # These should be ok using -Werror
1490       ;;
1491     3.*)
1492       # If gcc is version 3.3 (or higher?) it emits lots of false positive
1493       # "dereferencing type-punned pointer will break strict-aliasing rules"
1494       # warnings. Disable them by not doing any strict-aliasing. The
1495       # alternative is just too ugly. Thanks gcc guys!! ;)
1496       CFLAGS="$CFLAGS -fno-strict-aliasing"
1497       ;;
1498     4.*)
1499       # Do not show warnings related to (char * | unsigned char *) type
1500       # difference.
1501       CFLAGS="$CFLAGS -fno-strict-aliasing -Wno-pointer-sign"
1502       ;;
1503     *)
1504       # These should be ok using -Werror
1505       ;;
1506   esac
1507
1508   # GCC 4.2.1 warns if we use the address of an object in Boolean context:
1509   # warning: the address of `builtin_modules' will always evaluate as `true'
1510   # This hits the object_lock and foreach_module macros in particular.
1511   # It would be okay to put something in the macros to avoid the warning,
1512   # but currently this seems to require defining parallel macros that skip
1513   # the NULL check, and that's too ugly.  So we instead disable the warning.
1514   # GCC 4.2.1 needs -Wno-address, but GCC 4.2 snapshots need -Wno-always-true.
1515   # GCC 4.1.3 recognizes neither and exits with code 1 if they are given.
1516   for warning_flag in -Wno-address -Wno-always-true; do
1517     AC_MSG_CHECKING([whether $CC accepts $warning_flag])
1518     EL_SAVE_FLAGS
1519     CFLAGS="$CFLAGS $warning_flag"
1520     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1521       [AC_MSG_RESULT([yes])
1522        break],
1523       [AC_MSG_RESULT([no])])
1524     EL_RESTORE_FLAGS
1525   done
1526
1527   # Bug 1012: Some parts of ELinks do arithmetic with signed integers
1528   # in such a way that an overflow is possible.  GCC 4.2.1 warns
1529   # "warning: assuming signed overflow does not occur when assuming
1530   # that (X + c) > X is always true", which may be an incorrect
1531   # optimization (although allowed by the standard), and breaks the
1532   # build with -Werror.
1533   #
1534   # All of the following tests included -S -Wall -Wextra:
1535   #
1536   # GCC: (GNU) 4.0.4 20060507 (prerelease) (Debian 4.0.3-3)
1537   # * gcc-4.0 -O0: OK, compares the values
1538   # * gcc-4.0 -O2: assumes no overflow, does not warn
1539   # * gcc-4.0 -O0 -fno-strict-overflow: unrecognized command line option
1540   # * gcc-4.0 -O0 -fwrapv: OK, compares the values
1541   # * gcc-4.0 -O2 -fwrapv: OK, compares the values
1542   # * gcc-4.0 -O0 -ftrapv: OK, calls __addvsi3
1543   # * gcc-4.0 -O2 -ftrapv: assumes no overflow, does not warn
1544   # * gcc-4.0 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1545   # * gcc-4.0 -O2 -fwrapv -ftrapv: compares the values
1546   #
1547   # GCC: (GNU) 4.1.3 20070812 (prerelease) (Debian 4.1.2-15)
1548   # * gcc-4.1 -O0: assumes no overflow, does not warn
1549   # * gcc-4.1 -O2: assumes no overflow, does not warn
1550   # * gcc-4.1 -O0 -fno-strict-overflow: unrecognized command line option
1551   # * gcc-4.1 -O0 -fwrapv: OK, compares the values
1552   # * gcc-4.1 -O2 -fwrapv: OK, compares the values
1553   # * gcc-4.1 -O0 -ftrapv: OK, calls __addvsi3
1554   # * gcc-4.1 -O2 -ftrapv: compares the values
1555   # * gcc-4.1 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1556   # * gcc-4.1 -O2 -fwrapv -ftrapv: compares the values
1557   #
1558   # GCC: (GNU) 4.2.1 (Debian 4.2.1-5)
1559   # * gcc-4.2 -O0: OK, compares the values
1560   # * gcc-4.2 -O2: assumes no overflow, warns about it
1561   # * gcc-4.2 -O0 -fno-strict-overflow: OK, compares the values
1562   # * gcc-4.2 -O2 -fno-strict-overflow: OK, compares the values
1563   # * gcc-4.2 -O0 -fwrapv: OK, compares the values
1564   # * gcc-4.2 -O2 -fwrapv: OK, compares the values
1565   # * gcc-4.2 -O0 -ftrapv: OK, calls __addvsi3
1566   # * gcc-4.2 -O2 -ftrapv: compares the values
1567   # * gcc-4.2 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1568   # * gcc-4.2 -O2 -fwrapv -ftrapv: compares the values
1569   #
1570   # Apparently, -ftrapv does not work reliably at all.
1571   for overflow_flag in -fno-strict-overflow -fwrapv; do
1572     AC_MSG_CHECKING([whether $CC accepts $overflow_flag])
1573     EL_SAVE_FLAGS
1574     CFLAGS="$CFLAGS $overflow_flag"
1575     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1576       [AC_MSG_RESULT([yes])
1577        break],
1578       [AC_MSG_RESULT([no])])
1579     EL_RESTORE_FLAGS
1580   done
1581 fi
1582
1583 EL_LOG_CONFIG(CFLAGS, [Compiler flags (CFLAGS)], [])
1584 EL_LOG_CONFIG(CPPFLAGS, [Preprocessor flags (CPPFLAGS)], [])
1585 EL_LOG_CONFIG(LDFLAGS, [Linker flags (LDFLAGS)], [])
1586 EL_LOG_CONFIG(LIBS, [Library flags (LIBS)], [])
1587
1588 # ===================================================================
1589 # Colored make output
1590 # ===================================================================
1591
1592 if test $(`which tput` colors) -ge 4; then
1593         MAKE_COLOR=1
1594         AC_SUBST(MAKE_COLOR)
1595 fi
1596
1597 # ===================================================================
1598 # Generated files
1599 # ===================================================================
1600
1601 AC_CONFIG_FILES([ \
1602  Makefile.config \
1603  contrib/elinks.spec \
1604  contrib/lua/hooks.lua \
1605  contrib/conv/w3m2links.awk \
1606  doc/Doxyfile \
1607  doc/man/man1/elinks.1 \
1608  src/intl/gettext/ref-add.sed \
1609  src/intl/gettext/ref-del.sed
1610 ])
1611 AC_OUTPUT
1612
1613 abs_srcdir="$(cd "$srcdir" && pwd)"
1614 # builddir is always absolute!
1615 if test "$abs_srcdir" != "$builddir"; then
1616         # Bootstrap the Makefile creation
1617         echo "include $abs_srcdir/Makefile" > "$builddir/Makefile"
1618         "$MAKE" "SRC=$abs_srcdir" init
1619
1620         # Make cg-status ignore this build directory
1621         echo "*" > "$builddir/.gitignore"
1622 fi
1623
1624 # ===================================================================
1625 # Configuration summary
1626 # ===================================================================
1627
1628 AC_MSG_RESULT(The following feature summary has been saved to features.log)
1629 cat features.log