CMakeLists.txt

   1 # CMake build for CompilerRT.
   2 #
   3 # This build assumes that CompilerRT is checked out into the
   4 # 'projects/compiler-rt' inside of an LLVM tree.
   5 # Standalone build system for CompilerRT is not yet ready.
   6 #
   7 # An important constraint of the build is that it only produces libraries
   8 # based on the ability of the host toolchain to target various platforms.
   9
  10 # Check if compiler-rt is built as a standalone project.
  11 if (CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
  12   project(CompilerRT)
  13   set(COMPILER_RT_STANDALONE_BUILD TRUE)
  14 else()
  15   set(COMPILER_RT_STANDALONE_BUILD FALSE)
  16 endif()
  17
  18 # The CompilerRT build system requires CMake version 2.8.8 or higher in order
  19 # to use its support for building convenience "libraries" as a collection of
  20 # .o files. This is particularly useful in producing larger, more complex
  21 # runtime libraries.
  22 if (NOT MSVC)
  23   cmake_minimum_required(VERSION 2.8.8)
  24 else()
  25   # Version 2.8.12.1 is required to build with Visual Studion 2013.
  26   cmake_minimum_required(VERSION 2.8.12.1)
  27 endif()
  28
  29 # FIXME: It may be removed when we use 2.8.12.
  30 if(CMAKE_VERSION VERSION_LESS 2.8.12)
  31   # Invalidate a couple of keywords.
  32   set(cmake_2_8_12_INTERFACE)
  33   set(cmake_2_8_12_PRIVATE)
  34 else()
  35   # Use ${cmake_2_8_12_KEYWORD} intead of KEYWORD in target_link_libraries().
  36   set(cmake_2_8_12_INTERFACE INTERFACE)
  37   set(cmake_2_8_12_PRIVATE PRIVATE)
  38   if(POLICY CMP0022)
  39     cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  40   endif()
  41 endif()
  42
  43 # Top level target used to build all compiler-rt libraries.
  44 add_custom_target(compiler-rt ALL)
  45
  46 if (NOT COMPILER_RT_STANDALONE_BUILD)
  47   # Compute the Clang version from the LLVM version.
  48   # FIXME: We should be able to reuse CLANG_VERSION variable calculated
  49   #        in Clang cmake files, instead of copying the rules here.
  50   string(REGEX MATCH "[0-9]+\\.[0-9]+(\\.[0-9]+)?" CLANG_VERSION
  51          ${PACKAGE_VERSION})
  52   # Setup the paths where compiler-rt runtimes and headers should be stored.
  53   set(COMPILER_RT_OUTPUT_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR}/clang/${CLANG_VERSION})
  54   set(COMPILER_RT_EXEC_OUTPUT_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
  55   set(COMPILER_RT_INSTALL_PATH lib${LLVM_LIBDIR_SUFFIX}/clang/${CLANG_VERSION})
  56   option(COMPILER_RT_INCLUDE_TESTS "Generate and build compiler-rt unit tests."
  57          ${LLVM_INCLUDE_TESTS})
  58  option(COMPILER_RT_ENABLE_WERROR "Fail and stop if warning is triggered"
  59         ${LLVM_ENABLE_WERROR})
  60   # Use just-built Clang to compile/link tests.
  61   set(COMPILER_RT_TEST_COMPILER ${LLVM_RUNTIME_OUTPUT_INTDIR}/clang)
  62   set(COMPILER_RT_TEST_COMPILER_ID Clang)
  63 else()
  64   # Take output dir and install path from the user.
  65   set(COMPILER_RT_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR} CACHE PATH
  66     "Path where built compiler-rt libraries should be stored.")
  67   set(COMPILER_RT_EXEC_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/bin CACHE PATH
  68     "Path where built compiler-rt executables should be stored.")
  69   set(COMPILER_RT_INSTALL_PATH ${CMAKE_INSTALL_PREFIX} CACHE PATH
  70     "Path where built compiler-rt libraries should be installed.")
  71   option(COMPILER_RT_INCLUDE_TESTS "Generate and build compiler-rt unit tests." OFF)
  72   option(COMPILER_RT_ENABLE_WERROR "Fail and stop if warning is triggered" OFF)
  73   # Use a host compiler to compile/link tests.
  74   set(COMPILER_RT_TEST_COMPILER ${CMAKE_C_COMPILER})
  75   set(COMPILER_RT_TEST_COMPILER_ID ${CMAKE_C_COMPILER_ID})
  76
  77   if (NOT LLVM_CONFIG_PATH)
  78     find_program(LLVM_CONFIG_PATH "llvm-config"
  79                  DOC "Path to llvm-config binary")
  80     if (NOT LLVM_CONFIG_PATH)
  81       message(FATAL_ERROR "llvm-config not found: specify LLVM_CONFIG_PATH")
  82     endif()
  83   endif()
  84   execute_process(
  85     COMMAND ${LLVM_CONFIG_PATH} "--obj-root" "--bindir" "--libdir" "--src-root"
  86     RESULT_VARIABLE HAD_ERROR
  87     OUTPUT_VARIABLE CONFIG_OUTPUT)
  88   if (HAD_ERROR)
  89     message(FATAL_ERROR "llvm-config failed with status ${HAD_ERROR}")
  90   endif()
  91   string(REGEX REPLACE "[ \t]*[\r\n]+[ \t]*" ";" CONFIG_OUTPUT ${CONFIG_OUTPUT})
  92   list(GET CONFIG_OUTPUT 0 LLVM_BINARY_DIR)
  93   list(GET CONFIG_OUTPUT 1 LLVM_TOOLS_BINARY_DIR)
  94   list(GET CONFIG_OUTPUT 2 LLVM_LIBRARY_DIR)
  95   list(GET CONFIG_OUTPUT 3 LLVM_MAIN_SRC_DIR)
  96
  97   # Make use of LLVM CMake modules.
  98   file(TO_CMAKE_PATH ${LLVM_BINARY_DIR} LLVM_BINARY_DIR_CMAKE_STYLE)
  99   set(LLVM_CMAKE_PATH "${LLVM_BINARY_DIR_CMAKE_STYLE}/share/llvm/cmake")
 100   list(APPEND CMAKE_MODULE_PATH "${LLVM_CMAKE_PATH}")
 101   # Get some LLVM variables from LLVMConfig.
 102   include("${LLVM_CMAKE_PATH}/LLVMConfig.cmake")
 103
 104   set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib)
 105
 106   # Find Python interpreter.
 107   set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5)
 108   include(FindPythonInterp)
 109   if(NOT PYTHONINTERP_FOUND)
 110     message(FATAL_ERROR "
 111       Unable to find Python interpreter required testing. Please install Python
 112       or specify the PYTHON_EXECUTABLE CMake variable.")
 113   endif()
 114
 115   # Define default arguments to lit.
 116   set(LIT_ARGS_DEFAULT "-sv")
 117   if (MSVC OR XCODE)
 118     set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 119   endif()
 120   set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 121 endif()
 122
 123 string(TOLOWER ${CMAKE_SYSTEM_NAME} COMPILER_RT_OS_DIR)
 124 set(COMPILER_RT_LIBRARY_OUTPUT_DIR
 125   ${COMPILER_RT_OUTPUT_DIR}/lib/${COMPILER_RT_OS_DIR})
 126 set(COMPILER_RT_LIBRARY_INSTALL_DIR
 127   ${COMPILER_RT_INSTALL_PATH}/lib/${COMPILER_RT_OS_DIR})
 128
 129 # Add path for custom compiler-rt modules.
 130 set(CMAKE_MODULE_PATH
 131   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 132   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules"
 133   ${CMAKE_MODULE_PATH}
 134   )
 135 include(CompilerRTUtils)
 136
 137 set(COMPILER_RT_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
 138 set(COMPILER_RT_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
 139 # Setup custom SDK sysroots.
 140 set(COMPILER_RT_DARWIN_SDK_SYSROOT ${COMPILER_RT_SOURCE_DIR}/SDKs/darwin)
 141 set(COMPILER_RT_LINUX_SDK_SYSROOT ${COMPILER_RT_SOURCE_DIR}/SDKs/linux)
 142
 143 set(COMPILER_RT_EXTRA_ANDROID_HEADERS ${COMPILER_RT_SOURCE_DIR}/third_party/android/include)
 144
 145 # Detect whether the current target platform is 32-bit or 64-bit, and setup
 146 # the correct commandline flags needed to attempt to target 32-bit and 64-bit.
 147 if (NOT CMAKE_SIZEOF_VOID_P EQUAL 4 AND
 148     NOT CMAKE_SIZEOF_VOID_P EQUAL 8)
 149   message(FATAL_ERROR "Please use architecture with 4 or 8 byte pointers.")
 150 endif()
 151 if (NOT MSVC)
 152   set(TARGET_64_BIT_CFLAGS "-m64")
 153   set(TARGET_32_BIT_CFLAGS "-m32")
 154 else()
 155   set(TARGET_64_BIT_CFLAGS "")
 156   set(TARGET_32_BIT_CFLAGS "")
 157 endif()
 158
 159 # List of architectures we can target.
 160 set(COMPILER_RT_SUPPORTED_ARCH)
 161
 162 function(get_target_flags_for_arch arch out_var)
 163   list(FIND COMPILER_RT_SUPPORTED_ARCH ${arch} ARCH_INDEX)
 164   if(ARCH_INDEX EQUAL -1)
 165     message(FATAL_ERROR "Unsupported architecture: ${arch}")
 166   else()
 167     set(${out_var} ${TARGET_${arch}_CFLAGS} PARENT_SCOPE)
 168   endif()
 169 endfunction()
 170
 171 # Try to compile a very simple source file to ensure we can target the given
 172 # platform. We use the results of these tests to build only the various target
 173 # runtime libraries supported by our current compilers cross-compiling
 174 # abilities.
 175 set(SIMPLE_SOURCE ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/simple.c)
 176 file(WRITE ${SIMPLE_SOURCE} "#include <stdlib.h>\nint main() {}")
 177
 178 # test_target_arch(<arch> <target flags...>)
 179 # Sets the target flags for a given architecture and determines if this
 180 # architecture is supported by trying to build a simple file.
 181 macro(test_target_arch arch)
 182   set(TARGET_${arch}_CFLAGS ${ARGN})
 183   try_compile(CAN_TARGET_${arch} ${CMAKE_BINARY_DIR} ${SIMPLE_SOURCE}
 184               COMPILE_DEFINITIONS "${TARGET_${arch}_CFLAGS}"
 185               CMAKE_FLAGS "-DCMAKE_EXE_LINKER_FLAGS:STRING=${TARGET_${arch}_CFLAGS}")
 186   if(${CAN_TARGET_${arch}})
 187     list(APPEND COMPILER_RT_SUPPORTED_ARCH ${arch})
 188   endif()
 189 endmacro()
 190
 191 if(ANDROID_COMMON_FLAGS)
 192   test_target_arch(arm_android "${ANDROID_COMMON_FLAGS}")
 193 else()
 194   if("${LLVM_NATIVE_ARCH}" STREQUAL "X86")
 195     if (NOT MSVC)
 196       test_target_arch(x86_64 ${TARGET_64_BIT_CFLAGS})
 197     endif()
 198     test_target_arch(i386 ${TARGET_32_BIT_CFLAGS})
 199   elseif("${LLVM_NATIVE_ARCH}" STREQUAL "PowerPC")
 200     test_target_arch(powerpc64 ${TARGET_64_BIT_CFLAGS})
 201   elseif("${LLVM_NATIVE_ARCH}" STREQUAL "ARM")
 202     test_target_arch(arm "")
 203   endif()
 204 endif()
 205
 206 # We only support running instrumented tests when we're not cross compiling
 207 # and target a unix-like system. We can run tests on Android even when we are
 208 # cross-compiling.
 209 if(("${CMAKE_HOST_SYSTEM}" STREQUAL "${CMAKE_SYSTEM}" AND UNIX) OR ANDROID)
 210   option(COMPILER_RT_CAN_EXECUTE_TESTS "Can we execute instrumented tests" ON)
 211 else()
 212   option(COMPILER_RT_CAN_EXECUTE_TESTS "Can we execute instrumented tests" OFF)
 213 endif()
 214
 215 # Check if compiler-rt is built with libc++.
 216 find_flag_in_string("${CMAKE_CXX_FLAGS}" "-stdlib=libc++"
 217                     COMPILER_RT_USES_LIBCXX)
 218
 219 function(filter_available_targets out_var)
 220   set(archs)
 221   foreach(arch ${ARGN})
 222     list(FIND COMPILER_RT_SUPPORTED_ARCH ${arch} ARCH_INDEX)
 223     if(NOT (ARCH_INDEX EQUAL -1) AND CAN_TARGET_${arch})
 224       list(APPEND archs ${arch})
 225     endif()
 226   endforeach()
 227   set(${out_var} ${archs} PARENT_SCOPE)
 228 endfunction()
 229
 230 option(COMPILER_RT_DEBUG "Build runtimes with full debug info" OFF)
 231 # COMPILER_RT_DEBUG_PYBOOL is used by lit.common.configured.in.
 232 pythonize_bool(COMPILER_RT_DEBUG)
 233
 234 #================================
 235 # Setup Compiler Flags
 236 #================================
 237 include(config-ix)
 238
 239 if(MSVC)
 240   append_string_if(COMPILER_RT_HAS_W3_FLAG /W3 CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 241 else()
 242   append_string_if(COMPILER_RT_HAS_WALL_FLAG -Wall CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 243 endif()
 244 if(COMPILER_RT_ENABLE_WERROR)
 245   append_string_if(COMPILER_RT_HAS_WERROR_FLAG -Werror CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 246   append_string_if(COMPILER_RT_HAS_WX_FLAG /WX CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 247 endif()
 248
 249 # Emulate C99 and C++11's __func__ for MSVC prior to 2013 CTP.
 250 if(NOT COMPILER_RT_HAS_FUNC_SYMBOL)
 251   add_definitions(-D__func__=__FUNCTION__)
 252 endif()
 253
 254 # Provide some common commmandline flags for Sanitizer runtimes.
 255 append_if(COMPILER_RT_HAS_FPIC_FLAG -fPIC SANITIZER_COMMON_CFLAGS)
 256 append_if(COMPILER_RT_HAS_FNO_BUILTIN_FLAG -fno-builtin SANITIZER_COMMON_CFLAGS)
 257 append_if(COMPILER_RT_HAS_FNO_EXCEPTIONS_FLAG -fno-exceptions SANITIZER_COMMON_CFLAGS)
 258 append_if(COMPILER_RT_HAS_FOMIT_FRAME_POINTER_FLAG -fomit-frame-pointer SANITIZER_COMMON_CFLAGS)
 259 append_if(COMPILER_RT_HAS_FUNWIND_TABLES_FLAG -funwind-tables SANITIZER_COMMON_CFLAGS)
 260 append_if(COMPILER_RT_HAS_FNO_STACK_PROTECTOR_FLAG -fno-stack-protector SANITIZER_COMMON_CFLAGS)
 261 append_if(COMPILER_RT_HAS_FVISIBILITY_HIDDEN_FLAG -fvisibility=hidden SANITIZER_COMMON_CFLAGS)
 262 append_if(COMPILER_RT_HAS_FNO_FUNCTION_SECTIONS_FLAG -fno-function-sections SANITIZER_COMMON_CFLAGS)
 263
 264 if(MSVC)
 265   # Remove /MD flag so that it doesn't conflict with /MT.
 266   if(COMPILER_RT_HAS_MT_FLAG)
 267     string(REGEX REPLACE "(^| ) */MDd? *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 268     list(APPEND SANITIZER_COMMON_CFLAGS /MT)
 269   endif()
 270   append_if(COMPILER_RT_HAS_Oy_FLAG /Oy- SANITIZER_COMMON_CFLAGS)
 271   append_if(COMPILER_RT_HAS_GS_FLAG /GS- SANITIZER_COMMON_CFLAGS)
 272 endif()
 273
 274 # Build with optimization, unless we're in debug mode. If we're using MSVC,
 275 # always respect the optimization flags set by CMAKE_BUILD_TYPE instead.
 276 if(NOT COMPILER_RT_DEBUG AND NOT MSVC)
 277   list(APPEND SANITIZER_COMMON_CFLAGS -O3)
 278 endif()
 279
 280 # Build sanitizer runtimes with debug info.
 281 if(COMPILER_RT_HAS_GLINE_TABLES_ONLY_FLAG)
 282   list(APPEND SANITIZER_COMMON_CFLAGS -gline-tables-only)
 283 elseif(COMPILER_RT_HAS_G_FLAG)
 284   list(APPEND SANITIZER_COMMON_CFLAGS -g)
 285 elseif(COMPILER_RT_HAS_Zi_FLAG)
 286   list(APPEND SANITIZER_COMMON_CFLAGS /Zi)
 287 endif()
 288
 289 # Turn off several warnings.
 290 append_if(COMPILER_RT_HAS_WNO_GNU_FLAG -Wno-gnu SANITIZER_COMMON_CFLAGS)
 291 append_if(COMPILER_RT_HAS_WNO_VARIADIC_MACROS_FLAG -Wno-variadic-macros SANITIZER_COMMON_CFLAGS)
 292 append_if(COMPILER_RT_HAS_WNO_C99_EXTENSIONS_FLAG -Wno-c99-extensions SANITIZER_COMMON_CFLAGS)
 293 append_if(COMPILER_RT_HAS_WNO_NON_VIRTUAL_DTOR_FLAG -Wno-non-virtual-dtor SANITIZER_COMMON_CFLAGS)
 294 append_if(COMPILER_RT_HAS_WD4722_FLAG /wd4722 SANITIZER_COMMON_CFLAGS)
 295
 296 if(APPLE)
 297   # Obtain the iOS Simulator SDK path from xcodebuild.
 298   execute_process(
 299     COMMAND xcodebuild -version -sdk iphonesimulator Path
 300     OUTPUT_VARIABLE IOSSIM_SDK_DIR
 301     OUTPUT_STRIP_TRAILING_WHITESPACE
 302   )
 303   string(REGEX MATCH "-mmacosx-version-min="
 304          MACOSX_VERSION_MIN_FLAG "${CMAKE_CXX_FLAGS}")
 305   set(SANITIZER_COMMON_SUPPORTED_DARWIN_OS osx)
 306   if (IOSSIM_SDK_DIR AND NOT MACOSX_VERSION_MIN_FLAG)
 307     list(APPEND SANITIZER_COMMON_SUPPORTED_DARWIN_OS iossim)
 308   endif()
 309
 310   if(COMPILER_RT_USES_LIBCXX)
 311     set(SANITIZER_MIN_OSX_VERSION 10.7)
 312   else()
 313     set(SANITIZER_MIN_OSX_VERSION 10.6)
 314   endif()
 315   set(DARWIN_osx_CFLAGS -mmacosx-version-min=${SANITIZER_MIN_OSX_VERSION})
 316   set(DARWIN_iossim_CFLAGS
 317     -mios-simulator-version-min=7.0 -isysroot ${IOSSIM_SDK_DIR})
 318   set(DARWIN_osx_LINKFLAGS)
 319   set(DARWIN_iossim_LINKFLAGS
 320     -Wl,-ios_simulator_version_min,7.0.0
 321     -mios-simulator-version-min=7.0
 322     -isysroot ${IOSSIM_SDK_DIR})
 323 endif()
 324
 325 # Architectures supported by Sanitizer runtimes. Specific sanitizers may
 326 # support only subset of these (e.g. TSan works on x86_64 only).
 327 filter_available_targets(SANITIZER_COMMON_SUPPORTED_ARCH
 328   x86_64 i386 powerpc64 arm)
 329 filter_available_targets(ASAN_SUPPORTED_ARCH x86_64 i386 powerpc64)
 330 filter_available_targets(DFSAN_SUPPORTED_ARCH x86_64)
 331 filter_available_targets(LSAN_SUPPORTED_ARCH x86_64)
 332 filter_available_targets(MSAN_SUPPORTED_ARCH x86_64)
 333 filter_available_targets(TSAN_SUPPORTED_ARCH x86_64)
 334 filter_available_targets(UBSAN_SUPPORTED_ARCH x86_64 i386)
 335
 336 add_subdirectory(include)
 337
 338 set(COMPILER_RT_LIBCXX_PATH ${LLVM_MAIN_SRC_DIR}/projects/libcxx)
 339 if(EXISTS ${COMPILER_RT_LIBCXX_PATH}/)
 340   set(COMPILER_RT_HAS_LIBCXX_SOURCES TRUE)
 341 else()
 342   set(COMPILER_RT_HAS_LIBCXX_SOURCES FALSE)
 343 endif()
 344
 345 add_subdirectory(lib)
 346
 347 if(COMPILER_RT_INCLUDE_TESTS)
 348   add_subdirectory(unittests)
 349 endif()
 350 add_subdirectory(test)