CMakeLists.txt

   1 # CMake build for CompilerRT.
   2 #
   3 # This build assumes that CompilerRT is checked out into the
   4 # 'projects/compiler-rt' inside of an LLVM tree.
   5 # Standalone build system for CompilerRT is not yet ready.
   6 #
   7 # An important constraint of the build is that it only produces libraries
   8 # based on the ability of the host toolchain to target various platforms.
   9
  10 # Check if compiler-rt is built as a standalone project.
  11 if (CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
  12   project(CompilerRT)
  13   set(COMPILER_RT_STANDALONE_BUILD TRUE)
  14 else()
  15   set(COMPILER_RT_STANDALONE_BUILD FALSE)
  16 endif()
  17
  18 # The CompilerRT build system requires CMake version 2.8.8 or higher in order
  19 # to use its support for building convenience "libraries" as a collection of
  20 # .o files. This is particularly useful in producing larger, more complex
  21 # runtime libraries.
  22 if (NOT MSVC)
  23   cmake_minimum_required(VERSION 2.8.8)
  24 else()
  25   # Version 2.8.12.1 is required to build with Visual Studion 2013.
  26   cmake_minimum_required(VERSION 2.8.12.1)
  27 endif()
  28
  29 # FIXME: It may be removed when we use 2.8.12.
  30 if(CMAKE_VERSION VERSION_LESS 2.8.12)
  31   # Invalidate a couple of keywords.
  32   set(cmake_2_8_12_INTERFACE)
  33   set(cmake_2_8_12_PRIVATE)
  34 else()
  35   # Use ${cmake_2_8_12_KEYWORD} intead of KEYWORD in target_link_libraries().
  36   set(cmake_2_8_12_INTERFACE INTERFACE)
  37   set(cmake_2_8_12_PRIVATE PRIVATE)
  38   if(POLICY CMP0022)
  39     cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  40   endif()
  41 endif()
  42
  43 # Top level target used to build all compiler-rt libraries.
  44 add_custom_target(compiler-rt ALL)
  45
  46 if (NOT COMPILER_RT_STANDALONE_BUILD)
  47   # Compute the Clang version from the LLVM version.
  48   # FIXME: We should be able to reuse CLANG_VERSION variable calculated
  49   #        in Clang cmake files, instead of copying the rules here.
  50   string(REGEX MATCH "[0-9]+\\.[0-9]+(\\.[0-9]+)?" CLANG_VERSION
  51          ${PACKAGE_VERSION})
  52   # Setup the paths where compiler-rt runtimes and headers should be stored.
  53   set(COMPILER_RT_OUTPUT_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR}/clang/${CLANG_VERSION})
  54   set(COMPILER_RT_EXEC_OUTPUT_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
  55   set(COMPILER_RT_INSTALL_PATH lib${LLVM_LIBDIR_SUFFIX}/clang/${CLANG_VERSION})
  56   option(COMPILER_RT_INCLUDE_TESTS "Generate and build compiler-rt unit tests."
  57          ${LLVM_INCLUDE_TESTS})
  58  option(COMPILER_RT_ENABLE_WERROR "Fail and stop if warning is triggered"
  59         ${LLVM_ENABLE_WERROR})
  60   # Use just-built Clang to compile/link tests.
  61   set(COMPILER_RT_TEST_COMPILER ${LLVM_RUNTIME_OUTPUT_INTDIR}/clang)
  62 else()
  63   # Take output dir and install path from the user.
  64   set(COMPILER_RT_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR} CACHE PATH
  65     "Path where built compiler-rt libraries should be stored.")
  66   set(COMPILER_RT_EXEC_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/bin CACHE PATH
  67     "Path where built compiler-rt executables should be stored.")
  68   set(COMPILER_RT_INSTALL_PATH ${CMAKE_INSTALL_PREFIX} CACHE PATH
  69     "Path where built compiler-rt libraries should be installed.")
  70   option(COMPILER_RT_INCLUDE_TESTS "Generate and build compiler-rt unit tests." OFF)
  71   option(COMPILER_RT_ENABLE_WERROR "Fail and stop if warning is triggered" OFF)
  72   # Use a host compiler to compile/link tests.
  73   set(COMPILER_RT_TEST_COMPILER ${CMAKE_C_COMPILER} CACHE PATH "Compiler to use for testing")
  74
  75   if (NOT LLVM_CONFIG_PATH)
  76     find_program(LLVM_CONFIG_PATH "llvm-config"
  77                  DOC "Path to llvm-config binary")
  78     if (NOT LLVM_CONFIG_PATH)
  79       message(FATAL_ERROR "llvm-config not found: specify LLVM_CONFIG_PATH")
  80     endif()
  81   endif()
  82   execute_process(
  83     COMMAND ${LLVM_CONFIG_PATH} "--obj-root" "--bindir" "--libdir" "--src-root"
  84     RESULT_VARIABLE HAD_ERROR
  85     OUTPUT_VARIABLE CONFIG_OUTPUT)
  86   if (HAD_ERROR)
  87     message(FATAL_ERROR "llvm-config failed with status ${HAD_ERROR}")
  88   endif()
  89   string(REGEX REPLACE "[ \t]*[\r\n]+[ \t]*" ";" CONFIG_OUTPUT ${CONFIG_OUTPUT})
  90   list(GET CONFIG_OUTPUT 0 LLVM_BINARY_DIR)
  91   list(GET CONFIG_OUTPUT 1 LLVM_TOOLS_BINARY_DIR)
  92   list(GET CONFIG_OUTPUT 2 LLVM_LIBRARY_DIR)
  93   list(GET CONFIG_OUTPUT 3 LLVM_MAIN_SRC_DIR)
  94
  95   # Make use of LLVM CMake modules.
  96   file(TO_CMAKE_PATH ${LLVM_BINARY_DIR} LLVM_BINARY_DIR_CMAKE_STYLE)
  97   set(LLVM_CMAKE_PATH "${LLVM_BINARY_DIR_CMAKE_STYLE}/share/llvm/cmake")
  98   list(APPEND CMAKE_MODULE_PATH "${LLVM_CMAKE_PATH}")
  99   # Get some LLVM variables from LLVMConfig.
 100   include("${LLVM_CMAKE_PATH}/LLVMConfig.cmake")
 101
 102   set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib)
 103
 104   # Find Python interpreter.
 105   set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5)
 106   include(FindPythonInterp)
 107   if(NOT PYTHONINTERP_FOUND)
 108     message(FATAL_ERROR "
 109       Unable to find Python interpreter required testing. Please install Python
 110       or specify the PYTHON_EXECUTABLE CMake variable.")
 111   endif()
 112
 113   # Define default arguments to lit.
 114   set(LIT_ARGS_DEFAULT "-sv")
 115   if (MSVC OR XCODE)
 116     set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 117   endif()
 118   set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 119 endif()
 120
 121 if("${COMPILER_RT_TEST_COMPILER}" MATCHES "clang[+]*$")
 122   set(COMPILER_RT_TEST_COMPILER_ID Clang)
 123 else()
 124   set(COMPILER_RT_TEST_COMPILER_ID GNU)
 125 endif()
 126
 127 string(TOLOWER ${CMAKE_SYSTEM_NAME} COMPILER_RT_OS_DIR)
 128 set(COMPILER_RT_LIBRARY_OUTPUT_DIR
 129   ${COMPILER_RT_OUTPUT_DIR}/lib/${COMPILER_RT_OS_DIR})
 130 set(COMPILER_RT_LIBRARY_INSTALL_DIR
 131   ${COMPILER_RT_INSTALL_PATH}/lib/${COMPILER_RT_OS_DIR})
 132
 133 # Add path for custom compiler-rt modules.
 134 set(CMAKE_MODULE_PATH
 135   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 136   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules"
 137   ${CMAKE_MODULE_PATH}
 138   )
 139 include(CompilerRTUtils)
 140
 141 set(COMPILER_RT_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
 142 set(COMPILER_RT_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
 143 # Setup custom SDK sysroots.
 144 set(COMPILER_RT_DARWIN_SDK_SYSROOT ${COMPILER_RT_SOURCE_DIR}/SDKs/darwin)
 145 set(COMPILER_RT_LINUX_SDK_SYSROOT ${COMPILER_RT_SOURCE_DIR}/SDKs/linux)
 146
 147 set(COMPILER_RT_EXTRA_ANDROID_HEADERS ${COMPILER_RT_SOURCE_DIR}/android/include)
 148
 149 # Detect whether the current target platform is 32-bit or 64-bit, and setup
 150 # the correct commandline flags needed to attempt to target 32-bit and 64-bit.
 151 if (NOT CMAKE_SIZEOF_VOID_P EQUAL 4 AND
 152     NOT CMAKE_SIZEOF_VOID_P EQUAL 8)
 153   message(FATAL_ERROR "Please use architecture with 4 or 8 byte pointers.")
 154 endif()
 155 if (NOT MSVC)
 156   set(TARGET_64_BIT_CFLAGS "-m64")
 157   set(TARGET_32_BIT_CFLAGS "-m32")
 158 else()
 159   set(TARGET_64_BIT_CFLAGS "")
 160   set(TARGET_32_BIT_CFLAGS "")
 161 endif()
 162
 163 # List of architectures we can target.
 164 set(COMPILER_RT_SUPPORTED_ARCH)
 165
 166 function(get_target_flags_for_arch arch out_var)
 167   list(FIND COMPILER_RT_SUPPORTED_ARCH ${arch} ARCH_INDEX)
 168   if(ARCH_INDEX EQUAL -1)
 169     message(FATAL_ERROR "Unsupported architecture: ${arch}")
 170   else()
 171     set(${out_var} ${TARGET_${arch}_CFLAGS} PARENT_SCOPE)
 172   endif()
 173 endfunction()
 174
 175 # Try to compile a very simple source file to ensure we can target the given
 176 # platform. We use the results of these tests to build only the various target
 177 # runtime libraries supported by our current compilers cross-compiling
 178 # abilities.
 179 set(SIMPLE_SOURCE ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/simple.cc)
 180 file(WRITE ${SIMPLE_SOURCE} "#include <stdlib.h>\n#include <limits>\nint main() {}\n")
 181
 182 # test_target_arch(<arch> <target flags...>)
 183 # Sets the target flags for a given architecture and determines if this
 184 # architecture is supported by trying to build a simple file.
 185 macro(test_target_arch arch)
 186   set(TARGET_${arch}_CFLAGS ${ARGN})
 187   try_compile(CAN_TARGET_${arch} ${CMAKE_BINARY_DIR} ${SIMPLE_SOURCE}
 188               COMPILE_DEFINITIONS "${TARGET_${arch}_CFLAGS}"
 189               CMAKE_FLAGS "-DCMAKE_EXE_LINKER_FLAGS:STRING=${TARGET_${arch}_CFLAGS}")
 190   if(${CAN_TARGET_${arch}})
 191     list(APPEND COMPILER_RT_SUPPORTED_ARCH ${arch})
 192   endif()
 193 endmacro()
 194
 195 if(ANDROID_COMMON_FLAGS)
 196   test_target_arch(arm_android "${ANDROID_COMMON_FLAGS}")
 197 else()
 198   if("${LLVM_NATIVE_ARCH}" STREQUAL "X86")
 199     if (NOT MSVC)
 200       test_target_arch(x86_64 ${TARGET_64_BIT_CFLAGS})
 201     endif()
 202     test_target_arch(i386 ${TARGET_32_BIT_CFLAGS})
 203   elseif("${LLVM_NATIVE_ARCH}" STREQUAL "PowerPC")
 204     test_target_arch(powerpc64 ${TARGET_64_BIT_CFLAGS})
 205   elseif("${LLVM_NATIVE_ARCH}" STREQUAL "ARM")
 206     test_target_arch(arm "")
 207   endif()
 208 endif()
 209
 210 # We only support running instrumented tests when we're not cross compiling
 211 # and target a unix-like system. We can run tests on Android even when we are
 212 # cross-compiling.
 213 if(("${CMAKE_HOST_SYSTEM}" STREQUAL "${CMAKE_SYSTEM}" AND UNIX) OR ANDROID)
 214   option(COMPILER_RT_CAN_EXECUTE_TESTS "Can we execute instrumented tests" ON)
 215 else()
 216   option(COMPILER_RT_CAN_EXECUTE_TESTS "Can we execute instrumented tests" OFF)
 217 endif()
 218
 219 # Check if compiler-rt is built with libc++.
 220 find_flag_in_string("${CMAKE_CXX_FLAGS}" "-stdlib=libc++"
 221                     COMPILER_RT_USES_LIBCXX)
 222
 223 function(filter_available_targets out_var)
 224   set(archs)
 225   foreach(arch ${ARGN})
 226     list(FIND COMPILER_RT_SUPPORTED_ARCH ${arch} ARCH_INDEX)
 227     if(NOT (ARCH_INDEX EQUAL -1) AND CAN_TARGET_${arch})
 228       list(APPEND archs ${arch})
 229     endif()
 230   endforeach()
 231   set(${out_var} ${archs} PARENT_SCOPE)
 232 endfunction()
 233
 234 option(COMPILER_RT_DEBUG "Build runtimes with full debug info" OFF)
 235 # COMPILER_RT_DEBUG_PYBOOL is used by lit.common.configured.in.
 236 pythonize_bool(COMPILER_RT_DEBUG)
 237
 238 option(COMPILER_RT_BUILD_SHARED_ASAN "Build shared version of AddressSanitizer runtime" OFF)
 239
 240 #================================
 241 # Setup Compiler Flags
 242 #================================
 243 include(config-ix)
 244
 245 if(MSVC)
 246   append_string_if(COMPILER_RT_HAS_W3_FLAG /W3 CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 247 else()
 248   append_string_if(COMPILER_RT_HAS_WALL_FLAG -Wall CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 249 endif()
 250 if(COMPILER_RT_ENABLE_WERROR)
 251   append_string_if(COMPILER_RT_HAS_WERROR_FLAG -Werror CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 252   append_string_if(COMPILER_RT_HAS_WX_FLAG /WX CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 253 endif()
 254
 255 append_string_if(COMPILER_RT_HAS_STD_CXX11_FLAG -std=c++11 CMAKE_CXX_FLAGS)
 256
 257 # Emulate C99 and C++11's __func__ for MSVC prior to 2013 CTP.
 258 if(NOT COMPILER_RT_HAS_FUNC_SYMBOL)
 259   add_definitions(-D__func__=__FUNCTION__)
 260 endif()
 261
 262 # Provide some common commmandline flags for Sanitizer runtimes.
 263 append_if(COMPILER_RT_HAS_FPIC_FLAG -fPIC SANITIZER_COMMON_CFLAGS)
 264 append_if(COMPILER_RT_HAS_FNO_BUILTIN_FLAG -fno-builtin SANITIZER_COMMON_CFLAGS)
 265 append_if(COMPILER_RT_HAS_FNO_EXCEPTIONS_FLAG -fno-exceptions SANITIZER_COMMON_CFLAGS)
 266 append_if(COMPILER_RT_HAS_FOMIT_FRAME_POINTER_FLAG -fomit-frame-pointer SANITIZER_COMMON_CFLAGS)
 267 append_if(COMPILER_RT_HAS_FUNWIND_TABLES_FLAG -funwind-tables SANITIZER_COMMON_CFLAGS)
 268 append_if(COMPILER_RT_HAS_FNO_STACK_PROTECTOR_FLAG -fno-stack-protector SANITIZER_COMMON_CFLAGS)
 269 append_if(COMPILER_RT_HAS_FVISIBILITY_HIDDEN_FLAG -fvisibility=hidden SANITIZER_COMMON_CFLAGS)
 270 append_if(COMPILER_RT_HAS_FNO_FUNCTION_SECTIONS_FLAG -fno-function-sections SANITIZER_COMMON_CFLAGS)
 271
 272 if(MSVC)
 273   # Remove /MD flag so that it doesn't conflict with /MT.
 274   if(COMPILER_RT_HAS_MT_FLAG)
 275     string(REGEX REPLACE "(^| ) */MDd? *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 276     list(APPEND SANITIZER_COMMON_CFLAGS /MT)
 277   endif()
 278   append_if(COMPILER_RT_HAS_Oy_FLAG /Oy- SANITIZER_COMMON_CFLAGS)
 279   append_if(COMPILER_RT_HAS_GS_FLAG /GS- SANITIZER_COMMON_CFLAGS)
 280 endif()
 281
 282 # Build with optimization, unless we're in debug mode. If we're using MSVC,
 283 # always respect the optimization flags set by CMAKE_BUILD_TYPE instead.
 284 if(NOT COMPILER_RT_DEBUG AND NOT MSVC)
 285   list(APPEND SANITIZER_COMMON_CFLAGS -O3)
 286 endif()
 287
 288 # Build sanitizer runtimes with debug info.
 289 if(COMPILER_RT_HAS_GLINE_TABLES_ONLY_FLAG)
 290   list(APPEND SANITIZER_COMMON_CFLAGS -gline-tables-only)
 291 elseif(COMPILER_RT_HAS_G_FLAG)
 292   list(APPEND SANITIZER_COMMON_CFLAGS -g)
 293 elseif(COMPILER_RT_HAS_Zi_FLAG)
 294   list(APPEND SANITIZER_COMMON_CFLAGS /Zi)
 295 endif()
 296
 297 # Turn off several warnings.
 298 append_if(COMPILER_RT_HAS_WNO_GNU_FLAG -Wno-gnu SANITIZER_COMMON_CFLAGS)
 299 append_if(COMPILER_RT_HAS_WNO_VARIADIC_MACROS_FLAG -Wno-variadic-macros SANITIZER_COMMON_CFLAGS)
 300 append_if(COMPILER_RT_HAS_WNO_C99_EXTENSIONS_FLAG -Wno-c99-extensions SANITIZER_COMMON_CFLAGS)
 301 append_if(COMPILER_RT_HAS_WNO_NON_VIRTUAL_DTOR_FLAG -Wno-non-virtual-dtor SANITIZER_COMMON_CFLAGS)
 302 append_if(COMPILER_RT_HAS_WD4722_FLAG /wd4722 SANITIZER_COMMON_CFLAGS)
 303
 304 if(APPLE)
 305   # Obtain the iOS Simulator SDK path from xcodebuild.
 306   execute_process(
 307     COMMAND xcodebuild -version -sdk iphonesimulator Path
 308     OUTPUT_VARIABLE IOSSIM_SDK_DIR
 309     OUTPUT_STRIP_TRAILING_WHITESPACE
 310   )
 311   string(REGEX MATCH "-mmacosx-version-min="
 312          MACOSX_VERSION_MIN_FLAG "${CMAKE_CXX_FLAGS}")
 313   set(SANITIZER_COMMON_SUPPORTED_DARWIN_OS osx)
 314   if (IOSSIM_SDK_DIR AND NOT MACOSX_VERSION_MIN_FLAG)
 315     list(APPEND SANITIZER_COMMON_SUPPORTED_DARWIN_OS iossim)
 316   endif()
 317
 318   if(COMPILER_RT_USES_LIBCXX)
 319     set(SANITIZER_MIN_OSX_VERSION 10.7)
 320   else()
 321     set(SANITIZER_MIN_OSX_VERSION 10.6)
 322   endif()
 323   set(DARWIN_osx_CFLAGS -mmacosx-version-min=${SANITIZER_MIN_OSX_VERSION})
 324   set(DARWIN_iossim_CFLAGS
 325     -mios-simulator-version-min=7.0 -isysroot ${IOSSIM_SDK_DIR})
 326   set(DARWIN_osx_LINKFLAGS)
 327   set(DARWIN_iossim_LINKFLAGS
 328     -Wl,-ios_simulator_version_min,7.0.0
 329     -mios-simulator-version-min=7.0
 330     -isysroot ${IOSSIM_SDK_DIR})
 331 endif()
 332
 333 # Architectures supported by Sanitizer runtimes. Specific sanitizers may
 334 # support only subset of these (e.g. TSan works on x86_64 only).
 335 filter_available_targets(SANITIZER_COMMON_SUPPORTED_ARCH
 336   x86_64 i386 powerpc64 arm)
 337 filter_available_targets(ASAN_SUPPORTED_ARCH x86_64 i386 powerpc64)
 338 filter_available_targets(DFSAN_SUPPORTED_ARCH x86_64)
 339 filter_available_targets(LSAN_SUPPORTED_ARCH x86_64)
 340 filter_available_targets(MSAN_SUPPORTED_ARCH x86_64)
 341 filter_available_targets(PROFILE_SUPPORTED_ARCH x86_64 i386 arm)
 342 filter_available_targets(TSAN_SUPPORTED_ARCH x86_64)
 343 filter_available_targets(UBSAN_SUPPORTED_ARCH x86_64 i386)
 344
 345 add_subdirectory(include)
 346
 347 set(COMPILER_RT_LIBCXX_PATH ${LLVM_MAIN_SRC_DIR}/projects/libcxx)
 348 if(EXISTS ${COMPILER_RT_LIBCXX_PATH}/)
 349   set(COMPILER_RT_HAS_LIBCXX_SOURCES TRUE)
 350 else()
 351   set(COMPILER_RT_HAS_LIBCXX_SOURCES FALSE)
 352 endif()
 353
 354 add_subdirectory(lib)
 355
 356 if(COMPILER_RT_INCLUDE_TESTS)
 357   add_subdirectory(unittests)
 358 endif()
 359 add_subdirectory(test)