glutils.d

   1 /* DooM2D: Midnight on the Firing Line
   2  * coded by Ketmar // Invisible Vector <ketmar@ketmar.no-ip.org>
   3  * Understanding is not required. Only obedience.
   4  *
   5  * This program is free software: you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation, either version 3 of the License, or
   8  * (at your option) any later version.
   9  *
  10  * This program is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with this program. If not, see <http://www.gnu.org/licenses/>.
  17  */
  18 module glutils is aliced;
  19 private:
  20 import iv.glbinds;
  21 import iv.vfs;
  22 import arsd.color;
  23 import arsd.png;
  24
  25 import wadarc;
  26 import jpeg;
  27
  28
  29 // ////////////////////////////////////////////////////////////////////////// //
  30 __gshared bool glutilsShowShaderWarnings = false; // shut up!
  31
  32 /*
  33 __gshared GLuint glLastUsedTexture = 0;
  34
  35 public void useTexture (GLuint tid) {
  36   pragma(inline, true);
  37   if (glLastUsedTexture != tid) {
  38     glLastUsedTexture = tid;
  39     glBindTexture(GL_TEXTURE_2D, tid);
  40   }
  41 }
  42
  43 public void useTexture (Texture tex) { pragma(inline, true); useTexture(tex !is null ? tex.tid : 0); }
  44 */
  45
  46
  47 public TrueColorImage loadPngFile (string fname) {
  48   auto fl = openFile(fname);
  49   auto sz = fl.size;
  50   if (sz < 4 || sz > 32*1024*1024) throw new Exception("invalid png file size: '"~fname~"'");
  51   if (sz == 0) return null;
  52   auto res = new ubyte[](cast(uint)sz);
  53   if (fl.rawRead(res[]).length != res.length) throw new Exception("error reading png file '"~fname~"'");
  54   return imageFromPng(readPng(res)).getAsTrueColorImage;
  55 }
  56
  57
  58 // ////////////////////////////////////////////////////////////////////////// //
  59 class OpenGLObject {
  60   abstract @property uint id () const pure nothrow @nogc;
  61
  62   final void activate () nothrow @nogc {
  63     if (gloSP >= gloStack.length) assert(0, "glo stack overflow");
  64     gloStack.ptr[gloSP++] = this;
  65     activateObj();
  66   }
  67
  68   final void deactivate () nothrow @nogc {
  69     foreach_reverse (usize idx; 0..gloStack.length) {
  70       if (gloStack.ptr[idx] is this) {
  71         // find previous object of this type
  72         foreach_reverse (usize pidx; 0..idx) {
  73           if (typeid(gloStack.ptr[pidx]) is typeid(gloStack.ptr[idx])) {
  74             gloStack.ptr[pidx].activateObj();
  75             removeFromStack(pidx);
  76             return;
  77           }
  78         }
  79         deactivateObj();
  80         removeFromStack(idx);
  81         return;
  82       }
  83     }
  84     assert(0, "trying to deactivate inactive object");
  85   }
  86
  87 protected:
  88   abstract void activateObj () nothrow @nogc;
  89   abstract void deactivateObj () nothrow @nogc;
  90 }
  91
  92
  93 __gshared OpenGLObject[1024] gloStack;
  94 __gshared uint gloSP = 0;
  95
  96
  97 public void gloStackClear () nothrow @nogc {
  98   bindTexture(0);
  99   //glBindTexture(GL_TEXTURE_CUBE_MAP, 0);
 100   glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, 0);
 101   glUseProgram(0);
 102 }
 103
 104
 105 void removeFromStack (usize idx) nothrow @nogc {
 106   if (idx >= gloSP) return;
 107   if (idx != gloSP-1) {
 108     import core.stdc.string : memmove;
 109     memmove(gloStack.ptr+idx, gloStack.ptr+idx+1, (gloSP-idx-1)*gloStack[0].sizeof);
 110   }
 111   --gloSP;
 112 }
 113
 114
 115 // ////////////////////////////////////////////////////////////////////////// //
 116 public final class Texture : OpenGLObject {
 117   GLuint tid;
 118   int width, height;
 119
 120   override @property uint id () const pure nothrow @nogc => tid;
 121
 122   // default: repeat, linear
 123   enum Option : int {
 124     Repeat,
 125     Clamp,
 126     ClampBorder,
 127     Linear,
 128     Nearest,
 129     UByte,
 130     Float, // create floating point texture
 131     Depth, // FBO: attach depth buffer
 132   }
 133
 134   this (string fname, in Option[] opts...) { loadImage(fname, opts); }
 135   this (int w, int h, in Option[] opts...) { createIntr(w, h, null, opts); }
 136   this (TrueColorImage aimg, Option[] opts...) { createIntr(aimg.width, aimg.height, aimg, opts); }
 137   ~this () { clear(); }
 138
 139
 140   void clear () {
 141     if (tid) {
 142       //useTexture(tid);
 143       bindTexture(tid);
 144       glDeleteTextures(1, &tid);
 145       //useTexture(0);
 146       bindTexture(0);
 147       tid = 0;
 148       width = 0;
 149       height = 0;
 150     }
 151   }
 152
 153   private static void processOpt (GLuint* wrapOpt, GLuint* filterOpt, GLuint* ttype, in Option[] opts...) {
 154     foreach (immutable opt; opts) {
 155       switch (opt) with (Option) {
 156         case Repeat: *wrapOpt = GL_REPEAT; break;
 157         case Clamp: *wrapOpt = GL_CLAMP_TO_EDGE; break;
 158         case ClampBorder: *wrapOpt = GL_CLAMP_TO_BORDER; break;
 159         case Linear: *filterOpt = GL_LINEAR; break;
 160         case Nearest: *filterOpt = GL_NEAREST; break;
 161         case UByte: *ttype = GL_UNSIGNED_BYTE; break;
 162         case Float: *ttype = GL_FLOAT; break;
 163         default:
 164       }
 165     }
 166   }
 167
 168   void createIntr (int w, int h, TrueColorImage img, in Option[] opts...) {
 169     import core.stdc.stdlib : malloc, free;
 170     assert(w > 0);
 171     assert(h > 0);
 172     clear();
 173
 174     GLuint wrapOpt = GL_REPEAT;
 175     GLuint filterOpt = GL_LINEAR;
 176     GLuint ttype = GL_UNSIGNED_BYTE;
 177     processOpt(&wrapOpt, &filterOpt, &ttype, opts);
 178
 179     glGenTextures(1, &tid);
 180     //useTexture(tid);
 181     auto oldtid = boundTexture;
 182     bindTexture(tid);
 183     scope(exit) bindTexture(oldtid);
 184     glTexParameterf(GL_TEXTURE_2D, GL_TEXTURE_WRAP_S, wrapOpt);
 185     glTexParameterf(GL_TEXTURE_2D, GL_TEXTURE_WRAP_T, wrapOpt);
 186     glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, filterOpt);
 187     glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, filterOpt);
 188     //glTexEnvf(GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_MODULATE);
 189     //glTexEnvf(GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE);
 190     GLfloat[4] bclr = 0.0;
 191     glTexParameterfv(GL_TEXTURE_2D, GL_TEXTURE_BORDER_COLOR, bclr.ptr);
 192     if (img !is null && img.width == w && img.height == h) {
 193       // create straight from image
 194       glTexImage2D(GL_TEXTURE_2D, 0, (ttype == GL_FLOAT ? GL_RGBA16F : GL_RGBA), w, h, 0, GL_RGBA, GL_UNSIGNED_BYTE, img.imageData.bytes.ptr);
 195     } else {
 196       // create empty texture
 197       ubyte* ptr = null;
 198       scope(exit) if (ptr !is null) free(ptr);
 199       {
 200         import core.stdc.string : memset;
 201         ptr = cast(ubyte*)malloc(w*h*4);
 202         if (ptr !is null) memset(ptr, 0, w*h*4);
 203       }
 204       glTexImage2D(GL_TEXTURE_2D, 0, (ttype == GL_FLOAT ? GL_RGBA16F : GL_RGBA), w, h, 0, GL_RGBA, GL_UNSIGNED_BYTE, ptr);
 205       if (img !is null && img.width > 0 && img.height > 0) {
 206         // setup from image
 207         //TODO: dunno if it's ok to use images bigger than texture here
 208         glTexSubImage2D(GL_TEXTURE_2D, 0,  0, 0, img.width, img.height, GL_RGBA, GL_UNSIGNED_BYTE, img.imageData.bytes.ptr);
 209         // the following is ok too
 210         //bindTexture(0);
 211         //glTextureSubImage2D(tid, 0,  0, 0, img.width, img.height, GL_RGBA, GL_UNSIGNED_BYTE, img.imageData.bytes.ptr);
 212       }
 213     }
 214     width = w;
 215     height = h;
 216   }
 217
 218   void setFromImage (TrueColorImage img, int x=0, int y=0) {
 219     if (img is null || !tid || img.height < 1 || img.width < 1) return;
 220     if (x >= width || y >= height) return;
 221     if (x+img.width <= 0 || y+img.height <= 0) return; //TODO: overflow
 222     if (x >= 0 && y >= 0 && x+img.width <= width && y+img.height <= height) {
 223       // easy case, just copy it
 224       glTextureSubImage2D(tid, 0, x, y, img.width, img.height, GL_RGBA, GL_UNSIGNED_BYTE, img.imageData.bytes.ptr);
 225     } else {
 226       import core.stdc.stdlib : malloc, free;
 227       import core.stdc.string : memset, memcpy;
 228       // hard case, have to build the temp region
 229       uint* src = cast(uint*)img.imageData.bytes.ptr;
 230       // calc x skip and effective width
 231       int rwdt = img.width;
 232       if (x < 0) {
 233         rwdt += x;
 234         src -= x; // as `x` is negative here
 235         x = 0;
 236       }
 237       if (x+rwdt > width) rwdt = width-x;
 238       // calc y skip and effective height
 239       int rhgt = img.height;
 240       if (y < 0) {
 241         rhgt += y;
 242         src -= y*img.width; // as `y` is negative here
 243         y = 0;
 244       }
 245       if (y+rhgt > height) rhgt = height-y;
 246       assert(rwdt > 0 && rhgt > 0);
 247       uint* ptr = null;
 248       scope(exit) if (ptr !is null) free(ptr);
 249       ptr = cast(uint*)malloc(rwdt*rhgt*4);
 250       if (ptr is null) assert(0, "out of memory in `Texture.setFromImage()`");
 251       // now copy
 252       auto d = ptr;
 253       foreach (immutable _; 0..rhgt) {
 254         memcpy(d, src, rwdt*4);
 255         src += img.width;
 256         d += rwdt;
 257       }
 258       glTextureSubImage2D(tid, 0, x, y, rwdt, rhgt, GL_RGBA, GL_UNSIGNED_BYTE, ptr);
 259     }
 260   }
 261
 262   void loadPng (VFile fl, in Option[] opts...) {
 263     auto flsize = fl.size-fl.tell;
 264     if (flsize < 8 || flsize > 1024*1024*32) throw new Exception("png image too big");
 265     auto data = new ubyte[](cast(uint)flsize);
 266     fl.rawReadExact(data);
 267     auto png = readPng(data);
 268     auto ximg = imageFromPng(png).getAsTrueColorImage;
 269     if (ximg is null) throw new Exception("png: wtf?!");
 270     if (ximg.width < 1 || ximg.height < 1) throw new Exception("png image too small");
 271     createIntr(ximg.width, ximg.height, ximg, opts);
 272   }
 273
 274   void loadJpeg (VFile fl, in Option[] opts...) {
 275     auto jpg = new JpegDecoder(fl, JpegDecoder.Upsampling.BILINEAR);
 276     if (jpg.image.width < 1 || jpg.image.width > 32760) throw new Exception("invalid image width");
 277     if (jpg.image.height < 1 || jpg.image.height > 32760) throw new Exception("invalid image height");
 278     createIntr(jpg.image.width, jpg.image.height, jpg.image, opts);
 279   }
 280
 281   void loadImage (string fname, in Option[] opts...) {
 282     scope(failure) clear;
 283     auto fl = VFile(fname);
 284     scope(failure) fl.seek(0);
 285     char[8] sign;
 286     fl.seek(0);
 287     fl.rawReadExact(sign[]);
 288     fl.seek(0);
 289     // png?
 290     if (sign == "\x89\x50\x4E\x47\x0D\x0A\x1A\x0A") {
 291       loadPng(fl, opts);
 292       return;
 293     }
 294     // jpeg?
 295     if (sign[0..2] == "\xff\xd8") {
 296       fl.seek(-2, Seek.End);
 297       fl.rawReadExact(sign[0..2]);
 298       fl.seek(0);
 299       if (sign[0..2] == "\xff\xd9") {
 300         loadJpeg(fl, opts);
 301         return;
 302       }
 303     }
 304     throw new Exception("invalid texture image format");
 305   }
 306
 307 protected:
 308   override void activateObj () nothrow @nogc { /*if (tid)*/ bindTexture(tid); }
 309   override void deactivateObj () nothrow @nogc { /*if (tid)*/ bindTexture(0); }
 310 }
 311
 312
 313 // ////////////////////////////////////////////////////////////////////////// //
 314 public final class FBO : OpenGLObject {
 315   int width;
 316   int height;
 317   GLuint fbo;
 318   Texture tex;
 319   Texture texdepth;
 320   //Texture.Option[] xopts;
 321
 322   override @property uint id () const pure nothrow @nogc => fbo;
 323
 324   this (Texture atex) { createWithTexture(atex); }
 325
 326   this (int wdt, int hgt, Texture.Option[] opts...) {
 327     //xopts = opts.dup;
 328     createWithTexture(new Texture(wdt, hgt, opts), opts);
 329   }
 330
 331   ~this () {
 332     //FIXME: this may be wrong, as texture may be already destroyed (and it's wrong too); we need refcount for textures
 333     glFramebufferTexture2DEXT(GL_FRAMEBUFFER_EXT, GL_COLOR_ATTACHMENT0_EXT, GL_TEXTURE_2D, 0, 0);
 334     glDeleteFramebuffersEXT(1, &fbo);
 335     fbo = 0;
 336   }
 337
 338   void clear () {
 339     if (fbo) {
 340       // detach texture
 341       glFramebufferTexture2DEXT(GL_FRAMEBUFFER_EXT, GL_COLOR_ATTACHMENT0_EXT, GL_TEXTURE_2D, 0, 0);
 342       glDeleteFramebuffersEXT(1, &fbo);
 343       glFramebufferTexture2DEXT(GL_FRAMEBUFFER_EXT, GL_DEPTH_ATTACHMENT, GL_TEXTURE_2D, 0, 0);
 344       glDeleteFramebuffersEXT(1, &fbo);
 345       fbo = 0;
 346     }
 347     if (tex !is null) tex.clear();
 348     tex = null;
 349     if (texdepth !is null) texdepth.clear();
 350     texdepth = null;
 351   }
 352
 353 protected:
 354   override void activateObj () nothrow @nogc { /*if (fbo)*/ glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, fbo); }
 355   override void deactivateObj () nothrow @nogc { glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, 0); }
 356
 357   // this will deactivate current FBO!
 358   /+
 359   void replaceTexture (Texture ntex) {
 360     if (tex !is null) {
 361       if (ntex !is null && ntex.tid == tex.tid) return;
 362     } else {
 363       if (ntex is null) return;
 364     }
 365     glGenFramebuffersEXT(1, &fbo);
 366     glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, fbo);
 367     scope(exit) glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, 0);
 368     // detach texture
 369     glFramebufferTexture2DEXT(GL_FRAMEBUFFER_EXT, GL_COLOR_ATTACHMENT0_EXT, GL_TEXTURE_2D, 0, 0);
 370     glDeleteFramebuffersEXT(1, &fbo);
 371     fbo = 0;
 372     tex = ntex;
 373     // attach texture
 374     if (tex !is null) {
 375       glFramebufferTexture2DEXT(GL_FRAMEBUFFER_EXT, GL_COLOR_ATTACHMENT0_EXT, GL_TEXTURE_2D, tex.tid, 0);
 376       {
 377         GLenum status = glCheckFramebufferStatusEXT(GL_FRAMEBUFFER_EXT);
 378         if (status != GL_FRAMEBUFFER_COMPLETE_EXT) assert(0, "framebuffer fucked!");
 379       }
 380     }
 381   }
 382   +/
 383
 384 private:
 385   void createWithTexture (Texture atex, Texture.Option[] opts...) {
 386     assert(atex !is null && atex.tid);
 387
 388     tex = atex;
 389     glGenFramebuffersEXT(1, &fbo);
 390     glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, fbo);
 391     scope(exit) glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, 0);
 392     // attach 2D texture to this FBO
 393     glFramebufferTexture2DEXT(GL_FRAMEBUFFER_EXT, GL_COLOR_ATTACHMENT0_EXT, GL_TEXTURE_2D, tex.tid, 0);
 394     // GL_COLOR_ATTACHMENT0_EXT, GL_DEPTH_ATTACHMENT_EXT, GL_STENCIL_ATTACHMENT_EXT
 395
 396     void createDepth () {
 397       uint fboDepthId;
 398       glGenRenderbuffersEXT(1, &fboDepthId);
 399       glBindRenderbufferEXT(GL_RENDERBUFFER_EXT, fboDepthId);
 400       glRenderbufferStorageEXT(GL_RENDERBUFFER_EXT, GL_DEPTH_COMPONENT/*24*/, atex.width, atex.height);
 401       // attach depth buffer to FBO
 402       glFramebufferRenderbufferEXT(GL_FRAMEBUFFER_EXT, GL_DEPTH_ATTACHMENT_EXT, GL_RENDERBUFFER_EXT, fboDepthId);
 403       // kill it (we don't need it anymore)
 404       glDeleteRenderbuffersEXT(1, &fboDepthId);
 405     }
 406
 407     /*
 408     foreach (Texture.Option opt; opts) {
 409       if (opt == Texture.Option.Depth) {
 410         createDepth();
 411         break;
 412       }
 413     }
 414     */
 415     //createDepth();
 416
 417     {
 418       GLenum status = glCheckFramebufferStatusEXT(GL_FRAMEBUFFER_EXT);
 419       if (status != GL_FRAMEBUFFER_COMPLETE_EXT) assert(0, "framebuffer fucked!");
 420     }
 421     glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, 0);
 422
 423     width = tex.width;
 424     height = tex.height;
 425   }
 426 }
 427
 428
 429 // ////////////////////////////////////////////////////////////////////////// //
 430 public struct SVec2I { int x, y; }
 431 public struct SVec3I { int x, y, z; alias r = x; alias g = y; alias b = z; }
 432 public struct SVec4I { int x, y, z, w; alias r = x; alias g = y; alias b = z; alias a = w; }
 433
 434 public struct SVec2F { float x, y; }
 435 public struct SVec3F { float x, y, z; alias r = x; alias g = y; alias b = z; }
 436 public struct SVec4F { float x, y, z, w; alias r = x; alias g = y; alias b = z; alias a = w; }
 437
 438
 439 public final class Shader : OpenGLObject {
 440   string shaderName;
 441   GLuint prg = 0;
 442   GLint[string] vars;
 443
 444   override @property uint id () const pure nothrow @nogc => prg;
 445
 446   this (string ashaderName, const(char)[] src) {
 447     shaderName = ashaderName;
 448     if (src.length > int.max) {
 449       import core.stdc.stdio : printf;
 450       printf("shader '%.*s' code too long!", cast(uint)ashaderName.length, ashaderName.ptr);
 451       assert(0);
 452     }
 453     auto shaderId = glCreateShader(GL_FRAGMENT_SHADER);
 454     auto sptr = src.ptr;
 455     GLint slen = cast(int)src.length;
 456     glShaderSource(shaderId, 1, &sptr, &slen);
 457     glCompileShader(shaderId);
 458     GLint success = 0;
 459     glGetShaderiv(shaderId, GL_COMPILE_STATUS, &success);
 460     if (!success || glutilsShowShaderWarnings) {
 461       import core.stdc.stdio : printf;
 462       import core.stdc.stdlib : malloc, free;
 463       GLint logSize = 0;
 464       glGetShaderiv(shaderId, GL_INFO_LOG_LENGTH, &logSize);
 465       if (logSize > 0) {
 466         auto logStrZ = cast(GLchar*)malloc(logSize);
 467         glGetShaderInfoLog(shaderId, logSize, null, logStrZ);
 468         printf("shader '%.*s' compilation messages:\n%s\n", cast(uint)ashaderName.length, ashaderName.ptr, logStrZ);
 469         free(logStrZ);
 470       }
 471     }
 472     if (!success) assert(0);
 473     prg = glCreateProgram();
 474     glAttachShader(prg, shaderId);
 475     glLinkProgram(prg);
 476   }
 477
 478   GLint varId(NT) (NT vname) if (is(NT == char[]) || is(NT == const(char)[]) || is(NT == immutable(char)[])) {
 479     GLint id = -1;
 480     if (vname.length > 0 && vname.length <= 128) {
 481       if (auto vi = vname in vars) {
 482         id = *vi;
 483       } else {
 484         char[129] buf = void;
 485         buf[0..vname.length] = vname[];
 486         buf[vname.length] = 0;
 487         id = glGetUniformLocation(prg, buf.ptr);
 488         //{ import core.stdc.stdio; printf("[%.*s.%s]=%i\n", cast(uint)shaderName.length, shaderName.ptr, buf.ptr, id); }
 489         static if (is(NT == immutable(char)[])) {
 490           vars[vname.idup] = id;
 491         } else {
 492           vars[vname.idup] = id;
 493         }
 494         if (id < 0) {
 495           import core.stdc.stdio : printf;
 496           printf("shader '%.*s': unknown variable '%.*s'\n", cast(uint)shaderName.length, shaderName.ptr, cast(uint)vname.length, vname.ptr);
 497         }
 498       }
 499     }
 500     return id;
 501   }
 502
 503   // get unified var id
 504   GLint opIndex(NT) (NT vname) if (is(NT == char[]) || is(NT == const(char)[]) || is(NT == immutable(char)[])) {
 505     auto id = varId(vname);
 506     if (id < 0) {
 507       import core.stdc.stdio : printf;
 508       printf("shader '%.*s': unknown variable '%.*s'\n", cast(uint)shaderName.length, shaderName.ptr, cast(uint)vname.length, vname.ptr);
 509       assert(0);
 510     }
 511     return id;
 512   }
 513
 514   private import std.traits;
 515   void opIndexAssign(T, NT) (in auto ref T v, NT vname)
 516   if (((isIntegral!T && T.sizeof <= 4) || (isFloatingPoint!T && T.sizeof == float.sizeof) || isBoolean!T ||
 517        is(T : SVec2I) || is(T : SVec3I) || is(T : SVec4I) ||
 518        is(T : SVec2F) || is(T : SVec3F) || is(T : SVec4F)) &&
 519       (is(NT == char[]) || is(NT == const(char)[]) || is(NT == immutable(char)[])))
 520   {
 521     auto id = varId(vname);
 522     if (id < 0) return;
 523     //{ import core.stdc.stdio; printf("setting '%.*s' (%d)\n", cast(uint)vname.length, vname.ptr, id); }
 524          static if (isIntegral!T || isBoolean!T) glUniform1i(id, cast(int)v);
 525     else static if (isFloatingPoint!T) glUniform1f(id, cast(float)v);
 526     else static if (is(SVec2I : T)) glUniform2i(id, cast(int)v.x, cast(int)v.y);
 527     else static if (is(SVec3I : T)) glUniform3i(id, cast(int)v.x, cast(int)v.y, cast(int)v.z);
 528     else static if (is(SVec4I : T)) glUniform4i(id, cast(int)v.x, cast(int)v.y, cast(int)v.z, cast(int)v.w);
 529     else static if (is(SVec2F : T)) glUniform2f(id, cast(float)v.x, cast(float)v.y);
 530     else static if (is(SVec3F : T)) glUniform3f(id, cast(float)v.x, cast(float)v.y, cast(float)v.z);
 531     else static if (is(SVec4F : T)) glUniform4f(id, cast(float)v.x, cast(float)v.y, cast(float)v.z, cast(float)v.w);
 532     else static assert(0, "wtf?!");
 533   }
 534
 535 protected:
 536   override void activateObj () nothrow @nogc { /*if (prg)*/ glUseProgram(prg); }
 537   override void deactivateObj () nothrow @nogc { glUseProgram(0); }
 538 }
 539
 540
 541 // ////////////////////////////////////////////////////////////////////////// //
 542 //private import std.traits;
 543
 544 public:
 545 void exec(TO) (TO obj, scope void delegate () dg) if (is(typeof(() { obj.activate(); obj.deactivate(); }))) {
 546   obj.activate();
 547   scope(exit) obj.deactivate();
 548   dg();
 549 }
 550
 551 void exec(TO, TG) (TO obj, scope TG dg) if (is(typeof((TO obj) { dg(obj); })) && is(typeof(() { obj.activate(); obj.deactivate(); }))) {
 552   obj.activate();
 553   scope(exit) obj.deactivate();
 554   dg(obj);
 555 }
 556
 557
 558 // ////////////////////////////////////////////////////////////////////////// //
 559 void orthoCamera (int wdt, int hgt) {
 560   glMatrixMode(GL_PROJECTION); // for ortho camera
 561   glLoadIdentity();
 562   // left, right, bottom, top, near, far
 563   //glOrtho(0, wdt, 0, hgt, -1, 1); // bottom-to-top
 564   glOrtho(0, wdt, hgt, 0, -1, 1); // top-to-bottom
 565   glViewport(0, 0, wdt, hgt);
 566 }
 567 //glTranslatef(-cx, -cy, 0.0f);
 568
 569
 570 // origin is texture left top
 571 void drawAtXY (GLuint tid, int x, int y, int w, int h, bool mirrorX=false, bool mirrorY=false) {
 572   if (!tid || w < 1 || h < 1) return;
 573   w += x;
 574   h += y;
 575   if (mirrorX) { int tmp = x; x = w; w = tmp; }
 576   if (mirrorY) { int tmp = y; y = h; h = tmp; }
 577   bindTexture(tid);
 578   glBegin(GL_QUADS);
 579     glTexCoord2f(0.0f, 0.0f); glVertex2i(x, y); // top-left
 580     glTexCoord2f(1.0f, 0.0f); glVertex2i(w, y); // top-right
 581     glTexCoord2f(1.0f, 1.0f); glVertex2i(w, h); // bottom-right
 582     glTexCoord2f(0.0f, 1.0f); glVertex2i(x, h); // bottom-left
 583   glEnd();
 584 }
 585
 586
 587 // origin is texture center
 588 void drawAtXYC (Texture tex, int x, int y, bool mirrorX=false, bool mirrorY=false) {
 589   if (tex is null || !tex.tid) return;
 590   x -= tex.width/2;
 591   y -= tex.height/2;
 592   drawAtXY(tex.tid, x, y, tex.width, tex.height, mirrorX, mirrorY);
 593 }
 594
 595
 596 // origin is texture left top
 597 void drawAtXY (Texture tex, int x, int y, bool mirrorX=false, bool mirrorY=false) {
 598   if (tex is null || !tex.tid) return;
 599   drawAtXY(tex.tid, x, y, tex.width, tex.height, mirrorX, mirrorY);
 600 }
 601
 602
 603 private __gshared GLuint boundTexture = 0;
 604
 605 // make sure that texture unit 0 is active!
 606 void bindTexture (GLuint tid) nothrow @trusted @nogc {
 607   if (tid != boundTexture) {
 608     boundTexture = tid;
 609     glBindTexture(GL_TEXTURE_2D, tid);
 610   }
 611 }