configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl There are two types of comments in this file.
   4 dnl Comments that refer to Autoconf macros begin with "dnl", and m4
   5 dnl discards them.  Other comments begin with "#", and they get copied
   6 dnl to the configure script, hopefully making it easier to read.
   7
   8 dnl Autoconf 2.13 generates an incomplete config.h.in; see ELinks bug 936.
   9 dnl Autoconf 2.61 is installed in the computer that generates our nightly
  10 dnl snapshots, so we need to be compatible with that.  (Also, some files
  11 dnl in Autoconf 2.62 and 2.63 sources are not GPLv2 compatible.)
  12 AC_PREREQ(2.61)
  13 AC_INIT
  14 AC_CONFIG_SRCDIR([src/main/main.c])
  15 AC_CONFIG_AUX_DIR(config)
  16
  17 PACKAGE=elinks
  18 VERSION=0.13.GIT
  19 AC_SUBST(PACKAGE)
  20 AC_SUBST(VERSION)
  21 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Package version])
  22 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Package version])
  23 AC_CONFIG_HEADERS(config.h)
  24
  25 AC_CHECK_PROG(ACLOCAL,[aclocal],[aclocal],[config/missing aclocal])
  26 AC_CHECK_PROG(AUTOCONF,[autoconf],[autoconf],[config/missing autoconf])
  27 AC_CHECK_PROG(AUTOHEADER,[autoheader],[autoheader],[config/missing autoheader])
  28
  29 MAKE=
  30
  31 for make in gnumake gmake make false; do
  32         if test "x$MAKE" = x; then
  33                 AC_PATH_PROGS(MAKE, "$make")
  34         fi
  35 done
  36
  37 builddir="`pwd`"
  38
  39 # Cleanup if we are configuring with a previous build in the tree
  40 if test -e Makefile.config; then
  41         AC_MSG_CHECKING([for previous build to clean])
  42         "$MAKE" -C "$builddir/src" cleanall >/dev/null 2>/dev/null
  43         AC_MSG_RESULT(done)
  44 fi
  45
  46 # ===================================================================
  47 # Load feature configuration file and start logging features.
  48 # ===================================================================
  49
  50 features="features.conf"
  51 test -f "$srcdir/$features" && . "$srcdir/$features"
  52 test -f "$builddir/$features" && . "$builddir/$features"
  53 echo "Feature summary:" > features.log
  54
  55 # ===================================================================
  56 # Checks for programs.
  57 # ===================================================================
  58
  59 AC_PROG_CC
  60 AC_CHECK_TOOL([LD], [ld])
  61 AC_PROG_AWK
  62 AC_PATH_PROGS(AWK, "$AWK")
  63 AC_PROG_RANLIB
  64 AC_PROG_INSTALL
  65
  66 AC_PATH_PROGS(GIT, "git")
  67 AC_PATH_PROGS(SPARSE, "sparse")
  68
  69 CONFIG_ASCIIDOC="no"
  70 CONFIG_POD2HTML="no"
  71 CONFIG_XMLTO="no"
  72 CONFIG_JW="no"
  73
  74 if test "x$CONFIG_DOC" != xno; then
  75         AC_PATH_PROGS(PYTHON, "python")
  76         if test "x$PYTHON" != "x"; then
  77                 EL_CONFIG(CONFIG_ASCIIDOC, [AsciiDoc])
  78                 EL_CONFIG(MANUAL_ASCIIDOC, [HTML (one file)])
  79                 EL_CONFIG(MAN_ASCIIDOC, [HTML])
  80         fi
  81
  82         AC_PATH_PROGS(XMLTO, "xmlto")
  83         if test "x$XMLTO" != "x"; then
  84                 EL_CONFIG(CONFIG_XMLTO, [XmlTo])
  85                 EL_CONFIG(MANUAL_XMLTO, [HTML (multiple files)])
  86                 EL_CONFIG(MAN_XMLTO, [man (groff)])
  87         fi
  88
  89         AC_PATH_PROGS(JW, "jw")
  90         if test "x$JW" != "x"; then
  91                 EL_CONFIG(CONFIG_JW, [JadeWrapper])
  92                 EL_CONFIG(MANUAL_JW, [PDF])
  93         fi
  94
  95         AC_PATH_PROGS(POD2HTML, "pod2html")
  96         if test "x$POD2HTML" != "x"; then
  97                 EL_CONFIG(CONFIG_POD2HTML, [Pod2HTML])
  98         fi
  99
 100         AC_PATH_PROGS(DOXYGEN, "doxygen")
 101         if test "x$DOXYGEN" != "x"; then
 102                 EL_CONFIG(CONFIG_DOXYGEN, [Doxygen])
 103                 api_srcdir="$(cd "$srcdir" && pwd)/src"
 104                 AC_SUBST(api_srcdir)
 105         fi
 106 fi
 107
 108 AC_SUBST(CONFIG_ASCIIDOC)
 109 AC_SUBST(CONFIG_DOXYGEN)
 110 AC_SUBST(CONFIG_POD2HTML)
 111 AC_SUBST(CONFIG_XMLTO)
 112 AC_SUBST(CONFIG_JW)
 113
 114 EL_CONFIG_DEPENDS(CONFIG_DOC, [CONFIG_ASCIIDOC CONFIG_XMLTO CONFIG_JW CONFIG_POD2HTML], [Documentation Tools])
 115 EL_CONFIG_DEPENDS(CONFIG_MANUAL, [MANUAL_ASCIIDOC MANUAL_XMLTO MANUAL_JW], [Manual Formats])
 116 EL_CONFIG_DEPENDS(CONFIG_MANPAGE, [MAN_ASCIIDOC MAN_XMLTO], [Man Page Formats])
 117 EL_CONFIG_DEPENDS(CONFIG_APIDOCS, [CONFIG_DOXYGEN], [API Documentation])
 118
 119 # gcc specific options (to be continued at the bottom of configure)
 120 if test "x$ac_cv_c_compiler_gnu" = "xyes"; then
 121   # We want to see all warnings and live with none.
 122   # We can't set up -Werror here as there may be some warnings in test
 123   # suite of configure, and we don't want to fail them.
 124   CFLAGS="$CFLAGS -Wall"
 125 fi
 126
 127 # ===================================================================
 128 # Checks for special OSes.
 129 # ===================================================================
 130
 131 dnl EL_CHECK_COMPILER_MACRO(define, name, flagname)
 132 AC_DEFUN([EL_CHECK_COMPILER_MACROS],
 133 [
 134         AC_MSG_CHECKING([for $2])
 135
 136         for flag in $3; do
 137                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[#ifndef $flag
 138 kill me!
 139 #endif ]])],[$1=yes],[$1=no])
 140                 if test "[$]$1" = yes; then
 141                         EL_CONFIG([$1], [$2])
 142                         break
 143                 fi
 144         done
 145
 146         AC_MSG_RESULT([$]$1)
 147 ])
 148
 149 EL_CHECK_COMPILER_MACROS(CONFIG_OS_BEOS, [BEOS], [__BEOS__])
 150 AC_SUBST(CONFIG_OS_BEOS)
 151
 152 EL_CHECK_COMPILER_MACROS(CONFIG_OS_RISCOS, [RISCOS], [__riscos__])
 153 AC_SUBST(CONFIG_OS_RISCOS)
 154
 155 EL_CHECK_COMPILER_MACROS(CONFIG_OS_WIN32, [WIN32], [_WIN32 __WIN32__])
 156 AC_SUBST(CONFIG_OS_WIN32)
 157
 158 EL_CHECK_COMPILER_MACROS(CONFIG_OS_OS2, [EMX], [__EMX__])
 159 AC_SUBST(CONFIG_OS_OS2)
 160 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zexe//g"`
 161
 162 AC_MSG_CHECKING([for UNIX])
 163 dnl FIXME: some depend kind of mechanism
 164 if test "$CONFIG_OS_BEOS" = no && \
 165    test "$CONFIG_OS_RISCOS" = no && \
 166    test "$CONFIG_OS_WIN32" = no && \
 167    test "$CONFIG_OS_OS2" = no; then
 168         EL_CONFIG(CONFIG_OS_UNIX, [UNIX])
 169 else
 170         CONFIG_OS_UNIX=no
 171 fi
 172 AC_MSG_RESULT($CONFIG_OS_UNIX)
 173 AC_SUBST(CONFIG_OS_UNIX)
 174
 175 # ===================================================================
 176 # Checks for header files.
 177 # ===================================================================
 178
 179 AC_HEADER_DIRENT
 180 AC_HEADER_STDC
 181 AC_HEADER_SYS_WAIT
 182 AC_HEADER_TIME
 183
 184 AC_CHECK_HEADERS(wchar.h wctype.h)
 185 AC_CHECK_HEADERS(fcntl.h limits.h time.h unistd.h)
 186 AC_CHECK_HEADERS(sigaction.h)
 187 AC_CHECK_HEADERS(arpa/inet.h)
 188 AC_CHECK_HEADERS(netinet/in_systm.h netinet/in_system.h netinet/ip.h)
 189 AC_CHECK_HEADERS(netdb.h netinet/in.h netinet/in6_var.h)
 190 AC_CHECK_HEADERS(ifaddrs.h)
 191 AC_CHECK_HEADERS(sys/cygwin.h io.h)
 192 AC_CHECK_HEADERS(sys/fmutex.h)
 193 AC_CHECK_HEADERS(sys/ioctl.h sys/sockio.h)
 194 AC_CHECK_HEADERS(sys/resource.h)
 195 AC_CHECK_HEADERS(sys/select.h)
 196 AC_CHECK_HEADERS(sys/signal.h)
 197 AC_CHECK_HEADERS(sys/socket.h)
 198 AC_CHECK_HEADERS(sys/time.h)
 199 AC_CHECK_HEADERS(sys/utsname.h)
 200 AC_CHECK_HEADERS([net/if.h], [], [],
 201 [[#ifdef HAVE_SYS_SOCKET_H
 202 # include <sys/socket.h> /* <net/if.h> on Mac OS X 10.5.4 needs this */
 203 #endif
 204 ]])
 205 AC_CHECK_HEADERS(stdint.h inttypes.h)
 206 AC_CHECK_HEADERS(locale.h pwd.h)
 207 AC_CHECK_HEADERS(termios.h)
 208
 209
 210 AC_CHECK_HEADERS(sys/un.h,
 211         [CONFIG_INTERLINK=yes
 212          EL_CONFIG([CONFIG_INTERLINK], [interlinking])],
 213         [CONFIG_INTERLINK=no])
 214 AC_SUBST(CONFIG_INTERLINK)
 215
 216 # ===================================================================
 217 # Checks for typedefs, structures, and compiler characteristics.
 218 # ===================================================================
 219
 220 AC_STRUCT_TM
 221 AC_C_CONST
 222 AC_C_INLINE
 223 AC_MSG_CHECKING([[for C99-conforming inline]])
 224 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 225         int add(int change);
 226
 227         static int sum;
 228
 229         inline int
 230         add(int change)
 231         {
 232                 sum += change;
 233                 return sum;
 234         }
 235
 236         int
 237         sub(int change)
 238         {
 239                 return add(-change);
 240         }]])],
 241         [AC_MSG_RESULT([[yes]])
 242          AC_DEFINE([NONSTATIC_INLINE], [inline],
 243                 [Define as inline if the compiler lets you declare a function without inline, then define it with inline, and have that definition refer to identifiers with internal linkage.  This is allowed by C99 6.7.4p6 and 6.7.4p3 together.  Otherwise define as nothing.])],
 244         [AC_MSG_RESULT([[no]])
 245          AC_DEFINE([NONSTATIC_INLINE], [])])
 246 EL_CHECK_CODE(typeof, HAVE_TYPEOF, [], [int a; typeof(a) b;])
 247
 248 AC_SYS_LARGEFILE
 249 AC_TYPE_SIZE_T
 250 AC_TYPE_OFF_T
 251 EL_CHECK_TYPE(ssize_t, int)
 252 EL_CHECK_SYS_TYPE(long long, HAVE_LONG_LONG, [])
 253 EL_CHECK_SYS_TYPE(off_t, HAVE_OFF_T, [])
 254 EL_CHECK_INT_TYPE(int32_t, HAVE_INT32_T)
 255 EL_CHECK_INT_TYPE(uint32_t, HAVE_UINT32_T)
 256 EL_CHECK_INT_TYPE(uint16_t, HAVE_UINT16_T)
 257
 258 AC_CHECK_SIZEOF(char, 1)
 259 AC_CHECK_SIZEOF(short, 2)
 260 AC_CHECK_SIZEOF(int, 4)
 261 AC_CHECK_SIZEOF(long, 4)
 262 test "x$HAVE_LONG_LONG" = xyes && AC_CHECK_SIZEOF(long long, 8)
 263 test "x$HAVE_OFF_T" = xyes && AC_CHECK_SIZEOF(off_t, 4)
 264
 265 # Check for variadic macros
 266 EL_CHECK_CODE([variadic macros], HAVE_VARIADIC_MACROS,
 267                 [#include <stdio.h>
 268                  #define a(b,c...) printf(b,##c)],
 269                 [a("foo");a("%s","bar");a("%s%s","baz","quux");])
 270
 271 # ===================================================================
 272 # Checks for library functions.
 273 # ===================================================================
 274
 275 AC_PROG_GCC_TRADITIONAL
 276 AC_FUNC_MEMCMP
 277 AC_FUNC_MMAP
 278 AC_FUNC_STRFTIME
 279 AC_CHECK_FUNCS(atoll gethostbyaddr herror strerror)
 280 AC_CHECK_FUNCS(popen uname access chmod alarm timegm mremap)
 281 AC_CHECK_FUNCS(strcasecmp strncasecmp strcasestr strstr strchr strrchr)
 282 AC_CHECK_FUNCS(memmove bcopy stpcpy strdup index isdigit mempcpy memrchr)
 283 AC_CHECK_FUNCS(snprintf vsnprintf asprintf vasprintf)
 284 AC_CHECK_FUNCS(getifaddrs getpwnam inet_pton inet_ntop)
 285 AC_CHECK_FUNCS(fflush fsync fseeko ftello sigaction)
 286 AC_CHECK_FUNCS(gettimeofday clock_gettime)
 287 AC_CHECK_FUNCS(setitimer, HAVE_SETITIMER=yes)
 288
 289 AC_CHECK_FUNCS([cygwin_conv_to_full_win32_path])
 290
 291 AC_CHECK_FUNCS(setenv putenv, HAVE_SETENV_OR_PUTENV=yes)
 292 AC_CHECK_FUNCS(unsetenv)
 293 AC_CHECK_FUNCS(getuid, HAVE_GETUID=yes)
 294 AC_CHECK_FUNCS(geteuid, HAVE_GETEUID=yes)
 295
 296 AC_CHECK_FUNCS(wcwidth, HAVE_WCWIDTH=yes)
 297
 298 AC_CHECK_FUNCS(fork)
 299
 300 # These aren't probably needed now, as they are commented in links.h.
 301 # I've no idea about their historical background, but I keep them here
 302 # just in the case they will help later. --pasky
 303 AC_CHECK_FUNCS(getpid, HAVE_GETPID=yes)
 304 AC_CHECK_FUNCS(setpgid getpgid setpgrp getpgrp)
 305 AC_CHECK_FUNCS(raise, HAVE_RAISE=yes)
 306 AC_CHECK_FUNCS(kill, HAVE_KILL=yes)
 307
 308 AC_CHECK_FUNCS(fpathconf, HAVE_FPATHCONF=yes)
 309
 310 if test x"$HAVE_RAISE" = x; then
 311         if test x"$HAVE_KILL" = x || test x"$HAVE_GETPID" = x; then
 312                 AC_MSG_ERROR([Unable to emulate raise()])
 313         fi
 314 fi
 315
 316 AC_CACHE_CHECK([for __va_copy],el_cv_HAVE_VA_COPY,[
 317 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>
 318 va_list ap1,ap2;]], [[__va_copy(ap1,ap2);]])],[el_cv_HAVE_VA_COPY=yes],[el_cv_HAVE_VA_COPY=no])])
 319 if test x"$el_cv_HAVE_VA_COPY" = x"yes"; then
 320         EL_DEFINE(HAVE_VA_COPY, __va_copy)
 321 fi
 322
 323 AC_CACHE_CHECK([for sysconf(_SC_PAGE_SIZE)],el_cv_HAVE_SC_PAGE_SIZE,[
 324 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <unistd.h>
 325 ]], [[int page_size = sysconf(_SC_PAGE_SIZE);]])],[el_cv_HAVE_SC_PAGE_SIZE=yes],[el_cv_HAVE_SC_PAGE_SIZE=no])])
 326 if test x"$el_cv_HAVE_SC_PAGE_SIZE" = x"yes"; then
 327         EL_DEFINE(HAVE_SC_PAGE_SIZE, _SC_PAGE_SIZE)
 328 fi
 329
 330 AC_CACHE_CHECK([for C99 vsnprintf],el_cv_HAVE_C99_VSNPRINTF,[
 331 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 332 #include <stdio.h>
 333 #include <stdarg.h>
 334 #include <stdlib.h>
 335 #include <string.h>
 336
 337 char buf[8];
 338
 339 int bar(char *buf, const char *format, va_list ap)
 340 {
 341        return vsnprintf(buf, 0, format, ap);
 342 }
 343
 344 void foo(const char *format, ...) {
 345        va_list ap;
 346        int len;
 347
 348        va_start(ap, format);
 349        len = bar(buf, format, ap);
 350        va_end(ap);
 351        if ((len != 6) && (len != 7)) exit(1); /* \n -> \r\n */
 352
 353        va_start(ap, format);
 354        len = bar(buf, format, ap);
 355        va_end(ap);
 356        if ((len != 6) && (len != 7)) exit(1);
 357
 358        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 359
 360        exit(0);
 361 }
 362 main() { foo("hello\n"); }
 363 ]])],[el_cv_HAVE_C99_VSNPRINTF=yes],[el_cv_HAVE_C99_VSNPRINTF=no],[el_cv_HAVE_C99_VSNPRINTF=cross])])
 364 if test x"$el_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 365         EL_DEFINE(HAVE_C99_VSNPRINTF, [C99 compliant vsnprintf()])
 366 fi
 367
 368 # OpenSSL and Lua frequently need dlopen
 369 AC_CHECK_LIB(dl, dlopen)
 370
 371 # ===================================================================
 372 # Checks for libraries.
 373 # ===================================================================
 374
 375 AC_CHECK_FUNC(socket, cf_result=yes, cf_result=no)
 376 if test "$cf_result" = no; then
 377         AC_CHECK_LIB(socket, socket)
 378 fi
 379
 380 AC_CHECK_FUNC(setsockopt, cf_result=yes, cf_result=no)
 381 if test "$cf_result" = no; then
 382         AC_CHECK_LIB(socket, setsockopt)
 383 fi
 384
 385 AC_CHECK_FUNC(gethostbyname, cf_result=yes, cf_result=no)
 386 if test "$cf_result" = no; then
 387         AC_CHECK_LIB(socket, gethostbyname, cf_result=yes, cf_result=no)
 388         if test "$cf_result" = no; then
 389                 AC_CHECK_LIB(nsl, gethostbyname)
 390         else
 391                 test -z "`echo $LIBS | grep -- -lsocket`" && LIBS="$LIBS -lsocket"
 392         fi
 393 fi
 394
 395 # ===================================================================
 396 # Checks for packaging specific options.
 397 # ===================================================================
 398
 399 AC_ARG_WITH(xterm, [  --with-xterm            how to invoke the X terminal emulator],
 400             [ if test "$withval" != no && test "$withval" != yes; then
 401                 AC_DEFINE_UNQUOTED(XTERM, "$withval", [How to invoke XTerm])
 402               fi ])
 403
 404 # ===================================================================
 405 # Checks for a libraries, optional even if installed.
 406 # ===================================================================
 407
 408 dnl EL_CHECK_OPTIONAL_LIBRARY(define, name, header, lib, function)
 409 AC_DEFUN([EL_CHECK_OPTIONAL_LIBRARY],
 410 [
 411         AC_MSG_CHECKING([for $2 support])
 412
 413         if test "[$]$1" != no; then
 414                 AC_MSG_RESULT(yes)
 415                 EL_SAVE_FLAGS
 416                 if test -n "$withval" && test -d "$withval"; then
 417                         # Be a little more careful when setting
 418                         # include and lib directories. This way
 419                         # $withval will work when includes are
 420                         # there but the library is in the common
 421                         # /usr/lib ... Does the right thing when
 422                         # looking for gc on Debian.
 423                         if test -d "$withval/include"; then
 424                                 CFLAGS="$CFLAGS -I$withval/include"
 425                                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 426                         else
 427                                 CFLAGS="$CFLAGS -I$withval"
 428                                 CPPFLAGS="$CPPFLAGS -I$withval"
 429                         fi
 430                         if test -d "$withval/lib"; then
 431                                 LDFLAGS="$LDFLAGS -L$withval/lib"
 432                         fi
 433                 fi
 434
 435                 AC_CHECK_HEADERS([$3], [$1=yes], [$1=no; break;])
 436                 if test "[$]$1" = yes; then
 437                         AC_CHECK_LIB([$4], [$5], [$1=yes], [$1=no])
 438                 fi
 439
 440                 if test "[$]$1" = yes; then
 441                         EL_CONFIG([$1], [$2])
 442                         LIBS="$LIBS -l$4"
 443                 else
 444                         if test -n "[$]WITHVAL_$1" &&
 445                            test "x[$]WITHVAL_$1" != xno; then
 446                                 AC_MSG_ERROR([$2 not found])
 447                         fi
 448                         EL_RESTORE_FLAGS
 449                 fi
 450         else
 451                 AC_MSG_RESULT(disabled)
 452         fi
 453 ])
 454
 455 dnl EL_CONFIG_OPTIONAL_LIBRARY(define, name, header, lib, function, confhelp)
 456 AC_DEFUN([EL_CONFIG_OPTIONAL_LIBRARY],
 457 [
 458         if test "x[$]$1" != xno; then $1=yes; fi
 459         WITHVAL_$1=
 460
 461         AC_ARG_WITH([$2], [$6], [WITHVAL_$1="[$]withval"])
 462         if test "x[$]WITHVAL_$1" = xno; then $1=no; fi
 463         if test "x[$]WITHVAL_$1" = xyes; then $1=yes; fi
 464
 465         EL_CHECK_OPTIONAL_LIBRARY([$1], [$2], [$3], [$4], [$5])
 466
 467         EL_LOG_CONFIG([$1], [$2], [])
 468 ])
 469
 470 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GPM, gpm, gpm.h, gpm, Gpm_Open,
 471         [  --without-gpm           disable gpm (mouse) support])
 472
 473 # ELinks calls deflateInit2 with windowBits = MAX_WBITS | 32, to
 474 # enable automatic decoding of both zlib and gzip headers.  This
 475 # feature was added in zlib 1.2.0.2; earlier versions return an error.
 476 # The gzclearerr function was also added in zlib 1.2.0.2, so check for
 477 # that, even though ELinks does not actually call gzclearerr.
 478 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GZIP, zlib, zlib.h, z, gzclearerr,
 479         [  --without-zlib          disable zlib support])
 480
 481 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_BZIP2, bzlib, bzlib.h, bz2, BZ2_bzReadOpen,
 482         [  --without-bzlib         disable bzlib support])
 483
 484 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_IDN, idn, idna.h, idn, stringprep_check_version,
 485         [  --without-idn           disable international domain names support])
 486
 487 # LZMA disabled by default, because of little usability and compilation problems
 488 # with new xz
 489 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_LZMA, lzma, lzma.h, lzma, lzma_code,
 490         [  --with-lzma             enable lzma encoding support])
 491
 492 # ===================================================================
 493 # Check for GSSAPI, optional even if installed.
 494 # ===================================================================
 495
 496 enable_gssapi="no";
 497
 498 AC_ARG_WITH(gssapi, [  --with-gssapi           enable GSSAPI support],
 499             [ if test "x$withval" != xno; then enable_gssapi=yes; fi ])
 500
 501 AC_MSG_CHECKING([for GSSAPI])
 502
 503 if test "$enable_gssapi" = "yes"; then
 504         AC_MSG_RESULT(yes)
 505         GSSAPI_CFLAGS=`krb5-config --cflags gssapi`
 506         GSSAPI_LIBS=`krb5-config --libs gssapi`
 507         CFLAGS="$GSSAPI_CFLAGS $CFLAGS"
 508         LIBS="$GSSAPI_LIBS $LIBS"
 509         EL_CONFIG(CONFIG_GSSAPI, [GssApi])
 510 else
 511         AC_MSG_RESULT(no)
 512 fi
 513
 514 AC_SUBST(CONFIG_GSSAPI)
 515
 516 # ===================================================================
 517 # Bookmark and XBEL support
 518 # ===================================================================
 519
 520 EL_SAVE_FLAGS
 521
 522 EL_ARG_ENABLE(CONFIG_BOOKMARKS, bookmarks, [Bookmarks],
 523               [  --disable-bookmarks     disable bookmark support])
 524
 525 # Check whether --enable-xbel or --disable-xbel was given.
 526 if test "x${enable_xbel}" != xno; then
 527         AC_CHECK_HEADERS(expat.h, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 528
 529         if test "$HAVE_LIBEXPAT" = yes; then
 530                 AC_CHECK_LIB(expat, XML_ParserCreate, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 531                 if test "$HAVE_LIBEXPAT" = yes; then
 532                         LIBS="$LIBS -lexpat"
 533                 fi
 534         fi
 535 fi
 536
 537
 538 EL_ARG_DEPEND(CONFIG_XBEL_BOOKMARKS, xbel, [CONFIG_BOOKMARKS:yes HAVE_LIBEXPAT:yes],
 539               [XBEL bookmarks],
 540               [  --disable-xbel          disable XBEL bookmark support (requires expat)])
 541
 542 if test "$CONFIG_XBEL_BOOKMARKS" != yes; then
 543         EL_RESTORE_FLAGS
 544 fi
 545
 546 # ===================================================================
 547 # Checks for BSD sysmouse
 548 # ===================================================================
 549
 550 HAVE_SYSMOUSE_HEADER="no"
 551
 552 # Either of these header files provides the (same) sysmouse interface
 553 AC_CHECK_HEADERS(sys/consio.h machine/console.h, [HAVE_SYSMOUSE_HEADER="yes"])
 554
 555 # ===================================================================
 556 # Checks for OS/2
 557 # ===================================================================
 558
 559 if test "$CONFIG_OS_OS2" = yes; then
 560         EL_CONFIG_OS_OS2
 561 fi
 562
 563 # ===================================================================
 564 # Checks for Win32
 565 # ===================================================================
 566
 567 if test "$CONFIG_OS_WIN32" = yes; then
 568         EL_CONFIG_OS_WIN32
 569 fi
 570
 571 # ===================================================================
 572 # Check for SpiderMonkey, optional even if installed.
 573 # ===================================================================
 574
 575 # This option sets the $with_spidermonkey variable.
 576 AC_ARG_WITH([spidermonkey],
 577         [AS_HELP_STRING([--without-spidermonkey],
 578                 [disable SpiderMonkey Mozilla JavaScript engine support])])
 579
 580 # CONFIG_SPIDERMONKEY is initially blank.  We change it to "yes" or "no"
 581 # when we know for sure whether we're going to use SpiderMonkey or not.
 582 # (features.conf is not supposed to define it.)
 583 CONFIG_SPIDERMONKEY=
 584 EL_SAVE_FLAGS
 585
 586 case "$with_spidermonkey" in
 587         no)
 588                 # The user specified --without-spidermonkey.
 589                 # That overrides the other SpiderMonkey options.
 590                 AC_MSG_CHECKING([for SpiderMonkey])
 591                 AC_MSG_RESULT([disabled])
 592                 CONFIG_SPIDERMONKEY="no"
 593                 ;;
 594         "" | yes)
 595                 ;;
 596         *)
 597                 AC_MSG_WARN([This version of ELinks does not support --with-spidermonkey=DIRECTORY.])
 598                 ;;
 599 esac
 600
 601 # The SpiderMonkey 1.8.5 standalone sources install mozjs185.pc,
 602 # but the Debian libmozjs-dev package installs mozilla-js.pc.
 603 # Check mozjs185 first, because it has the version number in the name
 604 # and therefore is less likely to be a newer incompatible version.
 605 # (This configure script rejects older incompatible versions
 606 # but can let newer ones through.)
 607 for package in mozjs185 mozilla-js; do
 608         if test -n "$CONFIG_SPIDERMONKEY"; then
 609                 break
 610         else
 611                 AC_MSG_CHECKING([for SpiderMonkey (1.8.5 or later) in pkg-config $package])
 612                 # In pkg-config 0.25, pkg-config --exists mozjs185
 613                 # returns 0 (success) even if mozjs185 depends on
 614                 # nspr, which has not been installed.  However,
 615                 # pkg-config --cflags mozjs185 returns 1 then.
 616                 if pkg-config --cflags --libs $package > /dev/null 2>&AS_MESSAGE_LOG_FD; then
 617                         SPIDERMONKEY_LIBS="$(pkg-config --libs $package)"
 618                         SPIDERMONKEY_CFLAGS="$(pkg-config --cflags $package)"
 619                         LIBS="$SPIDERMONKEY_LIBS $LIBS_X"
 620                         CFLAGS="$CFLAGS_X $SPIDERMONKEY_CFLAGS"
 621                         CPPFLAGS="$CPPFLAGS_X $SPIDERMONKEY_CFLAGS"
 622                         AC_LINK_IFELSE(
 623                                 [AC_LANG_PROGRAM([[
 624                                         /* mozilla-js.pc may have -DXP_UNIX or similar in Cflags.
 625                                          * Avoid warnings about conflicting definitions.  */
 626                                         #if !defined(XP_BEOS) && !defined(XP_OS2) && !defined(XP_UNIX) && !defined(XP_WIN)
 627                                         # define XP_UNIX 1
 628                                         #endif
 629                                         #include <jsapi.h>
 630                                         #ifndef JS_VERSION
 631                                         # error <jsapi.h> did not define JS_VERSION
 632                                         #elif JS_VERSION < 185
 633                                         # error too old
 634                                         #endif]], [])],
 635                                 [CONFIG_SPIDERMONKEY=yes
 636                                  AC_MSG_RESULT([yes])],
 637                                 [# Leave CONFIG_SPIDERMONKEY blank, to continue the search.
 638                                  AC_MSG_RESULT([found but unusable])])
 639                 else
 640                         AC_MSG_RESULT([no])
 641                 fi
 642         fi
 643 done
 644
 645 if test -z "$CONFIG_SPIDERMONKEY"; then
 646         # Didn't find SpiderMonkey anywhere.
 647         CONFIG_SPIDERMONKEY=no
 648 fi
 649
 650 if test "$CONFIG_SPIDERMONKEY" = "yes"; then
 651         # LIBS, CFLAGS, and CPPFLAGS still include the SpiderMonkey options.
 652         AC_CHECK_FUNCS([JS_ReportAllocationOverflow])
 653         AC_CHECK_FUNCS([JS_SetBranchCallback])
 654         AC_CHECK_FUNCS([JS_TriggerOperationCallback], [HAVE_JS_TRIGGEROPERATIONCALLBACK=yes])
 655 elif test -n "$with_spidermonkey" && test "x$with_spidermonkey" != "xno"; then
 656         AC_MSG_WARN([SpiderMonkey was not found even though you specified --with-spidermonkey.])
 657 fi
 658 EL_RESTORE_FLAGS
 659
 660 if test "x$CONFIG_SPIDERMONKEY" = xyes; then
 661         EL_CONFIG(CONFIG_ECMASCRIPT_SMJS, [SpiderMonkey document scripting])
 662 else
 663         CONFIG_ECMASCRIPT_SMJS=no
 664 fi
 665
 666 EL_CONFIG_DEPENDS(CONFIG_ECMASCRIPT, [CONFIG_ECMASCRIPT_SMJS], [ECMAScript (JavaScript)])
 667 AC_SUBST(CONFIG_ECMASCRIPT_SMJS)
 668
 669 if test "x$CONFIG_ECMASCRIPT_SMJS" = xyes &&
 670    test "x$HAVE_JS_TRIGGEROPERATIONCALLBACK" = xyes &&
 671    test "x$HAVE_SETITIMER" = xyes; then
 672         EL_CONFIG(CONFIG_ECMASCRIPT_SMJS_HEARTBEAT, [ECMAScript heartbeat support])
 673 else
 674         CONFIG_ECMASCRIPT_SMJS_HEARTBEAT=no
 675 fi
 676 AC_SUBST(CONFIG_ECMASCRIPT_SMJS_HEARTBEAT)
 677
 678
 679 # ===================================================================
 680 # Optional Spidermonkey-based ECMAScript browser scripting
 681 # ===================================================================
 682
 683 AC_ARG_ENABLE(sm-scripting,
 684               [  --disable-sm-scripting  ECMAScript browser scripting (requires Spidermonkey)],
 685               [if test "$enableval" != no; then enableval="yes"; fi
 686                CONFIG_SCRIPTING_SPIDERMONKEY="$enableval";])
 687
 688 if test "x$CONFIG_SPIDERMONKEY" = xyes &&
 689    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 690         EL_CONFIG(CONFIG_SCRIPTING_SPIDERMONKEY, [SpiderMonkey])
 691 else
 692         CONFIG_SCRIPTING_SPIDERMONKEY=no
 693 fi
 694
 695 if test "x$CONFIG_ECMASCRIPT_SMJS" = xyes ||
 696    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 697         LIBS="$LIBS $SPIDERMONKEY_LIBS"
 698         AC_SUBST(SPIDERMONKEY_LIBS)
 699         AC_SUBST(SPIDERMONKEY_CFLAGS)
 700         AC_SUBST(CONFIG_SPIDERMONKEY)
 701 fi
 702
 703 # ===================================================================
 704 # Check for Guile, optional even if installed.
 705 # ===================================================================
 706
 707 enable_guile="no";
 708
 709 AC_ARG_WITH(guile, [  --with-guile            enable Guile support],
 710             [ if test "x$withval" != xno; then enable_guile=yes; fi ])
 711
 712 # The following is probably bad, ugly and so on. Stolen from Guile's (1.4)
 713 # GUILE_FLAGS but I really don't want to require people to have Guile in order
 714 # to compile CVS. Also, the macro seems to be really stupid regarding searching
 715 # for Guile in $PATH etc. --pasky
 716
 717 AC_MSG_CHECKING([for Guile])
 718
 719 if test "$enable_guile" = "yes"; then
 720         AC_MSG_RESULT(yes);
 721         ## Based on the GUILE_FLAGS macro.
 722
 723         if test -d "$withval"; then
 724                 GUILE_PATH="$withval:$PATH"
 725         else
 726                 GUILE_PATH="$PATH"
 727         fi
 728
 729         AC_PATH_PROG(GUILE_CONFIG, guile-config, no, $GUILE_PATH)
 730
 731         ## First, let's just see if we can find Guile at all.
 732         if test "$GUILE_CONFIG" != no; then
 733                 cf_result="yes";
 734
 735                 GUILE_LIBS="`guile-config link`"
 736                 GUILE_CFLAGS="`guile-config compile`"
 737                 LIBS="$GUILE_LIBS $LIBS"
 738                 EL_CONFIG(CONFIG_SCRIPTING_GUILE, [Guile])
 739                 AC_SUBST(GUILE_CFLAGS)
 740                 cat <<EOF
 741 ***********************************************************************
 742 The Guile support is incomplete and not so well integrated to ELinks
 743 yet. That means, e.g., that you have no Guile console and there might
 744 not be all the necessary hooks. Also, the Guile interface is not too
 745 well tested (success stories heartily welcomed!).  See
 746 src/scripting/guile/README for further details and hints.
 747 ***********************************************************************
 748 EOF
 749         else
 750                 if test -n "$withval" && test "x$withval" != xno; then
 751                         AC_MSG_ERROR([Guile not found])
 752                 else
 753                         AC_MSG_WARN([Guile support disabled])
 754                 fi
 755         fi
 756 else
 757         AC_MSG_RESULT(no);
 758 fi
 759
 760 # ===================================================================
 761 # Check for Perl
 762 # ===================================================================
 763 enable_perl="no";
 764
 765 AC_ARG_WITH(perl, [  --with-perl             enable Perl support],
 766             [
 767 if test "$withval" = yes; then
 768         # FIXME: If withval is a valid directory append it to PATH
 769         # so that you can specify one of several perl installations.
 770         withval="";
 771         enable_perl=yes;
 772 fi
 773             ])
 774
 775 AC_MSG_CHECKING([for Perl])
 776
 777 cf_result=no
 778
 779 EL_SAVE_FLAGS
 780
 781 if test "$enable_perl" = "yes"; then
 782         PERL_LIBS="`perl -MExtUtils::Embed -e ldopts`"
 783         PERL_CFLAGS="`perl -MExtUtils::Embed -e ccopts`"
 784         LIBS="$PERL_LIBS $LIBS"
 785         CFLAGS="$PERL_CFLAGS $CFLAGS"
 786         CPPFLAGS="$CPPFLAGS $PERL_CFLAGS"
 787         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 788 #include <EXTERN.h>
 789 #include <perl.h>
 790 #include <perlapi.h>
 791 ]], [[PerlInterpreter *my_perl = perl_alloc();]])],[cf_result=yes],[cf_result=no])
 792 fi
 793
 794 if test "$cf_result"; then AC_MSG_RESULT($cf_result); fi
 795
 796 AC_MSG_CHECKING([whether POPpx works without an n_a variable])
 797 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 798 #include <EXTERN.h>
 799 #include <perl.h>
 800 extern PerlInterpreter *my_perl;
 801 ]], [[dSP; (void) POPpx;]])],[AC_MSG_RESULT([yes])
 802 AC_DEFINE([CONFIG_PERL_POPPX_WITHOUT_N_A], [1],
 803                 [Define if using Perl 5.8.8 or later, where the "POPpx" macro
 804 no longer needs an "n_a" variable like it did in 5.8.7])],[AC_MSG_RESULT([no])])
 805
 806 if test "$cf_result" != "yes"; then
 807         EL_RESTORE_FLAGS
 808 else
 809         EL_CONFIG(CONFIG_SCRIPTING_PERL, [Perl])
 810
 811         CFLAGS="$CFLAGS_X"
 812         CPPFLAGS="$CPPFLAGS_X"
 813         AC_SUBST(PERL_LIBS)
 814         AC_SUBST(PERL_CFLAGS)
 815 fi
 816
 817 # ===================================================================
 818 # Check for Python
 819 # ===================================================================
 820 enable_python="no";
 821
 822 AC_ARG_WITH(python, [[  --with-python[=DIR]     enable Python support]],
 823             [ if test "x$withval" != xno; then enable_python=yes; fi ])
 824
 825 EL_SAVE_FLAGS
 826 cf_result=no
 827
 828 AC_MSG_CHECKING([for Python])
 829
 830 if test "$enable_python" = "yes"; then
 831         AC_MSG_RESULT(yes);
 832
 833         if test -d "$withval"; then
 834                 PYTHON_PATH="$withval:$PATH"
 835         else
 836                 PYTHON_PATH="$PATH"
 837         fi
 838
 839         AC_PATH_PROG(PYTHON, python, no, $PYTHON_PATH)
 840
 841         if test "$PYTHON" != no; then
 842                 cf_result="yes";
 843
 844                 PYTHON_CFLAGS="`$PYTHON -c 'from distutils import sysconfig; print "-I%s -I%s" % (sysconfig.get_python_inc(), sysconfig.get_python_inc(plat_specific=True))'`"
 845                 PYTHON_LIBS="`$PYTHON -c 'from distutils import sysconfig; var = sysconfig.get_config_var; print "%s %s %s -L%s -lpython%s" % (var("LINKFORSHARED"), var("LIBS"), var("SYSLIBS"), var("LIBPL"), var("VERSION"))'`"
 846                 LIBS="$PYTHON_LIBS $LIBS"
 847                 CPPFLAGS="$CPPFLAGS $PYTHON_CFLAGS"
 848                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <Python.h>]], [[Py_Initialize();]])],[cf_result=yes],[cf_result=no])
 849
 850                 if test "$cf_result" != "yes"; then
 851                         EL_RESTORE_FLAGS
 852                 else
 853                         EL_CONFIG(CONFIG_SCRIPTING_PYTHON, [Python])
 854                         AC_SUBST(PYTHON_LIBS)
 855                         AC_SUBST(PYTHON_CFLAGS)
 856                         CPPFLAGS="$CPPFLAGS_X"
 857                         cat <<EOF
 858 ***********************************************************************
 859 The Python support is incomplete and not so well integrated to ELinks
 860 yet. That means, e.g., that you have no Python console and there might
 861 not be all the necessary hooks. Also, the Python interface is not too
 862 well tested (success stories heartily welcomed!).
 863 ***********************************************************************
 864 EOF
 865                 fi
 866         else
 867                 if test -n "$withval" && test "x$withval" != xno; then
 868                         AC_MSG_ERROR([Python not found])
 869                 else
 870                         AC_MSG_WARN([Python support disabled])
 871                 fi
 872         fi
 873 else
 874         AC_MSG_RESULT(no);
 875 fi
 876
 877
 878 # ===================================================================
 879 # Check for Lua, optional even if installed.
 880 # ===================================================================
 881
 882 # Do this the long way, as FreeBSD reportedly needs -L<dir> for
 883 # anything other than /usr/lib, and Lua is very often in /usr/local/lib.
 884
 885 AC_ARG_WITH(lua, [  --without-lua           disable Lua support],
 886             [if test "$withval" = no; then disable_lua=yes; fi])
 887 AC_MSG_CHECKING([for Lua])
 888
 889 EL_SAVE_FLAGS
 890 cf_result=no
 891
 892 if test -z "$disable_lua"; then
 893         if test ! -d "$withval"; then
 894                 withval="";
 895         fi
 896         for luadir in "$withval" "" /usr /usr/local; do
 897                 for suffix in "" 5.1 51; do
 898                         if test "$cf_result" = no && ( test -f "$luadir/include/lua.h" || \
 899                            test -f "$luadir/include/lua$suffix/lua.h" ) ; then
 900                                 LUA_LIBS="-L$luadir/lib -llua$suffix -lm"
 901                                 LUA_CFLAGS="-I$luadir/include -I$luadir/include/lua$suffix"
 902
 903                                 LIBS="$LUA_LIBS $LIBS_X"
 904                                 CFLAGS="$CFLAGS_X $LUA_CFLAGS"
 905                                 CPPFLAGS="$CPPFLAGS_X $LUA_CFLAGS"
 906
 907                                 # Check that it is a compatible Lua version
 908                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[      #include <lauxlib.h>]
 909                                                 #include <lua.h>
 910                                                 #include <lualib.h>
 911                                                 ], [[   lua_State *L = luaL_newstate();
 912                                                 luaL_openlibs(L);
 913                                                 lua_pushboolean(L, 1);
 914                                                 lua_close(L);]])],[cf_result=yes],[cf_result=no])
 915                         fi
 916                 done
 917         done
 918 fi
 919
 920 AC_MSG_RESULT($cf_result)
 921
 922 if test "$cf_result" != yes; then
 923         EL_RESTORE_FLAGS
 924 else
 925         EL_CONFIG(CONFIG_SCRIPTING_LUA, [Lua])
 926         AC_CHECK_HEADERS(lauxlib.h)
 927
 928         CFLAGS="$CFLAGS_X"
 929         CPPFLAGS="$CPPFLAGS_X"
 930         AC_SUBST(LUA_LIBS)
 931         AC_SUBST(LUA_CFLAGS)
 932 fi
 933
 934 # ===================================================================
 935 # Check for TRE library
 936 # ===================================================================
 937 #
 938 # This section only checks that --without-tre is not given and the
 939 # library seems to work, and sets TRE_CFLAGS, TRE_LIBS, and
 940 # tre_log.  It does not define CONFIG_TRE, and always resets
 941 # LIBS and CFLAGS back to their original values.
 942 #
 943 # After any --enable-utf-8 and --disable-utf-8 options have been
 944 # handled, a separate section decides whether to actually use TRE.
 945 #
 946 # tre version 0.8.0 or higher is required which have the "tre_" prefix
 947 # for functions.
 948
 949 AC_ARG_WITH([[tre]], [[  --without-tre           disable TRE regex search support]])
 950 if test "$with_tre" = no; then
 951         AC_MSG_CHECKING([[for TRE]])
 952         AC_MSG_RESULT([[disabled]])
 953         tre_log="no (explicitly disabled)"
 954 else
 955         AC_MSG_CHECKING([[for TRE in pkg-config]])
 956         if pkg-config tre; then
 957                 TRE_CFLAGS=`pkg-config --cflags tre`
 958                 TRE_LIBS=`pkg-config --libs tre`
 959                 AC_MSG_RESULT([[yes]])
 960         else
 961                 # <http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=513055>
 962                 # "libtre-dev: /usr/lib/pkgconfig/tre.pc missing"
 963                 # so we look for the library even if pkg-config doesn't know about it.
 964                 TRE_CFLAGS=
 965                 TRE_LIBS=-ltre
 966                 AC_MSG_RESULT([[no, but let's try defaults]])
 967         fi
 968
 969         AC_MSG_CHECKING([[for TRE header and library]])
 970         EL_SAVE_FLAGS
 971         CFLAGS="$TRE_CFLAGS $CFLAGS"
 972         LIBS="$TRE_LIBS $LIBS" # must be first, because of regfree conflict
 973         AC_TRY_LINK([#include <tre/tre.h>],
 974                     [regex_t re;
 975                      regmatch_t match[1];
 976                      tre_regwcomp(&re, L"zap", REG_ICASE);
 977                      tre_regwexec(&re, L"ELIZAPROGRAM", 1, match, 0);],
 978                     [AC_MSG_RESULT([[yes]])
 979                      tre_log="available"],
 980                     [AC_MSG_RESULT([[no]])
 981                      tre_log="no (TRE not found)"])
 982         EL_RESTORE_FLAGS
 983 fi
 984
 985 # ===================================================================
 986 # Check for Ruby, optional even if installed.
 987 # ===================================================================
 988
 989 EL_CONFIG_SCRIPTING_RUBY
 990
 991 # ===================================================================
 992 # Setup global scripting
 993 # ===================================================================
 994
 995 EL_CONFIG_DEPENDS(CONFIG_SCRIPTING, [CONFIG_SCRIPTING_GUILE CONFIG_SCRIPTING_LUA CONFIG_SCRIPTING_PERL CONFIG_SCRIPTING_PYTHON CONFIG_SCRIPTING_RUBY CONFIG_SCRIPTING_SPIDERMONKEY], [Browser scripting])
 996 AC_SUBST(CONFIG_SCRIPTING_GUILE)
 997 AC_SUBST(CONFIG_SCRIPTING_LUA)
 998 AC_SUBST(CONFIG_SCRIPTING_PERL)
 999 AC_SUBST(CONFIG_SCRIPTING_PYTHON)
1000 AC_SUBST(CONFIG_SCRIPTING_RUBY)
1001 AC_SUBST(CONFIG_SCRIPTING_SPIDERMONKEY)
1002 AC_SUBST(CONFIG_SCRIPTING)
1003
1004
1005 # ===================================================================
1006 # Check for SSL support.
1007 # ===================================================================
1008
1009 # We by default use OpenSSL, and we always prefer it. However, when GNUTLS
1010 # is enabled, we won't try to use OpenSSL anymore.
1011
1012 # For wiping SSL hooks..
1013 #ifdef CONFIG_SSL
1014
1015 chosen_ssl_library=""
1016
1017 AC_ARG_WITH(gnutls, [[  --without-gnutls        disable GNUTLS SSL support]])
1018 AC_ARG_WITH(gnutls, [[  --with-gnutls           enable GNUTLS SSL support]],
1019             [case "$with_gnutls" in
1020                 "no")   : ;;
1021                 "yes")  chosen_ssl_library="GNUTLS" ;;
1022                 *)      chosen_ssl_library="GNUTLS"
1023                         AC_MSG_WARN([[Support for --with-gnutls=DIR has been removed.
1024 You may have to set the PKG_CONFIG_PATH environment variable instead.]]) ;;
1025              esac])
1026
1027 AC_ARG_WITH(openssl, [[  --without-openssl       disable OpenSSL support]])
1028 AC_ARG_WITH(openssl, [[  --with-openssl[=DIR]    enable OpenSSL support (default)]],
1029             [case "$with_openssl" in
1030                 "no")   : ;;
1031                 *)      chosen_ssl_library="OpenSSL" ;;
1032              esac])
1033
1034 AC_ARG_WITH(nss_compat_ossl, [[  --with-nss_compat_ossl[=DIR]
1035                           NSS compatibility SSL libraries/include files]],
1036             [case "$with_nss_compat_ossl" in
1037                 "no")   : ;;
1038                 *)      chosen_ssl_library="nss_compat_ossl" ;;
1039              esac])
1040
1041 # ---- nss_compat_ossl
1042
1043 if test "$with_nss_compat_ossl" = no; then
1044         # explicitly disabled
1045         :
1046 elif test -n "$chosen_ssl_library" && test "$chosen_ssl_library" != "nss_compat_ossl"; then
1047         # not used, because $chosen_ssl_library was chosen
1048         :
1049 elif test -z "${with_nss_compat_ossl+set}"; then
1050         # SSL_library_init() in nss_compat_ossl 0.9.2 calls exit(1)
1051         # with no error message if there is no certificate database.
1052         # https://bugzilla.redhat.com/show_bug.cgi?id=463437
1053         # So ELinks uses nss_compat_ossl only if explicitly requested.
1054         :
1055 else
1056         EL_SAVE_FLAGS
1057         if test "$with_nss_compat_ossl" = yes; then
1058                 if pkg-config nss; then
1059                         CFLAGS="$CFLAGS_X `pkg-config --cflags nss`"
1060                         LIBS="$LIBS_X `pkg-config --libs nss`"
1061                 else
1062                         with_nss_compat_ossl=no
1063                 fi
1064         else
1065                 # Without pkg-config, we'll kludge in some defaults
1066                 CFLAGS="$CFLAGS_X -I$with_nss_compat_ossl/include -I/usr/include/nss3 -I/usr/include/nspr4"
1067                 LIBS="$LIBS_X -L$with_nss_compat_ossl/lib -lssl3 -lsmime3 -lnss3 -lplds4 -lplc4 -lnspr4 -lpthread -ldl"
1068         fi
1069         AC_CHECK_HEADERS(nss_compat_ossl/nss_compat_ossl.h,, [with_nss_compat_ossl=no], [#define NSS_COMPAT_OSSL_H])
1070         AC_CHECK_LIB(nss_compat_ossl, X509_free,, [with_nss_compat_ossl=no])
1071
1072         if test "$with_nss_compat_ossl" = "no"; then
1073                 EL_RESTORE_FLAGS
1074         else
1075                 LIBS="$LIBS -lnss_compat_ossl"
1076                 EL_CONFIG(CONFIG_NSS_COMPAT_OSSL, [nss_compat_ossl])
1077                 chosen_ssl_library="nss_compat_ossl"
1078         fi
1079 fi
1080
1081 # ---- OpenSSL
1082
1083 AC_MSG_CHECKING([for OpenSSL])
1084
1085 EL_SAVE_FLAGS
1086
1087 if test "$with_openssl" = no; then
1088         cf_result="explicitly disabled"
1089
1090 elif test -n "$chosen_ssl_library" && test "$chosen_ssl_library" != "OpenSSL"; then
1091         cf_result="not used, because $chosen_ssl_library was chosen"
1092
1093 else
1094         cf_result=no
1095         for ssldir in "$with_openssl" "" /usr /usr/local/openssl \
1096                          /usr/lib/openssl /usr/local/ssl \
1097                          /usr/local/www /usr/lib/ssl /usr/local \
1098                          /usr/pkg /opt /opt/openssl; do
1099                 if test "$cf_result" = no; then
1100                         if test -d "$ssldir"; then
1101                                 OPENSSL_CFLAGS="-I$ssldir/include"
1102                                 LIBS="-L$ssldir/lib -lssl -lcrypto $LIBS_X"
1103                                 CFLAGS="$CFLAGS_X $OPENSSL_CFLAGS"
1104                                 CPPFLAGS="$CPPFLAGS_X $OPENSSL_CFLAGS"
1105 #                               # FIXME: This created serious portability problems. --pasky
1106 #                               if test "$CC" == "gcc"; then
1107 #                                       # I'm not sure about compatibility here. --pasky
1108 #                                       LIBS="$LIBS -R$ssldir/lib"
1109 #                               fi
1110                         else
1111                                 LIBS="-lssl -lcrypto $LIBS_X"
1112                         fi
1113                         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <openssl/ssl.h>]], [[OpenSSL_add_all_algorithms()]])],[cf_result=yes],[cf_result=no])
1114                         if test "$cf_result" != yes; then
1115                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <openssl/ssl.h>]], [[SSLeay_add_ssl_algorithms()]])],[cf_result=yes],[cf_result=no])
1116                         fi
1117                 fi
1118         done
1119
1120         if test "$cf_result" != yes; then
1121                 if test "${with_openssl-no}" != "no"; then
1122                         AC_MSG_ERROR([OpenSSL not found])
1123                 fi
1124                 EL_RESTORE_FLAGS
1125         else
1126                 EL_CONFIG(CONFIG_OPENSSL, [OpenSSL])
1127                 chosen_ssl_library="OpenSSL"
1128
1129                 CFLAGS="$CFLAGS_X"
1130                 AC_SUBST(OPENSSL_CFLAGS)
1131         fi
1132 fi
1133
1134 AC_MSG_RESULT($cf_result)
1135
1136 # ---- GNU TLS
1137
1138 # GnuTLS 2.2.0 changed libgnutls-openssl from GPLv2+
1139 # to GPLv3+.  Don't link that with the GPLv2 ELinks.
1140 # ELinks will use its internal MD5 code instead.
1141 CONFIG_GNUTLS_OPENSSL_COMPAT=no
1142
1143 if test "$with_gnutls" = no; then
1144         AC_MSG_CHECKING([[for GNUTLS]])
1145         AC_MSG_RESULT([[explicitly disabled]])
1146
1147 elif test -n "$chosen_ssl_library" && test "$chosen_ssl_library" != "GNUTLS"; then
1148         AC_MSG_CHECKING([[for GNUTLS]])
1149         AC_MSG_RESULT([[not used, because $chosen_ssl_library was chosen]])
1150
1151 else
1152         cf_result=no
1153         AC_MSG_CHECKING([[for GNUTLS (1.2 or later) in pkg-config]])
1154         if pkg-config --atleast-version=1.2 gnutls; then
1155                 GNUTLS_CFLAGS=`pkg-config --cflags gnutls`
1156                 GNUTLS_LIBS=`pkg-config --libs gnutls`
1157                 AC_MSG_RESULT([[yes: $GNUTLS_CFLAGS $GNUTLS_LIBS]])
1158
1159                 EL_SAVE_FLAGS
1160                 LIBS="$GNUTLS_LIBS $LIBS"
1161                 CFLAGS="$CFLAGS $GNUTLS_CFLAGS"
1162                 CPPFLAGS="$CPPFLAGS $GNUTLS_CFLAGS"
1163
1164                 # Verify if it's really usable.  gnutls_session was
1165                 # renamed to gnutls_session_t before GNU TLS 1.2.0
1166                 # (on 2004-06-13); ELinks now requires this.
1167                 AC_MSG_CHECKING([[whether GNUTLS can be linked with]])
1168                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <gnutls/gnutls.h>]],
1169                                                 [[gnutls_session_t dummy;
1170                                                   gnutls_check_version(NULL)]])],
1171                                [cf_result=yes],
1172                                [cf_result=no])
1173                 AC_MSG_RESULT([[$cf_result]])
1174
1175                 if test "$cf_result" = yes; then
1176                         # According to gnutls/NEWS, the function was originally
1177                         # added as gnutls_set_default_priority2 in GNUTLS 2.1.4
1178                         # (released 2007-10-27) and then renamed to
1179                         # gnutls_priority_set_direct in GNUTLS 2.1.7 (released
1180                         # 2007-11-29).
1181                         AC_CHECK_FUNCS([gnutls_priority_set_direct])
1182                 fi
1183
1184                 EL_RESTORE_FLAGS
1185         else
1186                 AC_MSG_RESULT([[$cf_result]])
1187         fi
1188
1189         if test "$cf_result" = yes; then
1190                 EL_CONFIG(CONFIG_GNUTLS, [GNUTLS])
1191                 chosen_ssl_library="GNUTLS"
1192
1193                 # gcry_create_nounce is part of libgcrypt
1194                 LIBGCRYPT_CFLAGS=`libgcrypt-config --cflags`
1195                 LIBGCRYPT_LIBS=`libgcrypt-config --libs`
1196
1197                 LIBS="$LIBGCRYPT_LIBS $GNUTLS_LIBS $LIBS"
1198                 AC_SUBST(LIBGCRYPT_CFLAGS)
1199                 AC_SUBST(GNUTLS_CFLAGS)
1200
1201         elif test "${with_gnutls-no}" != "no"; then
1202                 AC_MSG_ERROR([[GNUTLS (1.2 or later) not found.  ELinks no longer supports GNUTLS 1.1.]])
1203         fi
1204 fi
1205
1206 # Final SSL setup
1207
1208 EL_CONFIG_DEPENDS(CONFIG_SSL, [CONFIG_OPENSSL CONFIG_GNUTLS CONFIG_NSS_COMPAT_OSSL], [SSL])
1209 AC_SUBST(CONFIG_GNUTLS_OPENSSL_COMPAT)
1210 AC_SUBST(CONFIG_OPENSSL)
1211 AC_SUBST(CONFIG_GNUTLS)
1212 AC_SUBST(CONFIG_NSS_COMPAT_OSSL)
1213
1214 #endif
1215
1216 AC_MSG_CHECKING([whether to be or not to be])
1217 AC_MSG_RESULT([needs to be determined experimentally])
1218
1219 # ===================================================================
1220 # Check for IPv6 support and related functions.
1221 # ===================================================================
1222
1223 EL_CHECK_NET_TYPE(struct sockaddr_storage, HAVE_SA_STORAGE, [])
1224 EL_CHECK_NET_TYPE(struct sockaddr_in6, HAVE_SA_IN6, [#include <netinet/in.h>])
1225 EL_CHECK_NET_TYPE(struct addrinfo, HAVE_ADDRINFO, [#include <netdb.h>])
1226
1227 AC_CHECK_FUNC(getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1228 if test "$HAVE_GETADDRINFO" != yes; then
1229         AC_CHECK_LIB(inet6, getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1230         if test "$HAVE_GETADDRINFO" = yes; then
1231                 LIBS="$LIBS -linet6"
1232         fi
1233 fi
1234
1235
1236 # ===================================================================
1237 # Checking for X11 (window title restoring).
1238 # ===================================================================
1239
1240 AC_PATH_X
1241 if test x"$no_x" != xyes; then
1242         EL_SAVE_FLAGS
1243         if test -n "$x_includes"; then
1244                 X_CFLAGS="-I$x_includes"
1245                 CPPFLAGS="$CPPLAGS $X_CFLAGS"
1246                 CFLAGS="$CFLAGS $X_CFLAGS"
1247         fi
1248         if test -n "$x_libraries"; then
1249                 LDFLAGS="$LDFLAGS -L$x_libraries"
1250         fi
1251         LIBS="-lX11 $LIBS"
1252         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]], [[XrmInitialize()]])],[cf_result=yes],[cf_result=no])
1253         EL_RESTORE_FLAGS
1254         if test "$cf_result" = yes; then
1255                 if test -n "$x_libraries"; then
1256                         LDFLAGS="$LDFLAGS -L$x_libraries"
1257                 fi
1258                 LIBS="-lX11 $LIBS"
1259                 EL_DEFINE(HAVE_X11, [X11 for restoring window titles])
1260                 AC_SUBST(X_CFLAGS)
1261         fi
1262 fi
1263
1264
1265 # ===================================================================
1266 # Backtraces displaying support.
1267 # ===================================================================
1268
1269 AC_CHECK_HEADERS(execinfo.h, HAVE_EXECINFO=yes, HAVE_EXECINFO=no)
1270 # possible checks for other system-specific means go here
1271
1272
1273 # ===================================================================
1274 # Gettext grey zone. Beware.
1275 # ===================================================================
1276
1277 ALL_LINGUAS="af be bg ca cs da de el es et fi fr gl hr hu id is it lt nl nb pl pt pt_BR ro ru sk sr sv tr uk"
1278
1279 AM_GNU_GETTEXT
1280
1281 # iconv is always used
1282 LIBS="$LIBS $LIBICONV"
1283
1284 dnl AC_MSG_CHECKING([how many characters your English alphabet has])
1285 dnl # f33r d4 l33t... I hope it's portable. :)
1286 dnl cf_result=$((48#z - 48#a + 1));
1287 dnl AC_MSG_RESULT($cf_result)
1288
1289
1290 # ===================================================================
1291 # Compile-time features control
1292 # ===================================================================
1293
1294 EL_ARG_ENABLE(CONFIG_COOKIES, cookies, [Cookies],
1295               [  --disable-cookies       disable cookie support])
1296
1297 EL_ARG_ENABLE(CONFIG_FORMHIST, formhist, [Form history],
1298               [  --disable-formhist      disable form history support])
1299
1300 EL_ARG_ENABLE(CONFIG_GLOBHIST, globhist, [Global history],
1301               [  --disable-globhist      disable global history support])
1302
1303
1304 EL_ARG_ENABLE(CONFIG_MAILCAP, mailcap, [Mailcap],
1305               [  --disable-mailcap       disable mailcap support])
1306
1307 EL_ARG_ENABLE(CONFIG_MIMETYPES, mimetypes, [Mimetypes files],
1308               [  --disable-mimetypes     disable mimetypes files support])
1309
1310
1311 EL_ARG_DEPEND(CONFIG_IPV6, ipv6,
1312               [HAVE_SA_STORAGE:yes HAVE_SA_IN6:yes HAVE_ADDRINFO:yes HAVE_GETADDRINFO:yes],
1313               [IPv6],
1314               [  --disable-ipv6          disable IPv6 support])
1315
1316 EL_ARG_ENABLE(CONFIG_BITTORRENT, bittorrent, [BitTorrent protocol],
1317               [  --enable-bittorrent     enable BitTorrent protocol support])
1318
1319 EL_ARG_ENABLE(CONFIG_DATA, data, [Data protocol],
1320               [  --disable-data          disable data protocol support])
1321
1322 EL_ARG_ENABLE(CONFIG_URI_REWRITE, uri-rewrite, [URI rewriting],
1323               [  --disable-uri-rewrite   disable URI rewrite support])
1324
1325 EL_ARG_DEPEND(CONFIG_CGI, cgi, [HAVE_SETENV_OR_PUTENV:yes], [Local CGI],
1326               [  --enable-cgi            enable local CGI support])
1327
1328 EL_ARG_ENABLE(CONFIG_FINGER, finger, [Finger protocol],
1329               [  --enable-finger         enable finger protocol support])
1330
1331 # ===================================================================
1332 # FSP protocol
1333 # ===================================================================
1334 EL_SAVE_FLAGS
1335
1336 if test "x${enable_fsp}" != xno; then
1337         AC_CHECK_HEADERS(fsplib.h, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1338
1339         if test "$HAVE_FSPLIB" = yes; then
1340                 AC_CHECK_LIB(fsplib, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1341                 if test "$HAVE_FSPLIB" = yes; then
1342                         LIBS="$LIBS -lfsplib"
1343                 else
1344                         AC_CHECK_LIB(fsp, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1345                         if test "$HAVE_FSPLIB" = yes; then
1346                                 LIBS="$LIBS -lfsp"
1347                         fi
1348                 fi
1349         fi
1350 fi
1351
1352 EL_ARG_DEPEND(CONFIG_FSP, fsp, [HAVE_FSPLIB:yes], [FSP protocol],
1353               [  --enable-fsp            enable FSP protocol support])
1354
1355 if test "x$CONFIG_FSP" = xno; then
1356         EL_RESTORE_FLAGS
1357 fi
1358
1359 EL_ARG_ENABLE(CONFIG_FTP, ftp, [FTP protocol],
1360               [  --disable-ftp           disable ftp protocol support])
1361
1362 EL_ARG_ENABLE(CONFIG_GOPHER, gopher, [Gopher protocol],
1363               [  --enable-gopher         enable gopher protocol support])
1364
1365 EL_ARG_ENABLE(CONFIG_NNTP, nntp, [NNTP protocol],
1366               [  --enable-nntp           enable nntp protocol support])
1367
1368 # ===================================================================
1369 # SMB protocol support.
1370 # ===================================================================
1371 EL_SAVE_FLAGS
1372
1373 if test "x${enable_smb}" != xno; then
1374         AC_CHECK_HEADERS(libsmbclient.h, HAVE_SMBCLIENT=yes, HAVE_SMBCLIENT=no)
1375
1376         if test "$HAVE_SMBCLIENT" = yes; then
1377                 AC_CHECK_LIB(smbclient, smbc_init, HAVE_SMBCLIENT=yes, HAVE_SMBCLIENT=no)
1378                 if test "$HAVE_SMBCLIENT" = yes; then
1379                         LIBS="$LIBS -lsmbclient"
1380                 fi
1381         fi
1382 fi
1383
1384 EL_ARG_DEPEND(CONFIG_SMB, smb, [HAVE_SMBCLIENT:yes], [Samba protocol],
1385               [  --enable-smb            enable Samba protocol support])
1386
1387 if test "x$CONFIG_SMB" = xno; then
1388         EL_RESTORE_FLAGS
1389 fi
1390
1391
1392 EL_ARG_ENABLE(CONFIG_MOUSE, mouse, [Mouse handling],
1393               [  --disable-mouse         disable mouse support])
1394
1395 # GPM mouse is Linux specific, so ...
1396 CONFIG_SYSMOUSE=yes
1397 EL_ARG_DEPEND(CONFIG_SYSMOUSE, sysmouse,
1398               [CONFIG_MOUSE:yes CONFIG_GPM:no HAVE_SYSMOUSE_HEADER:yes],
1399               [BSD sysmouse],
1400               [  --disable-sysmouse      disable BSD sysmouse support])
1401
1402 EL_ARG_ENABLE(CONFIG_88_COLORS, 88-colors, [88 colors],
1403               [  --enable-88-colors      enable 88 color support])
1404
1405 EL_ARG_ENABLE(CONFIG_256_COLORS, 256-colors, [256 colors],
1406               [  --enable-256-colors     enable 256 color support])
1407
1408 EL_ARG_ENABLE(CONFIG_TRUE_COLOR, true-color, [true color],
1409               [  --enable-true-color     enable true color support])
1410
1411 EL_ARG_ENABLE(CONFIG_EXMODE, exmode, [Exmode interface],
1412               [  --enable-exmode         enable exmode (CLI) interface])
1413
1414 EL_ARG_ENABLE(CONFIG_LEDS, leds, [LEDs],
1415               [  --disable-leds          disable LEDs support])
1416
1417 EL_ARG_ENABLE(CONFIG_MARKS, marks, [Marks],
1418               [  --disable-marks         disable document marks support])
1419
1420
1421 EL_ARG_ENABLE(CONFIG_CSS, css, [Cascading Style Sheets],
1422               [  --disable-css           disable Cascading Style Sheet support])
1423
1424 EL_ARG_DEPEND(CONFIG_HTML_HIGHLIGHT, html-highlight, [CONFIG_CSS:yes], [HTML highlighting],
1425               [  --enable-html-highlight HTML highlighting using DOM engine])
1426
1427 # Everything in the tree already uses CONFIG_DOM
1428 # so resolve CONFIG_HTML_HIGHLIGHT to CONFIG_DOM
1429 EL_CONFIG_DEPENDS(CONFIG_DOM, [CONFIG_HTML_HIGHLIGHT], [DOM engine])
1430
1431 EL_ARG_DEPEND(CONFIG_BACKTRACE, backtrace, [HAVE_EXECINFO:yes], [Backtrace],
1432               [  --disable-backtrace     disable backtrace support])
1433
1434 EL_ARG_DEPEND(CONFIG_NO_ROOT_EXEC, no-root, [HAVE_GETUID:yes HAVE_GETEUID:yes], [No root exec],
1435               [  --enable-no-root        enable prevention of usage by root])
1436
1437
1438 EL_ARG_ENABLE(CONFIG_DEBUG, debug, [Debug mode],
1439               [  --enable-debug          enable leak debug and internal error checking])
1440
1441 EL_ARG_DEPEND(CONFIG_FASTMEM, fastmem, [CONFIG_DEBUG:no], [Fast mode],
1442               [  --enable-fastmem        enable direct use of system allocation functions, not usable with --enable-debug])
1443
1444 EL_ARG_ENABLE(CONFIG_OWN_LIBC, own-libc, [Own libc stubs],
1445               [  --enable-own-libc       force use of internal functions instead of those of system libc])
1446
1447 EL_ARG_ENABLE(CONFIG_SMALL, small, [Small binary],
1448               [  --enable-small          reduce binary size as far as possible (but see the bottom of doc/small.txt!)])
1449
1450 EL_ARG_ENABLE(CONFIG_UTF8, utf-8, [UTF-8],
1451               [  --disable-utf-8         disable UTF-8 support])
1452
1453 EL_ARG_DEPEND(CONFIG_COMBINE, combining, [CONFIG_UTF8:yes HAVE_WCWIDTH:yes], [Combining characters],
1454               [  --enable-combining      support Unicode combining characters (experimental)])
1455
1456
1457 AC_ARG_ENABLE(weehoofooboomookerchoo,
1458               [
1459     Also check out the features.conf file for more information about features!
1460               ],
1461               [AC_MSG_ERROR(Are you strange, or what?)])
1462
1463
1464 # ===================================================================
1465 # Decide whether to use TRE
1466 # ===================================================================
1467 #
1468 # This must be done after the CONFIG_UTF8 check above.
1469 # The first part of the TRE check is separate, to get
1470 # the configure --help output in a sensible order.
1471 #
1472 # After this section, nothing else must be added to the
1473 # beginning of $LIBS.
1474
1475 if test "$tre_log" = "available"; then
1476         if test "$CONFIG_UTF8" = "yes"; then
1477                 # When CONFIG_UTF8 and CONFIG_TRE are both defined,
1478                 # src/viewer/text/search.c makes a string of
1479                 # unicode_val_T and gives it to regwexec(), which
1480                 # expects a string of wchar_t.  If the unicode_val_T
1481                 # and wchar_t types are too different, this won't
1482                 # work, so try to detect that and disable regexp
1483                 # operations entirely in that case.
1484                 #
1485                 # Currently, this code only compares the sizes of the
1486                 # types.  src/intl/charsets.h defines unicode_val_T as
1487                 # uint32_t, so we check whether wchar_t has exactly 32
1488                 # bits.  But don't use AC_CHECK_SIZEOF for this, because
1489                 # there doesn't seem to be a documented way to get the
1490                 # result of that for use in the configure script.
1491                 #
1492                 # C99 says the implementation can define
1493                 # __STDC_ISO_10646__ if wchar_t values match ISO 10646
1494                 # (or Unicode) numbers in all locales.  Do not check
1495                 # that macro here, because it is too restrictive: it
1496                 # should be enough for ELinks if the values match in
1497                 # the locales where ELinks is actually run.
1498                 AC_MSG_CHECKING([[whether wchar_t is exactly 32-bit]])
1499                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1500 #include <limits.h>
1501 #include <stddef.h>
1502 int dummy[(sizeof(wchar_t) * CHAR_BIT == 32) ? 1 : -1];]], [])],
1503                         [AC_MSG_RESULT([[yes]])
1504                          tre_log="TRE"],
1505                         [AC_MSG_RESULT([[no]])
1506                          tre_log="no (unsuitable wchar_t)"])
1507         else
1508                 # If UTF-8 is not used, then wchar_t doesn't matter.
1509                 tre_log="TRE"
1510         fi
1511 fi
1512
1513 if test "$tre_log" = "TRE"; then
1514         AC_DEFINE([CONFIG_TRE], [1],
1515                 [Define as 1 to use the TRE library for regular expression searching.  This requires the <tre/regex.h> header file.  If you define CONFIG_UTF8 too, then wchar_t must be exactly 32-bit so that it matches unicode_val_T.])
1516         # TRE_CFLAGS will be used only where needed.
1517         #
1518         # Bug 1081: If both TRE and libc define the regfree function,
1519         # ELinks needs to use the version defined by TRE because
1520         # that's the one compatible with regex_t initialized by the
1521         # regwcomp function of TRE.  Therefore put $TRE_LIBS at the
1522         # very beginning of $LIBS so that the linker hopefully finds
1523         # regfree there before it examines libc.  In particular,
1524         # $PERL_LIBS appears to often include "-lc".
1525         #
1526         # This scheme still risks a crash if ELinks is linked with
1527         # some static library that uses GNU <regex.h> extensions that
1528         # TRE does not implement.  For example, the library might call
1529         # re_compile_pattern, which is found in GNU libc, and then
1530         # regfree, which is found in TRE and probably crashes with the
1531         # GNU-initialized regex_t.  Ways to avoid such crashes:
1532         #
1533         # - Change TRE so it defines only tre_... functions and does
1534         #   not attempt to override the POSIX names by default.
1535         #
1536         # - Change ELinks to access TRE only via dlopen and dlsym.
1537         #   The problem then is how to find the correct file name.
1538         #   There might be libtre.so.4 and libtre.so.5 with different
1539         #   ABI.  How can this configure script detect which of them
1540         #   matches the <tre/regex.h> in the include path?
1541         #
1542         # - Replace the static library with a shared library.  At
1543         #   least on GNU/Linux, when the shared library is built, the
1544         #   linker should note that e.g. regfree is defined in libc
1545         #   and has the GLIBC_2.0 version there, and write that
1546         #   version string to the shared library as well; because TRE
1547         #   does not provide regfree with that version, any regfree
1548         #   calls at run time should then get resolved to libc.
1549         LIBS="$TRE_LIBS $LIBS"
1550 else
1551         TRE_LIBS=
1552         TRE_CFLAGS=
1553 fi
1554 AC_SUBST(TRE_CFLAGS)
1555 AC_SUBST(TRE_LIBS)
1556 EL_LOG_CONFIG([CONFIG_TRE], [[Regexp searching]], [[$tre_log]])
1557
1558
1559 # ===================================================================
1560 # Further LDFLAGS tweaks
1561 # ===================================================================
1562
1563 # == EMX hack
1564
1565 test "$CONFIG_OS_OS2" = yes && LDFLAGS="$LDFLAGS -Zexe"
1566 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zbin-files//g"`
1567
1568
1569 # Check for -rdynamic
1570 #
1571 # gcc -rdynamic calls ld -export-dynamic, which adds all symbols of
1572 # the executable to its dynamic symbol table.  ELinks uses this for
1573 # two purposes:
1574 #
1575 # 1. If ELinks detects a bug, it can try to display a backtrace by
1576 #    calling backtrace_symbols_fd() in the GNU libc.  The glibc-2.3.6
1577 #    manual states users of GNU ld must pass -rdynamic to make the
1578 #    symbols available to the program.
1579 #
1580 # 2. It would eventually be nice to dynamically load shared
1581 #    libraries as plugins (bug 73).  The plugins must be able to
1582 #    call ELinks functions.  This can be implemented either by
1583 #    registering all callable functions in ELinks-specific data
1584 #    structures, or by letting the dynamic linker handle them.
1585 #    The latter way requires something equivalent to -rdynamic.
1586 #
1587 # Because backtraces are not needed for correct operation, and bug
1588 # 73 is not yet being fixed, the configure script and makefiles
1589 # should not complain to the user if they find that -rdynamic does
1590 # not work.  Besides, it was reported at elinks-users on 2006-09-12
1591 # that gcc-3.4.2 with "ld: Software Generation Utilities - Solaris
1592 # Link Editors: 5.8-1.284" on Sun Solaris 8 Sparc does not support
1593 # -rdynamic but does something equivalent automatically.  (This was
1594 # tested with "nm -D elinks | grep redraw_from_window".)
1595 #
1596 # With Sun Studio 11 on Solaris 9, we get "cc: Warning: illegal option
1597 # -dynamic"; then, cc proceeds anyway, but the option can prevent the
1598 # linker from finding the libraries listed in -l operands.  So this
1599 # -rdynamic check needs to happen after the libraries have already
1600 # been added to $LDFLAGS.
1601 AC_MSG_CHECKING([for -rdynamic])
1602 LDFLAGS_X="$LDFLAGS"
1603 LDFLAGS="-rdynamic $LDFLAGS"
1604 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[]])],[have_rdynamic=yes],[have_rdynamic=no])
1605 test "$have_rdynamic" = no && LDFLAGS="$LDFLAGS_X"
1606 AC_MSG_RESULT($have_rdynamic)
1607
1608 # ===================================================================
1609 # Export directory paths
1610 # ===================================================================
1611
1612 # Set up the ``entry points'' if they were not supplied by builder
1613 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1614 test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1615
1616 # Create CONFDIR #define for config.h
1617
1618 # XXX: This may be dependent on a particular version of autoconf. Whatever,
1619 # it's autoconf fault to force us to do such hacks ;p.
1620 if test x"$sysconfdir" = x"\${prefix}/etc"; then
1621   # sysconfdir is set to its default value... fine, let's append /elinks/
1622   # XXX: We can't modify listing of the default in ./configure --help :-(
1623   sysconfdir_n=`eval echo "$sysconfdir"`
1624   sysconfdir=$sysconfdir_n
1625   (echo "$sysconfdir" | grep elinks >/dev/null 2>/dev/null) || \
1626         sysconfdir="$sysconfdir/elinks"
1627 fi
1628
1629 CONFDIR=$sysconfdir
1630 AC_DEFINE_UNQUOTED(CONFDIR, "$CONFDIR", [Directory containing default config])
1631 AC_SUBST(CONFDIR)
1632
1633 # Create LOCALEDIR #define for config.h
1634 LOCALEDIR=`eval echo "$datadir/locale"`
1635 while echo "$LOCALEDIR" | grep "\\$"
1636 do
1637         LOCALEDIR=`eval echo "$LOCALEDIR"`
1638 done > /dev/null 2> /dev/null
1639 AC_DEFINE_UNQUOTED(LOCALEDIR, "$LOCALEDIR", [Directory containing locales])
1640 AC_SUBST(LOCALEDIR)
1641
1642 # Create LIBDIR #define for config.h
1643 LIBDIR=`eval echo "$libdir"`
1644 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [Directory containing libraries])
1645 AC_SUBST(LIBDIR)
1646
1647 EL_LOG_CONFIG(CONFDIR, [System configuration directory], [])
1648 EL_LOG_CONFIG(LOCALEDIR, [Locale catalogs directory], [])
1649
1650
1651 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stddef.h>
1652 ]], [[#if !defined(__TINYC__) || !defined(alloca)
1653         #error not tcc
1654         #endif ]])],[cf_result=yes],[cf_result=no])
1655
1656 if test "$cf_result" = "yes"; then
1657         AC_DEFINE([HAVE_ALLOCA])
1658         AC_DEFINE([_ALLOCA_H], [1], [Define as 1 if you are using Tiny C Compiler
1659                 with the GNU C Library, and <alloca.h> of glibc would otherwise
1660                 override the alloca macro defined in <stddef.h> of TCC.
1661                 If <alloca.h> of glibc sees the _ALLOCA_H macro, it assumes
1662                 it has already been included, and does not redefine alloca.
1663                 This might not work in future glibc versions though, because
1664                 the names of the #include guard macros are not documented.
1665                 The incompatibility has been reported to the tinycc-devel
1666                 mailing list on 2008-07-14.  If a future version of TCC provides
1667                 an <alloca.h> of its own, this hack won't be needed.])
1668 fi
1669 # ===================================================================
1670 # A little fine tuning of gcc specific options (continued)
1671 # ===================================================================
1672
1673 GETTEXT_CFLAGS=
1674 if test "x$ac_cv_c_compiler_gnu" = "xyes"; then
1675   if test "$CONFIG_DEBUG" = "yes"; then
1676     # We want to see all warnings and live with none (in debug mode).
1677     CFLAGS="$CFLAGS -Werror"
1678   fi
1679   GETTEXT_CFLAGS="-Wno-uninitialized"
1680
1681   case "`$CC -dumpversion`" in
1682     3.0|3.1|3.2)
1683       # These should be ok using -Werror
1684       ;;
1685     3.*)
1686       # If gcc is version 3.3 (or higher?) it emits lots of false positive
1687       # "dereferencing type-punned pointer will break strict-aliasing rules"
1688       # warnings. Disable them by not doing any strict-aliasing. The
1689       # alternative is just too ugly. Thanks gcc guys!! ;)
1690       CFLAGS="$CFLAGS -fno-strict-aliasing"
1691       ;;
1692     4.5*)
1693       CFLAGS="$CFLAGS -fno-strict-aliasing -Wno-pointer-sign -Wno-enum-compare"
1694       ;;
1695     4.*)
1696       # Do not show warnings related to (char * | unsigned char *) type
1697       # difference.
1698       CFLAGS="$CFLAGS -fno-strict-aliasing -Wno-pointer-sign"
1699       ;;
1700     *)
1701       # These should be ok using -Werror
1702       ;;
1703   esac
1704
1705   # GCC 4.2.1 warns if we use the address of an object in Boolean context:
1706   # warning: the address of `builtin_modules' will always evaluate as `true'
1707   # This hits the object_lock and foreach_module macros in particular.
1708   # It would be okay to put something in the macros to avoid the warning,
1709   # but currently this seems to require defining parallel macros that skip
1710   # the NULL check, and that's too ugly.  So we instead disable the warning.
1711   # GCC 4.2.1 needs -Wno-address, but GCC 4.2 snapshots need -Wno-always-true.
1712   # GCC 4.1.3 recognizes neither and exits with code 1 if they are given.
1713   for warning_flag in -Wno-address -Wno-always-true; do
1714     AC_MSG_CHECKING([whether $CC accepts $warning_flag])
1715     EL_SAVE_FLAGS
1716     CFLAGS="$CFLAGS $warning_flag"
1717     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1718       [AC_MSG_RESULT([yes])
1719        break],
1720       [AC_MSG_RESULT([no])])
1721     EL_RESTORE_FLAGS
1722   done
1723
1724   # Bug 1012: Some parts of ELinks do arithmetic with signed integers
1725   # in such a way that an overflow is possible.  GCC 4.2.1 warns
1726   # "warning: assuming signed overflow does not occur when assuming
1727   # that (X + c) > X is always true", which may be an incorrect
1728   # optimization (although allowed by the standard), and breaks the
1729   # build with -Werror.
1730   #
1731   # All of the following tests included -S -Wall -Wextra:
1732   #
1733   # GCC: (GNU) 4.0.4 20060507 (prerelease) (Debian 4.0.3-3)
1734   # * gcc-4.0 -O0: OK, compares the values
1735   # * gcc-4.0 -O2: assumes no overflow, does not warn
1736   # * gcc-4.0 -O0 -fno-strict-overflow: unrecognized command line option
1737   # * gcc-4.0 -O0 -fwrapv: OK, compares the values
1738   # * gcc-4.0 -O2 -fwrapv: OK, compares the values
1739   # * gcc-4.0 -O0 -ftrapv: OK, calls __addvsi3
1740   # * gcc-4.0 -O2 -ftrapv: assumes no overflow, does not warn
1741   # * gcc-4.0 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1742   # * gcc-4.0 -O2 -fwrapv -ftrapv: compares the values
1743   #
1744   # GCC: (GNU) 4.1.3 20070812 (prerelease) (Debian 4.1.2-15)
1745   # * gcc-4.1 -O0: assumes no overflow, does not warn
1746   # * gcc-4.1 -O2: assumes no overflow, does not warn
1747   # * gcc-4.1 -O0 -fno-strict-overflow: unrecognized command line option
1748   # * gcc-4.1 -O0 -fwrapv: OK, compares the values
1749   # * gcc-4.1 -O2 -fwrapv: OK, compares the values
1750   # * gcc-4.1 -O0 -ftrapv: OK, calls __addvsi3
1751   # * gcc-4.1 -O2 -ftrapv: compares the values
1752   # * gcc-4.1 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1753   # * gcc-4.1 -O2 -fwrapv -ftrapv: compares the values
1754   #
1755   # GCC: (GNU) 4.2.1 (Debian 4.2.1-5)
1756   # * gcc-4.2 -O0: OK, compares the values
1757   # * gcc-4.2 -O2: assumes no overflow, warns about it
1758   # * gcc-4.2 -O0 -fno-strict-overflow: OK, compares the values
1759   # * gcc-4.2 -O2 -fno-strict-overflow: OK, compares the values
1760   # * gcc-4.2 -O0 -fwrapv: OK, compares the values
1761   # * gcc-4.2 -O2 -fwrapv: OK, compares the values
1762   # * gcc-4.2 -O0 -ftrapv: OK, calls __addvsi3
1763   # * gcc-4.2 -O2 -ftrapv: compares the values
1764   # * gcc-4.2 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1765   # * gcc-4.2 -O2 -fwrapv -ftrapv: compares the values
1766   #
1767   # Apparently, -ftrapv does not work reliably at all.
1768   for overflow_flag in -fno-strict-overflow -fwrapv; do
1769     AC_MSG_CHECKING([whether $CC accepts $overflow_flag])
1770     EL_SAVE_FLAGS
1771     CFLAGS="$CFLAGS $overflow_flag"
1772     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1773       [AC_MSG_RESULT([yes])
1774        break],
1775       [AC_MSG_RESULT([no])])
1776     EL_RESTORE_FLAGS
1777   done
1778 fi
1779
1780 AC_SUBST(GETTEXT_CFLAGS)
1781 EL_LOG_CONFIG(CFLAGS, [Compiler flags (CFLAGS)], [])
1782 EL_LOG_CONFIG(CPPFLAGS, [Preprocessor flags (CPPFLAGS)], [])
1783 EL_LOG_CONFIG(LDFLAGS, [Linker flags (LDFLAGS)], [])
1784 EL_LOG_CONFIG(LIBS, [Library flags (LIBS)], [])
1785
1786 # ===================================================================
1787 # Colored make output
1788 # ===================================================================
1789
1790 if test $(`which tput` colors 2> /dev/null || echo 0) -ge 4; then
1791         MAKE_COLOR=1
1792         AC_SUBST(MAKE_COLOR)
1793 fi
1794
1795 # ===================================================================
1796 # Generated files
1797 # ===================================================================
1798
1799 AC_CONFIG_FILES([ \
1800  Makefile.config \
1801  contrib/elinks.spec \
1802  contrib/lua/hooks.lua \
1803  contrib/conv/w3m2links.awk \
1804  doc/Doxyfile \
1805  doc/man/man1/elinks.1 \
1806  src/intl/gettext/ref-add.sed \
1807  src/intl/gettext/ref-del.sed
1808 ])
1809 AC_OUTPUT
1810
1811 abs_srcdir="$(cd "$srcdir" && pwd)"
1812 # builddir is always absolute!
1813 if test "$abs_srcdir" != "$builddir"; then
1814         # Bootstrap the Makefile creation
1815         echo "include $abs_srcdir/Makefile" > "$builddir/Makefile"
1816         "$MAKE" "SRC=$abs_srcdir" init
1817
1818         # Make cg-status ignore this build directory
1819         echo "*" > "$builddir/.gitignore"
1820 fi
1821
1822 # ===================================================================
1823 # Configuration summary
1824 # ===================================================================
1825
1826 AC_MSG_RESULT(The following feature summary has been saved to features.log)
1827 cat features.log