sqlite.lisp

   1 (defpackage :sqlite
   2   (:use :cl :iter)
   3   (:export :sqlite-handle
   4            :connect
   5            :set-busy-timeout
   6            :disconnect
   7            :sqlite-statement
   8            :prepare-statement
   9            :finalize-statement
  10            :step-statement
  11            :reset-statement
  12            :statement-column-value
  13            :bind-parameter
  14            :execute-non-query
  15            :execute-to-list
  16            :execute-single
  17            :execute-one-row-m-v
  18            :last-insert-rowid
  19            :with-transaction
  20            :with-open-database))
  21
  22 (in-package :sqlite)
  23
  24 ;(declaim (optimize (speed 3) (safety 0) (debug 0)))
  25
  26 (defclass sqlite-handle ()
  27   ((handle :accessor handle)
  28    (database-path :accessor database-path)
  29    (cache :accessor cache)
  30    (statements :initform nil :accessor sqlite-handle-statements))
  31   (:documentation "Class that encapsulates the connection to the database. Use connect and disconnect."))
  32
  33 (defmethod initialize-instance :after ((object sqlite-handle) &key (database-path ":memory:") &allow-other-keys)
  34   (cffi:with-foreign-object (ppdb 'sqlite-ffi:p-sqlite3)
  35     (let ((error-code (sqlite-ffi:sqlite3-open database-path ppdb)))
  36       (if (eq error-code :ok)
  37           (setf (handle object) (cffi:mem-ref ppdb 'sqlite-ffi:p-sqlite3)
  38                 (database-path object) database-path)
  39           (error "Received error code ~A when trying to open sqlite3 database ~A"
  40                  error-code database-path))))
  41   (setf (cache object) (make-instance 'sqlite.cache:mru-cache :cache-size 16 :destructor #'really-finalize-statement)))
  42
  43 (defun connect (database-path &key busy-timeout)
  44   "Connect to the sqlite database at the given DATABASE-PATH. Returns the SQLITE-HANDLE connected to the database. Use DISCONNECT to disconnect.
  45    Operations will wait for locked databases for up to BUSY-TIMEOUT milliseconds; if BUSY-TIMEOUT is NIL, then operations on locked databases will fail immediately."
  46   (let ((db (make-instance 'sqlite-handle
  47                            :database-path (etypecase database-path
  48                                             (string database-path)
  49                                             (pathname (namestring database-path))))))
  50     (when busy-timeout
  51       (set-busy-timeout db busy-timeout))
  52     db))
  53
  54 (defun set-busy-timeout (db milliseconds)
  55   "Sets the maximum amount of time to wait for a locked database."
  56   (sqlite-ffi:sqlite3-busy-timeout (handle db) milliseconds))
  57
  58 (defun disconnect (handle)
  59   "Disconnects the given HANDLE from the database. All further operations on the handle are invalid."
  60   (sqlite.cache:purge-cache (cache handle))
  61   (iter (with statements = (copy-list (sqlite-handle-statements handle)))
  62         (declare (dynamic-extent statements))
  63         (for statement in statements)
  64         (really-finalize-statement statement))
  65   (let ((error-code (sqlite-ffi:sqlite3-close (handle handle))))
  66     (unless (eq error-code :ok)
  67       (error "Received error code ~A when trying to close ~A (connected to ~A)" error-code handle (database-path handle)))
  68     (slot-makunbound handle 'handle)))
  69
  70 (defclass sqlite-statement ()
  71   ((db :reader db :initarg :db)
  72    (handle :accessor handle)
  73    (sql :reader sql :initarg :sql)
  74    (columns-count :accessor resultset-columns-count)
  75    (columns-names :accessor resultset-columns-names)
  76    (parameters-count :accessor parameters-count)
  77    (parameters-names :accessor parameters-names))
  78   (:documentation "Class that represents the prepared statement."))
  79
  80 (defmethod initialize-instance :after ((object sqlite-statement) &key &allow-other-keys)
  81   (cffi:with-foreign-object (p-statement 'sqlite-ffi:p-sqlite3-stmt)
  82     (cffi:with-foreign-object (p-tail '(:pointer :char))
  83       (cffi:with-foreign-string (sql (sql object))
  84         (let ((error-code (sqlite-ffi:sqlite3-prepare (handle (db object)) sql -1 p-statement p-tail)))
  85           (unless (eq error-code :ok)
  86             (error "Error when trying to prepare sqlite statement '~A'. Code: ~A, message: ~A" (sql object) error-code (sqlite-ffi:sqlite3-errmsg (handle (db object)))))
  87           (unless (zerop (cffi:mem-ref (cffi:mem-ref p-tail '(:pointer :char)) :uchar))
  88             (error "SQL string '~A' contains more than one SQL statements" (sql object)))
  89           (setf (handle object) (cffi:mem-ref p-statement 'sqlite-ffi:p-sqlite3-stmt)
  90                 (resultset-columns-count object) (sqlite-ffi:sqlite3-column-count (handle object))
  91                 (resultset-columns-names object) (loop
  92                                                     for i below (resultset-columns-count object)
  93                                                     collect (sqlite-ffi:sqlite3-column-name (handle object) i))
  94                 (parameters-count object) (sqlite-ffi:sqlite3-bind-parameter-count (handle object))
  95                 (parameters-names object) (loop
  96                                              for i from 1 to (parameters-count object)
  97                                              collect (sqlite-ffi:sqlite3-bind-parameter-name (handle object) i))))))))
  98
  99 (defun prepare-statement (db sql)
 100   "Prepare the statement to the DB that will execute the commands that are in SQL.
 101
 102 Returns the SQLITE-STATEMENT.
 103
 104 SQL must contain exactly one statement.
 105 SQL may have some positional (not named) parameters specified with question marks.
 106
 107 Example:
 108
 109  select name from users where id = ?"
 110   (or (sqlite.cache:get-from-cache (cache db) sql)
 111       (let ((statement (make-instance 'sqlite-statement :db db :sql sql)))
 112         (push statement (sqlite-handle-statements db))
 113         statement)))
 114
 115 (defun really-finalize-statement (statement)
 116   (setf (sqlite-handle-statements (db statement))
 117         (delete statement (sqlite-handle-statements (db statement))))
 118   (sqlite-ffi:sqlite3-finalize (handle statement))
 119   (slot-makunbound statement 'handle))
 120
 121 (defun finalize-statement (statement)
 122   "Finalizes the statement and signals that associated resources may be released.
 123 Note: does not immediately release resources because statements are cached."
 124   (progn
 125     (let ((error-code (sqlite-ffi:sqlite3-reset (handle statement))))
 126      (unless (eq error-code :ok)
 127        (error "When resetting statement ~A (sql: ~A), error ~A (~A)" statement (sql statement) error-code (sqlite-ffi:sqlite3-errmsg (handle (db statement))))))
 128     (sqlite.cache:put-to-cache (cache (db statement)) (sql statement) statement)))
 129
 130 (defun step-statement (statement)
 131   "Steps to the next row of the resultset of STATEMENT.
 132 Returns T is successfully advanced to the next row and NIL if there are no more rows."
 133   (let ((error-code (sqlite-ffi:sqlite3-step (handle statement))))
 134     (case error-code
 135       (:done nil)
 136       (:row t)
 137       (t (error "When stepping statement ~A (sql: ~A), error ~A (~A)" statement (sql statement) error-code (sqlite-ffi:sqlite3-errmsg (handle (db statement))))))))
 138
 139 (defun reset-statement (statement)
 140   "Resets the STATEMENT and prepare it to be called again."
 141   (let ((error-code (sqlite-ffi:sqlite3-reset (handle statement))))
 142     (unless (eq error-code :ok)
 143       (error "When resetting statment ~A (sql: ~A), error ~A (~A)" statement (sql statement) error-code (sqlite-ffi:sqlite3-errmsg (handle (db statement)))))))
 144
 145 (defun statement-column-value (statement column-number)
 146   "Returns the COLUMN-NUMBER-th column's value of the current row of the STATEMENT. Columns are numbered from zero.
 147 Returns:
 148  * NIL for NULL
 149  * INTEGER for integers
 150  * DOUBLE-FLOAT for floats
 151  * STRING for text
 152  * (SIMPLE-ARRAY (UNSIGNED-BYTE 8)) for BLOBs"
 153   (let ((type (sqlite-ffi:sqlite3-column-type (handle statement) column-number)))
 154     (ecase type
 155       (:null nil)
 156       (:text (sqlite-ffi:sqlite3-column-text (handle statement) column-number))
 157       (:integer (sqlite-ffi:sqlite3-column-int64 (handle statement) column-number))
 158       (:float (sqlite-ffi:sqlite3-column-double (handle statement) column-number))
 159       (:blob (let* ((blob-length (sqlite-ffi:sqlite3-column-bytes (handle statement) column-number))
 160                     (result (make-array (the fixnum blob-length) :element-type '(unsigned-byte 8)))
 161                     (blob (sqlite-ffi:sqlite3-column-blob (handle statement) column-number)))
 162                (loop
 163                   for i below blob-length
 164                   do (setf (aref result i) (cffi:mem-aref blob :unsigned-char i)))
 165                result)))))
 166
 167 (defun execute-non-query (db sql &rest parameters)
 168   "Executes the query SQL to the database DB with given PARAMETERS. Returns nothing.
 169
 170 Example:
 171
 172 \(execute-non-query db \"insert into users (user_name, real_name) values (?, ?)\" \"joe\" \"Joe the User\")
 173
 174 See BIND-PARAMETER for the list of supported parameter types."
 175   (declare (dynamic-extent parameters))
 176   (let ((stmt (prepare-statement db sql)))
 177     (iter (for i from 1)
 178           (declare (type fixnum i))
 179           (for value in parameters)
 180           (bind-parameter stmt i value))
 181     (step-statement stmt)
 182     (finalize-statement stmt)
 183     (values)))
 184
 185 (defun execute-to-list (db sql &rest parameters)
 186   "Executes the query SQL to the database DB with given PARAMETERS. Returns the results as list of lists.
 187
 188 Example:
 189
 190 \(execute-to-list db \"select id, user_name, real_name from users where user_name = ?\" \"joe\")
 191 =>
 192 \((1 \"joe\" \"Joe the User\")
 193  (2 \"joe\" \"Another Joe\"))
 194
 195 See BIND-PARAMETER for the list of supported parameter types."
 196   (declare (dynamic-extent parameters))
 197   (let ((stmt (prepare-statement db sql))
 198         result)
 199     (iter (for i from 1)
 200           (declare (type fixnum i))
 201           (for value in parameters)
 202           (bind-parameter stmt i value))
 203     (loop (if (step-statement stmt)
 204               (push (iter (for i from 0 below (the fixnum (sqlite-ffi:sqlite3-column-count (handle stmt))))
 205                           (declare (type fixnum i))
 206                           (collect (statement-column-value stmt i)))
 207                     result)
 208               (return)))
 209     (finalize-statement stmt)
 210     (nreverse result)))
 211
 212 (defun execute-one-row-m-v (db sql &rest parameters)
 213   "Executes the query SQL to the database DB with given PARAMETERS. Returns the first row as multiple values.
 214
 215 Example:
 216 \(execute-one-row-m-v db \"select id, user_name, real_name from users where id = ?\" 1)
 217 =>
 218 \(values 1 \"joe\" \"Joe the User\")
 219
 220 See BIND-PARAMETER for the list of supported parameter types."
 221   (let ((stmt (prepare-statement db sql)))
 222     (unwind-protect
 223          (progn
 224            (iter (for i from 1)
 225                  (declare (type fixnum i))
 226                  (for value in parameters)
 227                  (bind-parameter stmt i value))
 228            (if (step-statement stmt)
 229                (return-from execute-one-row-m-v
 230                  (values-list (iter (for i from 0 below (the fixnum (sqlite-ffi:sqlite3-column-count (handle stmt))))
 231                                     (declare (type fixnum i))
 232                                     (collect (statement-column-value stmt i)))))
 233                (return-from execute-one-row-m-v
 234                  (values-list (loop repeat (the fixnum (sqlite-ffi:sqlite3-column-count (handle stmt))) collect nil)))))
 235       (finalize-statement stmt))))
 236
 237 (defun statement-parameter-index (statement parameter-name)
 238   (sqlite-ffi:sqlite3-bind-parameter-index (handle statement) parameter-name))
 239
 240 (defun bind-parameter (statement parameter value)
 241   "Sets the PARAMETER-th parameter in STATEMENT to the VALUE.
 242 Parameters are numbered from one.
 243 Supported types:
 244  * NULL. Passed as NULL
 245  * INTEGER. Passed as an 64-bit integer
 246  * STRING. Passed as a string
 247  * FLOAT. Passed as a double
 248  * (VECTOR (UNSIGNED-BYTE 8)) and VECTOR that contains integers in range [0,256). Passed as a BLOB"
 249   (let ((index (etypecase parameter
 250                  (integer parameter)
 251                  (string (statement-parameter-index statement parameter)))))
 252     (declare (type fixnum index))
 253     (let ((error-code (typecase value
 254                         (null (sqlite-ffi:sqlite3-bind-null (handle statement) index))
 255                         (integer (sqlite-ffi:sqlite3-bind-int64 (handle statement) index value))
 256                         (double-float (sqlite-ffi:sqlite3-bind-double (handle statement) index value))
 257                         (real (sqlite-ffi:sqlite3-bind-double (handle statement) index (coerce value 'double-float)))
 258                         (string (sqlite-ffi:sqlite3-bind-text (handle statement) index value -1 (sqlite-ffi:destructor-transient)))
 259                         ((vector (unsigned-byte 8)) (cffi:with-pointer-to-vector-data (ptr value)
 260                                                       (sqlite-ffi:sqlite3-bind-blob (handle statement) index ptr (length value) (sqlite-ffi:destructor-transient))))
 261                         (vector (cffi:with-foreign-object (array :unsigned-char (length value))
 262                                   (loop
 263                                      for i from 0 below (length value)
 264                                      do (setf (cffi:mem-aref array :unsigned-char i) (aref value i)))
 265                                   (sqlite-ffi:sqlite3-bind-blob (handle statement) index array (length value) (sqlite-ffi:destructor-transient))))
 266                         (t (error "Do not know how to pass value ~A of type ~A to sqlite" value (type-of value))))))
 267       (unless (eq error-code :ok)
 268         (error "When binding parameter ~A to value ~A for statment ~A (sql: ~A), error ~A (~A)" parameter value statement (sql statement) error-code (sqlite-ffi:sqlite3-errmsg (handle (db statement))))))))
 269
 270 (defun execute-single (db sql &rest parameters)
 271   "Executes the query SQL to the database DB with given PARAMETERS. Returns the first column of the first row as single value.
 272
 273 Example:
 274 \(execute-single db \"select user_name from users where id = ?\" 1)
 275 =>
 276 \"joe\"
 277
 278 See BIND-PARAMETER for the list of supported parameter types."
 279   (declare (dynamic-extent parameters))
 280   (let ((stmt (prepare-statement db sql)))
 281     (unwind-protect
 282          (progn
 283            (iter (for i from 1)
 284                  (declare (type fixnum i))
 285                  (for value in parameters)
 286                  (bind-parameter stmt i value))
 287            (if (step-statement stmt)
 288                (statement-column-value stmt 0)
 289                nil))
 290       (finalize-statement stmt))))
 291
 292 (defun last-insert-rowid (db)
 293   "Returns the auto-generated ID of the last inserted row on the database connection DB."
 294   (sqlite-ffi:sqlite3-last-insert-rowid (handle db)))
 295
 296 (defmacro with-transaction (db &body body)
 297   "Wraps the BODY inside the transaction."
 298   (let ((ok (gensym "TRANSACTION-COMMIT-"))
 299         (db-var (gensym "DB-"))
 300         (result (gensym "RESULT-")))
 301     `(let (,ok
 302            (,db-var ,db))
 303        (execute-non-query ,db-var "begin transaction")
 304        (unwind-protect
 305             (progn
 306               (let ((,result (progn
 307                                ,@body)))
 308                 (setf ,ok t)
 309                 ,result))
 310          (if ,ok
 311              (execute-non-query ,db-var "commit transaction")
 312              (execute-non-query ,db-var "rollback transaction"))))))
 313
 314 (defmacro with-open-database ((db path &key busy-timeout) &body body)
 315   `(let ((,db (connect ,path :busy-timeout ,busy-timeout)))
 316      (unwind-protect
 317           (progn ,@body)
 318        (disconnect ,db))))
 319
 320 (defmacro-driver (FOR vars IN-SQLITE-QUERY query-expression ON-DATABASE db &optional WITH-PARAMETERS parameters)
 321   (let ((statement (gensym "STATEMENT-"))
 322         (kwd (if generate 'generate 'for)))
 323     `(progn (with ,statement = (prepare-statement ,db ,query-expression))
 324             (finally-protected (when ,statement (finalize-statement ,statement)))
 325             ,@(when parameters
 326                     (list `(initially ,@(iter (for i from 1)
 327                                               (for value in parameters)
 328                                               (collect `(sqlite:bind-parameter ,statement ,i ,value))))))
 329             (,kwd ,(if (symbolp vars)
 330                        `(values ,vars)
 331                        `(values ,@vars))
 332                   next (progn (if (step-statement ,statement)
 333                                   (values ,@(iter (for i from 0 below (if (symbolp vars) 1 (length vars)))
 334                                                   (collect `(statement-column-value ,statement ,i))))
 335                                   (terminate)))))))
 336
 337 (defmacro-driver (FOR vars ON-SQLITE-STATEMENT statement)
 338   (let ((statement-var (gensym "STATEMENT-"))
 339         (kwd (if generate 'generate 'for)))
 340     `(progn (with ,statement-var = ,statement)
 341             (,kwd ,(if (symbolp vars)
 342                        `(values ,vars)
 343                        `(values ,@vars))
 344                   next (progn (if (step-statement ,statement-var)
 345                                   (values ,@(iter (for i from 0 below (if (symbolp vars) 1 (length vars)))
 346                                                   (collect `(statement-column-value ,statement-var ,i))))
 347                                   (terminate)))))))