sql/loop-extension.lisp

   1 ;;;; -*- Mode: LISP; Syntax: ANSI-Common-Lisp; Base: 10 -*-
   2 ;;;; *************************************************************************
   3 ;;;; FILE IDENTIFICATION
   4 ;;;;
   5 ;;;; Name:    loop-extension.lisp
   6 ;;;; Purpose: Extensions to the Loop macro for CLSQL
   7 ;;;;
   8 ;;;; Copyright (c) 2001-2006 Kevin Rosenberg and (c) 1999-2001 Pierre R. Mai
   9 ;;;;
  10 ;;;; $Id$
  11 ;;;; *************************************************************************
  12
  13 (in-package #:clsql-sys)
  14
  15 #+(or allegro sbcl)
  16 (eval-when (:compile-toplevel :load-toplevel :execute)
  17   (defpackage #:ansi-loop
  18     (:import-from #+sbcl #:sb-loop #+allegro #:excl
  19                   #:*loop-epilogue*
  20                   #:*loop-ansi-universe*
  21                   #:add-loop-path)))
  22
  23 #+(or allegro sbcl)
  24 (defun ansi-loop::loop-gentemp (&optional (pref 'loopva-))
  25   (gensym (string pref)))
  26
  27 #+clisp
  28 (eval-when (:compile-toplevel :load-toplevel :execute)
  29   (when (find-package "ANSI-LOOP") (push :clisp-aloop cl:*features*)))
  30
  31 #+(or allegro clisp-aloop cmu openmcl sbcl scl)
  32 (defun loop-record-iteration-path (variable data-type prep-phrases)
  33   (let ((in-phrase nil)
  34         (from-phrase nil))
  35     (loop for (prep . rest) in prep-phrases
  36           do
  37           (case prep
  38             ((:in :of)
  39              (when in-phrase
  40                (error 'clsql:sql-user-error
  41                       :message
  42                       (format nil
  43                               "Duplicate OF or IN iteration path: ~S."
  44                               (cons prep rest))))
  45              (setq in-phrase rest))
  46             ((:from)
  47              (when from-phrase
  48                (error 'clsql:sql-user-error
  49                       :message
  50                       (format nil
  51                               "Duplicate FROM iteration path: ~S."
  52                               (cons prep rest))))
  53              (setq from-phrase rest))
  54             (t
  55              (error 'clsql:sql-user-error
  56                     :message
  57                     (format nil"Unknown preposition: ~S." prep)))))
  58     (unless in-phrase
  59       (error 'clsql:sql-user-error
  60              :message "Missing OF or IN iteration path."))
  61     (unless from-phrase
  62       (setq from-phrase '(*default-database*)))
  63
  64     (unless (consp variable)
  65       (setq variable (list variable)))
  66
  67     (cond
  68      ;; object query
  69      ((and (consp (first in-phrase))
  70            (string-equal "sql-query" (symbol-name (caar in-phrase)))
  71            (consp (second (first in-phrase)))
  72            (eq 'quote (first (second (first in-phrase))))
  73            (symbolp (second (second (first in-phrase)))))
  74
  75        (let ((result-var (ansi-loop::loop-gentemp
  76                               'loop-record-result-))
  77              (step-var (ansi-loop::loop-gentemp 'loop-record-step-)))
  78          `(((,variable nil ,@(and data-type (list data-type)))
  79             (,result-var (query ,(first in-phrase)))
  80             (,step-var nil))
  81            ()
  82            ()
  83            ()
  84            (if (null ,result-var)
  85                t
  86                (progn
  87                  (setq ,step-var (first ,result-var))
  88                  (setq ,result-var (rest ,result-var))
  89                  nil))
  90            (,variable ,step-var)
  91            (null ,result-var)
  92            ()
  93            (if (null ,result-var)
  94                t
  95                (progn
  96                  (setq ,step-var (first ,result-var))
  97                  (setq ,result-var (rest ,result-var))
  98                  nil))
  99            (,variable ,step-var))))
 100
 101       ((consp variable)
 102        (let ((query-var (ansi-loop::loop-gentemp 'loop-record-))
 103              (db-var (ansi-loop::loop-gentemp 'loop-record-database-))
 104              (result-set-var (ansi-loop::loop-gentemp
 105                               'loop-record-result-set-))
 106              (step-var (ansi-loop::loop-gentemp 'loop-record-step-)))
 107          (push `(when ,result-set-var
 108                   (database-dump-result-set ,result-set-var ,db-var))
 109                ansi-loop::*loop-epilogue*)
 110          `(((,variable nil ,@(and data-type (list data-type)))
 111             (,query-var ,(first in-phrase))
 112             (,db-var ,(first from-phrase))
 113             (,result-set-var t)
 114             (,step-var nil))
 115            ((multiple-value-bind (%rs %cols)
 116                 (database-query-result-set ,query-var ,db-var :result-types :auto)
 117               (setq ,result-set-var %rs ,step-var (make-list %cols))))
 118            ()
 119            ()
 120            (not (database-store-next-row ,result-set-var ,db-var ,step-var))
 121            (,variable ,step-var)
 122            (not ,result-set-var)
 123            ()
 124            (not (database-store-next-row ,result-set-var ,db-var ,step-var))
 125            (,variable ,step-var)))))))
 126
 127 #+(or allegro clisp-aloop cmu openmcl sbcl scl)
 128 (ansi-loop::add-loop-path '(record records tuple tuples)
 129                           'loop-record-iteration-path
 130                           ansi-loop::*loop-ansi-universe*
 131                           :preposition-groups '((:of :in) (:from))
 132                           :inclusive-permitted nil)
 133
 134
 135 #+lispworks
 136 (cl-user::define-loop-method (loop::record loop::records loop::tuple loop::tuples)
 137     clsql-loop-method
 138   (loop::in loop::of loop::from))
 139
 140 #+lispworks
 141 (defun clsql-loop-method (method-name iter-var iter-var-data-type
 142                           prep-phrases inclusive? allowed-preps
 143                           method-specific-data)
 144   (declare (ignore method-name iter-var-data-type inclusive? allowed-preps method-specific-data))
 145   (let ((in-phrase nil)
 146         (from-phrase nil))
 147     (loop for (prep . rest) in prep-phrases
 148           do
 149           (cond
 150             ((or (eq prep 'loop::in) (eq prep 'loop::of))
 151              (when in-phrase
 152                (error 'clsql:sql-user-error
 153                       :message
 154                       (format nil "Duplicate OF or IN iteration path: ~S."
 155                               (cons prep rest))))
 156              (setq in-phrase rest))
 157             ((eq prep 'loop::from)
 158              (when from-phrase
 159                (error 'clsql:sql-user-error
 160                       :message
 161                       (format nil "Duplicate FROM iteration path: ~S."
 162                               (cons prep rest))))
 163              (setq from-phrase rest))
 164             (t
 165              (error 'clsql:sql-user-error
 166                     :message (format nil "Unknown preposition: ~S." prep)))))
 167     (unless in-phrase
 168       (error 'clsql:sql-user-error
 169              :message "Missing OF or IN iteration path."))
 170     (unless from-phrase
 171       (setq from-phrase '(clsql:*default-database*)))
 172
 173     (unless (consp iter-var)
 174       (setq iter-var (list iter-var)))
 175
 176     (cond
 177      ;; object query
 178      ((and (consp in-phrase)
 179            (string-equal "sql-query" (symbol-name (car in-phrase)))
 180            (consp (second in-phrase))
 181            (eq 'quote (first (second in-phrase)))
 182            (symbolp (second (second in-phrase))))
 183
 184        (let ((result-var (gensym "LOOP-RECORD-RESULT-"))
 185              (step-var (gensym "LOOP-RECORD-STEP-")))
 186          (values
 187           t
 188           nil
 189           `(,@(mapcar (lambda (v) `(,v nil)) iter-var)
 190               (,result-var (clsql:query ,in-phrase))
 191               (,step-var nil))
 192           ()
 193           ()
 194           ()
 195           `((if (null ,result-var)
 196                 t
 197                 (progn
 198                   (setq ,step-var (first ,result-var))
 199                   (setq ,result-var (rest ,result-var))
 200                   nil)))
 201           `(,iter-var ,step-var)
 202           `((if (null ,result-var)
 203                 t
 204                 (progn
 205                   (setq ,step-var (first ,result-var))
 206                   (setq ,result-var (rest ,result-var))
 207                   nil)))
 208            `(,iter-var ,step-var)
 209            ()
 210            ()
 211            )))
 212
 213       ((consp iter-var)
 214        (let ((query-var (gensym "LOOP-RECORD-"))
 215              (db-var (gensym "LOOP-RECORD-DATABASE-"))
 216              (result-set-var (gensym "LOOP-RECORD-RESULT-SET-"))
 217              (step-var (gensym "LOOP-RECORD-STEP-")))
 218          (values
 219           t
 220           nil
 221           `(,@(mapcar (lambda (v) `(,v nil)) iter-var)
 222             (,query-var ,in-phrase)
 223             (,db-var ,(first from-phrase))
 224             (,result-set-var nil)
 225             (,step-var nil))
 226           `((multiple-value-bind (%rs %cols)
 227                 (clsql-sys:database-query-result-set ,query-var ,db-var :result-types :auto)
 228               (setq ,result-set-var %rs ,step-var (make-list %cols))))
 229           ()
 230           ()
 231           `((unless (clsql-sys:database-store-next-row ,result-set-var ,db-var ,step-var)
 232               (when ,result-set-var
 233                 (clsql-sys:database-dump-result-set ,result-set-var ,db-var))
 234               t))
 235           `(,iter-var ,step-var)
 236           `((unless (clsql-sys:database-store-next-row ,result-set-var ,db-var ,step-var)
 237               (when ,result-set-var
 238                 (clsql-sys:database-dump-result-set ,result-set-var ,db-var))
 239               t))
 240           `(,iter-var ,step-var)
 241           ()
 242           ()))))))
 243
 244
 245 #+clisp-aloop
 246 (eval-when (:compile-toplevel :load-toplevel :execute)
 247   (setq cl:*features* (delete :clisp-aloop cl:*features*)))
 248