lib/tsan/CMakeLists.txt

   1 # Build for the ThreadSanitizer runtime support library.
   2
   3 include_directories(..)
   4
   5 set(TSAN_CFLAGS ${SANITIZER_COMMON_CFLAGS})
   6 # SANITIZER_COMMON_CFLAGS contains -fPIC, but it's performance-critical for
   7 # TSan runtime to be built with -fPIE to reduce the number of register spills.
   8 append_if(TSAN_CFLAGS COMPILER_RT_HAS_FPIE_FLAG -fPIE)
   9 append_no_rtti_flag(TSAN_CFLAGS)
  10
  11 set(TSAN_RTL_CFLAGS ${TSAN_CFLAGS})
  12 append_if(TSAN_RTL_CFLAGS COMPILER_RT_HAS_WFRAME_LARGER_THAN_FLAG -Wframe-larger-than=512)
  13 append_if(TSAN_RTL_CFLAGS COMPILER_RT_HAS_WGLOBAL_CONSTRUCTORS_FLAG -Wglobal-constructors)
  14 # FIXME: Add support for --sysroot=. compile flag:
  15
  16 if("${CMAKE_BUILD_TYPE}" EQUAL "Release")
  17   set(TSAN_COMMON_DEFINITIONS DEBUG=0)
  18 else()
  19   set(TSAN_COMMON_DEFINITIONS DEBUG=1)
  20 endif()
  21
  22 set(TSAN_SOURCES
  23   rtl/tsan_clock.cc
  24   rtl/tsan_flags.cc
  25   rtl/tsan_fd.cc
  26   rtl/tsan_ignoreset.cc
  27   rtl/tsan_interceptors.cc
  28   rtl/tsan_interface_ann.cc
  29   rtl/tsan_interface_atomic.cc
  30   rtl/tsan_interface.cc
  31   rtl/tsan_interface_java.cc
  32   rtl/tsan_md5.cc
  33   rtl/tsan_mman.cc
  34   rtl/tsan_mutex.cc
  35   rtl/tsan_mutexset.cc
  36   rtl/tsan_report.cc
  37   rtl/tsan_rtl.cc
  38   rtl/tsan_rtl_mutex.cc
  39   rtl/tsan_rtl_report.cc
  40   rtl/tsan_rtl_thread.cc
  41   rtl/tsan_stat.cc
  42   rtl/tsan_suppressions.cc
  43   rtl/tsan_symbolize.cc
  44   rtl/tsan_sync.cc)
  45
  46 if(APPLE)
  47   list(APPEND TSAN_SOURCES rtl/tsan_platform_mac.cc)
  48 elseif(UNIX)
  49   # Assume Linux
  50   list(APPEND TSAN_SOURCES
  51     rtl/tsan_platform_linux.cc)
  52 endif()
  53
  54 add_custom_target(tsan)
  55 # TSan is currently supported on 64-bit Linux only.
  56 if(CAN_TARGET_x86_64 AND UNIX AND NOT APPLE)
  57   set(TSAN_ASM_SOURCES rtl/tsan_rtl_amd64.S)
  58   # Pass ASM file directly to the C++ compiler.
  59   set_source_files_properties(${TSAN_ASM_SOURCES} PROPERTIES
  60     LANGUAGE C)
  61   set(arch "x86_64")
  62   add_compiler_rt_static_runtime(clang_rt.tsan-${arch} ${arch}
  63     SOURCES ${TSAN_SOURCES} ${TSAN_ASM_SOURCES}
  64             $<TARGET_OBJECTS:RTInterception.${arch}>
  65             $<TARGET_OBJECTS:RTSanitizerCommon.${arch}>
  66             $<TARGET_OBJECTS:RTSanitizerCommonLibc.${arch}>
  67     CFLAGS ${TSAN_RTL_CFLAGS}
  68     DEFS ${TSAN_COMMON_DEFINITIONS})
  69   add_sanitizer_rt_symbols(clang_rt.tsan-${arch} rtl/tsan.syms.extra)
  70   add_dependencies(tsan clang_rt.tsan-${arch}
  71     clang_rt.tsan-${arch}-symbols)
  72 endif()
  73
  74 if(LLVM_INCLUDE_TESTS)
  75   add_subdirectory(tests)
  76 endif()