src/clfswm.lisp

   1 ;;; --------------------------------------------------------------------------
   2 ;;; CLFSWM - FullScreen Window Manager
   3 ;;;
   4 ;;; --------------------------------------------------------------------------
   5 ;;; Documentation: Main functions
   6 ;;; --------------------------------------------------------------------------
   7 ;;;
   8 ;;; (C) 2012 Philippe Brochard <pbrochard@common-lisp.net>
   9 ;;;
  10 ;;; This program is free software; you can redistribute it and/or modify
  11 ;;; it under the terms of the GNU General Public License as published by
  12 ;;; the Free Software Foundation; either version 3 of the License, or
  13 ;;; (at your option) any later version.
  14 ;;;
  15 ;;; This program is distributed in the hope that it will be useful,
  16 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;;; GNU General Public License for more details.
  19 ;;;
  20 ;;; You should have received a copy of the GNU General Public License
  21 ;;; along with this program; if not, write to the Free Software
  22 ;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  23 ;;;
  24 ;;; --------------------------------------------------------------------------
  25
  26 (in-package :clfswm)
  27
  28
  29 (define-handler main-mode :key-press (code state)
  30   (funcall-key-from-code *main-keys* code state))
  31
  32 (define-handler main-mode :button-press (code state window root-x root-y)
  33   (unless (funcall-button-from-code *main-mouse* code state window root-x root-y *fun-press*)
  34     (replay-button-event)))
  35
  36 (define-handler main-mode :button-release (code state window root-x root-y)
  37   (unless (funcall-button-from-code *main-mouse* code state window root-x root-y *fun-release*)
  38     (replay-button-event)))
  39
  40 (define-handler main-mode :motion-notify (window root-x root-y)
  41   (unless (compress-motion-notify)
  42     (funcall-button-from-code *main-mouse* 'motion
  43                               (modifiers->state *default-modifiers*)
  44                               window root-x root-y *fun-press*)))
  45
  46
  47 (define-handler main-mode :configure-request (stack-mode window x y width height border-width value-mask)
  48   (let ((change nil))
  49     (labels ((has-x (mask) (= 1 (logand mask 1)))
  50              (has-y (mask) (= 2 (logand mask 2)))
  51              (has-w (mask) (= 4 (logand mask 4)))
  52              (has-h (mask) (= 8 (logand mask 8)))
  53              (has-bw (mask) (= 16 (logand mask 16)))
  54              (has-stackmode (mask) (= 64 (logand mask 64)))
  55              (adjust-from-request ()
  56                (when (has-x value-mask) (setf (x-drawable-x window) x
  57                                               change :moved))
  58                (when (has-y value-mask) (setf (x-drawable-y window) y
  59                                               change :moved))
  60                (when (has-h value-mask) (setf (x-drawable-height window) height
  61                                               change :resized))
  62                (when (has-w value-mask) (setf (x-drawable-width window) width
  63                                               change :resized))))
  64       (when window
  65         (xlib:with-state (window)
  66           (let ((current-root (find-current-root)))
  67             (if (find-child window current-root)
  68                 (let ((parent (find-parent-frame window current-root)))
  69                   (if (and parent (managed-window-p window parent))
  70                       (setf change (adapt-child-to-parent window parent))
  71                       (adjust-from-request)))
  72                 (adjust-from-request)))
  73           (when (has-bw value-mask)
  74             (setf (x-drawable-border-width window) border-width
  75                   change :resized))
  76           (when (has-stackmode value-mask)
  77             (case stack-mode
  78               (:above
  79                (unless (null-size-window-p window)
  80                  (when (or (child-equal-p window (current-child))
  81                            (is-in-current-child-p window))
  82                    (setf change (or change :moved))
  83                    (raise-window window)
  84                    (focus-window window)
  85                    (focus-all-children window (find-parent-frame window (find-current-root)))))))))
  86         (unless (eq change :resized)
  87           ;; To be ICCCM compliant, send a fake configuration notify event only when
  88           ;; the window has moved and not when it has been resized or the border width has changed.
  89           (send-configuration-notify window (x-drawable-x window) (x-drawable-y window)
  90                                      (x-drawable-width window) (x-drawable-height window)
  91                                      (x-drawable-border-width window)))))))
  92
  93
  94 (define-handler main-mode :map-request (window send-event-p)
  95   (unless send-event-p
  96     (unless (find-child window *root-frame*)
  97       (unhide-window window)
  98       (process-new-window window)
  99       (map-window window)
 100       (unless (null-size-window-p window)
 101         (multiple-value-bind (never-managed raise)
 102             (never-managed-window-p window)
 103           (unless (and never-managed raise)
 104             (show-all-children)))))))
 105
 106
 107
 108 (define-handler main-mode :unmap-notify (send-event-p event-window window)
 109   (unless (and (not send-event-p)
 110                (not (xlib:window-equal window event-window)))
 111     (when (find-child window *root-frame*)
 112       (setf (window-state window) +withdrawn-state+)
 113       (xlib:unmap-window window)
 114       (delete-child-in-all-frames window)
 115       (show-all-children))))
 116
 117
 118
 119
 120
 121 (define-handler main-mode :destroy-notify (send-event-p event-window window)
 122   (unless (or send-event-p
 123               (xlib:window-equal window event-window))
 124     (when (find-child window *root-frame*)
 125       (delete-child-in-all-frames window)
 126       (show-all-children)
 127       (xlib:destroy-window window))))
 128
 129 (define-handler main-mode :enter-notify  (window root-x root-y)
 130   (unless (and (> root-x (- (xlib:screen-width *screen*) 3))
 131                (> root-y (- (xlib:screen-height *screen*) 3)))
 132     (case (if (frame-p (current-child))
 133               (frame-focus-policy (current-child))
 134               *default-focus-policy*)
 135       (:sloppy (focus-window window))
 136       (:sloppy-strict (when (and (frame-p (current-child))
 137                                  (child-member window (frame-child (current-child))))
 138                         (focus-window window)))
 139       (:sloppy-select (let* ((child (find-child-under-mouse root-x root-y))
 140                              (parent (find-parent-frame child)))
 141                         (unless (or (child-root-p child)
 142                                     (equal (typecase child
 143                                              (xlib:window parent)
 144                                              (t child))
 145                                            (current-child)))
 146                             (focus-all-children child parent)
 147                             (show-all-children)))))))
 148
 149 (define-handler main-mode :exposure (window)
 150   (awhen (find-frame-window window)
 151     (display-frame-info it)))
 152
 153
 154 (defun error-handler (display error-key &rest key-vals &key asynchronous &allow-other-keys)
 155   "Handle X errors"
 156   (cond
 157     ;; ignore asynchronous window errors
 158     ((and asynchronous
 159           (find error-key '(xlib:window-error xlib:drawable-error xlib:match-error)))
 160      #+:xlib-debug (format t "~&Ignoring XLib asynchronous error: ~s~%" error-key))
 161     ((eq error-key 'xlib:access-error)
 162      (write-line "~&Another window manager is running.")
 163      (throw 'exit-clfswm nil))
 164     ;; all other asynchronous errors are printed.
 165     (asynchronous
 166      #+:xlib-debug (format t "~&Caught Asynchronous X Error: ~s ~s" error-key key-vals))
 167     ;;((find error-key '(xlib:window-error xlib:drawable-error xlib:match-error))
 168     ;; (format t "~&Ignoring Xlib error: ~S ~S~%" error-key key-vals))
 169     (t
 170      (apply 'error error-key :display display :error-key error-key key-vals))))
 171
 172
 173 (defun main-loop ()
 174   (loop
 175      (with-xlib-protect (:main-loop nil)
 176        (call-hook *loop-hook*)
 177        (process-timers)
 178        (when (xlib:event-listen *display* *loop-timeout*)
 179          (xlib:process-event *display* :handler #'handle-event))
 180        (xlib:display-finish-output *display*)
 181        (setf *x-error-count* 0))))
 182
 183
 184
 185
 186 (defun open-display (display-str protocol)
 187   (multiple-value-bind (host display-num) (parse-display-string display-str)
 188     (setf *display* (xlib:open-display host :display display-num :protocol protocol)
 189           (xlib:display-error-handler *display*) 'error-handler
 190           (getenv "DISPLAY") display-str)))
 191
 192
 193
 194 (defun default-init-hook ()
 195   (let ((frame (add-frame (create-frame :name "Default"
 196                                         :layout nil :x 0.05 :y 0.05
 197                                         :w 0.9 :h 0.9)
 198                           *root-frame*)))
 199     (setf (current-child) frame)))
 200
 201
 202 (defun init-display ()
 203   (reset-root-list)
 204   (reset-bind-or-jump-slots)
 205   (reset-open-menu)
 206   (fill-handle-event-fun-symbols)
 207   (assoc-keyword-handle-event 'main-mode)
 208   (setf *screen* (first (xlib:display-roots *display*))
 209         *root* (xlib:screen-root *screen*)
 210         *no-focus-window* (xlib:create-window :parent *root* :x 0 :y 0 :width 1 :height 1)
 211         *default-font* (xlib:open-font *display* *default-font-string*)
 212         *pixmap-buffer* (xlib:create-pixmap :width (xlib:screen-width *screen*)
 213                                             :height (xlib:screen-height *screen*)
 214                                             :depth (xlib:screen-root-depth *screen*)
 215                                             :drawable *root*)
 216         *in-second-mode* nil
 217         *x-error-count* 0)
 218   (store-root-background)
 219   (init-modifier-list)
 220   (xgrab-init-pointer)
 221   (xgrab-init-keyboard)
 222   (init-last-child)
 223   (call-hook *binding-hook*)
 224   (clear-timers)
 225   (map-window *no-focus-window*)
 226   (dbg *display*)
 227   (setf (xlib:window-event-mask *root*) (xlib:make-event-mask :substructure-redirect
 228                                                               :substructure-notify
 229                                                               :structure-notify
 230                                                               :property-change
 231                                                               ;;:resize-redirect
 232                                                               :exposure
 233                                                               :button-press
 234                                                               :button-release
 235                                                               :pointer-motion))
 236   (xlib:display-finish-output *display*)
 237   ;;(intern-atoms *display*)
 238   (netwm-set-properties)
 239   (xlib:display-force-output *display*)
 240   (setf *child-selection* nil)
 241   (setf *root-frame* (create-frame :name "Root" :number 0)
 242         (current-child) *root-frame*)
 243   (call-hook *init-hook*)
 244   (unsure-at-least-one-root)
 245   (process-existing-windows *screen*)
 246   (show-all-children)
 247   (grab-main-keys)
 248   (xlib:display-finish-output *display*)
 249   (optimize-event-hook))
 250
 251
 252
 253
 254 (defun read-conf-file ()
 255   (let* ((conf (conf-file-name)))
 256     (if conf
 257         (handler-case (load conf)
 258           (error (c)
 259             (format t "~2%*** Error loading configuration file: ~A ***~&~A~%" conf c)
 260             (values nil (format nil "~s" c) conf))
 261           (:no-error (&rest args)
 262             (declare (ignore args))
 263             (values t nil conf)))
 264         (values t nil nil))))
 265
 266
 267
 268
 269
 270
 271 (defun exit-clfswm ()
 272   "Exit clfswm"
 273   (throw 'exit-clfswm nil))
 274
 275 (defun reset-clfswm ()
 276   "Reset clfswm"
 277   (throw 'exit-main-loop nil))
 278
 279
 280
 281
 282 (defun main-unprotected (&key (display (or (getenv "DISPLAY") ":0")) protocol
 283                          (base-dir (asdf:system-source-directory :clfswm))
 284                          (read-conf-file-p t) (alternate-conf nil)
 285                          error-msg)
 286   (setf *contrib-dir* (merge-pathnames "contrib/" base-dir))
 287   (conf-file-name alternate-conf)
 288   (when read-conf-file-p
 289     (read-conf-file))
 290   (create-configuration-menu :clear t)
 291   (call-hook *main-entrance-hook*)
 292   (handler-case
 293       (open-display display protocol)
 294     (xlib:access-error (c)
 295       (format t "~&~A~&Maybe another window manager is running. [1]~%" c)
 296       (force-output)
 297       (exit-clfswm)))
 298   (handler-case
 299       (init-display)
 300     (xlib:access-error (c)
 301       (ungrab-main-keys)
 302       (xlib:destroy-window *no-focus-window*)
 303       (xlib:close-display *display*)
 304       (format t "~&~A~&Maybe another window manager is running. [2]~%" c)
 305       (force-output)
 306       (exit-clfswm)))
 307   (when error-msg
 308     (info-mode error-msg))
 309   (catch 'exit-main-loop
 310       (unwind-protect
 311            (main-loop)
 312         (progn
 313           (ungrab-main-keys)
 314           (xlib:destroy-window *no-focus-window*)
 315           (xlib:free-pixmap *pixmap-buffer*)
 316           (destroy-all-frames-window)
 317           (call-hook *close-hook*)
 318           (clear-event-hooks)
 319           (xlib:close-display *display*)
 320           #+:event-debug
 321           (format t "~2&Unhandled events: ~A~%" *unhandled-events*)))))
 322
 323
 324
 325 (defun main (&key (display (or (getenv "DISPLAY") ":0")) protocol
 326              (base-dir (asdf:system-source-directory :clfswm))
 327              (read-conf-file-p t)
 328              (alternate-conf nil))
 329   (let (error-msg)
 330     (catch 'exit-clfswm
 331       (loop
 332          (handler-case
 333              (if *other-window-manager*
 334                  (run-other-window-manager)
 335                  (main-unprotected :display display :protocol protocol :base-dir base-dir
 336                                    :read-conf-file-p read-conf-file-p
 337                                    :alternate-conf alternate-conf
 338                                    :error-msg error-msg))
 339            (error (c)
 340              (let ((msg (format nil "CLFSWM Error: ~A." c)))
 341                (format t "~&~A~%Reinitializing...~%" msg)
 342                (setf error-msg (list (list msg *info-color-title*)
 343                                      "Reinitializing...")))))))))
 344
 345
 346