boost/tools/regression/xsl_reports/xsl/links_page.xsl

   1 <?xml version="1.0" encoding="utf-8"?>
   2 <!--
   3
   4 Copyright MetaCommunications, Inc. 2003-2004.
   5
   6 Distributed under the Boost Software License, Version 1.0. (See
   7 accompanying file LICENSE_1_0.txt or copy at
   8 http://www.boost.org/LICENSE_1_0.txt)
   9
  10 -->
  11
  12 <xsl:stylesheet
  13     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  14     xmlns:exsl="http://exslt.org/common"
  15     xmlns:func="http://exslt.org/functions"
  16     xmlns:str="http://exslt.org/strings"
  17     xmlns:set="http://exslt.org/sets"
  18     xmlns:meta="http://www.meta-comm.com"
  19     extension-element-prefixes="func exsl"
  20     exclude-result-prefixes="set str meta"
  21     version="1.0">
  22
  23     <xsl:import href="common.xsl"/>
  24
  25     <xsl:output method="html"
  26         doctype-public="-//W3C//DTD HTML 4.01 Transitional//EN"
  27         encoding="utf-8"
  28         indent="yes"
  29         />
  30
  31     <xsl:param name="source"/>
  32     <xsl:param name="run_date"/>
  33     <xsl:param name="comment_file"/>
  34     <xsl:param name="explicit_markup_file"/>
  35
  36     <xsl:variable name="explicit_markup" select="document( $explicit_markup_file )"/>
  37
  38     <xsl:template match="test-log[ meta:show_output( $explicit_markup, . ) ]">
  39         <xsl:variable name="document_path" select="meta:output_file_path( @target-directory )"/>
  40
  41         <xsl:message>Writing log file document <xsl:value-of select="$document_path"/></xsl:message>
  42
  43         <exsl:document href="{$document_path}"
  44         method="html"
  45         doctype-public="-//W3C//DTD XHTML 1.0 Strict//EN"
  46         encoding="utf-8"
  47         indent="yes">
  48
  49         <html>
  50             <xsl:variable name="component">
  51             <xsl:choose>
  52                 <xsl:when test="@test-name != ''">
  53                 <div class="log-test-title">
  54                     <xsl:value-of select="concat( @library, ' - ', @test-name, ' / ', @toolset )"/>
  55                 </div>
  56                 </xsl:when>
  57                 <xsl:otherwise>
  58                 <xsl:value-of select="@target-dir"/>
  59                 </xsl:otherwise>
  60             </xsl:choose>
  61             </xsl:variable>
  62
  63             <head>
  64             <link rel="stylesheet" type="text/css" href="../master.css" title="master" />
  65             <title>Boost regression - test run output: <xsl:value-of select="$component"/></title>
  66             </head>
  67
  68             <body>
  69             <div>
  70                 <div class="log-test-title">
  71                 Boost regression - test run output: <xsl:value-of select="$component"/>
  72             </div>
  73
  74
  75             <xsl:if test="notes/note">
  76                 <p>
  77                 <div class="notes-title">Notes</div>
  78                 <xsl:call-template name="show_notes">
  79                     <xsl:with-param name="notes" select="notes/note"/>
  80                     <xsl:with-param name="explicit_markup" select="$explicit_markup"/>
  81                 </xsl:call-template>
  82                 </p>
  83             </xsl:if>
  84
  85             <xsl:if test="compile">
  86                 <p>
  87                 <div class="log-compiler-output-title">Compiler output:</div>
  88                 <pre>
  89                     <xsl:copy-of select="compile/node()"/>
  90                 </pre>
  91                 </p>
  92             </xsl:if>
  93
  94             <xsl:if test="link">
  95                 <p>
  96                 <div class="log-linker-output-title">Linker output:</div>
  97                 <pre>
  98                     <xsl:copy-of select="link/node()"/>
  99                 </pre>
 100                 </p>
 101             </xsl:if>
 102
 103             <xsl:if test="lib">
 104                 <p>
 105                 <div class="log-linker-output-title">Lib output:</div>
 106                 <p>
 107                     See <a href="{meta:encode_path( lib/node() )}.html">
 108                     <xsl:copy-of select="lib/node()"/>
 109                     </a>
 110                 </p>
 111                 </p>
 112             </xsl:if>
 113
 114             <xsl:if test="run">
 115                 <p>
 116                 <div class="log-run-output-title">Run output:</div>
 117                 <pre>
 118                     <xsl:copy-of select="run/node()"/>
 119                 </pre>
 120                 </p>
 121             </xsl:if>
 122
 123             </div>
 124
 125             <xsl:copy-of select="document( 'html/make_tinyurl.html' )"/>
 126
 127             </body>
 128
 129         </html>
 130         </exsl:document>
 131
 132     </xsl:template>
 133
 134 </xsl:stylesheet>