src/clfswm.lisp

   1 ;;; --------------------------------------------------------------------------
   2 ;;; CLFSWM - FullScreen Window Manager
   3 ;;;
   4 ;;; --------------------------------------------------------------------------
   5 ;;; Documentation: Main functions
   6 ;;; --------------------------------------------------------------------------
   7 ;;;
   8 ;;; (C) 2010 Philippe Brochard <hocwp@free.fr>
   9 ;;;
  10 ;;; This program is free software; you can redistribute it and/or modify
  11 ;;; it under the terms of the GNU General Public License as published by
  12 ;;; the Free Software Foundation; either version 3 of the License, or
  13 ;;; (at your option) any later version.
  14 ;;;
  15 ;;; This program is distributed in the hope that it will be useful,
  16 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;;; GNU General Public License for more details.
  19 ;;;
  20 ;;; You should have received a copy of the GNU General Public License
  21 ;;; along with this program; if not, write to the Free Software
  22 ;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  23 ;;;
  24 ;;; --------------------------------------------------------------------------
  25
  26 (in-package :clfswm)
  27
  28
  29 (define-handler main-mode :key-press (code state)
  30   (funcall-key-from-code *main-keys* code state))
  31
  32 (define-handler main-mode :button-press (code state window root-x root-y)
  33   (unless (funcall-button-from-code *main-mouse* code state window root-x root-y *fun-press*)
  34     (replay-button-event)))
  35
  36 (define-handler main-mode :button-release (code state window root-x root-y)
  37   (unless (funcall-button-from-code *main-mouse* code state window root-x root-y *fun-release*)
  38     (replay-button-event)))
  39
  40 (define-handler main-mode :motion-notify (window root-x root-y)
  41   (unless (compress-motion-notify)
  42     (funcall-button-from-code *main-mouse* 'motion
  43                               (modifiers->state *default-modifiers*)
  44                               window root-x root-y *fun-press*)))
  45
  46 (define-handler main-mode :configure-request (stack-mode window x y width height border-width value-mask)
  47   (labels ((has-x (mask) (= 1 (logand mask 1)))
  48            (has-y (mask) (= 2 (logand mask 2)))
  49            (has-w (mask) (= 4 (logand mask 4)))
  50            (has-h (mask) (= 8 (logand mask 8)))
  51            (has-bw (mask) (= 16 (logand mask 16)))
  52            (has-stackmode (mask) (= 64 (logand mask 64)))
  53            (adjust-from-request ()
  54              (when (has-x value-mask) (setf (xlib:drawable-x window) x))
  55              (when (has-y value-mask) (setf (xlib:drawable-y window) y))
  56              (when (has-h value-mask) (setf (xlib:drawable-height window) height))
  57              (when (has-w value-mask) (setf (xlib:drawable-width window) width))))
  58     (xlib:with-state (window)
  59       (when (has-bw value-mask)
  60         (setf (xlib:drawable-border-width window) border-width))
  61       (if (find-child window *current-root*)
  62           (let ((parent (find-parent-frame window *current-root*)))
  63             (if (and parent (managed-window-p window parent))
  64                 (adapt-child-to-parent window parent)
  65                 (adjust-from-request)))
  66           (adjust-from-request))
  67       (send-configuration-notify window (xlib:drawable-x window) (xlib:drawable-y window)
  68                                  (xlib:drawable-width window) (xlib:drawable-height window)
  69                                  (xlib:drawable-border-width window))
  70       (when (has-stackmode value-mask)
  71         (case stack-mode
  72           (:above
  73            (unless (null-size-window-p window)
  74              (when (or (child-equal-p window *current-child*)
  75                        (is-in-current-child-p window))
  76                (raise-window window)
  77                (focus-window window)
  78                (focus-all-children window (find-parent-frame window *current-root*))))))))))
  79
  80
  81 (define-handler main-mode :map-request (window send-event-p)
  82   (unless send-event-p
  83     (unhide-window window)
  84     (process-new-window window)
  85     (map-window window)
  86     (unless (null-size-window-p window)
  87       (multiple-value-bind (never-managed raise)
  88           (never-managed-window-p window)
  89         (unless (and never-managed raise)
  90           (show-all-children))))))
  91
  92
  93 (define-handler main-mode :unmap-notify (send-event-p event-window window)
  94   (unless (and (not send-event-p)
  95                (not (xlib:window-equal window event-window)))
  96     (when (find-child window *root-frame*)
  97       (delete-child-in-all-frames window)
  98       (show-all-children))))
  99
 100
 101 (define-handler main-mode :destroy-notify (send-event-p event-window window)
 102   (unless (or send-event-p
 103               (xlib:window-equal window event-window))
 104     (when (find-child window *root-frame*)
 105       (delete-child-in-all-frames window)
 106       (show-all-children))))
 107
 108 (define-handler main-mode :enter-notify  (window root-x root-y)
 109   (unless (and (> root-x (- (xlib:screen-width *screen*) 3))
 110                (> root-y (- (xlib:screen-height *screen*) 3)))
 111     (case (if (frame-p *current-child*)
 112               (frame-focus-policy *current-child*)
 113               *default-focus-policy*)
 114       (:sloppy (focus-window window))
 115       (:sloppy-strict (when (and (frame-p *current-child*)
 116                                  (child-member window (frame-child *current-child*)))
 117                         (focus-window window)))
 118       (:sloppy-select (let* ((child (find-child-under-mouse root-x root-y))
 119                              (parent (find-parent-frame child)))
 120                         (unless (or (child-equal-p child *current-root*)
 121                                     (equal (typecase child
 122                                              (xlib:window parent)
 123                                              (t child))
 124                                            *current-child*))
 125                             (focus-all-children child parent)
 126                             (show-all-children)))))))
 127
 128 (define-handler main-mode :exposure (window)
 129   (awhen (find-frame-window window *current-root*)
 130     (display-frame-info it)))
 131
 132
 133 (defun error-handler (display error-key &rest key-vals &key asynchronous &allow-other-keys)
 134   "Handle X errors"
 135   (cond
 136     ;; ignore asynchronous window errors
 137     ((and asynchronous
 138           (find error-key '(xlib:window-error xlib:drawable-error xlib:match-error)))
 139      (format t "Ignoring XLib asynchronous error: ~s~%" error-key))
 140     ((eq error-key 'xlib:access-error)
 141      (write-line "Another window manager is running.")
 142      (throw 'exit-clfswm nil))
 143      ;; all other asynchronous errors are printed.
 144      (asynchronous
 145       (format t "Caught Asynchronous X Error: ~s ~s" error-key key-vals))
 146      (t
 147       (apply 'error error-key :display display :error-key error-key key-vals))))
 148
 149
 150 (defun main-loop ()
 151   (loop
 152      (call-hook *loop-hook*)
 153      (process-timers)
 154      (with-xlib-protect
 155        (when (xlib:event-listen *display* *loop-timeout*)
 156          (xlib:process-event *display* :handler #'handle-event))
 157        (xlib:display-finish-output *display*))))
 158
 159
 160
 161 (defun open-display (display-str protocol)
 162   (multiple-value-bind (host display-num) (parse-display-string display-str)
 163     (setf *display* (xlib:open-display host :display display-num :protocol protocol)
 164           (xlib:display-error-handler *display*) 'error-handler
 165           (getenv "DISPLAY") display-str)))
 166
 167
 168
 169 (defun default-init-hook ()
 170   (let ((frame (add-frame (create-frame :name "Default"
 171                                         :layout nil :x 0.05 :y 0.05
 172                                         :w 0.9 :h 0.9) *root-frame*)))
 173     (setf *current-child* frame)))
 174
 175
 176 (defun init-display ()
 177   (fill-handle-event-fun-symbols)
 178   (assoc-keyword-handle-event 'main-mode)
 179   (setf *screen* (first (xlib:display-roots *display*))
 180         *root* (xlib:screen-root *screen*)
 181         *no-focus-window* (xlib:create-window :parent *root* :x 0 :y 0 :width 1 :height 1)
 182         *default-font* (xlib:open-font *display* *default-font-string*)
 183         *pixmap-buffer* (xlib:create-pixmap :width (xlib:screen-width *screen*)
 184                                             :height (xlib:screen-height *screen*)
 185                                             :depth (xlib:screen-root-depth *screen*)
 186                                             :drawable *root*)
 187         *in-second-mode* nil)
 188   (init-modifier-list)
 189   (xgrab-init-pointer)
 190   (xgrab-init-keyboard)
 191   (init-last-child)
 192   (call-hook *binding-hook*)
 193   (clear-timers)
 194   (map-window *no-focus-window*)
 195   (dbg *display*)
 196   (setf (xlib:window-event-mask *root*) (xlib:make-event-mask :substructure-redirect
 197                                                               :substructure-notify
 198                                                               :property-change
 199                                                               :exposure
 200                                                               :button-press
 201                                                               :button-release
 202                                                               :pointer-motion))
 203   ;;(intern-atoms *display*)
 204   (netwm-set-properties)
 205   (xlib:display-force-output *display*)
 206   (setf *child-selection* nil)
 207   (setf *root-frame* (create-frame :name "Root" :number 0)
 208         *current-root* *root-frame*
 209         *current-child* *current-root*)
 210   (call-hook *init-hook*)
 211   (process-existing-windows *screen*)
 212   (show-all-children *current-root*)
 213   (grab-main-keys)
 214   (xlib:display-finish-output *display*))
 215
 216
 217
 218 (defun read-conf-file ()
 219   (let* ((conf (conf-file-name)))
 220     (if conf
 221         (handler-case (load conf)
 222           (error (c)
 223             (format t "~2%*** Error loading configuration file: ~A ***~&~A~%" conf c)
 224             (values nil (format nil "~s" c) conf))
 225           (:no-error (&rest args)
 226             (declare (ignore args))
 227             (values t nil conf)))
 228         (values t nil nil))))
 229
 230
 231
 232
 233
 234
 235 (defun exit-clfswm ()
 236   "Exit clfswm"
 237   (throw 'exit-clfswm nil))
 238
 239 (defun reset-clfswm ()
 240   "Reset clfswm"
 241   (throw 'exit-main-loop nil))
 242
 243
 244
 245
 246 (defun main-unprotected (&key (display (or (getenv "DISPLAY") ":0")) protocol
 247                          (base-dir (directory-namestring (or *load-truename* "")))
 248                          (read-conf-file-p t) (alternate-conf nil)
 249                          error-msg)
 250   (setf *contrib-dir* base-dir)
 251   (conf-file-name alternate-conf)
 252   (when read-conf-file-p
 253     (read-conf-file))
 254   (call-hook *main-entrance-hook*)
 255   (handler-case
 256       (open-display display protocol)
 257     (xlib:access-error (c)
 258       (format t "~&~A~&Maybe another window manager is running. [1]~%" c)
 259       (force-output)
 260       (exit-clfswm)))
 261   (handler-case
 262       (init-display)
 263     (xlib:access-error (c)
 264       (ungrab-main-keys)
 265       (xlib:destroy-window *no-focus-window*)
 266       (xlib:close-display *display*)
 267       (format t "~&~A~&Maybe another window manager is running. [2]~%" c)
 268       (force-output)
 269       (exit-clfswm)))
 270   (when error-msg
 271     (info-mode error-msg))
 272   (catch 'exit-main-loop
 273       (unwind-protect
 274            (main-loop)
 275         (ungrab-main-keys)
 276         (xlib:destroy-window *no-focus-window*)
 277         (xlib:free-pixmap *pixmap-buffer*)
 278         (call-hook *close-hook*)
 279         (xlib:close-display *display*)
 280         #+:event-debug
 281         (format t "~2&Unhandled events: ~A~%" *unhandled-events*))))
 282
 283
 284
 285 (defun main (&key (display (or (getenv "DISPLAY") ":0")) protocol
 286              (base-dir (directory-namestring (or *load-truename* "")))
 287              (read-conf-file-p t)
 288              (alternate-conf nil))
 289   (let (error-msg)
 290     (catch 'exit-clfswm
 291       (loop
 292          (handler-case
 293              (if *other-window-manager*
 294                  (run-other-window-manager)
 295                  (main-unprotected :display display :protocol protocol :base-dir base-dir
 296                                    :read-conf-file-p read-conf-file-p
 297                                    :alternate-conf alternate-conf
 298                                    :error-msg error-msg))
 299            (error (c)
 300              (let ((msg (format nil "CLFSWM Error: ~A." c)))
 301                (format t "~&~A~%Reinitializing...~%" msg)
 302                (setf error-msg (list (list msg *info-color-title*)
 303                                      "Reinitializing...")))))))))
 304
 305
 306