configure.in

   1 dnl Configure script for bug-buddy
   2
   3 AC_INIT([bug-buddy],[2.27.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=bug-buddy])
   4
   5 AC_CANONICAL_TARGET
   6
   7 AC_CONFIG_HEADERS([config.h])
   8
   9 AM_INIT_AUTOMAKE([1.9 foreign no-dist-gzip dist-bzip2 tar-ustar])
  10
  11 GNOME_DOC_INIT
  12
  13 AM_MAINTAINER_MODE
  14 IT_PROG_INTLTOOL([0.40.0])
  15 AM_DISABLE_STATIC
  16
  17 AC_PATH_PROG(GCONFTOOL, gconftool-2)
  18 AM_GCONF_SOURCE_2
  19
  20 AC_PROG_CC
  21 AC_PROG_CXX
  22 AC_ISC_POSIX
  23 AC_HEADER_STDC
  24 AC_PROG_LIBTOOL
  25
  26 dnl required modules
  27 BONOBO_ACTIVATION_REQUIRED="bonobo-activation-2.0 >= 1.0.0"
  28 GDK_PIXBUF_REQUIRED="gdk-pixbuf-2.0 >= 2.0.0"
  29 GMODULE_REQUIRED="gmodule-2.0 >= 2.0.0"
  30 LIBBONOBO_REQUIRED="libbonobo-2.0 >= 2.0.0"
  31 LIBGNOMEMENU_REQUIRED="libgnome-menu >= 2.11.1"
  32 LIBXML_REQUIRED="libxml-2.0 >= 2.4.6"
  33 GTK_REQUIRED="gtk+-2.0 >= 2.14.0"
  34 GIO_REQUIRED="gio-2.0 >= 2.16.0"
  35 LIBSOUP_REQUIRED="libsoup-2.4"
  36 LIBGTOP_REQUIRED="libgtop-2.0 >= 2.13.3"
  37 LIBGCONF_REQUIRED="gconf-2.0"
  38
  39 PKG_CHECK_MODULES(BUG_BUDDY,
  40 [
  41         $BONOBO_ACTIVATION_REQUIRED
  42         $GDK_PIXBUF_REQUIRED
  43         $GMODULE_REQUIRED
  44         $GIO_REQUIRED
  45         $LIBBONOBO_REQUIRED
  46         $LIBGNOMEMENU_REQUIRED
  47         $LIBXML_REQUIRED
  48         $GTK_REQUIRED
  49         $LIBSOUP_REQUIRED
  50         $LIBGTOP_REQUIRED
  51         $LIBGCONF_REQUIRED
  52 ])
  53
  54 AC_SUBST(BUG_BUDDY_CFLAGS)
  55 AC_SUBST(BUG_BUDDY_LIBS)
  56
  57 dnl optional modules (can be turned on/off at compile time)
  58 LIBEBOOK_REQUIRED="libebook-1.2 >= 1.3.0"
  59
  60 AC_ARG_ENABLE([eds],
  61         [AC_HELP_STRING([--enable-eds],
  62                         [Enable support for getting user email from eds [default=yes]])],
  63                         enable_eds="$enableval", enable_eds=yes)
  64 if test "x$enable_eds" = "xyes"; then
  65     PKG_CHECK_MODULES(BUG_BUDDY_EDS, $LIBEBOOK_REQUIRED)
  66     AC_DEFINE(ENABLE_EDS, 1, [turn on support for getting user email from eds])
  67 fi
  68
  69 AC_SUBST(BUG_BUDDY_EDS_CFLAGS)
  70 AC_SUBST(BUG_BUDDY_EDS_LIBS)
  71
  72
  73
  74 AC_CHECK_LIB(elf, elf_version)
  75 AC_CHECK_HEADERS([libelf.h],[],[AC_MSG_ERROR([libelf.h not found.])])
  76 AC_CHECK_HEADERS([gelf.h],[],[AC_MSG_ERROR([gelf.h not found.])])
  77
  78 AC_ARG_ENABLE([google-breakpad],
  79         [AC_HELP_STRING([--enable-google-breakpad],
  80                         [Enable support for retrieving minidumps with Google \
  81                          Breakpad [default=yes]])],
  82         enable_google_breakpad="$enableval", enable_google_breakpad=yes)
  83
  84 if test "x$enable_google_breakpad" = "xyes"; then
  85         AC_CONFIG_SUBDIRS(google-breakpad)
  86
  87         GOOGLE_BREAKPAD_SUPPORTED_OS="no"
  88         case $target_os in
  89                 solaris*)
  90                         solaris=yes
  91                         GOOGLE_BREAKPAD_SUPPORTED_OS="yes"
  92                 ;;
  93                 linux*)
  94                         linux=yes
  95                         GOOGLE_BREAKPAD_SUPPORTED_OS="yes"
  96                 ;;
  97         esac
  98
  99         GOOGLE_BREAKPAD_SUPPORTED_ARCH="no"
 100         case $target_cpu in
 101                 *86)
 102         GOOGLE_BREAKPAD_SUPPORTED_ARCH="yes" ;;
 103         esac
 104
 105         if test x$GOOGLE_BREAKPAD_SUPPORTED_OS = xyes ; then
 106                 if test x$GOOGLE_BREAKPAD_SUPPORTED_ARCH = xyes ; then
 107                         echo "OS and CPU supported: enabling google-breakpad"
 108                         AC_DEFINE(ENABLE_GOOGLE_BREAKPAD, 1, [define if google-break is enabled])
 109                         use_google_breakpad=yes
 110                 fi
 111         fi
 112 fi
 113
 114 AM_CONDITIONAL(USE_GOOGLE_BREAKPAD, test x$use_google_breakpad = xyes)
 115 AM_CONDITIONAL(BREAKPAD_SOLARIS, test x$solaris = xyes)
 116 AM_CONDITIONAL(BREAKPAD_LINUX, test x$linux = xyes)
 117
 118 GDK_REQUIRED="x11 gdk-x11-2.0 >= 2.9"
 119 PKG_CHECK_MODULES(GNOME_BREAKPAD,
 120 [
 121         $GDK_REQUIRED
 122 ])
 123 AC_SUBST(GNOME_BREAKPAD_CFLAGS)
 124 AC_SUBST(GNOME_BREAKPAD_LIBS)
 125
 126
 127 PKG_CHECK_MODULES(GNOME_CRASH, $GTK_REQUIRED)
 128 AC_SUBST(GNOME_CRASH_CFLAGS)
 129 AC_SUBST(GNOME_CRASH_LIBS)
 130
 131 GETTEXT_PACKAGE=bug-buddy
 132 AC_SUBST(GETTEXT_PACKAGE)
 133 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE")
 134
 135 AM_GLIB_GNU_GETTEXT
 136
 137 AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal)
 138
 139 GNOME_COMMON_INIT
 140 GNOME_COMPILE_WARNINGS([maximum])
 141 GNOME_MAINTAINER_MODE_DEFINES
 142
 143 if test "$enable_maintainer_mode" = "yes"; then
 144         DISABLE_SINGLE_INCLUDES="-DG_DISABLE_SINGLE_INCLUDES -DGTK_DISABLE_SINGLE_INCLUDES -DGDK_PIXBUF_DISABLE_SINGLE_INCLUDES"
 145         AC_SUBST(DISABLE_SINGLE_INCLUDES)
 146 fi
 147
 148 AC_OUTPUT([
 149 Makefile
 150 data/Makefile
 151 data/icons/Makefile
 152 data/bug-buddy.schemas
 153 data/bug-buddy.menu
 154 data/bug-buddy.desktop.in
 155 docs/Makefile
 156 po/Makefile.in
 157 gnome-breakpad/Makefile
 158 src/Makefile
 159 ])
 160
 161 dnl help is totally hosed
 162 dnl help/Makefile
 163 dnl help/C/Makefile
 164
 165 echo "
 166
 167 Configuration:
 168
 169         CFLAGS: ${BUG_BUDDY_CFLAGS}
 170
 171         LIBS:   ${BUG_BUDDY_LIBS}
 172
 173 "