contrib/ncurses-5.4/mk-2nd.awk

   1 # $Id: mk-2nd.awk,v 1.15 2003/11/01 22:42:50 tom Exp $
   2 ##############################################################################
   3 # Copyright (c) 1998-2000,2003 Free Software Foundation, Inc.                #
   4 #                                                                            #
   5 # Permission is hereby granted, free of charge, to any person obtaining a    #
   6 # copy of this software and associated documentation files (the "Software"), #
   7 # to deal in the Software without restriction, including without limitation  #
   8 # the rights to use, copy, modify, merge, publish, distribute, distribute    #
   9 # with modifications, sublicense, and/or sell copies of the Software, and to #
  10 # permit persons to whom the Software is furnished to do so, subject to the  #
  11 # following conditions:                                                      #
  12 #                                                                            #
  13 # The above copyright notice and this permission notice shall be included in #
  14 # all copies or substantial portions of the Software.                        #
  15 #                                                                            #
  16 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR #
  17 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,   #
  18 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL    #
  19 # THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER      #
  20 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING    #
  21 # FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER        #
  22 # DEALINGS IN THE SOFTWARE.                                                  #
  23 #                                                                            #
  24 # Except as contained in this notice, the name(s) of the above copyright     #
  25 # holders shall not be used in advertising or otherwise to promote the sale, #
  26 # use or other dealings in this Software without prior written               #
  27 # authorization.                                                             #
  28 ##############################################################################
  29 #
  30 # Author: Thomas E. Dickey
  31 #
  32 # Generate compile-rules for the modules that we are using in libraries or
  33 # programs.  We are listing them explicitly because we have turned off the
  34 # suffix rules (to force compilation with the appropriate flags).  We could use
  35 # make-recursion but that would result in makefiles that are useless for
  36 # development.
  37 #
  38 # Variables:
  39 #       model
  40 #       MODEL (uppercase version of "model"; toupper is not portable)
  41 #       echo (yes iff we will show the $(CC) lines)
  42 #       subset ("none", "base", "base+ext_funcs" or "termlib")
  43 #
  44 # Fields in src/modules:
  45 #       $1 = module name
  46 #       $2 = progs|lib|c++
  47 #       $3 = source-directory
  48 #
  49 # Fields in src/modules past $3 are dependencies
  50 #
  51 BEGIN   {
  52                 found = 0
  53                 using = 0
  54         }
  55         /^@/ {
  56                 using = 0
  57                 if (subset == "none") {
  58                         using = 1
  59                 } else if (index(subset,$2) > 0) {
  60                         if (using == 0) {
  61                                 if (found == 0) {
  62                                         print  ""
  63                                         print  "# generated by mk-2nd.awk"
  64                                         print  ""
  65                                 }
  66                                 using = 1
  67                         }
  68                 }
  69         }
  70         /^[@#]/ {
  71                 next
  72         }
  73         $1 ~ /trace/ {
  74                 if (traces != "all" && traces != MODEL && $1 != "lib_trace")
  75                         next
  76         }
  77         {
  78                 if ($0 != "" \
  79                  && using != 0) {
  80                         found = 1
  81                         if ( $1 != "" ) {
  82                                 print  ""
  83                                 if ( $2 == "c++" ) {
  84                                         compile="CXX"
  85                                         suffix=".cc"
  86                                 } else {
  87                                         compile="CC"
  88                                         suffix=".c"
  89                                 }
  90                                 printf "../%s/%s$o :\t%s/%s%s", model, $1, $3, $1, suffix
  91                                 for (n = 4; n <= NF; n++) printf " \\\n\t\t\t%s", $n
  92                                 print  ""
  93                                 if ( echo == "yes" )
  94                                         atsign=""
  95                                 else {
  96                                         atsign="@"
  97                                         printf "\t@echo 'compiling %s (%s)'\n", $1, model
  98                                 }
  99                                 if ( $3 == "." || srcdir == "." ) {
 100                                         dir = $3 "/"
 101                                         sub("^\\$\\(srcdir\\)/","",dir);
 102                                         sub("^\\./","",dir);
 103                                         printf "\t%scd ../%s; $(LIBTOOL_COMPILE) $(%s) $(CFLAGS_%s) -c ../%s/%s%s%s", atsign, model, compile, MODEL, name, dir, $1, suffix
 104                                 } else
 105                                         printf "\t%scd ../%s; $(LIBTOOL_COMPILE) $(%s) $(CFLAGS_%s) -c %s/%s%s", atsign, model, compile, MODEL, $3, $1, suffix
 106                         } else {
 107                                 printf "%s", $1
 108                                 for (n = 2; n <= NF; n++) printf " %s", $n
 109                         }
 110                         print  ""
 111                 }
 112         }
 113 END     {
 114                 print  ""
 115         }