src/impl-allegro.lisp

   1 ;;;; -*- indent-tabs-mode: nil -*-
   2
   3 #|
   4 Copyright 2006, 2007 Greg Pfeil
   5
   6 Distributed under the MIT license (see LICENSE file)
   7 |#
   8
   9 (in-package #:bordeaux-threads)
  10
  11 ;;; documentation on the Allegro Multiprocessing interface can be found at
  12 ;;; http://www.franz.com/support/documentation/8.1/doc/multiprocessing.htm
  13
  14 ;;; Resource contention: locks and recursive locks
  15
  16 (defun make-lock (&optional name)
  17   (mp:make-process-lock :name (or name "Anonymous lock")))
  18
  19 (defun make-recursive-lock (&optional name)
  20   (mp:make-process-lock :name (or name "Anonymous recursive lock")))
  21
  22 (defun acquire-lock (lock &optional (wait-p t))
  23   (mp:process-lock lock mp:*current-process* "Lock" (if wait-p nil 0)))
  24
  25 (defun release-lock (lock)
  26   (mp:process-unlock lock))
  27
  28 (defmacro with-lock-held ((place) &body body)
  29   `(mp:with-process-lock (,place :norecursive t)
  30      ,@body))
  31
  32 (defmacro with-recursive-lock-held ((place &key timeout) &body body)
  33   `(mp:with-process-lock (,place :timeout ,timeout)
  34      ,@body))
  35
  36 ;;; Resource contention: condition variables
  37
  38 (defun make-condition-variable (&key name)
  39   (declare (ignorable name))
  40   #-(version>= 9)
  41   (mp:make-gate nil)
  42   #+(version>= 9)
  43   (mp:make-condition-variable :name name))
  44
  45 (defun condition-wait (condition-variable lock)
  46   #-(version>= 9)
  47   (progn
  48     (release-lock lock)
  49     (mp:process-wait "wait for message" #'mp:gate-open-p condition-variable)
  50     (acquire-lock lock)
  51     (mp:close-gate condition-variable))
  52   #+(version>= 9)
  53   (mp:condition-variable-wait condition-variable lock))
  54
  55 (defun condition-notify (condition-variable)
  56   #-(version>= 9)
  57   (mp:open-gate condition-variable)
  58   #+(version>= 9)
  59   (mp:condition-variable-signal condition-variable))
  60
  61 (defun thread-yield ()
  62   (mp:process-allow-schedule))
  63
  64 (deftype thread ()
  65   'mp:process)
  66
  67 ;;; Thread Creation
  68
  69 (defun start-multiprocessing ()
  70   (mp:start-scheduler))
  71
  72 (defun %make-thread (function name)
  73   #+smp
  74   (mp:process-run-function name function)
  75   #-smp
  76   (mp:process-run-function
  77    name
  78    (lambda ()
  79      (let ((return-values
  80              (multiple-value-list (funcall function))))
  81        (setf (getf (mp:process-property-list mp:*current-process*)
  82                    'return-values)
  83              return-values)
  84        (values-list return-values)))))
  85
  86 (defun current-thread ()
  87   mp:*current-process*)
  88
  89 (defun threadp (object)
  90   (typep object 'mp:process))
  91
  92 (defun thread-name (thread)
  93   (mp:process-name thread))
  94
  95 ;;; Timeouts
  96
  97 (defmacro with-timeout ((timeout) &body body)
  98   (once-only (timeout)
  99     `(mp:with-timeout (,timeout (error 'timeout :length ,timeout))
 100        ,@body)))
 101
 102 ;;; Introspection/debugging
 103
 104 (defun all-threads ()
 105   mp:*all-processes*)
 106
 107 (defun interrupt-thread (thread function &rest args)
 108   (apply #'mp:process-interrupt thread function args))
 109
 110 (defun destroy-thread (thread)
 111   (signal-error-if-current-thread thread)
 112   (mp:process-kill thread))
 113
 114 (defun thread-alive-p (thread)
 115   (mp:process-alive-p thread))
 116
 117 (defun join-thread (thread)
 118   #+smp
 119   (values-list (mp:process-join thread))
 120   #-smp
 121   (progn
 122     (mp:process-wait (format nil "Waiting for thread ~A to complete" thread)
 123                      (complement #'mp:process-alive-p)
 124                      thread)
 125     (let ((return-values
 126             (getf (mp:process-property-list thread) 'return-values)))
 127       (values-list return-values))))
 128
 129 (mark-supported)