lib/sanitizer_common/CMakeLists.txt

   1 # Build system for the common Sanitizer runtime support library components.
   2 # These components are shared between AddressSanitizer and ThreadSanitizer.
   3
   4 set(SANITIZER_SOURCES
   5   sanitizer_allocator.cc
   6   sanitizer_common.cc
   7   sanitizer_coverage.cc
   8   sanitizer_deadlock_detector1.cc
   9   sanitizer_deadlock_detector2.cc
  10   sanitizer_flags.cc
  11   sanitizer_libc.cc
  12   sanitizer_libignore.cc
  13   sanitizer_linux.cc
  14   sanitizer_mac.cc
  15   sanitizer_platform_limits_linux.cc
  16   sanitizer_platform_limits_posix.cc
  17   sanitizer_posix.cc
  18   sanitizer_printf.cc
  19   sanitizer_procmaps_linux.cc
  20   sanitizer_procmaps_mac.cc
  21   sanitizer_stackdepot.cc
  22   sanitizer_stacktrace.cc
  23   sanitizer_suppressions.cc
  24   sanitizer_symbolizer.cc
  25   sanitizer_symbolizer_libbacktrace.cc
  26   sanitizer_symbolizer_win.cc
  27   sanitizer_tls_get_addr.cc
  28   sanitizer_thread_registry.cc
  29   sanitizer_win.cc)
  30
  31 set(SANITIZER_LIBCDEP_SOURCES
  32   sanitizer_common_libcdep.cc
  33   sanitizer_linux_libcdep.cc
  34   sanitizer_posix_libcdep.cc
  35   sanitizer_stacktrace_libcdep.cc
  36   sanitizer_stoptheworld_linux_libcdep.cc
  37   sanitizer_symbolizer_libcdep.cc
  38   sanitizer_symbolizer_posix_libcdep.cc)
  39
  40 # Explicitly list all sanitizer_common headers. Not all of these are
  41 # included in sanitizer_common source files, but we need to depend on
  42 # headers when building our custom unit tests.
  43 set(SANITIZER_HEADERS
  44   sanitizer_addrhashmap.h
  45   sanitizer_allocator.h
  46   sanitizer_allocator_internal.h
  47   sanitizer_atomic.h
  48   sanitizer_atomic_clang.h
  49   sanitizer_atomic_msvc.h
  50   sanitizer_bitvector.h
  51   sanitizer_bvgraph.h
  52   sanitizer_common.h
  53   sanitizer_common_interceptors.inc
  54   sanitizer_common_interceptors_ioctl.inc
  55   sanitizer_common_interceptors_format.inc
  56   sanitizer_common_syscalls.inc
  57   sanitizer_deadlock_detector.h
  58   sanitizer_deadlock_detector_interface.h
  59   sanitizer_flags.h
  60   sanitizer_internal_defs.h
  61   sanitizer_lfstack.h
  62   sanitizer_libc.h
  63   sanitizer_libignore.h
  64   sanitizer_linux.h
  65   sanitizer_list.h
  66   sanitizer_mac.h
  67   sanitizer_mutex.h
  68   sanitizer_placement_new.h
  69   sanitizer_platform.h
  70   sanitizer_platform_interceptors.h
  71   sanitizer_platform_limits_posix.h
  72   sanitizer_procmaps.h
  73   sanitizer_quarantine.h
  74   sanitizer_report_decorator.h
  75   sanitizer_stackdepot.h
  76   sanitizer_stacktrace.h
  77   sanitizer_stoptheworld.h
  78   sanitizer_suppressions.h
  79   sanitizer_symbolizer.h
  80   sanitizer_symbolizer_libbacktrace.h
  81   sanitizer_syscall_generic.inc
  82   sanitizer_syscall_linux_x86_64.inc
  83   sanitizer_thread_registry.h)
  84
  85 set(SANITIZER_COMMON_DEFINITIONS)
  86
  87 if(MSVC)
  88   list(APPEND SANITIZER_COMMON_DEFINITIONS
  89     SANITIZER_NEEDS_SEGV=0)
  90 else()
  91   list(APPEND SANITIZER_COMMON_DEFINITIONS
  92     SANITIZER_NEEDS_SEGV=1)
  93 endif()
  94
  95 set(SANITIZER_CFLAGS ${SANITIZER_COMMON_CFLAGS})
  96 append_no_rtti_flag(SANITIZER_CFLAGS)
  97
  98 append_if(COMPILER_RT_HAS_WFRAME_LARGER_THAN_FLAG -Wframe-larger-than=512 SANITIZER_CFLAGS)
  99 append_if(COMPILER_RT_HAS_WGLOBAL_CONSTRUCTORS_FLAG -Wglobal-constructors SANITIZER_CFLAGS)
 100
 101 add_custom_target(sanitizer_common)
 102 set(SANITIZER_RUNTIME_LIBRARIES)
 103 if(APPLE)
 104   # Build universal binary on APPLE.
 105   foreach(os ${SANITIZER_COMMON_SUPPORTED_DARWIN_OS})
 106     add_compiler_rt_darwin_object_library(RTSanitizerCommon ${os}
 107       ARCH ${SANITIZER_COMMON_SUPPORTED_ARCH}
 108       SOURCES ${SANITIZER_SOURCES} ${SANITIZER_LIBCDEP_SOURCES}
 109       CFLAGS ${SANITIZER_CFLAGS}
 110       DEFS ${SANITIZER_COMMON_DEFINITIONS})
 111     list(APPEND SANITIZER_RUNTIME_LIBRARIES RTSanitizerCommon.${os})
 112   endforeach()
 113 elseif(ANDROID)
 114   add_library(RTSanitizerCommon.arm.android OBJECT
 115     ${SANITIZER_SOURCES} ${SANITIZER_LIBCDEP_SOURCES})
 116   set_target_compile_flags(RTSanitizerCommon.arm.android
 117     ${SANITIZER_CFLAGS})
 118   set_property(TARGET RTSanitizerCommon.arm.android APPEND PROPERTY
 119     COMPILE_DEFINITIONS ${SANITIZER_COMMON_DEFINITIONS})
 120   list(APPEND SANITIZER_RUNTIME_LIBRARIES RTSanitizerCommon.arm.android)
 121 else()
 122   # Otherwise, build separate libraries for each target.
 123   foreach(arch ${SANITIZER_COMMON_SUPPORTED_ARCH})
 124     add_compiler_rt_object_library(RTSanitizerCommon ${arch}
 125       SOURCES ${SANITIZER_SOURCES} CFLAGS ${SANITIZER_CFLAGS}
 126       DEFS ${SANITIZER_COMMON_DEFINITIONS})
 127     add_compiler_rt_object_library(RTSanitizerCommonLibc ${arch}
 128       SOURCES ${SANITIZER_LIBCDEP_SOURCES} CFLAGS ${SANITIZER_CFLAGS}
 129       DEFS ${SANITIZER_COMMON_DEFINITIONS})
 130     list(APPEND SANITIZER_RUNTIME_LIBRARIES RTSanitizerCommon.${arch}
 131                                             RTSanitizerCommonLibc.${arch})
 132     add_compiler_rt_static_runtime(clang_rt.san-${arch} ${arch}
 133       SOURCES $<TARGET_OBJECTS:RTSanitizerCommon.${arch}>
 134               $<TARGET_OBJECTS:RTSanitizerCommonLibc.${arch}>
 135       CFLAGS ${SANITIZER_CFLAGS}
 136       DEFS ${SANITIZER_COMMON_DEFINITIONS})
 137     add_dependencies(sanitizer_common clang_rt.san-${arch})
 138   endforeach()
 139 endif()
 140
 141 add_dependencies(compiler-rt sanitizer_common)
 142
 143 # Unit tests for common sanitizer runtime.
 144 if(COMPILER_RT_INCLUDE_TESTS)
 145   add_subdirectory(tests)
 146 endif()