configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([centerim], m4_esyscmd([misc/git-version-gen .tarball-version]), [http://bugzilla.centerim.org])
   6 AC_CONFIG_SRCDIR([config.h.in])
   7 AC_CONFIG_HEADER([config.h])
   8 AM_INIT_AUTOMAKE([-Wall])
   9
  10 AC_ISC_POSIX
  11
  12 AC_CANONICAL_HOST
  13
  14 AC_GNU_SOURCE
  15
  16 ########################
  17 # Checks for programs. #
  18 ########################
  19 AC_PROG_CC
  20 AC_PROG_CXX
  21 AC_PROG_CPP
  22 AC_PROG_RANLIB
  23 AM_GNU_GETTEXT
  24 AM_GNU_GETTEXT_VERSION([0.14.6])
  25
  26
  27 #########################
  28 # Checks for libraries. #
  29 #########################
  30 AC_ARG_ENABLE(icq,
  31               AS_HELP_STRING([--disable-icq], [Build without ICQ]),
  32               build_icq="$enableval",
  33               build_icq="yes"
  34               )
  35 AC_ARG_ENABLE(yahoo,
  36               AS_HELP_STRING([--disable-yahoo], [Build without Yahoo!]),
  37               build_yahoo="$enableval",
  38               build_yahoo="yes"
  39               )
  40 AC_ARG_ENABLE(aim,
  41               AS_HELP_STRING([--disable-aim], [Build without AIM]),
  42               build_aim="$enableval",
  43               build_aim="yes"
  44               )
  45 AC_ARG_ENABLE(irc,
  46               AS_HELP_STRING([--disable-irc], [Build without IRC]),
  47               build_irc="$enableval",
  48               build_irc="yes"
  49               )
  50 AC_ARG_ENABLE(jabber,
  51               AS_HELP_STRING([--disable-jabber], [Build without Jabber]),
  52               build_jabber="$enableval",
  53               build_jabber="yes"
  54               )
  55 AC_ARG_ENABLE(gg,
  56               AS_HELP_STRING([--disable-gg], [Build without Gadu-Gadu]),
  57               build_gg="$enableval",
  58               build_gg="yes"
  59               )
  60 AC_ARG_ENABLE(msn,
  61               AS_HELP_STRING([--disable-msn], [Build without MSN]),
  62               build_msn="$enableval",
  63               build_msn="yes"
  64               )
  65 AC_ARG_ENABLE(rss,
  66               AS_HELP_STRING([--disable-rss], [Build without RSS reader]),
  67               build_rss="$enableval",
  68               build_rss="yes"
  69               )
  70 AC_ARG_ENABLE(lj,
  71               AS_HELP_STRING([--disable-lj], [Build without LiveJournal client]),
  72               build_lj="$enableval",
  73               build_lj="yes"
  74               )
  75 AC_ARG_ENABLE(locales-fix,
  76               AS_HELP_STRING([--enable-locales-fix], [enables workaround for
  77                               broken locales. use this option if some of
  78                               characters in your texts in Chinese or Japanese
  79                               disappear]),
  80               locales_fix="$enableval",
  81               locales_fix="yes"
  82               )
  83
  84 AC_ARG_WITH(fribidi,
  85             AS_HELP_STRING([--with-fribidi=[DIR]], [enable Hebrew and Arabic
  86                             support using fribidi library in DIR]),
  87             [with_fribidi=$withval],
  88             [with_fribidi=no]
  89             )
  90 AC_ARG_WITH(ssl,
  91             AS_HELP_STRING([--with-ssl], [enable SSL secured connections using
  92                             either OpenSSL or GnuTLS (auto)]),
  93             [with_ssl=$withval]
  94             )
  95 AC_ARG_WITH(openssl,
  96             AS_HELP_STRING([--with-openssl=[DIR]], [enable SSL secured
  97                             connections using the OpenSSL library in DIR
  98                             (optional)]),
  99             [with_openssl=$withval]
 100             )
 101 AC_ARG_WITH(nss_compat,
 102             AS_HELP_STRING([--with-nss_compat=[DIR]], [enable SSL secured
 103                             connections using the NSS compat library in DIR
 104                             (optional)]),
 105             [with_nss_compat=$withval]
 106             )
 107 AM_PATH_GPGME(
 108             [0.4.2],
 109             [have_gpgme=yes],
 110             [have_gpgme=no]
 111             )
 112 LIBCURL_CHECK_CONFIG(
 113             [yes],
 114             [4.12.0],
 115             [have_libcurl=yes],
 116             [have_libcurl=no]
 117             )
 118 AC_ARG_WITH(libjpeg,
 119             AS_HELP_STRING([--without-libjpeg], [Compile without JPEG token
 120                             support (for Gadu-Gadu registration)])
 121             )
 122 AC_ARG_WITH(libotr,
 123             AS_HELP_STRING([--with-libotr], [enable Off-the-Record Messaging (libotr) WARNING: use at your own risk, not supported yet]),
 124             [with_libotr=$withval],
 125             [with_libotr=no]
 126             )
 127 AC_ARG_WITH(libXss,
 128             AS_HELP_STRING([--with-libXss], [enable Xss]),
 129             [with_libXss=$withval],
 130             [with_libXss=no],
 131             )
 132
 133 #####################
 134 # Check for fribidi #
 135 #####################
 136 AC_MSG_CHECKING(whether to use fribidi)
 137 FRIBIDI_LIBS=""
 138 FRIBIDI_CFLAGS=""
 139 FRIBIDI_PC=""
 140 have_fribidi=no
 141
 142 if test "x$with_fribidi" = "xyes"; then
 143         if ! pkg-config fribidi; then
 144                 AC_MSG_ERROR([*** fribidi.pc not found])
 145         fi
 146
 147         FRIBIDI_CFLAGS=`pkg-config --cflags fribidi`
 148         CFLAGS="$CFLAGS $FRIBIDI_CFLAGS"
 149         FRIBIDI_LIBS=`pkg-config --libs fribidi`
 150         FRIBIDI_PC="fribidi,"
 151
 152         AC_CHECK_LIB(fribidi, fribidi_get_mirror_char, :, AC_MSG_ERROR([*** libfribidi not found.]), $FRIBIDI_LIBS)
 153         AC_DEFINE(HAVE_FRIBIDI, 1, [has fribidi library])
 154     AC_DEFINE(KTOOL_USE_FRIBIDI, 1, [use fribidi in ktools])
 155         have_fribidi=yes
 156 fi
 157 AC_MSG_RESULT([$have_fribidi])
 158
 159 #################
 160 # Check for SSL #
 161 #################
 162
 163 if test "x$with_ssl" != "xno"; then
 164
 165         with_ssl="no"
 166
 167         AC_MSG_CHECKING(for OpenSSL)
 168         if test -z "$with_openssl" -o "x$with_openssl" = "xyes"; then
 169                 for ac_dir in $with_openssl /usr/local /usr; do
 170                         if test -f "$ac_dir/include/openssl/ssl.h"; then
 171                                 with_openssl=$ac_dir
 172                                 break;
 173                         fi
 174                 done
 175         fi
 176
 177         if test -n "$with_openssl" -a "x$with_openssl" != "xno" -a -z "$with_nss_compat"; then
 178                 CFLAGS="$CFLAGS -I${with_openssl}"
 179
 180                 AC_MSG_RESULT([found in $with_openssl])
 181                 AC_DEFINE(HAVE_OPENSSL, 1, [use openssl])
 182                 with_ssl="yes"
 183
 184                 AC_CHECK_LIB(crypto, main)
 185                 AC_CHECK_LIB(ssl, main)
 186
 187                 AC_CHECK_LIB(crypto, SSLeay_add_all_algorithms,
 188                         AC_DEFINE(HAVE_SSLEAY, 1, [use SSLeay]))
 189         else
 190                 AC_MSG_RESULT([not found or disabled])
 191         fi
 192
 193         if test "x$with_ssl" = "xno" -a -z "$with_nss_compat"; then
 194                 AC_CHECK_LIB(gnutls-extra, gnutls_global_init_extra, [
 195                         AC_CHECK_LIB(lzo, lzo1x_1_compress, LZO_LIBS=-llzo)
 196
 197                         if test -z "$LZO_LIBS"; then
 198                                  AC_CHECK_LIB(lzo2, lzo1x_1_compress, LZO_LIBS=-llzo2, [
 199                                          AC_MSG_ERROR(
 200 ***
 201 *** Could not find liblzo or liblzo2.
 202 )
 203                                  ])
 204                         fi
 205
 206                         CXXFLAGS="$CXXFLAGS $LIBGNUTLS_CFLAGS"
 207                         LIBS="$LIBS $LIBGNUTLS_LIBS -lgnutls-extra -lgnutls"
 208                         AC_DEFINE(HAVE_GNUTLS, 1, [use gnutls])
 209                         with_ssl="yes"
 210                 ], AC_MSG_ERROR(
 211 Could not find gnutls-extra. Stopping.
 212       ))
 213         fi
 214
 215         if test "x$with_ssl" = "xno"; then
 216                 PKG_PROG_PKG_CONFIG
 217
 218                 # NSS is essential for OpenSSL compatibility layer
 219                 # drags in NSPR as well
 220                 PKG_CHECK_MODULES(NSS, nss >= 3)
 221                 CFLAGS="$CFLAGS $NSS_CFLAGS"
 222                 CXXFLAGS="$CXXFLAGS $NSS_CFLAGS"
 223                 LIBS="$LIBS $NSS_LIBS"
 224
 225                 # The compatibility layer
 226                 AC_MSG_CHECKING(for NSS compat)
 227                 if test -n "$with_nss_compat" -a "x$with_nss_compat" != "xno"; then
 228                         if test -f "${with_nss_compat}"; then
 229                                 CFLAGS="$CFLAGS -I${with_nss_compat} -I/usr/include/nspr4"
 230                                 CXXFLAGS="$CXXFLAGS -I${with_nss_compat} -I/usr/include/nspr4"
 231                         fi
 232                         AC_CHECK_LIB(nss_compat_ossl, SSL_CTX_new, [
 233                                 AC_DEFINE(HAVE_NSS_COMPAT, 1, [use nss_compat])
 234                                 LIBS="$LIBS -lnss_compat_ossl"
 235                                 with_ssl="yes"
 236                         ])
 237                 else
 238                         AC_MSG_RESULT([Not enabled, sadly])
 239                 fi
 240         fi
 241
 242         if test x"$with_ssl" != x"no"; then
 243                  AC_DEFINE(HAVE_SSL, 1, [ssl is available])
 244         else
 245                  AC_MSG_ERROR([Karamba! SSL library not found.])
 246         fi
 247
 248 else
 249         AC_MSG_RESULT([disabled (use --with-ssl=[DIR] to enable)])
 250 fi
 251
 252 ###################
 253 # Check for gpgme #
 254 ###################
 255 if test "x$have_gpgme" = "xyes"; then
 256          AC_DEFINE(HAVE_GPGME, 1, [has gpgme library])
 257          GPGME_CXXFLAGS="$GPGME_CFLAGS"
 258          CFLAGS="$CFLAGS $GPGME_CFLAGS"
 259          CXXFLAGS="$CXXFLAGS $GPGME_CXXFLAGS"
 260          LIBS="$LIBS $GPGME_LIBS"
 261 fi
 262
 263 ###############################
 264 # Check for Largefile support #
 265 ###############################
 266 AC_SYS_LARGEFILE
 267 AC_FUNC_FSEEKO
 268 AC_TYPE_OFF_T
 269
 270 #############################
 271 # Check for pthread library #
 272 #############################
 273 original_LIBS="$LIBS"
 274 LIBS="-lpthread $original_LIBS"
 275
 276 AC_TRY_LINK([#include<pthread.h>],
 277             [pthread_create((void *)0, (void *)0, (void *)0, (void *)0)],
 278             [pthread=yes], [pthread=no])
 279
 280 if test x${pthread} = xyes; then
 281         AC_MSG_RESULT([yes])
 282         AC_DEFINE(HAVE_THREAD, 1, [pthread library is available])
 283 else
 284         LIBS="$original_LIBS"
 285         AC_MSG_RESULT([no])
 286 fi
 287
 288 AC_CHECK_HEADERS(sys/utsname.h,
 289                  [
 290                   AC_CHECK_FUNC(uname, AC_DEFINE(HAVE_UNAME, 1, [check uname function]),)
 291                  ])
 292
 293 #####################
 294 # Check for libcurl #
 295 #####################
 296
 297 CURL_CFLAGS="$LIBCURL_CPPFLAGS"
 298 CURL_CXXFLAGS="$LIBCURL_CPPFLAGS"
 299 CURL_LIBS="$LIBCURL"
 300 CFLAGS="$CFLAGS $CURL_CFLAGS"
 301 CXXFLAGS="$CXXFLAGS $CURL_CXXFLAGS"
 302 LIBS="$LIBS $CURL_LIBS"
 303
 304 #####################
 305 # Check for libjpeg #
 306 #####################
 307 AC_MSG_CHECKING(for libjpeg (for Gadu-Gadu registration))
 308 JPEG_LIBS=""
 309 have_libjpeg=no
 310
 311 if test "x$with_libjpeg" != "xno"; then
 312         AC_MSG_RESULT([])
 313
 314         AC_CHECK_LIB(jpeg, jpeg_start_decompress,
 315         [
 316                 AC_CHECK_HEADERS(jpeglib.h,
 317                 [
 318                         AC_DEFINE(HAVE_LIBJPEG, 1, [define if you have libjpeg])
 319                         JPEG_LIBS="-ljpeg $LIBS"
 320                         LIBS="$LIBS $JPEG_LIBS"
 321                         have_libjpeg=yes
 322                 ])
 323         ])
 324 fi
 325
 326
 327 #####################
 328 # Check for libotr #
 329 #####################
 330 AC_MSG_CHECKING(for libotr)
 331 have_libotr=no
 332
 333 if test "x$with_libotr" != "xno"; then
 334         AC_MSG_RESULT([])
 335
 336         AC_CHECK_LIB(otr, otrl_init,
 337         [
 338                 AC_CHECK_HEADERS(libotr/context.h libotr/userstate.h,
 339                 [
 340                         AC_DEFINE(HAVE_LIBOTR, 1, [define if you have libotr])
 341                         OTR_LIBS="-lotr $LIBS"
 342                         LIBS="$LIBS $OTR_LIBS"
 343                         have_libotr=yes
 344                 ])
 345         ])
 346 fi
 347
 348 #####################
 349 # Check for Xss     #
 350 #####################
 351 AC_MSG_CHECKING(whether to use Xss)
 352 have_libXss=no
 353
 354 if test "x$with_libXss" = "xyes"; then
 355         AC_MSG_RESULT([])
 356
 357         AC_CHECK_LIB(Xss, XScreenSaverQueryInfo,
 358         [
 359                 AC_CHECK_HEADER(X11/extensions/scrnsaver.h,
 360                 [
 361                         AC_DEFINE(HAVE_LIBXSS, 1, [define if you have Xss])
 362                         XSS_LIBS="-lX11 -lXss"
 363                         LIBS="$LIBS $XSS_LIBS"
 364                         have_libXss=yes
 365                         AC_MSG_RESULT([yes])
 366                 ])
 367         ])
 368 fi
 369
 370
 371
 372 ####################
 373 # Check for others #
 374 ####################
 375 AC_C_BIGENDIAN
 376
 377 AM_ICONV_LINK
 378
 379 LIBS="$LIBS $LIBICONV"
 380
 381 AC_CHECK_SIZEOF([int])
 382 AC_CHECK_SIZEOF([short])
 383
 384 AC_CHECK_LIB(socket, socket)
 385 AC_CHECK_LIB(nsl, gethostbyname)
 386
 387 AX_WITH_CURSES
 388 if test "x$ax_cv_ncurses" = "xyes"
 389 then
 390                 LIBS="$LIBS $CURSES_LIB"
 391 else
 392                 AC_MSG_ERROR([You need ncurses/ncursesw library and header files.])
 393 fi
 394
 395
 396 AC_TRY_COMPILE([
 397     #include <sys/types.h>
 398     #include <sys/socket.h>
 399 ],[ socklen_t foo; ], ac_cv_c_socklen_t=yes, ac_cv_c_socklen_t=no)
 400
 401 if test "x$ac_cv_c_socklen_t" = "xno"; then
 402   AC_DEFINE(socklen_t, int, [Define type of socklen_t for systems missing it])
 403 fi
 404
 405 case "$host_os" in
 406   darwin*)
 407         LIBS="$LIBS -flat_namespace"
 408         CXXFLAGS="$CXXFLAGS -I/sw/include"
 409         ;;
 410 esac
 411
 412 AM_CONDITIONAL(BUILD_ICQ, test "x$build_icq" = "xyes")
 413 AM_CONDITIONAL(BUILD_YAHOO, test "x$build_yahoo" = "xyes")
 414 AM_CONDITIONAL(BUILD_AIM, test "x$build_aim" = "xyes")
 415 AM_CONDITIONAL(BUILD_IRC, test "x$build_irc" = "xyes")
 416 AM_CONDITIONAL(BUILD_FIRETALK, test "x$build_irc" = "xyes" -o "x$build_aim" = "xyes")
 417 AM_CONDITIONAL(BUILD_JABBER, test "x$build_jabber" = "xyes")
 418 AM_CONDITIONAL(BUILD_GADU, test "x$build_gg" = "xyes")
 419 AM_CONDITIONAL(BUILD_MSN, test "x$build_msn" = "xyes")
 420 AM_CONDITIONAL(BUILD_RSS, test "x$build_rss" = "xyes" -o "x$build_lj" = "xyes")
 421 AM_CONDITIONAL(BUILD_LJ, test "x$build_lj" = "xyes")
 422 AM_CONDITIONAL(HAVE_THREAD, test "x$pthread" = "xyes")
 423 AM_CONDITIONAL(HAVE_LIBOTR, test "x$have_libotr" = "xyes")
 424 AM_CONDITIONAL(HAVE_FRIBIDI, test "x$have_fribidi" = "xyes")
 425
 426 if test "x$build_icq" = "xyes"; then
 427         AC_DEFINE(BUILD_ICQ, 1, [build with ICQ support])
 428 fi
 429 if test "x$build_yahoo" = "xyes"; then
 430         if test "x$have_curl" = "xno"; then
 431                 AC_MSG_ERROR([Yahoo cannot be built without the curl library.])
 432         fi
 433         if test -z "$libcurl_feature_SSL" -o "x$libcurl_feature_SSL" = "xno"; then
 434                 AC_MSG_ERROR([Yahoo requires libcurl built with SSL support.])
 435         fi
 436         AC_DEFINE(BUILD_YAHOO, 1, [build with yahoo support])
 437 fi
 438 if test "x$build_aim" = "xyes"; then
 439         AC_DEFINE(BUILD_AIM, 1, [build with aim support])
 440 fi
 441 if test "x$build_irc" = "xyes";
 442         then AC_DEFINE(BUILD_IRC, 1, [build with irc support])
 443 fi
 444 if test "x$build_jabber" = "xyes"; then
 445         if test "x$have_gpgme" = "xno"; then
 446                 AC_MSG_WARN([No GPG support in Jabber, since GPGME library not found or its setup not ok])
 447         fi
 448         AC_DEFINE(BUILD_JABBER, 1, [build with jabber support])
 449 fi
 450 if test "x$build_gg" = "xyes"; then
 451         if test "x$have_libjpeg" = "xno"; then
 452                 AC_MSG_WARN([No jpeg support in Gadu-Gadu, you will not be able to register??????????])
 453         fi
 454         AC_DEFINE(BUILD_GADU, 1, [build with gadu-gadu support])
 455 fi
 456 if test "x$build_msn" = "xyes"; then
 457         if test "x$have_curl" = "xno"; then
 458                 AC_MSG_ERROR([MSN cannot be built without the curl library.])
 459         fi
 460         if test -z "$libcurl_feature_SSL" -o "x$libcurl_feature_SSL" = "xno"; then
 461                 AC_MSG_ERROR([MSN requires libcurl built with SSL support.])
 462         fi
 463         AC_DEFINE(BUILD_MSN, 1, [build with MSN support])
 464 fi
 465 if test "x$build_rss" = "xyes" -o "x$build_lj" = "xyes"; then
 466         AC_DEFINE(BUILD_RSS, 1, [build the integrated rss feeds reader])
 467 fi
 468 if test "x$build_lj" = "xyes"; then
 469         AC_DEFINE(BUILD_LJ, 1, [build the integrated livejournal client])
 470 fi
 471 if test "x$locales_fx" != "xno"; then
 472   AC_DEFINE([LOCALES_HACK], 1, [enables workaround for broken locales])
 473 fi
 474
 475 ############################
 476 # Checks for header files. #
 477 ############################
 478 AC_FUNC_ALLOCA
 479 AC_HEADER_DIRENT
 480 AC_HEADER_STDC
 481 AC_HEADER_SYS_WAIT
 482 AC_CHECK_HEADERS([argz.h])
 483 AC_CHECK_HEADERS([arpa/inet.h])
 484 AC_CHECK_HEADERS([fcntl.h])
 485 AC_CHECK_HEADERS([float.h])
 486 AC_CHECK_HEADERS([ftw.h])
 487 AC_CHECK_HEADERS([inttypes.h])
 488 AC_CHECK_HEADERS([langinfo.h])
 489 AC_CHECK_HEADERS([libintl.h])
 490 AC_CHECK_HEADERS([limits.h])
 491 AC_CHECK_HEADERS([locale.h])
 492 AC_CHECK_HEADERS([malloc.h])
 493 AC_CHECK_HEADERS([netdb.h])
 494 AC_CHECK_HEADERS([netinet/in.h])
 495 AC_CHECK_HEADERS([stddef.h])
 496 AC_CHECK_HEADERS([stdint.h])
 497 AC_CHECK_HEADERS([stdio_ext.h])
 498 AC_CHECK_HEADERS([stdlib.h])
 499 AC_CHECK_HEADERS([string.h])
 500 AC_CHECK_HEADERS([strings.h])
 501 AC_CHECK_HEADERS([sys/ioctl.h])
 502 AC_CHECK_HEADERS([sys/mount.h])
 503 AC_CHECK_HEADERS([sys/param.h])
 504 AC_CHECK_HEADERS([sys/socket.h])
 505 AC_CHECK_HEADERS([sys/statvfs.h])
 506 AC_CHECK_HEADERS([sys/time.h])
 507 AC_CHECK_HEADERS([sys/vfs.h])
 508 AC_CHECK_HEADERS([syslog.h])
 509 AC_CHECK_HEADERS([unistd.h])
 510 AC_CHECK_HEADERS([utmp.h])
 511 AC_CHECK_HEADERS([wchar.h])
 512 AC_CHECK_HEADERS([sys/types.h])
 513 AC_CHECK_HEADERS([_G_config.h])
 514
 515 AC_LANG_SAVE
 516 AC_LANG_CPLUSPLUS
 517 AC_CHECK_HEADERS([vector iostream fstream string algorithm list memory iterator exception utility],, AC_MSG_ERROR([You need to have the libstdc++ headers installed]))
 518 AC_CHECK_HEADERS([hash_map strstream ext/hash_map sstream],,)
 519 AC_LANG_RESTORE
 520
 521 ##################################################
 522 # check whether make supports order-only targets #
 523 ##################################################
 524
 525 AC_CACHE_CHECK([whether ${MAKE-make} supports order-only targets],
 526 [centerim_cv_make_order_only],
 527 [cat >conftest.make <<\_ACEOF
 528 SHELL = /bin/sh
 529 all: | say
 530
 531 say:
 532         echo say
 533
 534 .PHONY: all say
 535 _ACEOF
 536 centerim_cv_make_order_only=no
 537
 538 ${MAKE-make} -f conftest.make >/dev/null 2>&1 && centerim_cv_make_order_only=yes
 539 rm -f conftest.make
 540 ])
 541 if test x$centerim_cv_make_order_only = xyes; then
 542   ORDER_ONLY="|"
 543 fi
 544
 545
 546 ##################################################################
 547 # Checks for typedefs, structures, and compiler characteristics. #
 548 ##################################################################
 549 AC_STRUCT_TIMEZONE
 550 AC_HEADER_STDBOOL
 551 AC_C_CONST
 552 AC_C_INLINE
 553 AC_C_RESTRICT
 554 AC_TYPE_SIZE_T
 555 AC_HEADER_TIME
 556 AC_STRUCT_TM
 557 AC_C_VOLATILE
 558 AC_CHECK_TYPES([ptrdiff_t])
 559 AC_TYPE_SIGNAL
 560
 561 #################
 562 # Substitutions #
 563 #################
 564 AC_SUBST(FRIBIDI_LIBS)
 565 AC_SUBST(FRIBIDI_CFLAGS)
 566 AC_SUBST(FRIBIDI_PC)
 567
 568 AC_SUBST(GPGME_LIBS)
 569 AC_SUBST(GPGME_CFLAGS)
 570 AC_SUBST(GPGME_CXXFLAGS)
 571
 572 AC_SUBST(GNUTLS_LIBS)
 573 AC_SUBST(GNUTLS_CFLAGS)
 574 AC_SUBST(GNUTLS_CXXFLAGS)
 575
 576 AC_SUBST(CURL_LIBS)
 577 AC_SUBST(CURL_CFLAGS)
 578 AC_SUBST(CURL_CXXFLAGS)
 579
 580 AC_SUBST(JPEG_LIBS)
 581
 582 AC_SUBST(ORDER_ONLY)
 583
 584 #################################
 585 # Checks for library functions. #
 586 #################################
 587 AC_FUNC_SELECT_ARGTYPES
 588
 589 AC_CHECK_FUNCS([gethostbyname])
 590 AC_CHECK_FUNCS([gethostname])
 591 AC_CHECK_FUNCS([getpass])
 592 AC_CHECK_FUNCS([inet_aton])
 593 AC_CHECK_FUNCS([inet_ntoa])
 594 AC_CHECK_FUNCS([memset])
 595 AC_CHECK_FUNCS([select])
 596 AC_CHECK_FUNCS([setenv])
 597 AC_CHECK_FUNCS([socket])
 598 AC_CHECK_FUNCS([strerror])
 599 AC_CHECK_FUNCS([strtol])
 600
 601
 602 ########################
 603 # Create output files. #
 604 ########################
 605 ALL_LINGUAS="zh_TW zh_CN uk sv ru ro pt_BR pl nl ms it hu fr es de cs bg"
 606 AC_CONFIG_FILES([Makefile
 607                  connwrap/Makefile
 608                  firetalk/Makefile
 609                  kkconsui/Makefile
 610                  kkconsui/include/Makefile
 611                  kkconsui/src/Makefile
 612                  kkstrtext/Makefile
 613                  kksystr/Makefile
 614                  kksystr/include/Makefile
 615                  kksystr/src/Makefile
 616                  libgadu/Makefile
 617                  libicq2000/Makefile
 618                  libicq2000/libicq2000/Makefile
 619                  libicq2000/src/Makefile
 620                  libjabber/Makefile
 621                  libmsn/Makefile
 622                  libmsn/msn/Makefile
 623                  libyahoo2/Makefile
 624                  misc/Makefile
 625                  share/Makefile
 626                  src/Makefile
 627                  src/hooks/Makefile
 628                  intl/Makefile
 629                  po/Makefile.in])
 630
 631 AC_OUTPUT
 632
 633 AC_MSG_RESULT([
 634 Build options:
 635   Version               $VERSION
 636   Install prefix        $prefix
 637   CFLAGS                $CFLAGS
 638   CXXFLAGS              $CXXFLAGS
 639
 640 Protocols and Clients:])
 641 if test "x$build_icq" = "xyes"; then AC_MSG_RESULT([  ICQ]); fi
 642 if test "x$build_yahoo" = "xyes"; then AC_MSG_RESULT([  Yahoo]); fi
 643 if test "x$build_aim" = "xyes"; then AC_MSG_RESULT([  AIM]); fi
 644 if test "x$build_jabber" = "xyes"; then AC_MSG_RESULT([  jabber]); fi
 645 if test "x$build_gg" = "xyes"; then AC_MSG_RESULT([  Gadu-Gadu]); fi
 646 if test "x$build_msn" = "xyes"; then AC_MSG_RESULT([  MSN Messenger]); fi
 647 if test "x$build_rss" = "xyes"; then AC_MSG_RESULT([  RSS Reader]); fi
 648 if test "x$build_lj" = "xyes"; then AC_MSG_RESULT([  LiveJournal client]); fi
 649 if test "x$have_fribidi" = "xyes"; then AC_MSG_RESULT([  LiveJournal client]); fi
 650 if test "x$with_ssl" = "xno"; then
 651 AC_MSG_RESULT([
 652 WARNING: SSL disabled (This means no Google Talk)
 653 ]);
 654 else
 655 if test "x$have_gpgme" = "xno"; then
 656 AC_MSG_RESULT([
 657 WARNING: GPGME disabled (This means no encrypted messages between users)
 658 ]); fi
 659 if test "x$have_libotr" = "xyes"; then
 660 AC_MSG_RESULT([
 661 WARNING: libotr enabled (OTR is not supported yet, use at your own risk)
 662 ]); fi
 663 if test "x$pthread" = "xno"; then
 664 AC_MSG_RESULT([
 665 WARNING: pthreads disabled (No file-transfers in jabber)
 666 ]); fi
 667 fi
 668 AC_MSG_RESULT([
 669 Enjoy!])