satwrap.lisp

   1 ;;; -*- Mode: Lisp; Syntax: ANSI-Common-Lisp; Base: 10; -*-
   2 ;;;
   3 ;;; satwrap.lisp --- SAT solvers wrapped for CL
   4
   5 ;; Copyright (C) 2010 Utz-Uwe Haus <lisp@uuhaus.de>
   6 ;; $Id:$
   7 ;; This code is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the version 3 of the GNU General
   9 ;; Public License as published by the Free Software Foundation, as
  10 ;; clarified by the prequel found in LICENSE.Lisp-GPL-Preface.
  11 ;;
  12 ;; This code is distributed in the hope that it will be useful, but
  13 ;; without any warranty; without even the implied warranty of
  14 ;; merchantability or fitness for a particular purpose. See the GNU
  15 ;; Lesser General Public License for more details.
  16 ;;
  17 ;; Version 3 of the GNU General Public License is in the file
  18 ;; LICENSE.GPL that was distributed with this file. If it is not
  19 ;; present, you can access it from
  20 ;; http://www.gnu.org/copyleft/gpl.txt (until superseded by a
  21 ;; newer version) or write to the Free Software Foundation, Inc., 59
  22 ;; Temple Place, Suite 330, Boston, MA 02111-1307 USA
  23 ;;
  24 ;; Commentary:
  25
  26 ;;
  27
  28 ;;; Code:
  29
  30 (eval-when (:compile-toplevel :load-toplevel)
  31   (declaim (optimize (speed 3) (debug 1) (safety 1))))
  32
  33
  34 (in-package #:satwrap)
  35 \f
  36 (defvar *default-sat-backend* :minisat
  37   "Name of the default backend to be used by make-sat-solver.")
  38
  39 (defparameter *satwrap-backends*
  40   `((:precosat . ,(find-class 'satwrap.precosat:precosat-backend))
  41     (:minisat  . ,(find-class 'satwrap.minisat:minisat-backend)))
  42   "Alist of symbolic name to backend class name for all supported backends.")
  43
  44 (defun describe-supported-backends ()
  45   "Return a list of (designator . description) pairs of the supported backends"
  46   (loop :for (key . class) :in *satwrap-backends*
  47      :as descr := (let ((instance (make-instance class)))
  48                     (format nil "~A version ~A"
  49                             (satwrap.backend:sat-backend-name instance)
  50                             (satwrap.backend:sat-backend-version instance)))
  51      :collect `(,key . ,descr)))
  52
  53 \f
  54 ;;; Frontend:
  55 (defclass sat-solver ()
  56   ((backend :initarg :backend :accessor sat-solver-backend)
  57    (numvars :initform 0 :accessor sat-solver-numvars)
  58    ;; CNF; split into 'old' and 'new' to allow incremental solving
  59    (new-clauses :initform '() :accessor sat-solver-new-clauses)
  60    (old-clauses :initform '() :accessor sat-solver-old-clauses)
  61    )
  62   (:default-initargs :backend (make-instance (cdr (assoc *default-sat-backend*
  63                                                          *satwrap-backends*))))
  64   (:documentation "A Sat solver abstraction"))
  65
  66 (defmethod sat-solver-numclauses ((solver sat-solver))
  67   (+ (length (sat-solver-new-clauses solver))
  68      (length (sat-solver-old-clauses solver))
  69      ))
  70
  71 (defmethod print-object ((solver sat-solver) stream)
  72   (print-unreadable-object (solver stream :type T :identity T)
  73     (format stream "~D vars, ~D clauses, backend ~A"
  74             (sat-solver-numvars solver)
  75             (sat-solver-numclauses solver)
  76             (sat-solver-backend solver))))
  77
  78 (defmethod clause-valid ((solver sat-solver) (clause list))
  79   "Check that CLAUSE is a valid clause for SOLVER."
  80   (loop
  81      :with max := (sat-solver-numvars solver)
  82      :with min := (- max)
  83      :for v :in clause
  84      :always (and (not (zerop v))
  85                   (<= min v max))))
  86
  87 (defmacro iota (n &optional (start 1))
  88   "Return a list of the N sequential integers starting at START (default: 1)."
  89   (let ((i (gensym "i")))
  90     `(loop :repeat ,n
  91         :for ,i :from ,start
  92         :collect ,i)))
  93
  94 (define-condition satwrap-condition (error)
  95   ()
  96   (:documentation "Superclass of all conditions raised by satwrap code."))
  97
  98 (define-condition invalid-clause (satwrap-condition)
  99   ((solver :initarg :solver :reader invalid-clause-solver)
 100    (clause :initarg :clause :reader invalid-clause-clause))
 101   (:report (lambda (condition stream)
 102              (format stream "Invalid clause ~A for solver ~A"
 103                      (invalid-clause-clause condition)
 104                      (invalid-clause-solver condition)))))
 105
 106 (define-condition invalid-backend (satwrap-condition)
 107   ((name :initarg :name :reader invalid-backend-name))
 108   (:report (lambda (condition stream)
 109              (declare (special *satwrap-backends* *default-sat-backend*))
 110              (format stream "Invalid backend ~S specified. Supported: ~{~S~^, ~}, default ~S."
 111                      (invalid-backend-name condition)
 112                      (mapcar #'car *satwrap-backends*)
 113                      *default-sat-backend*))))
 114
 115 (defmethod flush-to-backend ((solver sat-solver))
 116   "Populate backend, possibly flushing old backend contents."
 117   (satwrap.backend:synchronize-backend (sat-solver-backend solver)
 118                                        (sat-solver-numvars solver)
 119                                        (sat-solver-new-clauses solver)
 120                                        '() ;; deleted clauses, not yet supported
 121                                        (sat-solver-old-clauses solver))
 122   (loop :with deleted := '()
 123      :for c :in (sat-solver-old-clauses solver)
 124      :unless (find c deleted :test #'equal)
 125      :do (push c (sat-solver-new-clauses solver)))
 126   (setf (sat-solver-old-clauses solver) (sat-solver-new-clauses solver)
 127         (sat-solver-new-clauses solver) '()))
 128
 129 \f
 130 (defun make-sat-solver (&optional (backend *default-sat-backend*))
 131   "Return a new sat solver instance. Optional argument BACKEND can be used to
 132 specify which backend should be used. It defaults to *default-sat-backend*."
 133   (let ((be (assoc backend *satwrap-backends* :test #'eq)))
 134     (if be
 135         (make-instance 'sat-solver :backend (make-instance (cdr be)))
 136         (error 'invalid-backend :name backend))))
 137
 138 (defgeneric add-variable (solver)
 139   (:documentation "Add another variable to SOLVER. Returns new variable index.")
 140   (:method ((solver sat-solver))
 141     (incf (sat-solver-numvars solver))))
 142
 143 (defgeneric add-clause (solver clause)
 144   (:documentation "Add CLAUSE to SOLVER's cnf formula. Clause is consumed.")
 145   (:method ((solver sat-solver) (clause list))
 146     (if (clause-valid solver clause)
 147         (push clause (sat-solver-new-clauses solver))
 148         (error 'invalid-clause :clause clause :solver solver)))
 149   (:method ((solver sat-solver) (clause vector))
 150     (add-clause solver (coerce clause 'list))))
 151
 152 (defgeneric satisfiablep (solver &key assume)
 153   (:documentation "Check whether current CNF in SOLVER is satisfiable.
 154 Keyword argument :ASSUME can provide a sequence of literals assumed TRUE or FALSE.
 155 Returns T or NIL.")
 156   (:method ((solver sat-solver) &key (assume '()))
 157     (if (clause-valid solver assume) ;; misusing 'clause' concept here
 158         (progn
 159           (flush-to-backend solver)
 160           (satwrap.backend:satisfiablep (sat-solver-backend solver) assume))
 161         (error 'invalid-clause :clause assume :solver solver))))
 162
 163 (defgeneric solution (solver &key interesting-vars)
 164   (:documentation "Return solution for SOLVER. If unsat, return '(). If sat return
 165 sequence of 0/1 values for variables [1...N]. Keyword argument INTERESTING-VARS can be used to restrict the variables whose values are reported. Solution components will be in the same order that INTERESTING-VARS lists the variables in.")
 166   (:method ((solver sat-solver)
 167             &key (interesting-vars (iota (sat-solver-numvars solver))))
 168     (satwrap.backend:solution (sat-solver-backend solver) interesting-vars)))
 169
 170 (defgeneric get-essential-variables (solver)
 171   (:documentation "Compute the variables that are essential, i.e. fixed in all solutions of SOLVER.
 172 Returns a list of literals fixed, sign according to phase.")
 173   (:method ((solver sat-solver))
 174     ;; The backend may define a specialized method, but then it has to
 175     ;; work on the one copy of data flushed to the solver. Precosat for example
 176     ;; does not allow that, so we define the universal implementation here instead of
 177     ;; a default implementation in the backend.
 178     (let ((have-specialized-method
 179            (find-method #'satwrap.backend:get-essential-variables
 180                         '()
 181                         `(,(class-of (sat-solver-backend solver)))
 182                         nil)))
 183       (if have-specialized-method
 184           (progn
 185             (flush-to-backend solver)
 186             (satwrap.backend:get-essential-variables (sat-solver-backend solver)))
 187           (let ((fixed '()))
 188             (loop :for var :of-type (integer 1) :in (iota (sat-solver-numvars solver))
 189                :as res-for-+ := (satisfiablep solver :assume `(,var ,@fixed))
 190                :as res-for-- := (satisfiablep solver :assume `(,(- var) ,@fixed))
 191                :do (cond
 192                      ((and res-for-+ (not res-for--))
 193                       (push var fixed))
 194                      ((and (not res-for-+) res-for--)
 195                       (push (- var) fixed))))
 196             fixed)))))
 197
 198 \f
 199 (defmacro with-sat-solver ((name numatoms &key (backend *default-sat-backend*))
 200                            &body body)
 201   "Bind NAME to a fresh sat-solver with backend :BACKEND (default: *default-sat-backend*) and declare NUMATOMS variables numbered 1..NUMATOMS for the duration of BODY."
 202   `(let ((,name (make-sat-solver ,backend)))
 203      (loop :repeat ,numatoms :do (add-variable ,name))
 204      (locally
 205          ,@body)))
 206
 207 (defmacro with-index-hash ((mapping &key (test 'cl:eq)) objects &body body)
 208   "Execute BODY while binding MAPPING to a hash-table (with predicate
 209 TEST, defaults to #'cl:eq) mapping the elements of the sequence OBJECTS
 210 to integer 1..[length objects].
 211 Typically used to map objects to variables inside WITH-SAT-SOLVER."
 212   (let ((o (gensym "objects")))
 213     `(let* ((,o ,objects)
 214             (,mapping (etypecase ,o
 215                        (list (loop :with ht := (make-hash-table :test ,test)
 216                                 :for x :in ,o
 217                                 :for num :of-type fixnum :from 1
 218                                 :do (setf (gethash x ht) num)
 219                                 :finally (return ht)))
 220                        (vector (loop :with ht := (make-hash-table :test ,test)
 221                                   :for x :across ,o
 222                                   :for num :of-type fixnum :from 1
 223                                   :do (setf (gethash x ht) num)
 224                                   :finally (return ht))))))
 225        ,@body)))