src/clfswm.lisp

   1 ;;; --------------------------------------------------------------------------
   2 ;;; CLFSWM - FullScreen Window Manager
   3 ;;;
   4 ;;; --------------------------------------------------------------------------
   5 ;;; Documentation: Main functions
   6 ;;; --------------------------------------------------------------------------
   7 ;;;
   8 ;;; (C) 2011 Philippe Brochard <hocwp@free.fr>
   9 ;;;
  10 ;;; This program is free software; you can redistribute it and/or modify
  11 ;;; it under the terms of the GNU General Public License as published by
  12 ;;; the Free Software Foundation; either version 3 of the License, or
  13 ;;; (at your option) any later version.
  14 ;;;
  15 ;;; This program is distributed in the hope that it will be useful,
  16 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;;; GNU General Public License for more details.
  19 ;;;
  20 ;;; You should have received a copy of the GNU General Public License
  21 ;;; along with this program; if not, write to the Free Software
  22 ;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  23 ;;;
  24 ;;; --------------------------------------------------------------------------
  25
  26 (in-package :clfswm)
  27
  28
  29 (define-handler main-mode :key-press (code state)
  30   (funcall-key-from-code *main-keys* code state))
  31
  32 (define-handler main-mode :button-press (code state window root-x root-y)
  33   (unless (funcall-button-from-code *main-mouse* code state window root-x root-y *fun-press*)
  34     (replay-button-event)))
  35
  36 (define-handler main-mode :button-release (code state window root-x root-y)
  37   (unless (funcall-button-from-code *main-mouse* code state window root-x root-y *fun-release*)
  38     (replay-button-event)))
  39
  40 (define-handler main-mode :motion-notify (window root-x root-y)
  41   (unless (compress-motion-notify)
  42     (funcall-button-from-code *main-mouse* 'motion
  43                               (modifiers->state *default-modifiers*)
  44                               window root-x root-y *fun-press*)))
  45
  46 (define-handler main-mode :configure-request (stack-mode window x y width height border-width value-mask)
  47   (labels ((has-x (mask) (= 1 (logand mask 1)))
  48            (has-y (mask) (= 2 (logand mask 2)))
  49            (has-w (mask) (= 4 (logand mask 4)))
  50            (has-h (mask) (= 8 (logand mask 8)))
  51            (has-bw (mask) (= 16 (logand mask 16)))
  52            (has-stackmode (mask) (= 64 (logand mask 64)))
  53            (adjust-from-request ()
  54              (when (has-x value-mask) (setf (x-drawable-x window) x))
  55              (when (has-y value-mask) (setf (x-drawable-y window) y))
  56              (when (has-h value-mask) (setf (x-drawable-height window) height))
  57              (when (has-w value-mask) (setf (x-drawable-width window) width))))
  58     (xlib:with-state (window)
  59       (when (has-bw value-mask)
  60         (setf (x-drawable-border-width window) border-width))
  61       (let ((current-root (find-current-root)))
  62         (if (find-child window current-root)
  63             (let ((parent (find-parent-frame window current-root)))
  64               (if (and parent (managed-window-p window parent))
  65                   (adapt-child-to-parent window parent)
  66                   (adjust-from-request)))
  67             (adjust-from-request)))
  68       (send-configuration-notify window (x-drawable-x window) (x-drawable-y window)
  69                                  (x-drawable-width window) (x-drawable-height window)
  70                                  (x-drawable-border-width window))
  71       (when (has-stackmode value-mask)
  72         (case stack-mode
  73           (:above
  74            (unless (null-size-window-p window)
  75              (when (or (child-equal-p window *current-child*)
  76                        (is-in-current-child-p window))
  77                (raise-window window)
  78                (focus-window window)
  79                (focus-all-children window (find-parent-frame window (find-current-root)))))))))))
  80
  81
  82 (define-handler main-mode :map-request (window send-event-p)
  83   (unless send-event-p
  84     (unhide-window window)
  85     (process-new-window window)
  86     (map-window window)
  87     (unless (null-size-window-p window)
  88       (multiple-value-bind (never-managed raise)
  89           (never-managed-window-p window)
  90         (unless (and never-managed raise)
  91           (show-all-children))))))
  92
  93
  94 (define-handler main-mode :unmap-notify (send-event-p event-window window)
  95   (unless (and (not send-event-p)
  96                (not (xlib:window-equal window event-window)))
  97     (when (find-child window *root-frame*)
  98       (clean-windows-in-all-frames)
  99       (show-all-children)
 100       (delete-child-in-all-frames window)
 101       (show-all-children))))
 102
 103
 104 (define-handler main-mode :destroy-notify (send-event-p event-window window)
 105   (unless (or send-event-p
 106               (xlib:window-equal window event-window))
 107     (when (find-child window *root-frame*)
 108       (clean-windows-in-all-frames)
 109       (show-all-children)
 110       (delete-child-in-all-frames window)
 111       (show-all-children))))
 112
 113 (define-handler main-mode :enter-notify  (window root-x root-y)
 114   (unless (and (> root-x (- (xlib:screen-width *screen*) 3))
 115                (> root-y (- (xlib:screen-height *screen*) 3)))
 116     (case (if (frame-p *current-child*)
 117               (frame-focus-policy *current-child*)
 118               *default-focus-policy*)
 119       (:sloppy (focus-window window))
 120       (:sloppy-strict (when (and (frame-p *current-child*)
 121                                  (child-member window (frame-child *current-child*)))
 122                         (focus-window window)))
 123       (:sloppy-select (let* ((child (find-child-under-mouse root-x root-y))
 124                              (parent (find-parent-frame child)))
 125                         (unless (or (child-root-p child)
 126                                     (equal (typecase child
 127                                              (xlib:window parent)
 128                                              (t child))
 129                                            *current-child*))
 130                             (focus-all-children child parent)
 131                             (show-all-children)))))))
 132
 133 (define-handler main-mode :exposure (window)
 134   (awhen (find-frame-window window)
 135     (display-frame-info it)))
 136
 137
 138 (defun error-handler (display error-key &rest key-vals &key asynchronous &allow-other-keys)
 139   "Handle X errors"
 140   (cond
 141     ;; ignore asynchronous window errors
 142     ((and asynchronous
 143           (find error-key '(xlib:window-error xlib:drawable-error xlib:match-error)))
 144      (format t "Ignoring XLib asynchronous error: ~s~%" error-key))
 145     ((eq error-key 'xlib:access-error)
 146      (write-line "Another window manager is running.")
 147      (throw 'exit-clfswm nil))
 148      ;; all other asynchronous errors are printed.
 149      (asynchronous
 150       (format t "Caught Asynchronous X Error: ~s ~s" error-key key-vals))
 151      (t
 152       (apply 'error error-key :display display :error-key error-key key-vals))))
 153
 154
 155 (defun main-loop ()
 156   (loop
 157      (call-hook *loop-hook*)
 158      (process-timers)
 159      (with-xlib-protect ()
 160        (when (xlib:event-listen *display* *loop-timeout*)
 161          (xlib:process-event *display* :handler #'handle-event))
 162        (xlib:display-finish-output *display*))))
 163
 164
 165
 166 (defun open-display (display-str protocol)
 167   (multiple-value-bind (host display-num) (parse-display-string display-str)
 168     (setf *display* (xlib:open-display host :display display-num :protocol protocol)
 169           (xlib:display-error-handler *display*) 'error-handler
 170           (getenv "DISPLAY") display-str)))
 171
 172
 173
 174 (defun default-init-hook ()
 175   (let ((frame (add-frame (create-frame :name "Default"
 176                                         :layout nil :x 0.05 :y 0.05
 177                                         :w 0.9 :h 0.9)
 178                           *root-frame*)))
 179     (setf *current-child* frame)))
 180
 181
 182 (defun init-display ()
 183   (fill-handle-event-fun-symbols)
 184   (assoc-keyword-handle-event 'main-mode)
 185   (setf *screen* (first (xlib:display-roots *display*))
 186         *root* (xlib:screen-root *screen*)
 187         *no-focus-window* (xlib:create-window :parent *root* :x 0 :y 0 :width 1 :height 1)
 188         *default-font* (xlib:open-font *display* *default-font-string*)
 189         *pixmap-buffer* (xlib:create-pixmap :width (xlib:screen-width *screen*)
 190                                             :height (xlib:screen-height *screen*)
 191                                             :depth (xlib:screen-root-depth *screen*)
 192                                             :drawable *root*)
 193         *in-second-mode* nil)
 194   (store-root-background)
 195   (init-modifier-list)
 196   (xgrab-init-pointer)
 197   (xgrab-init-keyboard)
 198   (init-last-child)
 199   (call-hook *binding-hook*)
 200   (clear-timers)
 201   (map-window *no-focus-window*)
 202   (dbg *display*)
 203   (dbg (xlib:display-roots *display*))
 204   (dbg (xlib:display-plist *display*))
 205   (dbg (xlib:query-extension *display* "XINERAMA"))
 206   (setf (xlib:window-event-mask *root*) (xlib:make-event-mask :substructure-redirect
 207                                                               :substructure-notify
 208                                                               :property-change
 209                                                               :exposure
 210                                                               :button-press
 211                                                               :button-release
 212                                                               :pointer-motion))
 213   ;;(intern-atoms *display*)
 214   (netwm-set-properties)
 215   (xlib:display-force-output *display*)
 216   (setf *child-selection* nil)
 217   (setf *root-frame* (create-frame :name "Root" :number 0)
 218         *current-root* *root-frame*  ;;; PHIL: TO REMOVE
 219         *current-child* *root-frame*)
 220   (call-hook *init-hook*)
 221   (process-existing-windows *screen*)
 222   (show-all-children)
 223   (grab-main-keys)
 224   (xlib:display-finish-output *display*))
 225
 226
 227
 228
 229 (defun read-conf-file ()
 230   (let* ((conf (conf-file-name)))
 231     (if conf
 232         (handler-case (load conf)
 233           (error (c)
 234             (format t "~2%*** Error loading configuration file: ~A ***~&~A~%" conf c)
 235             (values nil (format nil "~s" c) conf))
 236           (:no-error (&rest args)
 237             (declare (ignore args))
 238             (values t nil conf)))
 239         (values t nil nil))))
 240
 241
 242
 243
 244
 245
 246 (defun exit-clfswm ()
 247   "Exit clfswm"
 248   (throw 'exit-clfswm nil))
 249
 250 (defun reset-clfswm ()
 251   "Reset clfswm"
 252   (throw 'exit-main-loop nil))
 253
 254
 255
 256
 257 (defun main-unprotected (&key (display (or (getenv "DISPLAY") ":0")) protocol
 258                          (base-dir (asdf:system-source-directory :clfswm))
 259                          (read-conf-file-p t) (alternate-conf nil)
 260                          error-msg)
 261   (setf *contrib-dir* (merge-pathnames "contrib/" base-dir))
 262   (conf-file-name alternate-conf)
 263   (when read-conf-file-p
 264     (read-conf-file))
 265   (create-configuration-menu :clear t)
 266   (call-hook *main-entrance-hook*)
 267   (handler-case
 268       (open-display display protocol)
 269     (xlib:access-error (c)
 270       (format t "~&~A~&Maybe another window manager is running. [1]~%" c)
 271       (force-output)
 272       (exit-clfswm)))
 273   (handler-case
 274       (init-display)
 275     (xlib:access-error (c)
 276       (ungrab-main-keys)
 277       (xlib:destroy-window *no-focus-window*)
 278       (xlib:close-display *display*)
 279       (format t "~&~A~&Maybe another window manager is running. [2]~%" c)
 280       (force-output)
 281       (exit-clfswm)))
 282   (when error-msg
 283     (info-mode error-msg))
 284   (catch 'exit-main-loop
 285       (unwind-protect
 286            (main-loop)
 287         (ungrab-main-keys)
 288         (xlib:destroy-window *no-focus-window*)
 289         (xlib:free-pixmap *pixmap-buffer*)
 290         (destroy-all-frames-window)
 291         (call-hook *close-hook*)
 292         (xlib:close-display *display*)
 293         #+:event-debug
 294         (format t "~2&Unhandled events: ~A~%" *unhandled-events*))))
 295
 296
 297
 298 (defun main (&key (display (or (getenv "DISPLAY") ":0")) protocol
 299              (base-dir (asdf:system-source-directory :clfswm))
 300              (read-conf-file-p t)
 301              (alternate-conf nil))
 302   (let (error-msg)
 303     (catch 'exit-clfswm
 304       (loop
 305          (handler-case
 306              (if *other-window-manager*
 307                  (run-other-window-manager)
 308                  (main-unprotected :display display :protocol protocol :base-dir base-dir
 309                                    :read-conf-file-p read-conf-file-p
 310                                    :alternate-conf alternate-conf
 311                                    :error-msg error-msg))
 312            (error (c)
 313              (let ((msg (format nil "CLFSWM Error: ~A." c)))
 314                (format t "~&~A~%Reinitializing...~%" msg)
 315                (setf error-msg (list (list msg *info-color-title*)
 316                                      "Reinitializing...")))))))))
 317
 318
 319