opossum.peg

   1 ## -*- mode: peg -*-
   2 ## $Id:$
   3 ## PEG syntax in PEG as in the original report
   4
   5 # Hierarchical syntax
   6 Grammar <-
   7         Spacing
   8         Definition+
   9         EndOfFile
  10
  11 Definition <- Identifier LEFTARROW Expression
  12
  13 Expression <- Sequence (SLASH Sequence)*
  14
  15 Sequence <- Prefix*
  16
  17 Prefix <- (AND / NOT)? Suffix
  18
  19 Suffix <- Primary (QUESTION / STAR / PLUS)?
  20
  21 Primary <-
  22           Identifier !LEFTARROW
  23         / OPEN Expression CLOSE
  24         / Literal
  25         / Class
  26         / DOT
  27
  28 # Lexical syntax
  29 Identifier <- IdentStart IdentCont* Spacing
  30 IdentStart <- [a-zA-Z_]
  31 IdentCont  <- IdentStart / [0-9]
  32 Literal    <-
  33           ['] (!['] Char)* ['] Spacing
  34         / ["] (!["] Char)* ["] Spacing
  35 Class      <-
  36         '[' (!']' Range)* ']' Spacing
  37 Range <- Char '-' Char / Char
  38 Char <-
  39           '\\' [nrt'"\[\]\\]    #' ...un-confuse emacs highlighting
  40         / '\\' [0-2][0-7][0-7]
  41         / '\\' [0-7][0-7]?
  42         / !'\\' .
  43
  44
  45 LEFTARROW <- '<-' Spacing
  46 SLASH     <- '/'  Spacing
  47 AND       <- '&'  Spacing
  48 NOT       <- '!'  Spacing
  49 QUESTION  <- '?'  Spacing
  50 STAR      <- '*'  Spacing
  51 PLUS      <- '+'  Spacing
  52 OPEN      <- '('  Spacing
  53 CLOSE     <- ')'  Spacing
  54 DOT       <- '.'  Spacing
  55 Spacing   <- (Space / Comment)*
  56 Comment   <- '#' (!EndOfLine .)* EndOfLine
  57 Space     <- ' ' / '\t' / EndOfLine
  58 EndOfLine <- '\r\n' / '\n' / '\r'
  59 EndOfFile <- !.