src/clfswm.lisp

   1 ;;; --------------------------------------------------------------------------
   2 ;;; CLFSWM - FullScreen Window Manager
   3 ;;;
   4 ;;; --------------------------------------------------------------------------
   5 ;;; Documentation: Main functions
   6 ;;; --------------------------------------------------------------------------
   7 ;;;
   8 ;;; (C) 2012 Philippe Brochard <pbrochard@common-lisp.net>
   9 ;;;
  10 ;;; This program is free software; you can redistribute it and/or modify
  11 ;;; it under the terms of the GNU General Public License as published by
  12 ;;; the Free Software Foundation; either version 3 of the License, or
  13 ;;; (at your option) any later version.
  14 ;;;
  15 ;;; This program is distributed in the hope that it will be useful,
  16 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;;; GNU General Public License for more details.
  19 ;;;
  20 ;;; You should have received a copy of the GNU General Public License
  21 ;;; along with this program; if not, write to the Free Software
  22 ;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  23 ;;;
  24 ;;; --------------------------------------------------------------------------
  25
  26 (in-package :clfswm)
  27
  28
  29 (define-handler main-mode :key-press (code state)
  30   (funcall-key-from-code *main-keys* code state))
  31
  32 (define-handler main-mode :button-press (code state window root-x root-y)
  33   (unless (funcall-button-from-code *main-mouse* code state window root-x root-y *fun-press*)
  34     (replay-button-event)))
  35
  36 (define-handler main-mode :button-release (code state window root-x root-y)
  37   (unless (funcall-button-from-code *main-mouse* code state window root-x root-y *fun-release*)
  38     (replay-button-event)))
  39
  40 (define-handler main-mode :motion-notify (window root-x root-y)
  41   (unless (compress-motion-notify)
  42     (funcall-button-from-code *main-mouse* 'motion
  43                               (modifiers->state *default-modifiers*)
  44                               window root-x root-y *fun-press*)))
  45
  46
  47 (define-handler main-mode :configure-request (stack-mode window x y width height border-width value-mask)
  48   (let ((change nil))
  49     (labels ((has-x (mask) (= 1 (logand mask 1)))
  50              (has-y (mask) (= 2 (logand mask 2)))
  51              (has-w (mask) (= 4 (logand mask 4)))
  52              (has-h (mask) (= 8 (logand mask 8)))
  53              (has-bw (mask) (= 16 (logand mask 16)))
  54              (has-stackmode (mask) (= 64 (logand mask 64)))
  55              (adjust-from-request ()
  56                (when (has-x value-mask) (setf (x-drawable-x window) x
  57                                               change :moved))
  58                (when (has-y value-mask) (setf (x-drawable-y window) y
  59                                               change :moved))
  60                (when (has-h value-mask) (setf (x-drawable-height window) height
  61                                               change :resized))
  62                (when (has-w value-mask) (setf (x-drawable-width window) width
  63                                               change :resized))))
  64       (when window
  65         (xlib:with-state (window)
  66           (let ((current-root (find-current-root)))
  67             (if (find-child window current-root)
  68                 (let ((parent (find-parent-frame window current-root)))
  69                   (if (and parent (managed-window-p window parent))
  70                       (setf change (adapt-child-to-parent window parent))
  71                       (adjust-from-request)))
  72                 (adjust-from-request)))
  73           (when (has-bw value-mask)
  74             (setf (x-drawable-border-width window) border-width
  75                   change :resized))
  76           (when (has-stackmode value-mask)
  77             (case stack-mode
  78               (:above
  79                (when (or (child-equal-p window (current-child))
  80                          (is-in-current-child-p window))
  81                  (setf change (or change :moved))
  82                  (focus-window window)
  83                  (focus-all-children window (find-parent-frame window (find-current-root)))
  84                  (show-all-children))))))
  85         (unless (eq change :resized)
  86           ;; To be ICCCM compliant, send a fake configuration notify event only when
  87           ;; the window has moved and not when it has been resized or the border width has changed.
  88           (send-configuration-notify window (x-drawable-x window) (x-drawable-y window)
  89                                      (x-drawable-width window) (x-drawable-height window)
  90                                      (x-drawable-border-width window)))))))
  91
  92
  93 (define-handler main-mode :map-request (window send-event-p)
  94   (unless send-event-p
  95     (unless (find-child window *root-frame*)
  96       (unhide-window window)
  97       (process-new-window window)
  98       (map-window window)
  99       (multiple-value-bind (never-managed raise)
 100           (never-managed-window-p window)
 101         (unless (and never-managed raise)
 102           (show-all-children))))))
 103
 104
 105
 106 (define-handler main-mode :unmap-notify (send-event-p event-window window)
 107   (unless (and (not send-event-p)
 108                (not (xlib:window-equal window event-window)))
 109     (when (find-child window *root-frame*)
 110       (setf (window-state window) +withdrawn-state+)
 111       (remove-child-in-all-frames window)
 112       (show-all-children))))
 113
 114
 115 (define-handler main-mode :destroy-notify (send-event-p event-window window)
 116   (unless (or send-event-p
 117               (xlib:window-equal window event-window))
 118     (when (find-child window *root-frame*)
 119       (delete-child-in-all-frames window)
 120       (show-all-children))))
 121
 122
 123 (define-handler main-mode :enter-notify  (window root-x root-y)
 124   (unless (and (> root-x (- (xlib:screen-width *screen*) 3))
 125                (> root-y (- (xlib:screen-height *screen*) 3)))
 126     (manage-focus  window root-x root-y)))
 127
 128
 129 (define-handler main-mode :exposure (window)
 130   (awhen (find-frame-window window)
 131     (display-frame-info it)))
 132
 133
 134 (define-handler main-mode :configure-notify (window)
 135   (when (child-equal-p window *root*)
 136     (unless (eql (place-frames-from-xinerama-infos) :update)
 137       (finish-configuring-root))
 138     (show-all-children)
 139     (call-hook *root-size-change-hook*)))
 140
 141
 142 (defun error-handler (display error-key &rest key-vals &key asynchronous &allow-other-keys)
 143   "Handle X errors"
 144   (cond
 145     ;; ignore asynchronous window errors
 146     ((and asynchronous
 147           (find error-key '(xlib:window-error xlib:drawable-error xlib:match-error)))
 148      #+:xlib-debug (format t "~&Ignoring XLib asynchronous error: ~s~%" error-key))
 149     ((eq error-key 'xlib:access-error)
 150      (write-line "~&Another window manager is running.")
 151      (throw 'exit-clfswm nil))
 152     ;; all other asynchronous errors are printed.
 153     (asynchronous
 154      #+:xlib-debug (format t "~&Caught Asynchronous X Error: ~s ~s" error-key key-vals))
 155     ;;((find error-key '(xlib:window-error xlib:drawable-error xlib:match-error))
 156     ;; (format t "~&Ignoring Xlib error: ~S ~S~%" error-key key-vals))
 157     (t
 158      (apply 'error error-key :display display :error-key error-key key-vals))))
 159
 160
 161 (defun main-loop ()
 162   (loop
 163      (with-xlib-protect (:main-loop nil)
 164        (call-hook *loop-hook*)
 165        (process-timers)
 166        (when (xlib:event-listen *display* *loop-timeout*)
 167          (xlib:process-event *display* :handler #'handle-event))
 168        (xlib:display-finish-output *display*)
 169        (setf *x-error-count* 0))))
 170
 171
 172
 173
 174 (defun open-display (display-str protocol)
 175   (multiple-value-bind (host display-num) (parse-display-string display-str)
 176     (setf *display* (xlib:open-display host :display display-num :protocol protocol)
 177           (xlib:display-error-handler *display*) 'error-handler
 178           (getenv "DISPLAY") display-str)))
 179
 180
 181
 182 (defun default-init-hook ()
 183   (place-frames-from-xinerama-infos)
 184   (finish-configuring-root))
 185
 186
 187 (defun init-display ()
 188   (reset-root-list)
 189   (reset-last-head-size)
 190   (reset-bind-or-jump-slots)
 191   (reset-open-menu)
 192   (fill-handle-event-fun-symbols)
 193   (assoc-keyword-handle-event 'main-mode)
 194   (setf *screen* (first (xlib:display-roots *display*))
 195         *root* (xlib:screen-root *screen*)
 196         *no-focus-window* (xlib:create-window :parent *root* :x 0 :y 0 :width 1 :height 1)
 197         *default-font* (xlib:open-font *display* *default-font-string*)
 198         *pixmap-buffer* (xlib:create-pixmap :width (xlib:screen-width *screen*)
 199                                             :height (xlib:screen-height *screen*)
 200                                             :depth (xlib:screen-root-depth *screen*)
 201                                             :drawable *root*)
 202         *in-second-mode* nil
 203         *x-error-count* 0)
 204   (store-root-background)
 205   (init-modifier-list)
 206   (xgrab-init-pointer)
 207   (xgrab-init-keyboard)
 208   (init-last-child)
 209   (call-hook *binding-hook*)
 210   (clear-timers)
 211   (map-window *no-focus-window*)
 212   (dbg *display*)
 213   (setf (xlib:window-event-mask *root*) (xlib:make-event-mask :substructure-redirect
 214                                                               :substructure-notify
 215                                                               :structure-notify
 216                                                               :property-change
 217                                                               ;;:resize-redirect
 218                                                               :exposure
 219                                                               :button-press
 220                                                               :button-release
 221                                                               :pointer-motion))
 222   (xlib:display-finish-output *display*)
 223   ;;(intern-atoms *display*)
 224   (netwm-set-properties)
 225   (xlib:display-force-output *display*)
 226   (setf *child-selection* nil)
 227   (setf *root-frame* (create-frame :name "Root" :number 0)
 228         (current-child) *root-frame*)
 229   (call-hook *init-hook*)
 230   (process-existing-windows *screen*)
 231   (show-all-children)
 232   (grab-main-keys)
 233   (xlib:display-finish-output *display*)
 234   (optimize-event-hook))
 235
 236
 237
 238
 239 (defun read-conf-file ()
 240   (let* ((conf (conf-file-name)))
 241     (if conf
 242         (handler-case (load conf)
 243           (error (c)
 244             (format t "~2%*** Error loading configuration file: ~A ***~&~A~%" conf c)
 245             (values nil (format nil "~s" c) conf))
 246           (:no-error (&rest args)
 247             (declare (ignore args))
 248             (values t nil conf)))
 249         (values t nil nil))))
 250
 251
 252
 253
 254
 255
 256 (defun exit-clfswm ()
 257   "Exit clfswm"
 258   (throw 'exit-clfswm nil))
 259
 260 (defun reset-clfswm ()
 261   "Reset clfswm"
 262   (throw 'exit-main-loop nil))
 263
 264
 265
 266
 267 (defun main-unprotected (&key (display (or (getenv "DISPLAY") ":0")) protocol
 268                          (read-conf-file-p t) (alternate-conf nil)
 269                          error-msg)
 270   (conf-file-name alternate-conf)
 271   (when read-conf-file-p
 272     (read-conf-file))
 273   (create-configuration-menu :clear t)
 274   (call-hook *main-entrance-hook*)
 275   (handler-case
 276       (open-display display protocol)
 277     (xlib:access-error (c)
 278       (format t "~&~A~&Maybe another window manager is running. [1]~%" c)
 279       (force-output)
 280       (exit-clfswm)))
 281   (handler-case
 282       (init-display)
 283     (xlib:access-error (c)
 284       (ungrab-main-keys)
 285       (xlib:destroy-window *no-focus-window*)
 286       (xlib:close-display *display*)
 287       (format t "~&~A~&Maybe another window manager is running. [2]~%" c)
 288       (force-output)
 289       (exit-clfswm)))
 290   (when error-msg
 291     (info-mode error-msg))
 292   (catch 'exit-main-loop
 293       (unwind-protect
 294            (main-loop)
 295         (progn
 296           (ungrab-main-keys)
 297           (xlib:destroy-window *no-focus-window*)
 298           (xlib:free-pixmap *pixmap-buffer*)
 299           (destroy-all-frames-window)
 300           (call-hook *close-hook*)
 301           (clear-event-hooks)
 302           (xlib:close-display *display*)
 303           #+:event-debug
 304           (format t "~2&Unhandled events: ~A~%" *unhandled-events*)))))
 305
 306
 307
 308 (defun main (&key (display (or (getenv "DISPLAY") ":0")) protocol
 309              (read-conf-file-p t)
 310              (alternate-conf nil))
 311   (let (error-msg)
 312     (catch 'exit-clfswm
 313       (loop
 314          (handler-case
 315              (if *other-window-manager*
 316                  (run-other-window-manager)
 317                  (main-unprotected :display display :protocol protocol
 318                                    :read-conf-file-p read-conf-file-p
 319                                    :alternate-conf alternate-conf
 320                                    :error-msg error-msg))
 321            (error (c)
 322              (let ((msg (format nil "CLFSWM Error: ~A." c)))
 323                (format t "~&~A~%Reinitializing...~%" msg)
 324                (setf error-msg (list (list msg *info-color-title*)
 325                                      "Reinitializing...")))))))))
 326
 327
 328