configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.13)
   4 AC_INIT(src/main/main.c)
   5 AC_CONFIG_AUX_DIR(config)
   6
   7 PACKAGE=elinks
   8 VERSION=0.11.0
   9 AC_SUBST(PACKAGE)
  10 AC_SUBST(VERSION)
  11 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Package version])
  12 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Package version])
  13 AC_CONFIG_HEADERS(config.h)
  14
  15 AC_CHECK_PROG(ACLOCAL,[aclocal],[aclocal],[config/missing aclocal])
  16 AC_CHECK_PROG(AUTOCONF,[autoconf],[autoconf],[config/missing autoconf])
  17 AC_CHECK_PROG(AUTOHEADER,[autoheader],[autoheader],[config/missing autoheader])
  18
  19 AC_PROG_MAKE_SET
  20
  21 MAKE=
  22
  23 for make in gnumake gmake make false; do
  24         if test "x$MAKE" = x; then
  25                 AC_PATH_PROGS(MAKE, "$make")
  26         fi
  27 done
  28
  29 # Cleanup if we are configuring with a previous build in the tree
  30 if test -e Makefile.config; then
  31         "$MAKE" -C "$builddir" cleanall  >/dev/null 2>/dev/null
  32 fi
  33
  34 builddir="`pwd`"
  35
  36 dnl ===================================================================
  37 dnl Load feature configuration file and start logging features.
  38 dnl ===================================================================
  39
  40 features="features.conf"
  41 AC_CHECK_FILE("$srcdir/$features", [ . $srcdir/$features ])
  42 AC_CHECK_FILE("$builddir/$features", [ . $builddir/$features ])
  43 echo "Feature summary:" > features.log
  44
  45 dnl ===================================================================
  46 dnl Checks for programs.
  47 dnl ===================================================================
  48
  49 AC_PROG_CC
  50 AC_PROG_AWK
  51 AC_PATH_PROGS(AWK, "$AWK")
  52 AC_PROG_RANLIB
  53 AC_PROG_INSTALL
  54
  55 AC_PATH_PROGS(CG_COMMIT_ID, "cg-commit-id")
  56
  57 AC_PATH_PROGS(SPARSE, "sparse")
  58 AC_SUBST(SPARSE)
  59
  60 CONFIG_ASCIIDOC="no"
  61 CONFIG_POD2HTML="no"
  62 CONFIG_XMLTO="no"
  63 CONFIG_JW="no"
  64
  65 if test "x$CONFIG_DOC" != xno; then
  66         AC_PATH_PROGS(ASCIIDOC, "asciidoc")
  67         if test "x$ASCIIDOC" != "x"; then
  68                 EL_CONFIG(CONFIG_ASCIIDOC, [AsciiDoc])
  69                 EL_CONFIG(MANUAL_ASCIIDOC, [HTML (one file)])
  70                 EL_CONFIG(MAN_ASCIIDOC, [HTML])
  71         fi
  72
  73         AC_PATH_PROGS(XMLTO, "xmlto")
  74         if test "x$XMLTO" != "x"; then
  75                 EL_CONFIG(CONFIG_XMLTO, [XmlTo])
  76                 EL_CONFIG(MANUAL_XMLTO, [HTML (multiple files)])
  77                 EL_CONFIG(MAN_XMLTO, [man (groff)])
  78         fi
  79
  80         AC_PATH_PROGS(JW, "jw")
  81         if test "x$JW" != "x"; then
  82                 EL_CONFIG(CONFIG_JW, [JadeWrapper])
  83                 EL_CONFIG(MANUAL_JW, [PDF])
  84         fi
  85
  86         AC_PATH_PROGS(POD2HTML, "pod2html")
  87         if test "x$POD2HTML" != "x"; then
  88                 EL_CONFIG(CONFIG_POD2HTML, [Pod2HTML])
  89         fi
  90 fi
  91
  92 AC_SUBST(CONFIG_ASCIIDOC)
  93 AC_SUBST(CONFIG_POD2HTML)
  94 AC_SUBST(CONFIG_XMLTO)
  95 AC_SUBST(CONFIG_JW)
  96
  97 EL_CONFIG_DEPENDS(CONFIG_DOC, [CONFIG_ASCIIDOC CONFIG_XMLTO CONFIG_JW CONFIG_POD2HTML], [Documentation])
  98
  99 if test "$CONFIG_ASCIIDOC" = yes &&
 100    test "$CONFIG_XMLTO" = yes &&
 101    test "$CONFIG_JW" = yes; then
 102         EL_CONFIG_DEPENDS(CONFIG_MANUAL, [MANUAL_ASCIIDOC MANUAL_XMLTO MANUAL_JW], [Manual Formats])
 103 fi
 104
 105 if test "$CONFIG_ASCIIDOC" = yes &&
 106    test "$CONFIG_XMLTO" = yes; then
 107         EL_CONFIG_DEPENDS(CONFIG_MANUAL, [MAN_ASCIIDOC MAN_XMLTO], [Man Page Formats])
 108 fi
 109
 110 AC_SUBST(CONFIG_ASCIIDOC)
 111 AC_SUBST(CONFIG_POD2HTML)
 112 AC_SUBST(CONFIG_XMLTO)
 113 AC_SUBST(CONFIG_JW)
 114
 115 dnl gcc specific options (to be continued at the bottom of configure)
 116 if test "x$ac_cv_prog_gcc" = "xyes"; then
 117   dnl We want to see all warnings and live with none.
 118   dnl We can't set up -Werror here as there may be some warnings in test
 119   dnl suite of configure, and we don't want to fail them.
 120   CFLAGS="$CFLAGS -Wall"
 121 fi
 122
 123 dnl ===================================================================
 124 dnl Checks for special OSes.
 125 dnl ===================================================================
 126
 127 dnl EL_CHECK_COMPILER_MACRO(define, name, flagname)
 128 AC_DEFUN([EL_CHECK_COMPILER_MACROS],
 129 [
 130         AC_MSG_CHECKING([for $2])
 131
 132         for flag in $3; do
 133                 AC_TRY_COMPILE(, [#ifndef $flag
 134 kill me!
 135 #endif ], $1=yes, $1=no)
 136                 if test "[$]$1" = yes; then
 137                         EL_CONFIG([$1], [$2])
 138                         break
 139                 fi
 140         done
 141
 142         AC_MSG_RESULT([$]$1)
 143 ])
 144
 145 EL_CHECK_COMPILER_MACROS(CONFIG_BEOS, [BEOS], [__BEOS__])
 146 AC_SUBST(CONFIG_BEOS)
 147
 148 EL_CHECK_COMPILER_MACROS(CONFIG_RISCOS, [RISCOS], [__riscos__])
 149 AC_SUBST(CONFIG_RISCOS)
 150
 151 EL_CHECK_COMPILER_MACROS(CONFIG_WIN32, [WIN32], [_WIN32 __WIN32__])
 152 AC_SUBST(CONFIG_WIN32)
 153
 154 EL_CHECK_COMPILER_MACROS(CONFIG_OS2, [EMX], [__EMX__])
 155 AC_SUBST(CONFIG_OS2)
 156 test "$CONFIG_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zexe//g"`
 157
 158 AC_MSG_CHECKING([for UNIX])
 159 dnl FIXME: some depend kind of mechanism
 160 if test "$CONFIG_BEOS" = no && \
 161    test "$CONFIG_RISCOS" = no && \
 162    test "$CONFIG_WIN32" = no && \
 163    test "$CONFIG_OS2" = no; then
 164         EL_CONFIG(CONFIG_UNIX, [UNIX])
 165 else
 166         CONFIG_UNIX=no
 167 fi
 168 AC_MSG_RESULT($CONFIG_UNIX)
 169 AC_SUBST(CONFIG_UNIX)
 170
 171 dnl ===================================================================
 172 dnl Checks for header files.
 173 dnl ===================================================================
 174
 175 AC_HEADER_DIRENT
 176 AC_HEADER_STDC
 177 AC_HEADER_SYS_WAIT
 178 AC_HEADER_TIME
 179
 180 AC_CHECK_HEADERS(fcntl.h limits.h time.h unistd.h)
 181 AC_CHECK_HEADERS(sigaction.h)
 182 AC_CHECK_HEADERS(arpa/inet.h)
 183 AC_CHECK_HEADERS(netinet/in_systm.h netinet/in_system.h netinet/ip.h)
 184 AC_CHECK_HEADERS(net/if.h netdb.h netinet/in.h netinet/in6_var.h)
 185 AC_CHECK_HEADERS(ifaddrs.h)
 186 AC_CHECK_HEADERS(sys/cygwin.h io.h)
 187 AC_CHECK_HEADERS(sys/fmutex.h)
 188 AC_CHECK_HEADERS(sys/ioctl.h sys/sockio.h)
 189 AC_CHECK_HEADERS(sys/resource.h)
 190 AC_CHECK_HEADERS(sys/select.h)
 191 AC_CHECK_HEADERS(sys/signal.h)
 192 AC_CHECK_HEADERS(sys/socket.h)
 193 AC_CHECK_HEADERS(sys/time.h)
 194 AC_CHECK_HEADERS(sys/utsname.h)
 195 AC_CHECK_HEADERS(stdint.h inttypes.h)
 196 AC_CHECK_HEADERS(locale.h pwd.h)
 197 AC_CHECK_HEADERS(termios.h)
 198
 199
 200 AC_CHECK_HEADERS(sys/un.h,
 201         [CONFIG_INTERLINK=yes
 202          EL_CONFIG([CONFIG_INTERLINK], [interlinking])],
 203         [CONFIG_INTERLINK=no])
 204 AC_SUBST(CONFIG_INTERLINK)
 205
 206 dnl ===================================================================
 207 dnl Checks for typedefs, structures, and compiler characteristics.
 208 dnl ===================================================================
 209
 210 AC_STRUCT_TM
 211 AC_C_CONST
 212 AC_C_INLINE
 213 EL_CHECK_CODE(typeof, HAVE_TYPEOF, [], [int a; typeof(a) b;])
 214
 215 AC_SYS_LARGEFILE
 216 AC_TYPE_SIZE_T
 217 AC_TYPE_OFF_T
 218 EL_CHECK_TYPE(ssize_t, int)
 219 EL_CHECK_SYS_TYPE(long long, HAVE_LONG_LONG, [])
 220 EL_CHECK_INT_TYPE(int32_t, HAVE_INT32_T)
 221 EL_CHECK_INT_TYPE(uint32_t, HAVE_UINT32_T)
 222 EL_CHECK_INT_TYPE(uint16_t, HAVE_UINT16_T)
 223
 224 AC_CHECK_SIZEOF(char, 1)
 225 AC_CHECK_SIZEOF(short, 2)
 226 AC_CHECK_SIZEOF(int, 4)
 227 AC_CHECK_SIZEOF(long, 4)
 228 test "x$HAVE_LONG_LONG" = xyes && AC_CHECK_SIZEOF(long long, 8)
 229
 230 dnl Check for variadic macros
 231 EL_CHECK_CODE([variadic macros], HAVE_VARIADIC_MACROS,
 232                 [#include <stdio.h>
 233                  #define a(b,c...) printf(b,##c)],
 234                 [a("foo");a("%s","bar");a("%s%s","baz","quux");])
 235
 236 dnl Check for -rdynamic
 237 dnl FIXME: This check doesn't work. Something to do with the compiler
 238 dnl happily ignoring it and stderr not being checked for error messages.
 239 AC_MSG_CHECKING([for -rdynamic])
 240 LDFLAGS_X="$LDFLAGS"
 241 LDFLAGS="$LDFLAGS -rdynamic"
 242 AC_TRY_LINK([], [], have_rdynamic=yes, have_rdynamic=no)
 243 test "$have_rdynamic" = no && LDFLAGS="$LDFLAGS_X"
 244 AC_MSG_RESULT($have_rdynamic)
 245
 246 dnl ===================================================================
 247 dnl Check for POSIX <regex.h>
 248 dnl ===================================================================
 249
 250 EL_CHECK_SYS_TYPE(regex_t, HAVE_REGEX_H, [#include <regex.h>])
 251
 252 dnl ===================================================================
 253 dnl Checks for library functions.
 254 dnl ===================================================================
 255
 256 AC_PROG_GCC_TRADITIONAL
 257 AC_FUNC_MEMCMP
 258 AC_FUNC_MMAP
 259 AC_FUNC_STRFTIME
 260 AC_CHECK_FUNCS(cfmakeraw gethostbyaddr herror strerror)
 261 AC_CHECK_FUNCS(popen uname access chmod alarm timegm mremap)
 262 AC_CHECK_FUNCS(strcasecmp strncasecmp strcasestr strstr strchr strrchr)
 263 AC_CHECK_FUNCS(memmove bcopy stpcpy strdup index isdigit mempcpy memrchr)
 264 AC_CHECK_FUNCS(snprintf vsnprintf asprintf vasprintf)
 265 AC_CHECK_FUNCS(getifaddrs getpwnam inet_pton inet_ntop)
 266 AC_CHECK_FUNCS(fflush fsync fseeko ftello sigaction)
 267 AC_CHECK_FUNCS(gettimeofday clock_gettime)
 268
 269 AC_HAVE_FUNCS(cygwin_conv_to_full_win32_path)
 270
 271 AC_CHECK_FUNCS(setenv putenv, HAVE_SETENV_OR_PUTENV=yes)
 272 AC_CHECK_FUNCS(getuid, HAVE_GETUID=yes)
 273 AC_CHECK_FUNCS(geteuid, HAVE_GETEUID=yes)
 274
 275 dnl These aren't probably needed now, as they are commented in links.h.
 276 dnl I've no idea about their historical background, but I keep them here
 277 dnl just in the case they will help later. --pasky
 278 AC_CHECK_FUNCS(getpid, HAVE_GETPID=yes)
 279 AC_CHECK_FUNCS(setpgid getpgid setpgrp getpgrp)
 280 AC_CHECK_FUNCS(raise, HAVE_RAISE=yes)
 281 AC_CHECK_FUNCS(kill, HAVE_KILL=yes)
 282
 283 if test x"$HAVE_RAISE" = x; then
 284         if test x"$HAVE_KILL" = x || test x"$HAVE_GETPID" = x; then
 285                 AC_ERROR([Unable to emulate raise()])
 286         fi
 287 fi
 288
 289 AC_CACHE_CHECK([for __va_copy],el_cv_HAVE_VA_COPY,[
 290 AC_TRY_LINK([#include <stdarg.h>
 291 va_list ap1,ap2;], [__va_copy(ap1,ap2);],
 292 el_cv_HAVE_VA_COPY=yes,el_cv_HAVE_VA_COPY=no)])
 293 if test x"$el_cv_HAVE_VA_COPY" = x"yes"; then
 294         EL_DEFINE(HAVE_VA_COPY, __va_copy)
 295 fi
 296
 297 AC_CACHE_CHECK([for sysconf(_SC_PAGE_SIZE)],el_cv_HAVE_SC_PAGE_SIZE,[
 298 AC_TRY_LINK([#include <unistd.h>
 299 ], [int page_size = sysconf(_SC_PAGE_SIZE);],
 300 el_cv_HAVE_SC_PAGE_SIZE=yes,el_cv_HAVE_SC_PAGE_SIZE=no)])
 301 if test x"$el_cv_HAVE_SC_PAGE_SIZE" = x"yes"; then
 302         EL_DEFINE(HAVE_SC_PAGE_SIZE, _SC_PAGE_SIZE)
 303 fi
 304
 305 AC_CACHE_CHECK([for C99 vsnprintf],el_cv_HAVE_C99_VSNPRINTF,[
 306 AC_TRY_RUN([
 307 #include <stdio.h>
 308 #include <stdarg.h>
 309 #include <stdlib.h>
 310 #include <string.h>
 311
 312 char buf[8];
 313
 314 int bar(char *buf, const char *format, va_list ap)
 315 {
 316        return vsnprintf(buf, 0, format, ap);
 317 }
 318
 319 void foo(const char *format, ...) {
 320        va_list ap;
 321        int len;
 322
 323        va_start(ap, format);
 324        len = bar(buf, format, ap);
 325        va_end(ap);
 326        if ((len != 6) && (len != 7)) exit(1); /* \n -> \r\n */
 327
 328        va_start(ap, format);
 329        len = bar(buf, format, ap);
 330        va_end(ap);
 331        if ((len != 6) && (len != 7)) exit(1);
 332
 333        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 334
 335        exit(0);
 336 }
 337 main() { foo("hello\n"); }
 338 ],
 339 el_cv_HAVE_C99_VSNPRINTF=yes,el_cv_HAVE_C99_VSNPRINTF=no,el_cv_HAVE_C99_VSNPRINTF=cross)])
 340 if test x"$el_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 341         EL_DEFINE(HAVE_C99_VSNPRINTF, [C99 compliant vsnprintf()])
 342 fi
 343
 344 AC_CHECK_LIB(dl, dlopen) # OpenSSL and Lua frequently needs it
 345
 346 dnl ===================================================================
 347 dnl Checks for libraries.
 348 dnl ===================================================================
 349
 350 dnl Replace `main' with a function in -lsocket:
 351 AC_CHECK_FUNC(socket, cf_result=yes, cf_result=no)
 352 if test "$cf_result" = no; then
 353         AC_CHECK_LIB(socket, socket)
 354 fi
 355
 356 AC_CHECK_FUNC(setsockopt, cf_result=yes, cf_result=no)
 357 if test "$cf_result" = no; then
 358         AC_CHECK_LIB(socket, setsockopt)
 359 fi
 360
 361 AC_CHECK_FUNC(gethostbyname, cf_result=yes, cf_result=no)
 362 if test "$cf_result" = no; then
 363         AC_CHECK_LIB(socket, gethostbyname, cf_result=yes, cf_result=no)
 364         if test "$cf_result" = no; then
 365                 AC_CHECK_LIB(nsl, gethostbyname)
 366         else
 367                 test -z "`echo $LIBS | grep -- -lsocket`" && LIBS="$LIBS -lsocket"
 368         fi
 369 fi
 370
 371 dnl ===================================================================
 372 dnl Checks for packaging specific options.
 373 dnl ===================================================================
 374
 375 AC_ARG_WITH(xterm, [  --with-xterm            how to invoke the X terminal emulator],
 376             [ if test "$withval" != no && test "$withval" != yes; then
 377                 AC_DEFINE_UNQUOTED(XTERM, "$withval", [How to invoke XTerm])
 378               fi ])
 379
 380 dnl ===================================================================
 381 dnl Checks for a libraries, optional even if installed.
 382 dnl ===================================================================
 383
 384 dnl EL_CHECK_OPTIONAL_LIBRARY(define, name, header, lib, function)
 385 AC_DEFUN([EL_CHECK_OPTIONAL_LIBRARY],
 386 [
 387         AC_MSG_CHECKING([for $2 support])
 388
 389         if test "[$]$1" != no; then
 390                 AC_MSG_RESULT(yes)
 391                 EL_SAVE_FLAGS
 392                 if test -n "$withval" && test -d "$withval"; then
 393                         CFLAGS="$CFLAGS -I$withval/include";
 394                         CPPFLAGS="$CPPFLAGS -I$withval/include";
 395                         LDFLAGS="$LDFLAGS -L$withval/lib";
 396                 fi
 397
 398                 AC_CHECK_HEADERS([$3], [$1=yes], [$1=no; break;])
 399                 if test "[$]$1" = yes; then
 400                         AC_CHECK_LIB([$4], [$5], [$1=yes], [$1=no])
 401                 fi
 402
 403                 if test "[$]$1" = yes; then
 404                         EL_CONFIG([$1], [$2])
 405                         LIBS="$LIBS -l$4"
 406                 else
 407                         if test -n "[$]WITHVAL_$1" &&
 408                            test "[$]WITHVAL_$1" != xno; then
 409                                 AC_MSG_ERROR([$2 not found])
 410                         fi
 411                         EL_RESTORE_FLAGS
 412                 fi
 413         else
 414                 AC_MSG_RESULT(disabled)
 415         fi
 416 ])
 417
 418 dnl EL_CONFIG_OPTIONAL_LIBRARY(define, name, header, lib, function, confhelp)
 419 AC_DEFUN([EL_CONFIG_OPTIONAL_LIBRARY],
 420 [
 421         $1=yes
 422         WITHVAL_$1=
 423
 424         AC_ARG_WITH([$2], [$6], [WITHVAL_$1="[$]withval"])
 425         if test "x[$]WITHVAL_$1" = xno; then $1=no; fi
 426
 427         EL_CHECK_OPTIONAL_LIBRARY([$1], [$2], [$3], [$4], [$5])
 428
 429         EL_LOG_CONFIG([$1], [$2], [])
 430 ])
 431
 432 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GPM, gpm, gpm.h, gpm, Gpm_Open,
 433         [  --without-gpm           disable gpm (mouse) support])
 434
 435 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GZIP, zlib, zlib.h, z, gzdopen,
 436         [  --without-zlib          disable zlib support])
 437
 438 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_BZIP2, bzlib, bzlib.h, bz2, BZ2_bzReadOpen,
 439         [  --without-bzlib         disable bzlib support])
 440
 441 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_IDN, idn, idna.h, idn, stringprep_check_version,
 442         [  --without-idn           disable international domain names support])
 443
 444 dnl ===================================================================
 445 dnl Bookmark and XBEL support
 446 dnl ===================================================================
 447
 448 EL_SAVE_FLAGS
 449
 450 EL_ARG_ENABLE(CONFIG_BOOKMARKS, bookmarks, [Bookmarks],
 451               [  --disable-bookmarks     disable bookmark support])
 452
 453 # Check whether --enable-xbel or --disable-xbel was given.
 454 if test "x${enable_xbel}" != xno; then
 455         AC_CHECK_HEADERS(expat.h, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 456
 457         if test "$HAVE_LIBEXPAT" = yes; then
 458                 AC_CHECK_LIB(expat, XML_ParserCreate, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 459                 if test "$HAVE_LIBEXPAT" = yes; then
 460                         LIBS="$LIBS -lexpat"
 461                 fi
 462         fi
 463 fi
 464
 465
 466 EL_ARG_DEPEND(CONFIG_XBEL_BOOKMARKS, xbel, [CONFIG_BOOKMARKS:yes HAVE_LIBEXPAT:yes],
 467               [XBEL bookmarks],
 468               [  --disable-xbel          disable XBEL bookmark support (requires expat)])
 469
 470 if test "$CONFIG_XBEL_BOOKMARKS" != yes; then
 471         EL_RESTORE_FLAGS
 472 fi
 473
 474 dnl ===================================================================
 475 dnl Checks for BSD sysmouse
 476 dnl ===================================================================
 477
 478 HAVE_SYSMOUSE_HEADER="no"
 479
 480 # Either of these header files provides the (same) sysmouse interface
 481 AC_CHECK_HEADERS(sys/consio.h machine/console.h, [HAVE_SYSMOUSE_HEADER="yes"])
 482
 483 dnl ===================================================================
 484 dnl Checks for OS/2
 485 dnl ===================================================================
 486
 487 if test "$CONFIG_OS2" = yes; then
 488         EL_CONFIG_OS2
 489 fi
 490
 491 dnl ===================================================================
 492 dnl Checks for Win32
 493 dnl ===================================================================
 494
 495 if test "$CONFIG_WIN32" = yes; then
 496         EL_CONFIG_WIN32
 497 fi
 498
 499 dnl ===================================================================
 500 dnl Check for SpiderMonkey, optional even if installed.
 501 dnl ===================================================================
 502
 503 AC_ARG_WITH(spidermonkey, [  --without-spidermonkey  disable SpiderMonkey Mozilla JavaScript engine support],
 504             [if test "$withval" = no; then disable_spidermonkey=yes; fi])
 505 AC_MSG_CHECKING([for SpiderMonkey])
 506
 507 EL_SAVE_FLAGS
 508 cf_result=no
 509
 510 if test -z "$disable_spidermonkey"; then
 511         if test ! -d "$withval"; then
 512                 withval="";
 513         fi
 514         for spidermonkeydir in "$withval" "" /usr /usr/local /opt/spidermonkey /opt/js; do
 515                 for spidermonkeyinclude in "/include" "/include/js" "/include/smjs"; do
 516                         for spidermonkeylib in js smjs; do
 517                                 if test "$cf_result" = no; then
 518                                         SPIDERMONKEY_LIBS="-l$spidermonkeylib"
 519
 520                                         if test ! -z "$spidermonkeydir"; then
 521                                                 SPIDERMONKEY_LIBS="-L$spidermonkeydir/lib $SPIDERMONKEY_LIBS"
 522                                                 SPIDERMONKEY_CFLAGS="-I$spidermonkeydir$spidermonkeyinclude"
 523                                         fi
 524
 525                                         LIBS="$SPIDERMONKEY_LIBS $LIBS_X"
 526                                         CFLAGS="$CFLAGS_X $SPIDERMONKEY_CFLAGS"
 527                                         CPPFLAGS="$CPPFLAGS_X $SPIDERMONKEY_CFLAGS"
 528
 529                                         AC_TRY_LINK([#define XP_UNIX
 530                                                      #include <jsapi.h>],
 531                                                      [JS_GetImplementationVersion()],
 532                                                      cf_result=yes, cf_result=no)
 533                                 fi
 534                         done
 535                 done
 536         done
 537 fi
 538
 539 AC_MSG_RESULT($cf_result)
 540
 541 if test "$cf_result" != yes; then
 542         EL_RESTORE_FLAGS
 543 else
 544         EL_CONFIG(CONFIG_SPIDERMONKEY, [SpiderMonkey])
 545
 546         CFLAGS="$CFLAGS_X"
 547         AC_SUBST(SPIDERMONKEY_LIBS)
 548         AC_SUBST(SPIDERMONKEY_CFLAGS)
 549 fi
 550
 551 AC_SUBST(CONFIG_SPIDERMONKEY)
 552
 553 EL_CONFIG_DEPENDS(CONFIG_ECMASCRIPT, [CONFIG_SPIDERMONKEY], [ECMAScript (JavaScript)])
 554
 555
 556 dnl ===================================================================
 557 dnl Check for Guile, optional even if installed.
 558 dnl ===================================================================
 559
 560 enable_guile="no";
 561
 562 AC_ARG_WITH(guile, [  --with-guile            enable Guile support],
 563             [ if test "x$withval" != xno; then enable_guile=yes; fi ])
 564
 565 # The following is probably bad, ugly and so on. Stolen from Guile's (1.4)
 566 # GUILE_FLAGS but I really don't want to require people to have Guile in order
 567 # to compile CVS. Also, the macro seems to be really stupid regarding searching
 568 # for Guile in $PATH etc. --pasky
 569
 570 AC_MSG_CHECKING([for Guile])
 571
 572 if test "$enable_guile" = "yes"; then
 573         AC_MSG_RESULT(yes);
 574         ## Based on the GUILE_FLAGS macro.
 575
 576         if test -d "$withval"; then
 577                 GUILE_PATH="$withval:$PATH"
 578         else
 579                 GUILE_PATH="$PATH"
 580         fi
 581
 582         AC_PATH_PROG(GUILE_CONFIG, guile-config, no, $GUILE_PATH)
 583
 584         ## First, let's just see if we can find Guile at all.
 585         if test "$GUILE_CONFIG" != no; then
 586                 cf_result="yes";
 587
 588                 GUILE_LIBS="`guile-config link`"
 589                 GUILE_CFLAGS="`guile-config compile`"
 590                 LIBS="$GUILE_LIBS $LIBS"
 591                 CPPFLAGS="$CPPFLAGS $GUILE_CFLAGS"
 592                 EL_CONFIG(CONFIG_GUILE, [Guile])
 593                 AC_SUBST(GUILE_CFLAGS)
 594                 cat <<EOF
 595 ***********************************************************************
 596 The Guile support is incomplete and not so well integrated to ELinks
 597 yet. That means, ie., that you have no Guile console and there might
 598 not be all the necessary hooks. Also, the Guile interface is not too
 599 well tested (success stories heartily welcomed!).  See
 600 src/scripting/guile/README for further details and hints.
 601 ***********************************************************************
 602 EOF
 603         else
 604                 if test -n "$withval" && test "x$withval" != xno; then
 605                         AC_MSG_ERROR([Guile not found])
 606                 else
 607                         AC_MSG_WARN([Guile support disabled])
 608                 fi
 609         fi
 610 else
 611         AC_MSG_RESULT(no);
 612 fi
 613
 614 dnl ===================================================================
 615 dnl Check for Perl
 616 dnl ===================================================================
 617 enable_perl="no";
 618
 619 AC_ARG_WITH(perl, [  --with-perl             enable Perl support],
 620             [
 621 if test "$withval" = yes; then
 622         # FIXME: If withval is a valid directory append it to PATH
 623         # so that you can specify one of several perl installations.
 624         withval="";
 625         enable_perl=yes;
 626 fi
 627             ])
 628
 629 AC_MSG_CHECKING([for Perl])
 630
 631 cf_result=no
 632
 633 EL_SAVE_FLAGS
 634
 635 if test "$enable_perl" = "yes"; then
 636         PERL_LIBS="`perl -MExtUtils::Embed -e ldopts`"
 637         PERL_CFLAGS="`perl -MExtUtils::Embed -e ccopts`"
 638         LIBS="$PERL_LIBS $LIBS"
 639         CFLAGS="$PERL_CFLAGS $CFLAGS"
 640         CPPFLAGS="$CPPFLAGS $PERL_CFLAGS"
 641         AC_TRY_LINK([
 642 #include <EXTERN.h>
 643 #include <perl.h>
 644 #include <perlapi.h>
 645 ],
 646                     [PerlInterpreter *my_perl = perl_alloc();],
 647                     cf_result=yes, cf_result=no)
 648 fi
 649
 650 if test "$cf_result" != "yes"; then
 651         EL_RESTORE_FLAGS
 652 else
 653         EL_CONFIG(CONFIG_PERL, [Perl])
 654
 655         CFLAGS="$CFLAGS_X"
 656         AC_SUBST(PERL_LIBS)
 657         AC_SUBST(PERL_CFLAGS)
 658 fi
 659
 660 if test "$cf_result"; then AC_MSG_RESULT($cf_result); fi
 661 dnl ===================================================================
 662 dnl Check for Python
 663 dnl ===================================================================
 664 enable_python="no";
 665
 666 AC_ARG_WITH(python, [  --with-python           enable Python support],
 667             [
 668 if test "$withval" = yes; then
 669         # FIXME: If withval is a valid directory append it to PATH
 670         # so that you can specify one of several Python installations.
 671         withval="";
 672         enable_python=yes;
 673         cat <<EOF
 674 ***********************************************************************
 675 The Python support is incomplete and not so well integrated to ELinks
 676 yet. That means, ie., that you have no Python console and there might
 677 not be all the necessary hooks. Also, the Python interface is not too
 678 well tested (success stories heartily welcomed!).
 679 ***********************************************************************
 680 EOF
 681 fi
 682             ])
 683
 684 AC_MSG_CHECKING([for Python])
 685
 686 cf_result=no
 687
 688 EL_SAVE_FLAGS
 689
 690 if test "$enable_python" = "yes"; then
 691         PYTHON_LIBS="-lpython"
 692         PYTHON_CFLAGS="-I`python -c 'from distutils import sysconfig; print sysconfig.get_python_inc()' 2> /dev/null`"
 693         LIBS="$PYTHON_LIBS $LIBS"
 694         CFLAGS="$PYTHON_CFLAGS $CFLAGS"
 695         CPPFLAGS="$CPPFLAGS $PYTHON_CFLAGS"
 696         AC_TRY_LINK([
 697 #include <Python.h>
 698 ],
 699                     [Py_Initialize();],
 700                     cf_result=yes, cf_result=no)
 701 fi
 702
 703 if test "$cf_result" != "yes"; then
 704         EL_RESTORE_FLAGS
 705 else
 706         EL_CONFIG(CONFIG_PYTHON, [Python])
 707
 708         CFLAGS="$CFLAGS_X"
 709         AC_SUBST(PYTHON_LIBS)
 710         AC_SUBST(PYTHON_CFLAGS)
 711 fi
 712
 713 if test "$cf_result"; then AC_MSG_RESULT($cf_result); fi
 714
 715
 716 dnl ===================================================================
 717 dnl Check for Lua, optional even if installed.
 718 dnl ===================================================================
 719
 720 dnl Do this the long way, as FreeBSD reportedly needs -L<dir> for
 721 dnl anything other than /usr/lib, and Lua is very often in /usr/local/lib.
 722
 723 AC_ARG_WITH(lua, [  --without-lua           disable Lua support],
 724             [if test "$withval" = no; then disable_lua=yes; fi])
 725 AC_MSG_CHECKING([for Lua])
 726
 727 EL_SAVE_FLAGS
 728 cf_result=no
 729
 730 if test -z "$disable_lua"; then
 731         if test ! -d "$withval"; then
 732                 withval="";
 733         fi
 734         for luadir in "$withval" "" /usr /usr/local; do
 735                 for suffix in "" 50 51; do
 736                         if test "$cf_result" = no; then
 737                                 LUA_LIBS="-llua$suffix -llualib$suffix -lm"
 738
 739                                 if test ! -z "$luadir"; then
 740                                         LUA_LIBS="-L$luadir/lib $LUA_LIBS"
 741                                         LUA_CFLAGS="-I$luadir/include -I$luadir/include/lua$suffix"
 742                                 fi
 743
 744                                 LIBS="$LUA_LIBS $LIBS_X"
 745                                 CFLAGS="$CFLAGS_X $LUA_CFLAGS"
 746                                 CPPFLAGS="$CPPFLAGS_X $LUA_CFLAGS"
 747
 748                                 # Check that it is a compatible Lua version
 749                                 AC_TRY_LINK([   #include <lua.h>
 750                                                 #include <lualib.h>],
 751                                             [   lua_State *L = lua_open();
 752                                                 lua_baselibopen(L);
 753                                                 lua_mathlibopen(L);
 754                                                 lua_strlibopen(L);
 755                                                 lua_tablibopen(L);
 756                                                 lua_pushboolean(L, 1);
 757                                                 lua_close(L);],
 758                                             cf_result=yes, cf_result=no)
 759                         fi
 760                 done
 761         done
 762 fi
 763
 764 AC_MSG_RESULT($cf_result)
 765
 766 if test "$cf_result" != yes; then
 767         EL_RESTORE_FLAGS
 768 else
 769         EL_CONFIG(CONFIG_LUA, [Lua])
 770         AC_CHECK_HEADERS(lauxlib.h)
 771
 772         CFLAGS="$CFLAGS_X"
 773         AC_SUBST(LUA_LIBS)
 774         AC_SUBST(LUA_CFLAGS)
 775 fi
 776
 777
 778 dnl ===================================================================
 779 dnl Check for Ruby, optional even if installed.
 780 dnl ===================================================================
 781
 782 EL_CONFIG_RUBY
 783
 784 dnl ===================================================================
 785 dnl Optional Spidermonkey-based ECMAScript browser scripting
 786 dnl ===================================================================
 787
 788 AC_ARG_ENABLE(sm-scripting,
 789               [  --disable-sm-scripting  ECMAScript browser scripting (requires Spidermonkey)],
 790               [if test "$enableval" != no; then enableval="yes"; fi
 791                CONFIG_SM_SCRIPTING="$enableval";])
 792
 793 if test "x$CONFIG_SPIDERMONKEY" = xyes &&
 794    test "x$CONFIG_SM_SCRIPTING" = xyes; then
 795         EL_CONFIG(CONFIG_SM_SCRIPTING, [SpiderMonkey])
 796 else
 797         CONFIG_SM_SCRIPTING=no
 798 fi
 799
 800 dnl ===================================================================
 801 dnl Setup global scripting
 802 dnl ===================================================================
 803
 804 EL_CONFIG_DEPENDS(CONFIG_SCRIPTING, [CONFIG_GUILE CONFIG_LUA CONFIG_PERL CONFIG_PYTHON CONFIG_RUBY CONFIG_SM_SCRIPTING], [Browser scripting])
 805 AC_SUBST(CONFIG_GUILE)
 806 AC_SUBST(CONFIG_LUA)
 807 AC_SUBST(CONFIG_PERL)
 808 AC_SUBST(CONFIG_PYTHON)
 809 AC_SUBST(CONFIG_RUBY)
 810 AC_SUBST(CONFIG_SM_SCRIPTING)
 811 AC_SUBST(CONFIG_SCRIPTING)
 812
 813
 814 dnl ===================================================================
 815 dnl Check for SSL support.
 816 dnl ===================================================================
 817
 818 dnl We by default use OpenSSL, and we always prefer it. However, when GNUTLS
 819 dnl is enabled, we won't try to use OpenSSL anymore.
 820
 821 dnl For wiping SSL hooks..
 822 #ifdef CONFIG_SSL
 823
 824 disable_openssl=""
 825 disable_gnutls=""
 826 enable_gnutls=""
 827
 828 AC_ARG_WITH(gnutls, [  --without-gnutls        disable GNUTLS SSL support],
 829             [if test "$with_gnutls" = no;  then disable_gnutls=yes; fi])
 830 AC_ARG_WITH(gnutls, [  --with-gnutls[=DIR]     enable GNUTLS SSL support],
 831             [if test "$with_gnutls" != no;  then enable_gnutls=yes; fi])
 832 gnutls_withval="$withval"
 833
 834 if test "$enable_gnutls" = yes; then
 835         disable_openssl=yes;
 836 fi
 837
 838 AC_ARG_WITH(openssl, [  --without-openssl       disable OpenSSL support],
 839             [if test "$with_openssl" = no;  then disable_openssl=yes; fi])
 840 AC_ARG_WITH(openssl, [  --with-openssl[=DIR]    enable OpenSSL support (default)])
 841 openssl_withval="$withval"
 842
 843 dnl ---- OpenSSL
 844
 845 AC_MSG_CHECKING([for OpenSSL])
 846
 847 EL_SAVE_FLAGS
 848 cf_result="no"
 849
 850 if test "$disable_openssl" = yes; then
 851         cf_result="not used"
 852 else
 853         for ssldir in "$openssl_withval" "" /usr /usr/local/openssl \
 854                          /usr/lib/openssl /usr/local/ssl \
 855                          /usr/local/www /usr/lib/ssl /usr/local \
 856                          /usr/pkg /opt /opt/openssl; do
 857                 if test "$cf_result" = no; then
 858                         if test -d "$ssldir"; then
 859                                 OPENSSL_CFLAGS="-I$ssldir/include"
 860                                 LIBS="-L$ssldir/lib -lssl -lcrypto $LIBS_X"
 861                                 CFLAGS="$CFLAGS_X $OPENSSL_CFLAGS"
 862                                 CPPFLAGS="$CPPFLAGS_X $OPENSSL_CFLAGS"
 863 #                               # FIXME: This created serious portability problems. --pasky
 864 #                               if test "$CC" == "gcc"; then
 865 #                                       # I'm not sure about compatibility here. --pasky
 866 #                                       LIBS="$LIBS -R$ssldir/lib"
 867 #                               fi
 868                         else
 869                                 LIBS="-lssl -lcrypto $LIBS_X"
 870                         fi
 871                         AC_TRY_LINK([#include <openssl/ssl.h>],
 872                                     [OpenSSL_add_all_algorithms()],
 873                                     cf_result=yes, cf_result=no)
 874                         if test "$cf_result" != yes; then
 875                                 AC_TRY_LINK([#include <openssl/ssl.h>],
 876                                             [SSLeay_add_ssl_algorithms()],
 877                                             cf_result=yes, cf_result=no)
 878                         fi
 879                 fi
 880         done
 881
 882         if test "$cf_result" != yes; then
 883                 if test -n "$openssl_withval" && test "x$openssl_withval" != xno; then
 884                         AC_MSG_ERROR([OpenSSL not found])
 885                 fi
 886                 EL_RESTORE_FLAGS
 887         else
 888                 EL_CONFIG(CONFIG_OPENSSL, [OpenSSL])
 889
 890                 CFLAGS="$CFLAGS_X"
 891                 AC_SUBST(OPENSSL_CFLAGS)
 892         fi
 893 fi
 894
 895 AC_MSG_RESULT($cf_result)
 896
 897 dnl ---- GNU TLS
 898 dnl We can't have AC_MSG_CHECKING here, because AC_PATH_PROG prints its own and
 899 dnl it looks ugly then.
 900
 901 if test "$cf_result" = yes; then
 902         cf_result="not used"
 903
 904 else
 905         EL_SAVE_FLAGS
 906         cf_result="no"
 907
 908         if test -z "$disable_gnutls"; then
 909                 # Sure, we maybe _could_ use their macro, but how to ensure
 910                 # that the ./configure script won't fail if the macro won't be
 911                 # found..? :( --pasky
 912
 913                 GNUTLS_PATH="$PATH:/usr/local/gnutls:/opt:/opt/gnutls"
 914
 915                 if test -d "$gnutls_withval"; then
 916                         GNUTLS_PATH="$gnutls_withval:$GNUTLS_PATH"
 917                 fi
 918
 919                 AC_PATH_PROG(LIBGNUTLS_CONFIG, libgnutls-config, no, $GNUTLS_PATH)
 920
 921                 if test "$LIBGNUTLS_CONFIG" = "no" ; then
 922                         cf_result=no
 923                 else
 924                         GNUTLS_CFLAGS=`$LIBGNUTLS_CONFIG --cflags`
 925                         GNUTLS_LIBS=`$LIBGNUTLS_CONFIG --libs`
 926
 927                         LIBS="$GNUTLS_LIBS $LIBS_X"
 928                         CFLAGS="$CFLAGS_X $GNUTLS_CFLAGS"
 929                         CPPFLAGS="$CPPFLAGS_X $GNUTLS_CFLAGS"
 930
 931                         # Verify if it's really usable.  gnutls_session was
 932                         # renamed to gnutls_session_t before GNU TLS 1.2.0
 933                         # (on 2004-06-13); ELinks now requires this.
 934                         AC_TRY_LINK([#include <gnutls/gnutls.h>],
 935                                     [gnutls_session_t dummy;
 936                                      gnutls_check_version(NULL)],
 937                                     cf_result=yes, cf_result=no)
 938                 fi
 939
 940                 if test "$cf_result" = yes; then
 941                         EL_CONFIG(CONFIG_GNUTLS, [GNUTLS])
 942
 943                         CFLAGS="$CFLAGS_X"
 944                         AC_SUBST(GNUTLS_CFLAGS)
 945
 946                         # Verify if the MD5 compatibility layer is usable.
 947                         CONFIG_GNUTLS_OPENSSL_COMPAT=yes
 948                         EL_CHECK_OPTIONAL_LIBRARY(CONFIG_GNUTLS_OPENSSL_COMPAT,
 949                                                   [GNU TLS OpenSSL compatibility],
 950                                                   gnutls/openssl.h, gnutls-openssl,
 951                                                   MD5_Init)
 952                 else
 953                         if test -n "$gnutls_withval" && test "x$gnutls_withval" != xno; then
 954                                 AC_MSG_ERROR([GNUTLS (1.2 or later) not found.  ELinks no longer supports GNUTLS 1.1.])
 955                         fi
 956                         EL_RESTORE_FLAGS
 957                 fi
 958         fi
 959 fi
 960
 961 AC_MSG_CHECKING([for GNU TLS (1.2 or later)])
 962 AC_MSG_RESULT($cf_result)
 963
 964 dnl Final SSL setup
 965
 966 EL_CONFIG_DEPENDS(CONFIG_SSL, [CONFIG_OPENSSL CONFIG_GNUTLS], [SSL])
 967 AC_SUBST(CONFIG_OPENSSL)
 968 AC_SUBST(CONFIG_GNUTLS)
 969
 970 #endif
 971
 972 AC_MSG_CHECKING([whether to be or not to be])
 973 AC_MSG_RESULT([needs to be determined experimentally])
 974
 975 dnl ===================================================================
 976 dnl Check for IPv6 support and related functions.
 977 dnl ===================================================================
 978
 979 EL_CHECK_NET_TYPE(struct sockaddr_storage, HAVE_SA_STORAGE, [])
 980 EL_CHECK_NET_TYPE(struct sockaddr_in6, HAVE_SA_IN6, [#include <netinet/in.h>])
 981 EL_CHECK_NET_TYPE(struct addrinfo, HAVE_ADDRINFO, [#include <netdb.h>])
 982
 983 AC_CHECK_FUNC(getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
 984 if test "$HAVE_GETADDRINFO" != yes; then
 985         AC_CHECK_LIB(inet6, getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
 986         if test "$HAVE_GETADDRINFO" = yes; then
 987                 LIBS="$LIBS -linet6"
 988         fi
 989 fi
 990
 991
 992 dnl ===================================================================
 993 dnl Checking for X11 (window title restoring).
 994 dnl ===================================================================
 995
 996 AC_PATH_X
 997 if test x"$no_x" != xyes; then
 998         if test -n "$x_includes"; then
 999                 X_CFLAGS="-I$x_includes"
1000                 CPPFLAGS="$CPPFLAGS -I$x_includes"
1001         fi
1002         if test -n "$x_libraries"; then
1003                 LDFLAGS="$LDFLAGS -L$x_libraries"
1004         fi
1005         LIBS="-lX11 $LIBS"
1006         EL_DEFINE(HAVE_X11, [X11 for restoring window titles])
1007         AC_SUBST(X_CFLAGS)
1008 fi
1009
1010
1011 dnl ===================================================================
1012 dnl Backtraces displaying support.
1013 dnl ===================================================================
1014
1015 AC_CHECK_HEADERS(execinfo.h, HAVE_EXECINFO=yes, HAVE_EXECINFO=no)
1016 # possible checks for other system-specific means go here
1017
1018
1019 dnl ===================================================================
1020 dnl SMB protocol support.
1021 dnl ===================================================================
1022
1023 AC_CHECK_PROG(HAVE_SMBCLIENT, smbclient, yes, no)
1024
1025
1026 dnl ===================================================================
1027 dnl Gettext grey zone. Beware.
1028 dnl ===================================================================
1029
1030 ALL_LINGUAS="be bg ca cs da de el es et fi fr gl hr hu id is it lt nl nb pl pt pt_BR ro ru sk sr sv tr uk"
1031
1032 AM_GNU_GETTEXT
1033
1034 dnl AC_MSG_CHECKING([how many characters your English alphabet has])
1035 dnl # f33r d4 l33t... I hope it's portable. :)
1036 dnl cf_result=$((48#z - 48#a + 1));
1037 dnl AC_MSG_RESULT($cf_result)
1038
1039
1040 dnl ===================================================================
1041 dnl Compile-time features control
1042 dnl ===================================================================
1043
1044 EL_ARG_ENABLE(CONFIG_COOKIES, cookies, [Cookies],
1045               [  --disable-cookies       disable cookie support])
1046
1047 EL_ARG_ENABLE(CONFIG_FORMHIST, formhist, [Form history],
1048               [  --disable-formhist      disable form history support])
1049
1050 EL_ARG_ENABLE(CONFIG_GLOBHIST, globhist, [Global history],
1051               [  --disable-globhist      disable global history support])
1052
1053
1054 EL_ARG_ENABLE(CONFIG_MAILCAP, mailcap, [Mailcap],
1055               [  --disable-mailcap       disable mailcap support])
1056
1057 EL_ARG_ENABLE(CONFIG_MIMETYPES, mimetypes, [Mimetypes files],
1058               [  --disable-mimetypes     disable mimetypes files support])
1059
1060
1061 EL_ARG_DEPEND(CONFIG_IPV6, ipv6,
1062               [HAVE_SA_STORAGE:yes HAVE_SA_IN6:yes HAVE_ADDRINFO:yes HAVE_GETADDRINFO:yes],
1063               [IPv6],
1064               [  --disable-ipv6          disable IPv6 support])
1065
1066 EL_ARG_ENABLE(CONFIG_BITTORRENT, bittorrent, [BitTorrent protocol],
1067               [  --enable-bittorrent     enable BitTorrent protocol support])
1068
1069 EL_ARG_ENABLE(CONFIG_DATA, data, [Data protocol],
1070               [  --disable-data          disable data protocol support])
1071
1072 EL_ARG_ENABLE(CONFIG_URI_REWRITE, uri-rewrite, [URI rewriting],
1073               [  --disable-uri-rewrite   disable URI rewrite support])
1074
1075 EL_ARG_DEPEND(CONFIG_CGI, cgi, [HAVE_SETENV_OR_PUTENV:yes], [Local CGI],
1076               [  --enable-cgi            enable local CGI support])
1077
1078 EL_ARG_ENABLE(CONFIG_FINGER, finger, [Finger protocol],
1079               [  --enable-finger         enable finger protocol support])
1080
1081 EL_ARG_ENABLE(CONFIG_FTP, ftp, [FTP protocol],
1082               [  --disable-ftp           disable ftp protocol support])
1083
1084 EL_ARG_ENABLE(CONFIG_GOPHER, gopher, [Gopher protocol],
1085               [  --enable-gopher         enable gopher protocol support])
1086
1087 EL_ARG_ENABLE(CONFIG_NNTP, nntp, [NNTP protocol],
1088               [  --enable-nntp           enable nntp protocol support])
1089
1090 EL_ARG_DEPEND(CONFIG_SMB, smb, [HAVE_SMBCLIENT:yes], [SMB protocol],
1091               [  --disable-smb           disable SMB protocol support (requires smbclient)])
1092
1093
1094 EL_ARG_ENABLE(CONFIG_MOUSE, mouse, [Mouse handling],
1095               [  --disable-mouse         disable mouse support])
1096
1097 # GPM mouse is Linux specific, so ...
1098 CONFIG_SYSMOUSE=yes
1099 EL_ARG_DEPEND(CONFIG_SYSMOUSE, sysmouse,
1100               [CONFIG_MOUSE:yes CONFIG_GPM:no HAVE_SYSMOUSE_HEADER:yes],
1101               [BSD sysmouse],
1102               [  --disable-sysmouse      disable BSD sysmouse support])
1103
1104 EL_ARG_ENABLE(CONFIG_88_COLORS, 88-colors, [88 colors],
1105               [  --enable-88-colors      enable 88 color support])
1106
1107 EL_ARG_ENABLE(CONFIG_256_COLORS, 256-colors, [256 colors],
1108               [  --enable-256-colors     enable 256 color support])
1109
1110
1111 EL_ARG_ENABLE(CONFIG_EXMODE, exmode, [Exmode interface],
1112               [  --enable-exmode         enable exmode (CLI) interface])
1113
1114 EL_ARG_ENABLE(CONFIG_LEDS, leds, [LEDs],
1115               [  --disable-leds          disable LEDs support])
1116
1117 EL_ARG_ENABLE(CONFIG_MARKS, marks, [Marks],
1118               [  --disable-marks         disable document marks support])
1119
1120
1121 EL_ARG_ENABLE(CONFIG_CSS, css, [Cascading Style Sheets],
1122               [  --disable-css           disable Cascading Style Sheet support])
1123
1124 EL_ARG_DEPEND(CONFIG_HTML_HIGHLIGHT, html-highlight, [CONFIG_CSS:yes], [HTML highlighting],
1125               [  --enable-html-highlight HTML highlighting using DOM engine])
1126
1127 dnl Everything in the tree already uses CONFIG_DOM
1128 dnl so resolve CONFIG_HTML_HIGHLIGHT to CONFIG_DOM
1129 EL_CONFIG_DEPENDS(CONFIG_DOM, [CONFIG_HTML_HIGHLIGHT], [DOM engine])
1130
1131 EL_ARG_DEPEND(CONFIG_BACKTRACE, backtrace, [HAVE_EXECINFO:yes], [Backtrace],
1132               [  --disable-backtrace     disable backtrace support])
1133
1134 EL_ARG_DEPEND(CONFIG_NO_ROOT_EXEC, no-root, [HAVE_GETUID:yes HAVE_GETEUID:yes], [No root exec],
1135               [  --enable-no-root        enable prevention of usage by root])
1136
1137
1138 EL_ARG_ENABLE(CONFIG_DEBUG, debug, [Debug mode],
1139               [  --enable-debug          enable leak debug and internal error checking])
1140
1141 EL_ARG_DEPEND(CONFIG_FASTMEM, fastmem, [CONFIG_DEBUG:no], [Fast mode],
1142               [  --enable-fastmem        enable direct use of system allocation functions, not usable with --enable-debug])
1143
1144 EL_ARG_ENABLE(CONFIG_OWN_LIBC, own-libc, [Own libc stubs],
1145               [  --enable-own-libc       force use of internal functions instead of those of system libc])
1146
1147 EL_ARG_ENABLE(CONFIG_SMALL, small, [Small binary],
1148               [  --enable-small          reduce binary size as far as possible (but see the bottom of doc/small.txt!)])
1149
1150 if test "$CONFIG_OPENSSL" != yes &&
1151    test "$CONFIG_GNUTLS_OPENSSL_COMPAT" != yes ||
1152    test "$CONFIG_OWN_LIBC" = yes;
1153 then
1154         AC_MSG_CHECKING(for built-in MD5 support)
1155         AC_MSG_RESULT(yes)
1156         EL_CONFIG(CONFIG_MD5, [Built-in MD5])
1157 fi
1158
1159 AC_SUBST(CONFIG_MD5)
1160
1161 if test "$CONFIG_BITTORRENT" = yes; then
1162         if test "$CONFIG_OPENSSL" != yes ||
1163            test "$CONFIG_OWN_LIBC" = yes;
1164         then
1165                 AC_MSG_CHECKING(for built-in SHA1 support)
1166                 AC_MSG_RESULT(yes)
1167                 EL_CONFIG(CONFIG_SHA1, [Built-in SHA1])
1168         fi
1169 fi
1170
1171 AC_SUBST(CONFIG_SHA1)
1172
1173 if test "$CONFIG_CSS" = yes || test "$CONFIG_DOM" = yes;
1174 then
1175         EL_CONFIG(CONFIG_SCANNER, [Built-in scanner])
1176 fi
1177 AC_SUBST(CONFIG_SCANNER)
1178
1179 AC_ARG_ENABLE(weehoofooboomookerchoo,
1180               [
1181     Also check out the features.conf file for more information about features!
1182               ],
1183               [AC_MSG_ERROR(Are you strange, or what?)])
1184
1185
1186 dnl == EMX hack
1187
1188 test "$CONFIG_OS2" = yes && LDFLAGS="$LDFLAGS -Zexe"
1189 test "$CONFIG_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zbin-files//g"`
1190
1191
1192 dnl ===================================================================
1193 dnl Export directory paths
1194 dnl ===================================================================
1195
1196 # Set up the ``entry points'' if they were not supplied by builder
1197 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1198 test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1199
1200 # Create CONFDIR #define for config.h
1201
1202 # XXX: This may be dependent on a particular version of autoconf. Whatever,
1203 # it's autoconf fault to force us to do such hacks ;p.
1204 if test x"$sysconfdir" = x"\${prefix}/etc"; then
1205   # sysconfdir is set to its default value... fine, let's append /elinks/
1206   # XXX: We can't modify listing of the default in ./configure --help :-(
1207   sysconfdir_n=`eval echo "$sysconfdir"`
1208   sysconfdir=$sysconfdir_n
1209   (echo "$sysconfdir" | grep elinks >/dev/null 2>/dev/null) || \
1210         sysconfdir="$sysconfdir/elinks"
1211 fi
1212
1213 CONFDIR=$sysconfdir
1214 AC_DEFINE_UNQUOTED(CONFDIR, "$CONFDIR", [Directory containing default config])
1215 AC_SUBST(CONFDIR)
1216
1217 # Create LOCALEDIR #define for config.h
1218 LOCALEDIR=`eval echo "$datadir/locale"`
1219 AC_DEFINE_UNQUOTED(LOCALEDIR, "$LOCALEDIR", [Directory containing locales])
1220 AC_SUBST(LOCALEDIR)
1221
1222 # Create LIBDIR #define for config.h
1223 LIBDIR=`eval echo "$libdir"`
1224 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [Directory containing libraries])
1225 AC_SUBST(LIBDIR)
1226
1227 EL_LOG_CONFIG(CONFDIR, [System configuration directory], [])
1228 EL_LOG_CONFIG(LOCALEDIR, [Locale catalogs directory], [])
1229
1230 dnl ===================================================================
1231 dnl A little fine tuning of gcc specific options (continued)
1232 dnl ===================================================================
1233
1234 if test "x$ac_cv_prog_gcc" = "xyes"; then
1235   if test "$CONFIG_DEBUG" = "yes"; then
1236     dnl We want to see all warnings and live with none (in debug mode).
1237     CFLAGS="$CFLAGS -Werror"
1238   fi
1239
1240   case "`$CC -dumpversion`" in
1241     3.0|3.1|3.2)
1242       # These should be ok using -Werror
1243       ;;
1244     3.*)
1245       # If gcc is version 3.3 (or higher?) it emits lots of false positive
1246       # "dereferencing type-punned pointer will break strict-aliasing rules"
1247       # warnings. Disable them by not doing any strict-aliasing. The
1248       # alternative is just too ugly. Thanks gcc guys!! ;)
1249       CFLAGS="$CFLAGS -fno-strict-aliasing"
1250       ;;
1251     4.*)
1252       # Do not show warnings related to (char * | unsigned char *) type
1253       # difference.
1254       CFLAGS="$CFLAGS -fno-strict-aliasing -Wno-pointer-sign"
1255       ;;
1256     *)
1257       # These should be ok using -Werror
1258       ;;
1259   esac
1260 fi
1261
1262 # CFLAGS doesn't contain all compile flags. Some will be added only when
1263 # needed in the respective source directory. To get all compile flags
1264 # easily just add CPPFLAGS.
1265 ALL_CFLAGS="$CFLAGS $CPPFLAGS"
1266
1267 EL_LOG_CONFIG(ALL_CFLAGS, [Compiler options (CFLAGS)], [])
1268 EL_LOG_CONFIG(LIBS, [Linker options (LIBS)], [])
1269
1270 dnl ===================================================================
1271 dnl Colored make output
1272 dnl ===================================================================
1273
1274 if test $(`which tput` colors) -ge 4; then
1275         MAKE_COLOR=1
1276         AC_SUBST(MAKE_COLOR)
1277 fi
1278
1279 dnl ===================================================================
1280 dnl Generated files
1281 dnl ===================================================================
1282
1283 AC_OUTPUT([ \
1284  Makefile.config \
1285  contrib/elinks.spec \
1286  contrib/lua/hooks.lua \
1287  contrib/conv/w3m2links.awk \
1288  doc/man/man1/elinks.1 \
1289  src/intl/gettext/ref-add.sed \
1290  src/intl/gettext/ref-del.sed
1291 ])
1292
1293 abs_srcdir="$(cd "$srcdir" && pwd)"
1294 # builddir is always absolute!
1295 if test "$abs_srcdir" != "$builddir"; then
1296         echo "include $abs_srcdir/Makefile" > "$builddir/Makefile"
1297         "$MAKE" "SRC=$abs_srcdir" init
1298 fi
1299
1300
1301 dnl ===================================================================
1302 dnl Configuration summary
1303 dnl ===================================================================
1304
1305 AC_MSG_RESULT(The following feature summary has been saved to features.log)
1306 cat features.log