src/bordeaux-threads.lisp

   1 ;;; -*- Mode: Lisp; Syntax: ANSI-Common-Lisp; indent-tabs-mode: nil -*-
   2
   3 #|
   4 Copyright 2006, 2007 Greg Pfeil
   5
   6 Distributed under the MIT license (see LICENSE file)
   7 |#
   8
   9 (in-package #:bordeaux-threads)
  10
  11 (defvar *supports-threads-p* nil
  12   "This should be set to T if the running instance has thread support.")
  13
  14 (defun mark-supported ()
  15   (setf *supports-threads-p* t)
  16   (pushnew :bordeaux-threads *features*))
  17
  18 (define-condition bordeaux-mp-condition (error)
  19   ((message :initarg :message :reader message))
  20   (:report (lambda (condition stream)
  21              (format stream (message condition)))))
  22
  23 (defgeneric make-threading-support-error ()
  24   (:documentation "Creates a BORDEAUX-THREADS condition which specifies
  25   whether there is no BORDEAUX-THREADS support for the implementation, no
  26   threads enabled for the system, or no support for a particular
  27   function.")
  28   (:method ()
  29     (make-condition
  30      'bordeaux-mp-condition
  31      :message (if *supports-threads-p*
  32                   "There is no support for this method on this implementation."
  33                   "There is no thread support in this instance."))))
  34
  35 #-sbcl
  36 (define-condition timeout (serious-condition)
  37   ((length :initform nil
  38              :initarg :length
  39              :reader timeout-length))
  40   (:report (lambda (c s)
  41              (if (timeout-length c)
  42                  (format s "A timeout set to ~A seconds occurred."
  43                          (timeout-length c))
  44                  (format s "A timeout occurred.")))))
  45
  46
  47 ;;; Thread Creation
  48
  49 ;;; See default-implementations.lisp for MAKE-THREAD.
  50
  51 ;; Forms are evaluated in the new thread or in the calling thread?
  52 (defvar *default-special-bindings* nil
  53   "This variable holds an alist associating special variable symbols
  54   to forms to evaluate. Special variables named in this list will
  55   be locally bound in the new thread before it begins executing user code.
  56
  57   This variable may be rebound around calls to MAKE-THREAD to
  58   add/alter default bindings. The effect of mutating this list is
  59   undefined, but earlier forms take precedence over later forms for
  60   the same symbol, so defaults may be overridden by consing to the
  61   head of the list.")
  62
  63 (defmacro defbindings (name docstring &body initforms)
  64   (check-type docstring string)
  65   `(defparameter ,name
  66      (list
  67       ,@(loop for (special form) in initforms
  68               collect `(cons ',special ',form)))
  69      ,docstring))
  70
  71 ;; Forms are evaluated in the new thread or in the calling thread?
  72 (defbindings *standard-io-bindings*
  73   "Standard bindings of printer/reader control variables as per CL:WITH-STANDARD-IO-SYNTAX."
  74   (*package*                   (find-package :common-lisp-user))
  75   (*print-array*               t)
  76   (*print-base*                10)
  77   (*print-case*                :upcase)
  78   (*print-circle*              nil)
  79   (*print-escape*              t)
  80   (*print-gensym*              t)
  81   (*print-length*              nil)
  82   (*print-level*               nil)
  83   (*print-lines*               nil)
  84   (*print-miser-width*         nil)
  85   (*print-pprint-dispatch*     (copy-pprint-dispatch nil))
  86   (*print-pretty*              nil)
  87   (*print-radix*               nil)
  88   (*print-readably*            t)
  89   (*print-right-margin*        nil)
  90   (*read-base*                 10)
  91   (*read-default-float-format* 'single-float)
  92   (*read-eval*                 t)
  93   (*read-suppress*             nil)
  94   (*readtable*                 (copy-readtable nil)))
  95
  96 (defun binding-default-specials (function special-bindings)
  97   "Return a closure that binds the symbols in SPECIAL-BINDINGS and calls
  98 FUNCTION."
  99   (let ((specials (remove-duplicates special-bindings :from-end t :key #'car)))
 100     (lambda ()
 101       (progv (mapcar #'car specials)
 102           (loop for (nil . form) in specials collect (eval form))
 103         (funcall function)))))
 104
 105 ;;; FIXME: This test won't work if CURRENT-THREAD
 106 ;;;        conses a new object each time
 107 (defun signal-error-if-current-thread (thread)
 108   (when (eq thread (current-thread))
 109     (error 'bordeaux-mp-condition
 110            :message "Cannot destroy the current thread")))